ui/base/resource/resource_bundle_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/base/resource/resource_bundle.h"
   6
   7 #import <AppKit/AppKit.h>
   8
   9 #include "base/basictypes.h"
  10 #include "base/files/file_path.h"
  11 #include "base/files/file_util.h"
  12 #include "base/mac/bundle_locations.h"
  13 #include "base/mac/scoped_nsobject.h"
  14 #include "base/memory/ref_counted_memory.h"
  15 #include "base/strings/sys_string_conversions.h"
  16 #include "base/synchronization/lock.h"
  17 #include "ui/base/resource/resource_handle.h"
  18 #include "ui/gfx/image/image.h"
  19
  20 namespace ui {
  21
  22 namespace {
  23
  24 base::FilePath GetResourcesPakFilePath(NSString* name, NSString* mac_locale) {
  25   NSString *resource_path;
  26   // Some of the helper processes need to be able to fetch resources
  27   // (chrome_main.cc: SubprocessNeedsResourceBundle()). Fetch the same locale
  28   // as the already-running browser instead of using what NSBundle might pick
  29   // based on values at helper launch time.
  30   if ([mac_locale length]) {
  31     resource_path = [base::mac::FrameworkBundle() pathForResource:name
  32                                                            ofType:@"pak"
  33                                                       inDirectory:@""
  34                                                   forLocalization:mac_locale];
  35   } else {
  36     resource_path = [base::mac::FrameworkBundle() pathForResource:name
  37                                                            ofType:@"pak"];
  38   }
  39
  40   if (!resource_path) {
  41     // Return just the name of the pack file.
  42     return base::FilePath(base::SysNSStringToUTF8(name) + ".pak");
  43   }
  44
  45   return base::FilePath([resource_path fileSystemRepresentation]);
  46 }
  47
  48 }  // namespace
  49
  50 void ResourceBundle::LoadCommonResources() {
  51   AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_100_percent",
  52                         nil), SCALE_FACTOR_100P);
  53
  54   // On Mac we load 1x and 2x resources and we let the UI framework decide
  55   // which one to use.
  56   if (IsScaleFactorSupported(SCALE_FACTOR_200P)) {
  57     AddDataPackFromPath(GetResourcesPakFilePath(@"chrome_200_percent", nil),
  58                         SCALE_FACTOR_200P);
  59   }
  60 }
  61
  62 base::FilePath ResourceBundle::GetLocaleFilePath(const std::string& app_locale,
  63                                                  bool test_file_exists) {
  64   NSString* mac_locale = base::SysUTF8ToNSString(app_locale);
  65
  66   // Mac OS X uses "_" instead of "-", so swap to get a Mac-style value.
  67   mac_locale = [mac_locale stringByReplacingOccurrencesOfString:@"-"
  68                                                      withString:@"_"];
  69
  70   // On disk, the "en_US" resources are just "en" (http://crbug.com/25578).
  71   if ([mac_locale isEqual:@"en_US"])
  72     mac_locale = @"en";
  73
  74   base::FilePath locale_file_path =
  75       GetResourcesPakFilePath(@"locale", mac_locale);
  76
  77   if (delegate_) {
  78     locale_file_path =
  79         delegate_->GetPathForLocalePack(locale_file_path, app_locale);
  80   }
  81
  82   // Don't try to load empty values or values that are not absolute paths.
  83   if (locale_file_path.empty() || !locale_file_path.IsAbsolute())
  84     return base::FilePath();
  85
  86   if (test_file_exists && !base::PathExists(locale_file_path))
  87     return base::FilePath();
  88
  89   return locale_file_path;
  90 }
  91
  92 gfx::Image& ResourceBundle::GetNativeImageNamed(int resource_id, ImageRTL rtl) {
  93   // Flipped images are not used on Mac.
  94   DCHECK_EQ(rtl, RTL_DISABLED);
  95
  96   // Check to see if the image is already in the cache.
  97   {
  98     base::AutoLock lock(*images_and_fonts_lock_);
  99     if (images_.count(resource_id)) {
 100       if (!images_[resource_id].HasRepresentation(gfx::Image::kImageRepCocoa)) {
 101         DLOG(WARNING) << "ResourceBundle::GetNativeImageNamed() is returning a"
 102           << " cached gfx::Image that isn't backed by an NSImage. The image"
 103           << " will be converted, rather than going through the NSImage loader."
 104           << " resource_id = " << resource_id;
 105       }
 106       return images_[resource_id];
 107     }
 108   }
 109
 110   gfx::Image image;
 111   if (delegate_)
 112     image = delegate_->GetNativeImageNamed(resource_id, rtl);
 113
 114   if (image.IsEmpty()) {
 115     base::scoped_nsobject<NSImage> ns_image;
 116     for (size_t i = 0; i < data_packs_.size(); ++i) {
 117       scoped_refptr<base::RefCountedStaticMemory> data(
 118           data_packs_[i]->GetStaticMemory(resource_id));
 119       if (!data.get())
 120         continue;
 121
 122       base::scoped_nsobject<NSData> ns_data(
 123           [[NSData alloc] initWithBytes:data->front() length:data->size()]);
 124       if (!ns_image.get()) {
 125         ns_image.reset([[NSImage alloc] initWithData:ns_data]);
 126       } else {
 127         NSImageRep* image_rep = [NSBitmapImageRep imageRepWithData:ns_data];
 128         if (image_rep)
 129           [ns_image addRepresentation:image_rep];
 130       }
 131     }
 132
 133     if (!ns_image.get()) {
 134       LOG(WARNING) << "Unable to load image with id " << resource_id;
 135       NOTREACHED();  // Want to assert in debug mode.
 136       return GetEmptyImage();
 137     }
 138
 139     image = gfx::Image(ns_image.release());
 140   }
 141
 142   base::AutoLock lock(*images_and_fonts_lock_);
 143
 144   // Another thread raced the load and has already cached the image.
 145   if (images_.count(resource_id))
 146     return images_[resource_id];
 147
 148   images_[resource_id] = image;
 149   return images_[resource_id];
 150 }
 151
 152 }  // namespace ui