sandbox/mac/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 component("sandbox") {
   6   sources = [
   7     "bootstrap_sandbox.cc",
   8     "bootstrap_sandbox.h",
   9     "launchd_interception_server.cc",
  10     "launchd_interception_server.h",
  11     "mach_message_server.cc",
  12     "mach_message_server.h",
  13     "message_server.h",
  14     "os_compatibility.cc",
  15     "os_compatibility.h",
  16     "policy.cc",
  17     "policy.h",
  18     "xpc.h",
  19   ]
  20
  21   defines = [ "SANDBOX_IMPLEMENTATION" ]
  22   libs = [ "bsm" ]
  23
  24   deps = [
  25     "//base",
  26     ":generate_stubs",
  27   ]
  28 }
  29
  30 generate_stubs_script = "//tools/generate_stubs/generate_stubs.py"
  31 generate_stubs_header = "xpc_stubs_header.fragment"
  32 generate_stubs_sig_public = "xpc_stubs.sig"
  33 generate_stubs_sig_private = "xpc_private_stubs.sig"
  34 generate_stubs_project = "sandbox/mac"
  35 generate_stubs_output_stem = "xpc_stubs"
  36
  37 action("generate_stubs") {
  38   script = generate_stubs_script
  39   sources = [ generate_stubs_sig_public, generate_stubs_sig_private ]
  40   source_prereqs = [ generate_stubs_header ]
  41   outputs = [
  42     "$target_gen_dir/$generate_stubs_output_stem.cc",
  43     "$target_gen_dir/$generate_stubs_output_stem.h",
  44   ]
  45   args = [
  46     "-i", rebase_path(target_gen_dir, root_build_dir),
  47     "-o", rebase_path(target_gen_dir, root_build_dir),
  48     "-t", "posix_stubs",
  49     "-e", rebase_path(generate_stubs_header, root_build_dir),
  50     "-s", generate_stubs_output_stem,
  51     "-p", generate_stubs_project,
  52   ]
  53   args += rebase_path(sources, root_build_dir)
  54 }
  55
  56 test("sandbox_mac_unittests") {
  57   sources = [
  58     "bootstrap_sandbox_unittest.mm",
  59     "policy_unittest.cc",
  60   ]
  61
  62   libs = [
  63     "CoreFoundation.framework",
  64     "Foundation.framework",
  65   ]
  66
  67   deps = [
  68     ":sandbox",
  69     "//base",
  70     "//base/test:run_all_unittests",
  71     "//testing/gtest",
  72   ]
  73 }