ui/accessibility/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/linux/pkg_config.gni")
   6 import("//build/config/ui.gni")
   7 import("//build/json_schema_api.gni")
   8 import("//testing/test.gni")
   9 if (is_android) {
  10   import("//build/config/android/rules.gni")
  11 }
  12
  13 if (use_x11) {
  14   pkg_config("atk") {
  15     packages = [ "atk" ]
  16     atk_lib_dir = exec_script(pkg_config_script,
  17                               [
  18                                 "--libdir",
  19                                 "atk",
  20                               ],
  21                               "string")
  22     defines = [ "ATK_LIB_DIR=\"$atk_lib_dir\"" ]
  23   }
  24
  25   # gn orders flags on a target before flags from configs. The default config
  26   # adds -Wall, and these flags have to be after -Wall -- so they need to come
  27   # from a config and can't be on the target directly.
  28   config("atk_warnings") {
  29     cflags = [
  30       # glib uses the pre-c++11 typedef-as-static_assert hack.
  31       "-Wno-unused-local-typedef",
  32
  33       # G_DEFINE_TYPE automatically generates a *get_instance_private
  34       # inline function after glib 2.37. That's unused. Prevent to
  35       # complain about it.
  36       "-Wno-unused-function",
  37     ]
  38   }
  39 }
  40
  41 component("accessibility") {
  42   sources = [
  43     "ax_node.cc",
  44     "ax_node.h",
  45     "ax_node_data.cc",
  46     "ax_node_data.h",
  47     "ax_serializable_tree.cc",
  48     "ax_serializable_tree.h",
  49     "ax_text_utils.cc",
  50     "ax_text_utils.h",
  51     "ax_tree.cc",
  52     "ax_tree.h",
  53     "ax_tree_serializer.cc",
  54     "ax_tree_serializer.h",
  55     "ax_tree_source.h",
  56     "ax_tree_update.h",
  57     "ax_view_state.cc",
  58     "ax_view_state.h",
  59     "platform/ax_platform_node.cc",
  60     "platform/ax_platform_node.h",
  61     "platform/ax_platform_node_base.cc",
  62     "platform/ax_platform_node_base.h",
  63     "platform/ax_platform_node_delegate.h",
  64     "platform/ax_platform_node_mac.h",
  65     "platform/ax_platform_node_mac.mm",
  66     "platform/ax_platform_node_win.cc",
  67     "platform/ax_platform_node_win.h",
  68   ]
  69
  70   defines = [ "ACCESSIBILITY_IMPLEMENTATION" ]
  71
  72   public_deps = [
  73     ":ax_gen",
  74     "//base",
  75     "//ui/gfx",
  76     "//ui/gfx/geometry",
  77   ]
  78
  79   if (is_win) {
  80     public_deps += [ "//third_party/iaccessible2" ]
  81   }
  82
  83   if (use_atk) {
  84     sources += [
  85       "platform/atk_util_auralinux.cc",
  86       "platform/atk_util_auralinux.h",
  87       "platform/ax_platform_node_auralinux.cc",
  88       "platform/ax_platform_node_auralinux.h",
  89     ]
  90
  91     configs += [
  92       ":atk",
  93       ":atk_warnings",
  94       "//build/config/linux:gconf",
  95       "//build/config/linux:glib",
  96     ]
  97   }
  98 }
  99
 100 if (is_android) {
 101   android_library("ui_accessibility_java") {
 102     deps = []
 103     srcjar_deps = [ ":ax_enumerations_srcjar" ]
 104   }
 105
 106   java_cpp_enum("ax_enumerations_srcjar") {
 107     sources = [
 108       "ax_enums.idl",
 109     ]
 110     outputs = [
 111       "org/chromium/ui/accessibility/AXTextStyle.java",
 112     ]
 113   }
 114 }
 115
 116 source_set("test_support") {
 117   sources = [
 118     "platform/test_ax_node_wrapper.cc",
 119     "platform/test_ax_node_wrapper.h",
 120     "tree_generator.cc",
 121     "tree_generator.h",
 122   ]
 123
 124   deps = [
 125     ":accessibility",
 126   ]
 127 }
 128
 129 # TODO(GYP): Delete this after we've converted everything to GN.
 130 # The _run targets exist only for compatibility w/ GYP.
 131 group("accessibility_unittests_run") {
 132   testonly = true
 133   deps = [
 134     ":accessibility_unittests",
 135   ]
 136 }
 137
 138 test("accessibility_unittests") {
 139   sources = [
 140     "ax_generated_tree_unittest.cc",
 141     "ax_text_utils_unittest.cc",
 142     "ax_tree_serializer_unittest.cc",
 143     "ax_tree_unittest.cc",
 144     "platform/ax_platform_node_win_unittest.cc",
 145   ]
 146
 147   deps = [
 148     ":accessibility",
 149     ":test_support",
 150     "//base",
 151     "//base/test:run_all_unittests",
 152     "//testing/gtest",
 153     "//ui/gfx",
 154     "//ui/gfx/geometry",
 155   ]
 156
 157   if (is_win) {
 158     deps += [ "//third_party/iaccessible2" ]
 159   }
 160 }
 161
 162 json_schema_api("ax_gen") {
 163   sources = [
 164     "ax_enums.idl",
 165   ]
 166   deps = [
 167     "//base/third_party/dynamic_annotations",
 168   ]
 169   root_namespace = "ui"
 170   schemas = true
 171 }