content/browser/devtools/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/grit/grit_rule.gni")
   6
   7 # In GYP: devtools_resources target.
   8 group("resources") {
   9   deps = [
  10     ":devtools_resources",
  11     ":devtools_protocol_handler",
  12   ]
  13 }
  14
  15 # In GYP: devtools_resources action in the devtools_resources target.
  16 grit("devtools_resources") {
  17   source = "$root_gen_dir/devtools/devtools_resources.grd"
  18
  19   # TOOD(brettw) remove this so the output file goes into the target_gen_dir,
  20   # but keep this for not for GYP compat.
  21   output_dir = "$root_gen_dir/blink"
  22   outputs = [
  23     "grit/devtools_resources.h",
  24     "devtools_resources.pak",
  25     "grit/devtools_resources_map.cc",
  26     "grit/devtools_resources_map.h",
  27   ]
  28
  29   defines =
  30       [ "SHARED_INTERMEDIATE_DIR=" + rebase_path(root_gen_dir, root_build_dir) ]
  31
  32   deps = [
  33     # This is the action that generates out .grd input file.
  34     "//third_party/WebKit/public:blink_generate_devtools_grd",
  35   ]
  36 }
  37
  38 action("gen_devtools_protocol_handler") {
  39   visibility = [ ":devtools_protocol_handler" ]
  40
  41   script = "//content/browser/devtools/protocol/" +
  42            "devtools_protocol_handler_generator.py"
  43
  44   blink_protocol = "//third_party/WebKit/Source/devtools/protocol.json"
  45   browser_protocol = "browser_protocol.json"
  46   inputs = [
  47     blink_protocol,
  48     browser_protocol,
  49   ]
  50
  51   outputs = [
  52     "$target_gen_dir/protocol/devtools_protocol_dispatcher.cc",
  53     "$target_gen_dir/protocol/devtools_protocol_dispatcher.h",
  54   ]
  55
  56   args =
  57       rebase_path(inputs, root_build_dir) + rebase_path(outputs, root_build_dir)
  58 }
  59
  60 source_set("devtools_protocol_handler") {
  61   visibility = [ ":resources" ]
  62   sources = get_target_outputs(":gen_devtools_protocol_handler")
  63 }