ui/gfx/screen_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/gfx/screen.h"
   6
   7 #import <ApplicationServices/ApplicationServices.h>
   8 #import <Cocoa/Cocoa.h>
   9
  10 #include <map>
  11
  12 #include "base/logging.h"
  13 #include "base/mac/sdk_forward_declarations.h"
  14 #include "base/timer/timer.h"
  15 #include "ui/gfx/display.h"
  16 #include "ui/gfx/display_change_notifier.h"
  17
  18 namespace {
  19
  20 // The delay to handle the display configuration changes.
  21 // See comments in ScreenMac::HandleDisplayReconfiguration.
  22 const int64 kConfigureDelayMs = 500;
  23
  24 gfx::Rect ConvertCoordinateSystem(NSRect ns_rect) {
  25   // Primary monitor is defined as the monitor with the menubar,
  26   // which is always at index 0.
  27   NSScreen* primary_screen = [[NSScreen screens] objectAtIndex:0];
  28   float primary_screen_height = [primary_screen frame].size.height;
  29   gfx::Rect rect(NSRectToCGRect(ns_rect));
  30   rect.set_y(primary_screen_height - rect.y() - rect.height());
  31   return rect;
  32 }
  33
  34 NSScreen* GetMatchingScreen(const gfx::Rect& match_rect) {
  35   // Default to the monitor with the current keyboard focus, in case
  36   // |match_rect| is not on any screen at all.
  37   NSScreen* max_screen = [NSScreen mainScreen];
  38   int max_area = 0;
  39
  40   for (NSScreen* screen in [NSScreen screens]) {
  41     gfx::Rect monitor_area = ConvertCoordinateSystem([screen frame]);
  42     gfx::Rect intersection = gfx::IntersectRects(monitor_area, match_rect);
  43     int area = intersection.width() * intersection.height();
  44     if (area > max_area) {
  45       max_area = area;
  46       max_screen = screen;
  47     }
  48   }
  49
  50   return max_screen;
  51 }
  52
  53 gfx::Display GetDisplayForScreen(NSScreen* screen) {
  54   NSRect frame = [screen frame];
  55
  56   CGDirectDisplayID display_id = [[[screen deviceDescription]
  57     objectForKey:@"NSScreenNumber"] unsignedIntValue];
  58
  59   gfx::Display display(display_id, gfx::Rect(NSRectToCGRect(frame)));
  60   NSRect visible_frame = [screen visibleFrame];
  61   NSScreen* primary = [[NSScreen screens] objectAtIndex:0];
  62
  63   // Convert work area's coordinate systems.
  64   if ([screen isEqual:primary]) {
  65     gfx::Rect work_area = gfx::Rect(NSRectToCGRect(visible_frame));
  66     work_area.set_y(frame.size.height - visible_frame.origin.y -
  67                     visible_frame.size.height);
  68     display.set_work_area(work_area);
  69   } else {
  70     display.set_bounds(ConvertCoordinateSystem(frame));
  71     display.set_work_area(ConvertCoordinateSystem(visible_frame));
  72   }
  73   CGFloat scale;
  74   if ([screen respondsToSelector:@selector(backingScaleFactor)])
  75     scale = [screen backingScaleFactor];
  76   else
  77     scale = [screen userSpaceScaleFactor];
  78   display.set_device_scale_factor(scale);
  79   // CGDisplayRotation returns a double. Display::SetRotationAsDegree will
  80   // handle the unexpected situations were the angle is not a multiple of 90.
  81   display.SetRotationAsDegree(static_cast<int>(CGDisplayRotation(display_id)));
  82   return display;
  83 }
  84
  85 class ScreenMac : public gfx::Screen {
  86  public:
  87   ScreenMac() {
  88     displays_ = BuildDisplaysFromQuartz();
  89
  90     CGDisplayRegisterReconfigurationCallback(
  91         ScreenMac::DisplayReconfigurationCallBack, this);
  92   }
  93
  94   ~ScreenMac() override {
  95     CGDisplayRemoveReconfigurationCallback(
  96         ScreenMac::DisplayReconfigurationCallBack, this);
  97   }
  98
  99   gfx::Point GetCursorScreenPoint() override {
 100     NSPoint mouseLocation  = [NSEvent mouseLocation];
 101     // Flip coordinates to gfx (0,0 in top-left corner) using primary screen.
 102     NSScreen* screen = [[NSScreen screens] objectAtIndex:0];
 103     mouseLocation.y = NSMaxY([screen frame]) - mouseLocation.y;
 104     return gfx::Point(mouseLocation.x, mouseLocation.y);
 105   }
 106
 107   gfx::NativeWindow GetWindowUnderCursor() override {
 108     NOTIMPLEMENTED();
 109     return gfx::NativeWindow();
 110   }
 111
 112   gfx::NativeWindow GetWindowAtScreenPoint(const gfx::Point& point) override {
 113     NOTIMPLEMENTED();
 114     return gfx::NativeWindow();
 115   }
 116
 117   int GetNumDisplays() const override { return GetAllDisplays().size(); }
 118
 119   std::vector<gfx::Display> GetAllDisplays() const override {
 120     return displays_;
 121   }
 122
 123   gfx::Display GetDisplayNearestWindow(gfx::NativeView view) const override {
 124     NSWindow* window = nil;
 125 #if !defined(USE_AURA)
 126     if (view)
 127       window = [view window];
 128 #endif
 129     if (!window)
 130       return GetPrimaryDisplay();
 131     NSScreen* match_screen = [window screen];
 132     if (!match_screen)
 133       return GetPrimaryDisplay();
 134     return GetDisplayForScreen(match_screen);
 135   }
 136
 137   gfx::Display GetDisplayNearestPoint(const gfx::Point& point) const override {
 138     NSPoint ns_point = NSPointFromCGPoint(point.ToCGPoint());
 139
 140     NSArray* screens = [NSScreen screens];
 141     NSScreen* primary = [screens objectAtIndex:0];
 142     ns_point.y = NSMaxY([primary frame]) - ns_point.y;
 143     for (NSScreen* screen in screens) {
 144       if (NSMouseInRect(ns_point, [screen frame], NO))
 145         return GetDisplayForScreen(screen);
 146     }
 147     return GetPrimaryDisplay();
 148   }
 149
 150   // Returns the display that most closely intersects the provided bounds.
 151   gfx::Display GetDisplayMatching(const gfx::Rect& match_rect) const override {
 152     NSScreen* match_screen = GetMatchingScreen(match_rect);
 153     return GetDisplayForScreen(match_screen);
 154   }
 155
 156   // Returns the primary display.
 157   gfx::Display GetPrimaryDisplay() const override {
 158     // Primary display is defined as the display with the menubar,
 159     // which is always at index 0.
 160     NSScreen* primary = [[NSScreen screens] objectAtIndex:0];
 161     gfx::Display display = GetDisplayForScreen(primary);
 162     return display;
 163   }
 164
 165   void AddObserver(gfx::DisplayObserver* observer) override {
 166     change_notifier_.AddObserver(observer);
 167   }
 168
 169   void RemoveObserver(gfx::DisplayObserver* observer) override {
 170     change_notifier_.RemoveObserver(observer);
 171   }
 172
 173   static void DisplayReconfigurationCallBack(CGDirectDisplayID display,
 174                                              CGDisplayChangeSummaryFlags flags,
 175                                              void* userInfo) {
 176     if (flags & kCGDisplayBeginConfigurationFlag)
 177       return;
 178
 179     static_cast<ScreenMac*>(userInfo)->HandleDisplayReconfiguration();
 180   }
 181
 182   void HandleDisplayReconfiguration() {
 183     // Given that we need to rebuild the list of displays, we want to coalesce
 184     // the events. For that, we use a timer that will be reset every time we get
 185     // a new event and will be fulfilled kConfigureDelayMs after the latest.
 186     if (configure_timer_.get() && configure_timer_->IsRunning()) {
 187       configure_timer_->Reset();
 188       return;
 189     }
 190
 191     configure_timer_.reset(new base::OneShotTimer<ScreenMac>());
 192     configure_timer_->Start(
 193         FROM_HERE,
 194         base::TimeDelta::FromMilliseconds(kConfigureDelayMs),
 195         this,
 196         &ScreenMac::ConfigureTimerFired);
 197   }
 198
 199  private:
 200   void ConfigureTimerFired() {
 201     std::vector<gfx::Display> old_displays = displays_;
 202     displays_ = BuildDisplaysFromQuartz();
 203
 204     change_notifier_.NotifyDisplaysChanged(old_displays, displays_);
 205   }
 206
 207   std::vector<gfx::Display> BuildDisplaysFromQuartz() const {
 208     // Don't just return all online displays.  This would include displays
 209     // that mirror other displays, which are not desired in this list.  It's
 210     // tempting to use the count returned by CGGetActiveDisplayList, but active
 211     // displays exclude sleeping displays, and those are desired.
 212
 213     // It would be ridiculous to have this many displays connected, but
 214     // CGDirectDisplayID is just an integer, so supporting up to this many
 215     // doesn't hurt.
 216     CGDirectDisplayID online_displays[128];
 217     CGDisplayCount online_display_count = 0;
 218     if (CGGetOnlineDisplayList(arraysize(online_displays),
 219                               online_displays,
 220                               &online_display_count) != kCGErrorSuccess) {
 221       return std::vector<gfx::Display>(1, GetPrimaryDisplay());
 222     }
 223
 224     typedef std::map<int64, NSScreen*> ScreenIdsToScreensMap;
 225     ScreenIdsToScreensMap screen_ids_to_screens;
 226     for (NSScreen* screen in [NSScreen screens]) {
 227       NSDictionary* screen_device_description = [screen deviceDescription];
 228       int64 screen_id = [[screen_device_description
 229         objectForKey:@"NSScreenNumber"] unsignedIntValue];
 230       screen_ids_to_screens[screen_id] = screen;
 231     }
 232
 233     std::vector<gfx::Display> displays;
 234     for (CGDisplayCount online_display_index = 0;
 235         online_display_index < online_display_count;
 236         ++online_display_index) {
 237       CGDirectDisplayID online_display = online_displays[online_display_index];
 238       if (CGDisplayMirrorsDisplay(online_display) == kCGNullDirectDisplay) {
 239         // If this display doesn't mirror any other, include it in the list.
 240         // The primary display in a mirrored set will be counted, but those that
 241         // mirror it will not be.
 242         ScreenIdsToScreensMap::iterator foundScreen =
 243           screen_ids_to_screens.find(online_display);
 244         if (foundScreen != screen_ids_to_screens.end()) {
 245             displays.push_back(GetDisplayForScreen(foundScreen->second));
 246         }
 247       }
 248     }
 249
 250     if (!displays.size())
 251       return std::vector<gfx::Display>(1, GetPrimaryDisplay());
 252
 253     return displays;
 254   }
 255
 256   // The displays currently attached to the device.
 257   std::vector<gfx::Display> displays_;
 258
 259   // The timer to delay configuring outputs. See also the comments in
 260   // HandleDisplayReconfiguration().
 261   scoped_ptr<base::OneShotTimer<ScreenMac> > configure_timer_;
 262
 263   gfx::DisplayChangeNotifier change_notifier_;
 264
 265   DISALLOW_COPY_AND_ASSIGN(ScreenMac);
 266 };
 267
 268 }  // namespace
 269
 270 namespace gfx {
 271
 272 #if !defined(USE_AURA)
 273 Screen* CreateNativeScreen() {
 274   return new ScreenMac;
 275 }
 276 #endif
 277
 278 }