base/debug/BUILD.gn

   1 # Copyright (c) 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 source_set("debug") {
   6   sources = [
   7     "alias.cc",
   8     "alias.h",
   9     "asan_invalid_access.cc",
  10     "asan_invalid_access.h",
  11     "crash_logging.cc",
  12     "crash_logging.h",
  13     "debugger.cc",
  14     "debugger.h",
  15     "debugger_posix.cc",
  16     "debugger_win.cc",
  17     "dump_without_crashing.cc",
  18     "dump_without_crashing.h",
  19     "gdi_debug_util_win.cc",
  20     "gdi_debug_util_win.h",
  21
  22     # This file depends on files from the "allocator" target,
  23     # but this target does not depend on "allocator" (see
  24     # allocator.gyp for details).
  25     "leak_annotations.h",
  26     "leak_tracker.h",
  27     "proc_maps_linux.cc",
  28     "proc_maps_linux.h",
  29     "profiler.cc",
  30     "profiler.h",
  31     "stack_trace.cc",
  32     "stack_trace.h",
  33     "stack_trace_android.cc",
  34     "stack_trace_posix.cc",
  35     "stack_trace_win.cc",
  36     "task_annotator.cc",
  37     "task_annotator.h",
  38   ]
  39
  40   if (is_android) {
  41     # Android uses some Linux sources, put those back.
  42     set_sources_assignment_filter([])
  43     sources += [ "proc_maps_linux.cc" ]
  44     set_sources_assignment_filter(sources_assignment_filter)
  45
  46     sources -= [ "stack_trace_posix.cc" ]
  47   }
  48
  49   if (is_nacl) {
  50     sources -= [
  51       "crash_logging.cc",
  52       "crash_logging.h",
  53       "stack_trace.cc",
  54       "stack_trace_posix.cc",
  55     ]
  56   }
  57
  58   defines = [ "BASE_IMPLEMENTATION" ]
  59
  60   deps = [
  61     "//base/memory",
  62     "//base/process",
  63   ]
  64
  65   if (is_linux) {
  66     deps += [ "//base/third_party/symbolize" ]
  67   }
  68
  69   allow_circular_includes_from = [
  70     "//base/memory",
  71     "//base/process",
  72   ]
  73
  74   visibility = [ "//base/*" ]
  75 }