components/scheduler/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//components/scheduler/scheduler.gni")
   6
   7 # GYP version: components/scheduler.gypi:scheduler
   8 component("scheduler") {
   9   sources = rebase_path(scheduler_gypi_values.scheduler_sources,
  10                         ".",
  11                         "//components/scheduler")
  12
  13   defines = [ "SCHEDULER_IMPLEMENTATION" ]
  14
  15   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  16   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  17
  18   deps = [
  19     ":common",
  20     "//base",
  21     "//cc:cc",
  22     "//third_party/WebKit/public:blink",
  23     "//ui/gfx:gfx",
  24   ]
  25
  26   public_deps = [
  27     "//third_party/WebKit/public:blink",
  28   ]
  29 }
  30
  31 # GYP version: components/scheduler.gypi:scheduler_common
  32 source_set("common") {
  33   sources = rebase_path(scheduler_gypi_values.scheduler_common_sources,
  34                         ".",
  35                         "//components/scheduler")
  36 }
  37
  38 source_set("unit_tests") {
  39   testonly = true
  40
  41   sources = [
  42     "child/nestable_task_runner_for_test.cc",
  43     "child/nestable_task_runner_for_test.h",
  44     "child/prioritizing_task_queue_selector_unittest.cc",
  45     "child/scheduler_helper_unittest.cc",
  46     "child/task_queue_manager_unittest.cc",
  47     "child/test_time_source.cc",
  48     "child/test_time_source.h",
  49     "child/webthread_impl_for_worker_scheduler_unittest.cc",
  50     "child/worker_scheduler_impl_unittest.cc",
  51     "renderer/deadline_task_runner_unittest.cc",
  52     "renderer/renderer_scheduler_impl_unittest.cc",
  53     "renderer/webthread_impl_for_renderer_scheduler_unittest.cc",
  54   ]
  55
  56   deps = [
  57     ":scheduler",
  58     "//cc:test_support",
  59     "//testing/gmock",
  60     "//testing/gtest",
  61   ]
  62 }