ui/shell_dialogs/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7 if (is_android) {
   8   import("//build/config/android/config.gni")
   9 }
  10
  11 component("shell_dialogs") {
  12   sources = [
  13     "android/shell_dialogs_jni_registrar.cc",
  14     "android/shell_dialogs_jni_registrar.h",
  15     "base_shell_dialog.cc",
  16     "base_shell_dialog.h",
  17     "base_shell_dialog_win.cc",
  18     "base_shell_dialog_win.h",
  19     "linux_shell_dialog.cc",
  20     "linux_shell_dialog.h",
  21     "select_file_dialog.cc",
  22     "select_file_dialog.h",
  23     "select_file_dialog_android.cc",
  24     "select_file_dialog_android.h",
  25     "select_file_dialog_factory.cc",
  26     "select_file_dialog_factory.h",
  27     "select_file_dialog_mac.h",
  28     "select_file_dialog_mac.mm",
  29     "select_file_dialog_win.cc",
  30     "select_file_dialog_win.h",
  31     "select_file_policy.cc",
  32     "select_file_policy.h",
  33     "selected_file_info.cc",
  34     "selected_file_info.h",
  35   ]
  36
  37   defines = [ "SHELL_DIALOGS_IMPLEMENTATION" ]
  38
  39   deps = [
  40     "//base",
  41     "//base:i18n",
  42     "//skia",
  43     "//ui/base",
  44     "//ui/strings",
  45   ]
  46
  47   if (use_aura) {
  48     if (is_mac) {
  49       # Will be automatically filtered out on non-Mac.
  50       sources -= [ "select_file_dialog_mac.mm" ]
  51     }
  52     deps += [ "//ui/aura" ]
  53   }
  54
  55   if (is_android) {
  56     deps += [
  57       "//ui/android",
  58       "//ui/android:ui_java",
  59       "//ui/base:ui_base_jni_headers",
  60     ]
  61     include_dirs = [ "$root_gen_dir/ui" ]
  62     libs = [ "jnigraphics" ]
  63   }
  64
  65   if (is_win) {
  66     deps += [ "//win8:metro_viewer" ]
  67   }
  68 }
  69
  70 test("shell_dialogs_unittests") {
  71   sources = [
  72     "select_file_dialog_win_unittest.cc",
  73   ]
  74
  75   deps = [
  76     ":shell_dialogs",
  77     "//base",
  78     "//base/test:test_support",
  79     "//base/test:run_all_unittests",
  80     "//testing/gtest",
  81   ]
  82 }