skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
  12   import("//build/config/mips.gni")
  13 }
  14
  15 skia_support_gpu = !is_ios
  16 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  17
  18 # The list of Skia defines that are to be set for blink.
  19 gypi_blink_skia_defines =
  20     exec_script("//build/gypi_to_gn.py",
  21                 [
  22                   rebase_path(
  23                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  24                   "--replace=<(skia_include_path)=//third_party/skia/include",
  25                   "--replace=<(skia_src_path)=//third_party/skia/src",
  26                 ],
  27                 "scope",
  28                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  29
  30 # The list of Skia defines that are to be set for chromium.
  31 gypi_skia_defines =
  32     exec_script("//build/gypi_to_gn.py",
  33                 [
  34                   rebase_path(
  35                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  36                   "--replace=<(skia_include_path)=//third_party/skia/include",
  37                   "--replace=<(skia_src_path)=//third_party/skia/src",
  38                 ],
  39                 "scope",
  40                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  41
  42 # The list of Skia core sources that are to be set for chromium.
  43 gypi_skia_core =
  44     exec_script("//build/gypi_to_gn.py",
  45                 [
  46                   rebase_path("//third_party/skia/gyp/core.gypi"),
  47                   "--replace=<(skia_include_path)=//third_party/skia/include",
  48                   "--replace=<(skia_src_path)=//third_party/skia/src",
  49                 ],
  50                 "scope",
  51                 [ "//third_party/skia/gyp/core.gypi" ])
  52
  53 # The list of Skia gpu sources that are to be set for chromium.
  54 if (skia_support_gpu) {
  55   gypi_skia_gpu =
  56       exec_script("//build/gypi_to_gn.py",
  57                   [
  58                     rebase_path("//third_party/skia/gyp/gpu.gypi"),
  59                     "--replace=<(skia_include_path)=//third_party/skia/include",
  60                     "--replace=<(skia_src_path)=//third_party/skia/src",
  61                   ],
  62                   "scope",
  63                   [ "//third_party/skia/gyp/gpu.gypi" ])
  64 }
  65
  66 # The list of Skia pdf sources that are to be set for chromium.
  67 if (skia_support_pdf) {
  68   gypi_skia_pdf =
  69       exec_script("//build/gypi_to_gn.py",
  70                   [
  71                     rebase_path("//third_party/skia/gyp/pdf.gypi"),
  72                     "--replace=<(skia_include_path)=//third_party/skia/include",
  73                     "--replace=<(skia_src_path)=//third_party/skia/src",
  74                   ],
  75                   "scope",
  76                   [ "//third_party/skia/gyp/pdf.gypi" ])
  77 }
  78
  79 # The list of Skia effects that are to be set for chromium.
  80 gypi_skia_effects =
  81     exec_script("//build/gypi_to_gn.py",
  82                 [
  83                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  84                   "--replace=<(skia_include_path)=//third_party/skia/include",
  85                   "--replace=<(skia_src_path)=//third_party/skia/src",
  86                 ],
  87                 "scope",
  88                 [ "//third_party/skia/gyp/effects.gypi" ])
  89
  90 # The list of Skia utils that are to be set for chromium.
  91 gypi_skia_utils =
  92     exec_script("//build/gypi_to_gn.py",
  93                 [
  94                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  95                   "--replace=<(skia_include_path)=//third_party/skia/include",
  96                   "--replace=<(skia_src_path)=//third_party/skia/src",
  97                 ],
  98                 "scope",
  99                 [ "//third_party/skia/gyp/utils.gypi" ])
 100
 101 gypi_skia_opts =
 102     exec_script("//build/gypi_to_gn.py",
 103                 [
 104                   rebase_path("//third_party/skia/gyp/opts.gypi"),
 105                   "--replace=<(skia_include_path)=//third_party/skia/include",
 106                   "--replace=<(skia_src_path)=//third_party/skia/src",
 107                 ],
 108                 "scope",
 109                 [ "//third_party/skia/gyp/opts.gypi" ])
 110
 111 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 112 gypi_values =
 113     exec_script("//build/gypi_to_gn.py",
 114                 [
 115                   rebase_path("skia_gn_files.gypi"),
 116                   "--replace=<(skia_include_path)=//third_party/skia/include",
 117                   "--replace=<(skia_src_path)=//third_party/skia/src",
 118                 ],
 119                 "scope",
 120                 [ "skia_gn_files.gypi" ])
 121
 122 # External-facing config for dependent code.
 123 config("skia_config") {
 124   include_dirs = [
 125     "config",
 126     "ext",
 127     "//third_party/skia/include/c",
 128     "//third_party/skia/include/config",
 129     "//third_party/skia/include/core",
 130     "//third_party/skia/include/effects",
 131     "//third_party/skia/include/images",
 132     "//third_party/skia/include/lazy",
 133     "//third_party/skia/include/pathops",
 134     "//third_party/skia/include/pdf",
 135     "//third_party/skia/include/pipe",
 136     "//third_party/skia/include/ports",
 137     "//third_party/skia/include/utils",
 138   ]
 139
 140   defines = gypi_blink_skia_defines.blink_skia_defines
 141   defines += gypi_skia_defines.skia_for_chromium_defines
 142
 143   defines += []
 144
 145   if (component_mode == "shared_library") {
 146     defines += [
 147       "SKIA_DLL",
 148       "GR_GL_IGNORE_ES3_MSAA=0",
 149     ]
 150   }
 151
 152   if (skia_support_gpu) {
 153     include_dirs += [
 154       "//third_party/skia/include/gpu",
 155       "//third_party/skia/src/gpu",
 156     ]
 157     defines += [ "SK_SUPPORT_GPU=1" ]
 158   } else {
 159     defines += [ "SK_SUPPORT_GPU=0" ]
 160   }
 161
 162   if (is_android) {
 163     defines += [
 164       "SK_BUILD_FOR_ANDROID",
 165       "USE_CHROMIUM_SKIA",
 166     ]
 167   }
 168
 169   if (is_mac) {
 170     defines += [ "SK_BUILD_FOR_MAC" ]
 171   }
 172 }
 173
 174 # Internal-facing config for Skia library code.
 175 config("skia_library_config") {
 176   # These include directories are only included for Skia code and are not
 177   # exported to dependents. It's not clear if this is on purpose, but this
 178   # matches the GYP build.
 179   include_dirs = [
 180     "//third_party/skia/include/private",
 181     "//third_party/skia/src/core",
 182     "//third_party/skia/src/image",
 183     "//third_party/skia/src/opts",
 184     "//third_party/skia/src/pdf",
 185     "//third_party/skia/src/ports",
 186     "//third_party/skia/src/sfnt",
 187     "//third_party/skia/src/utils",
 188     "//third_party/skia/src/lazy",
 189   ]
 190   if (is_mac || is_ios) {
 191     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 192   }
 193   if (is_mac) {
 194     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 195   }
 196
 197   defines = []
 198
 199   if (component_mode == "shared_library") {
 200     defines += [ "SKIA_IMPLEMENTATION=1" ]
 201   }
 202
 203   if (current_cpu == "arm") {
 204     if (arm_use_neon) {
 205       defines += [ "SK_ARM_HAS_NEON" ]
 206     } else if (arm_optionally_use_neon) {
 207       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 208     }
 209   }
 210
 211   # Settings for text blitting, chosen to approximate the system browser.
 212   if (is_linux) {
 213     defines += [
 214       "SK_GAMMA_EXPONENT=1.2",
 215       "SK_GAMMA_CONTRAST=0.2",
 216       "SK_HIGH_QUALITY_IS_LANCZOS",
 217     ]
 218   } else if (is_android) {
 219     defines += [
 220       "SK_GAMMA_APPLY_TO_A8",
 221       "SK_GAMMA_EXPONENT=1.4",
 222       "SK_GAMMA_CONTRAST=0.0",
 223     ]
 224   } else if (is_win) {
 225     defines += [
 226       "SK_GAMMA_SRGB",
 227       "SK_GAMMA_CONTRAST=0.5",
 228       "SK_HIGH_QUALITY_IS_LANCZOS",
 229     ]
 230   } else if (is_mac) {
 231     defines += [
 232       "SK_GAMMA_SRGB",
 233       "SK_GAMMA_CONTRAST=0.0",
 234       "SK_HIGH_QUALITY_IS_LANCZOS",
 235     ]
 236   }
 237
 238   if (is_android) {
 239     defines += [
 240       # Android devices are typically more memory constrained, so default to a
 241       # smaller glyph cache (it may be overriden at runtime when the renderer
 242       # starts up, depending on the actual device memory).
 243       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 244     ]
 245   } else {
 246     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 247   }
 248
 249   if (is_win) {
 250     include_dirs += [
 251       "//third_party/skia/include/utils/win",
 252       "//third_party/skia/src/utils/win",
 253     ]
 254
 255     defines += [
 256       # On windows, GDI handles are a scarse system-wide resource so we have to
 257       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 258       # fairly small size. http://crbug.com/314387
 259       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 260     ]
 261
 262     cflags = [
 263       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 264       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 265       "/wd4341",  # signed value is out of range for enum constant.
 266       "/wd4345",  # Object is default-initialized if initialization is omitted.
 267       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 268       "/wd4554",  # 'operator' : check operator precedence for possible error
 269       "/wd4748",  # compiler will disable optimizations if a function has inline
 270                   # assembly code contains flow control(jmp or jcc) statements.
 271
 272       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 273     ]
 274   }
 275 }
 276
 277 component("skia") {
 278   sources = [
 279     # Chrome sources.
 280     "ext/SkDiscardableMemory_chrome.cc",
 281     "ext/SkMemory_new_handler.cpp",
 282     "ext/analysis_canvas.cc",
 283     "ext/benchmarking_canvas.cc",
 284     "ext/convolver.cc",
 285     "ext/event_tracer_impl.cc",
 286     "ext/fontmgr_default_win.cc",
 287     "ext/google_logging.cc",
 288     "ext/image_operations.cc",
 289     "ext/opacity_filter_canvas.cc",
 290     "ext/pixel_ref_utils.cc",
 291     "ext/platform_canvas.cc",
 292     "ext/platform_device.cc",
 293     "ext/platform_device_linux.cc",
 294     "ext/platform_device_mac.cc",
 295     "ext/platform_device_win.cc",
 296     "ext/recursive_gaussian_convolution.cc",
 297     "ext/skia_utils_base.cc",
 298     "ext/skia_utils_ios.mm",
 299     "ext/skia_utils_mac.mm",
 300     "ext/skia_utils_win.cc",
 301   ]
 302
 303   if (current_cpu == "x86" || current_cpu == "x64") {
 304     sources += [ "ext/convolver_SSE2.cc" ]
 305   } else if (current_cpu == "mipsel" && mips_dsp_rev >= 2) {
 306     sources += [ "ext/convolver_mips_dspr2.cc" ]
 307   }
 308
 309   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 310   sources += gypi_skia_core.sources
 311   sources += gypi_skia_effects.sources
 312   sources += gypi_skia_utils.sources
 313   sources += gypi_values.skia_library_sources
 314
 315   # This and skia_opts are really the same conceptual target so share headers.
 316   allow_circular_includes_from = [ ":skia_opts" ]
 317
 318   if (current_cpu == "arm") {
 319     sources += [ "//third_party/skia/src/core/SkUtilsArm.cpp" ]
 320   }
 321
 322   # GPU
 323   if (skia_support_gpu) {
 324     sources += gypi_skia_gpu.skgpu_sources
 325     sources += gypi_skia_gpu.skgpu_null_gl_sources
 326   }
 327
 328   # Remove unused util files include in utils.gypi
 329   sources -= [
 330     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 331     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 332     "//third_party/skia/src/utils/SkCamera.cpp",
 333     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 334     "//third_party/skia/src/utils/SkCullPoints.cpp",
 335     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 336     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 337     "//third_party/skia/src/utils/SkInterpolator.cpp",
 338     "//third_party/skia/src/utils/SkLayer.cpp",
 339     "//third_party/skia/src/utils/SkMD5.cpp",
 340     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 341     "//third_party/skia/src/utils/SkNinePatch.cpp",
 342     "//third_party/skia/src/utils/SkOSFile.cpp",
 343     "//third_party/skia/src/utils/SkParsePath.cpp",
 344     "//third_party/skia/src/utils/SkSHA1.cpp",
 345
 346     # We don't currently need to change thread affinity, so leave out this complexity for now.
 347     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 348     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 349
 350     #testing
 351     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 352   ]
 353
 354   if (is_win) {
 355     sources -= [
 356       # Keeping _win.cpp
 357       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 358       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 359     ]
 360   } else {
 361     sources -= [
 362       # Keeping _pthread.cpp and _pthread_other.cpp.
 363       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 364     ]
 365   }
 366
 367   # need separate win section to handle chromes auto gn filter
 368   # (build/config/BUILDCONFIG.gn)
 369   if (is_win) {
 370     sources -= [
 371       #windows
 372       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 373       "//third_party/skia/src/utils/win/SkIStream.cpp",
 374       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 375     ]
 376   }
 377
 378   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 379     sources -= [ "ext/skia_utils_base.cc" ]
 380   }
 381
 382   # Fixup skia library sources.
 383   if (is_win) {
 384     sources -= [
 385       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 386       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 387       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 388     ]
 389   } else {
 390     sources -= [
 391       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 392       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 393       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 394       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 395       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 396       "//third_party/skia/src/ports/SkTLS_win.cpp",
 397       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 398     ]
 399   }
 400   if (!is_android) {
 401     sources -= [
 402       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 403       "//third_party/skia/src/ports/SkFontMgr_android_factory.cpp",
 404       "//third_party/skia/src/ports/SkFontMgr_android_parser.cpp",
 405     ]
 406   }
 407   if (!is_mac) {
 408     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 409   }
 410
 411   if (!is_linux) {
 412     sources -= [
 413       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 414       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 415       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 416     ]
 417   }
 418
 419   if (!is_linux && !is_android) {
 420     sources -= [
 421       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 422       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 423     ]
 424   }
 425
 426   # Select the right BitmapPlatformDevice.
 427   if (is_win) {
 428     sources += [ "ext/bitmap_platform_device_win.cc" ]
 429   } else if (is_mac) {
 430     sources += [ "ext/bitmap_platform_device_mac.cc" ]
 431   } else if (use_cairo) {
 432     sources += [ "ext/bitmap_platform_device_cairo.cc" ]
 433   } else {
 434     sources += [ "ext/bitmap_platform_device_skia.cc" ]
 435   }
 436
 437   if (is_clang) {
 438     # Skia won't compile with some of the more strict clang warnings.
 439     # e.g. it does:
 440     #  SkASSERT(!"sk_out_of_memory");
 441     configs -= [ "//build/config/clang:extra_warnings" ]
 442   }
 443
 444   configs -= [ "//build/config/compiler:chromium_code" ]
 445   configs += [
 446     ":skia_library_config",
 447     "//build/config/compiler:no_chromium_code",
 448   ]
 449   public_configs = [ ":skia_config" ]
 450
 451   deps = [
 452     ":skia_opts",
 453     "//base",
 454     "//base/third_party/dynamic_annotations",
 455     "//third_party/zlib",
 456   ]
 457
 458   if (is_linux) {
 459     configs += [
 460       "//build/config/linux:fontconfig",
 461       "//build/config/linux:freetype2",
 462     ]
 463     if (use_pango) {
 464       configs += [ "//build/config/linux:pangocairo" ]
 465     }
 466     deps += [ "//third_party/icu:icuuc" ]
 467   }
 468
 469   if (is_android) {
 470     set_sources_assignment_filter([])
 471     sources += [ "ext/platform_device_linux.cc" ]
 472     set_sources_assignment_filter(sources_assignment_filter)
 473     deps += [
 474       "//third_party/expat",
 475       "//third_party/freetype-android:freetype",
 476       "//third_party/android_tools:cpu_features",
 477     ]
 478   }
 479
 480   if (skia_support_pdf) {
 481     deps += [ "//third_party/sfntly" ]
 482     sources += gypi_skia_pdf.sources
 483   }
 484
 485   if (is_android && !is_debug) {
 486     configs -= [ "//build/config/compiler:optimize" ]
 487     configs += [ "//build/config/compiler:optimize_max" ]
 488   }
 489 }
 490
 491 # Separated out so it can be compiled with different flags for SSE.
 492 if (current_cpu == "x86" || current_cpu == "x64") {
 493   source_set("skia_opts_sse3") {
 494     sources = gypi_skia_opts.ssse3_sources
 495     if (!is_win || is_clang) {
 496       cflags = [ "-mssse3" ]
 497     }
 498     if (is_win) {
 499       defines = [ "SK_CPU_SSE_LEVEL=31" ]
 500     }
 501     visibility = [ ":skia_opts" ]
 502     configs -= [ "//build/config/compiler:chromium_code" ]
 503     configs += [
 504       ":skia_config",
 505       ":skia_library_config",
 506       "//build/config/compiler:no_chromium_code",
 507     ]
 508   }
 509   source_set("skia_opts_sse4") {
 510     sources = gypi_skia_opts.sse41_sources
 511     if (!is_win || is_clang) {
 512       cflags = [ "-msse4.1" ]
 513     }
 514     if (is_win) {
 515       defines = [ "SK_CPU_SSE_LEVEL=41" ]
 516     }
 517     visibility = [ ":skia_opts" ]
 518     configs -= [ "//build/config/compiler:chromium_code" ]
 519     configs += [
 520       ":skia_config",
 521       ":skia_library_config",
 522       "//build/config/compiler:no_chromium_code",
 523     ]
 524   }
 525 }
 526 source_set("skia_opts") {
 527   cflags = []
 528   defines = []
 529
 530   deps = [
 531     "//base",
 532   ]
 533
 534   if (current_cpu == "x86" || current_cpu == "x64") {
 535     sources = gypi_skia_opts.sse2_sources
 536     deps += [
 537       ":skia_opts_sse3",
 538       ":skia_opts_sse4",
 539     ]
 540   } else if (current_cpu == "arm") {
 541     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 542     # ARM), the compiler doesn't like that.
 543     cflags += [ "-fomit-frame-pointer" ]
 544
 545     if (arm_version >= 7) {
 546       sources = gypi_skia_opts.armv7_sources
 547       if (arm_use_neon || arm_optionally_use_neon) {
 548         sources += gypi_skia_opts.neon_sources
 549
 550         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 551         # when running this.
 552         if (!arm_use_neon) {
 553           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 554           cflags += [ "-mfpu=neon" ]
 555         }
 556       }
 557     } else {
 558       sources = gypi_skia_opts.none_sourcees
 559     }
 560   } else if (current_cpu == "mipsel") {
 561     cflags += [ "-fomit-frame-pointer" ]
 562
 563     if (mips_dsp_rev >= 1) {
 564       sources = gypi_skia_opts.mips_dsp_sources
 565     } else {
 566       sources = gypi_skia_opts.none_sources
 567     }
 568   } else {
 569     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 570   }
 571
 572   if (is_android && !is_debug) {
 573     configs -= [ "//build/config/compiler:optimize" ]
 574     configs += [ "//build/config/compiler:optimize_max" ]
 575   }
 576
 577   configs -= [ "//build/config/compiler:chromium_code" ]
 578   configs += [
 579     ":skia_config",
 580     ":skia_library_config",
 581     "//build/config/compiler:no_chromium_code",
 582   ]
 583
 584   visibility = [ ":skia" ]
 585 }
 586
 587 test("skia_unittests") {
 588   sources = [
 589     "ext/analysis_canvas_unittest.cc",
 590     "ext/bitmap_platform_device_mac_unittest.cc",
 591     "ext/convolver_unittest.cc",
 592     "ext/image_operations_unittest.cc",
 593     "ext/pixel_ref_utils_unittest.cc",
 594     "ext/platform_canvas_unittest.cc",
 595     "ext/recursive_gaussian_convolution_unittest.cc",
 596     "ext/refptr_unittest.cc",
 597     "ext/skia_utils_ios_unittest.mm",
 598     "ext/skia_utils_mac_unittest.mm",
 599   ]
 600
 601   if (!is_win && !is_mac) {
 602     sources -= [ "ext/platform_canvas_unittest.cc" ]
 603   }
 604
 605   deps = [
 606     ":skia",
 607     "//base",
 608     "//base/test:run_all_unittests",
 609     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 610     "//testing/gtest",
 611     "//ui/gfx",
 612     "//ui/gfx/geometry",
 613   ]
 614 }
 615
 616 if (is_linux && !is_chromeos) {
 617   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 618   executable("image_operations_bench") {
 619     sources = [
 620       "ext/image_operations_bench.cc",
 621     ]
 622
 623     deps = [
 624       ":skia",
 625       "//base",
 626     ]
 627   }
 628
 629   executable("filter_fuzz_stub") {
 630     testonly = true
 631     sources = [
 632       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 633     ]
 634
 635     deps = [
 636       ":skia",
 637       "//base",
 638       "//base/test:test_support",
 639     ]
 640   }
 641 }