media/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/arm.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/linux/pkg_config.gni")
   9 import("//build/config/ui.gni")
  10 import("//media/media_options.gni")
  11 import("//testing/test.gni")
  12
  13 # Common configuration for targets in the media directory.
  14 # NOT for exporting.
  15 config("media_config") {
  16   defines = [ "MEDIA_IMPLEMENTATION" ]
  17   if (!media_use_libvpx) {
  18     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  19   }
  20   if (!media_use_ffmpeg) {
  21     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  22   }
  23   if (current_cpu == "arm" && arm_use_neon) {
  24     defines += [ "USE_NEON" ]
  25   }
  26   if (use_pulseaudio) {
  27     defines += [ "USE_PULSEAUDIO" ]
  28     if (!link_pulseaudio) {
  29       defines += [ "DLOPEN_PULSEAUDIO" ]
  30     }
  31   }
  32   if (use_cras) {
  33     defines += [ "USE_CRAS" ]
  34   }
  35   if (use_alsa) {
  36     defines += [ "USE_ALSA" ]
  37   }
  38 }
  39
  40 config("media_dependent_config") {
  41   defines = []
  42   if (!media_use_libvpx) {
  43     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  44   }
  45   if (!media_use_ffmpeg) {
  46     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  47   }
  48   if (is_win) {
  49     ldflags = [
  50       "/DELAYLOAD:mf.dll",
  51       "/DELAYLOAD:mfplat.dll",
  52       "/DELAYLOAD:mfreadwrite.dll",
  53     ]
  54   }
  55 }
  56
  57 if (use_ozone) {
  58   action("generate_ozone_constructor_list") {
  59     # Ozone platform objects are auto-generated using similar
  60     # patterns for naming and classes constructors. Here we build the
  61     # object MediaOzonePlatform.
  62     script = "../ui/ozone/generate_constructor_list.py"
  63
  64     platform_list_txt_file = "$target_gen_dir/../ui/ozone/platform_list.txt"
  65     constructor_list_cc_file =
  66         "$target_gen_dir/../media/ozone/constructor_list.cc"
  67
  68     sources = [
  69       platform_list_txt_file,
  70     ]
  71     outputs = [
  72       constructor_list_cc_file,
  73     ]
  74     args = [
  75       "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
  76       "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
  77       "--namespace=media",
  78       "--typename=MediaOzonePlatform",
  79       "--include=\"media/ozone/media_ozone_platform.h\"",
  80     ]
  81   }
  82 }
  83
  84 component("media") {
  85   sources = [
  86     "blink/skcanvas_video_renderer.cc",
  87     "blink/skcanvas_video_renderer.h",
  88     "cdm/aes_decryptor.cc",
  89     "cdm/aes_decryptor.h",
  90     "cdm/cenc_utils.cc",
  91     "cdm/cenc_utils.h",
  92     "cdm/default_cdm_factory.cc",
  93     "cdm/default_cdm_factory.h",
  94     "cdm/json_web_key.cc",
  95     "cdm/json_web_key.h",
  96     "cdm/key_system_names.cc",
  97     "cdm/key_system_names.h",
  98     "cdm/player_tracker_impl.cc",
  99     "cdm/player_tracker_impl.h",
 100     "cdm/proxy_decryptor.cc",
 101     "cdm/proxy_decyrptor.h",
 102     "ffmpeg/ffmpeg_deleters.h",
 103     "filters/audio_clock.cc",
 104     "filters/audio_clock.h",
 105     "filters/audio_renderer_algorithm.cc",
 106     "filters/audio_renderer_algorithm.h",
 107     "filters/chunk_demuxer.cc",
 108     "filters/chunk_demuxer.h",
 109     "filters/context_3d.h",
 110     "filters/decoder_selector.cc",
 111     "filters/decoder_selector.h",
 112     "filters/decoder_stream.cc",
 113     "filters/decoder_stream.h",
 114     "filters/decoder_stream_traits.cc",
 115     "filters/decoder_stream_traits.h",
 116     "filters/decrypting_audio_decoder.cc",
 117     "filters/decrypting_audio_decoder.h",
 118     "filters/decrypting_demuxer_stream.cc",
 119     "filters/decrypting_demuxer_stream.h",
 120     "filters/decrypting_video_decoder.cc",
 121     "filters/decrypting_video_decoder.h",
 122     "filters/default_media_permission.cc",
 123     "filters/default_media_permission.h",
 124     "filters/file_data_source.cc",
 125     "filters/file_data_source.h",
 126     "filters/frame_processor.cc",
 127     "filters/frame_processor.h",
 128     "filters/gpu_video_decoder.cc",
 129     "filters/gpu_video_decoder.h",
 130     "filters/h264_bit_reader.cc",
 131     "filters/h264_bit_reader.h",
 132     "filters/h264_parser.cc",
 133     "filters/h264_parser.h",
 134     "filters/jpeg_parser.cc",
 135     "filters/jpeg_parser.h",
 136     "filters/source_buffer_platform.cc",
 137     "filters/source_buffer_platform.h",
 138     "filters/source_buffer_range.cc",
 139     "filters/source_buffer_range.h",
 140     "filters/source_buffer_stream.cc",
 141     "filters/source_buffer_stream.h",
 142     "filters/stream_parser_factory.cc",
 143     "filters/stream_parser_factory.h",
 144     "filters/video_frame_scheduler.h",
 145     "filters/video_frame_scheduler_impl.cc",
 146     "filters/video_frame_scheduler_impl.h",
 147     "filters/video_frame_scheduler_proxy.cc",
 148     "filters/video_frame_scheduler_proxy.h",
 149     "filters/vp8_bool_decoder.cc",
 150     "filters/vp8_bool_decoder.h",
 151     "filters/vp8_parser.cc",
 152     "filters/vp8_parser.h",
 153     "filters/webvtt_util.h",
 154     "filters/wsola_internals.cc",
 155     "filters/wsola_internals.h",
 156     "formats/common/offset_byte_queue.cc",
 157     "formats/common/offset_byte_queue.h",
 158     "formats/webm/webm_audio_client.cc",
 159     "formats/webm/webm_audio_client.h",
 160     "formats/webm/webm_cluster_parser.cc",
 161     "formats/webm/webm_cluster_parser.h",
 162     "formats/webm/webm_constants.cc",
 163     "formats/webm/webm_constants.h",
 164     "formats/webm/webm_content_encodings.cc",
 165     "formats/webm/webm_content_encodings.h",
 166     "formats/webm/webm_content_encodings_client.cc",
 167     "formats/webm/webm_content_encodings_client.h",
 168     "formats/webm/webm_crypto_helpers.cc",
 169     "formats/webm/webm_crypto_helpers.h",
 170     "formats/webm/webm_info_parser.cc",
 171     "formats/webm/webm_info_parser.h",
 172     "formats/webm/webm_parser.cc",
 173     "formats/webm/webm_parser.h",
 174     "formats/webm/webm_stream_parser.cc",
 175     "formats/webm/webm_stream_parser.h",
 176     "formats/webm/webm_tracks_parser.cc",
 177     "formats/webm/webm_tracks_parser.h",
 178     "formats/webm/webm_video_client.cc",
 179     "formats/webm/webm_video_client.h",
 180     "formats/webm/webm_webvtt_parser.cc",
 181     "formats/webm/webm_webvtt_parser.h",
 182     "midi/midi_manager.cc",
 183     "midi/midi_manager.h",
 184     "midi/midi_manager_mac.cc",
 185     "midi/midi_manager_mac.h",
 186     "midi/midi_manager_usb.cc",
 187     "midi/midi_manager_usb.h",
 188     "midi/midi_manager_win.cc",
 189     "midi/midi_manager_win.h",
 190     "midi/midi_message_queue.cc",
 191     "midi/midi_message_queue.h",
 192     "midi/midi_message_util.cc",
 193     "midi/midi_message_util.h",
 194     "midi/midi_port_info.cc",
 195     "midi/midi_port_info.h",
 196     "midi/usb_midi_descriptor_parser.cc",
 197     "midi/usb_midi_descriptor_parser.h",
 198     "midi/usb_midi_device.h",
 199     "midi/usb_midi_input_stream.cc",
 200     "midi/usb_midi_input_stream.h",
 201     "midi/usb_midi_jack.h",
 202     "midi/usb_midi_output_stream.cc",
 203     "midi/usb_midi_output_stream.h",
 204     "renderers/audio_renderer_impl.cc",
 205     "renderers/audio_renderer_impl.h",
 206     "renderers/gpu_video_accelerator_factories.cc",
 207     "renderers/gpu_video_accelerator_factories.h",
 208     "renderers/renderer_impl.cc",
 209     "renderers/renderer_impl.h",
 210     "renderers/video_renderer_impl.cc",
 211     "renderers/video_renderer_impl.h",
 212     "video/capture/file_video_capture_device.cc",
 213     "video/capture/file_video_capture_device.h",
 214     "video/capture/linux/video_capture_device_chromeos.cc",
 215     "video/capture/linux/video_capture_device_chromeos.h",
 216     "video/capture/linux/video_capture_device_linux.cc",
 217     "video/capture/linux/video_capture_device_linux.h",
 218     "video/capture/mac/platform_video_capturing_mac.h",
 219     "video/capture/mac/video_capture_device_avfoundation_mac.h",
 220     "video/capture/mac/video_capture_device_avfoundation_mac.mm",
 221     "video/capture/mac/video_capture_device_decklink_mac.h",
 222     "video/capture/mac/video_capture_device_decklink_mac.mm",
 223     "video/capture/mac/video_capture_device_factory_mac.h",
 224     "video/capture/mac/video_capture_device_factory_mac.mm",
 225     "video/capture/mac/video_capture_device_mac.h",
 226     "video/capture/mac/video_capture_device_mac.mm",
 227     "video/capture/mac/video_capture_device_qtkit_mac.h",
 228     "video/capture/mac/video_capture_device_qtkit_mac.mm",
 229     "video/capture/video_capture_device.cc",
 230     "video/capture/video_capture_device.h",
 231     "video/capture/video_capture_device_info.cc",
 232     "video/capture/video_capture_device_info.h",
 233     "video/capture/win/capability_list_win.cc",
 234     "video/capture/win/capability_list_win.h",
 235     "video/capture/win/filter_base_win.cc",
 236     "video/capture/win/filter_base_win.h",
 237     "video/capture/win/pin_base_win.cc",
 238     "video/capture/win/pin_base_win.h",
 239     "video/capture/win/sink_filter_observer_win.h",
 240     "video/capture/win/sink_filter_win.cc",
 241     "video/capture/win/sink_filter_win.h",
 242     "video/capture/win/sink_input_pin_win.cc",
 243     "video/capture/win/sink_input_pin_win.h",
 244     "video/capture/win/video_capture_device_factory_win.cc",
 245     "video/capture/win/video_capture_device_factory_win.h",
 246     "video/capture/win/video_capture_device_mf_win.cc",
 247     "video/capture/win/video_capture_device_mf_win.h",
 248     "video/capture/win/video_capture_device_win.cc",
 249     "video/capture/win/video_capture_device_win.h",
 250     "video/fake_video_encode_accelerator.cc",
 251     "video/fake_video_encode_accelerator.h",
 252     "video/h264_poc.cc",
 253     "video/h264_poc.h",
 254     "video/picture.cc",
 255     "video/picture.h",
 256     "video/video_decode_accelerator.cc",
 257     "video/video_decode_accelerator.h",
 258     "video/video_encode_accelerator.cc",
 259     "video/video_encode_accelerator.h",
 260   ]
 261
 262   configs += [
 263     ":media_config",
 264
 265     # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 266     # See http://crbug.com/171009
 267     "//build/config/compiler:no_size_t_to_int_warning",
 268   ]
 269   all_dependent_configs = [ ":media_dependent_config" ]
 270
 271   cflags = []
 272   libs = []
 273   defines = []
 274   deps = []
 275
 276   include_dirs = [ "." ]
 277   if (media_use_ffmpeg) {
 278     deps += [ "//third_party/ffmpeg" ]
 279     sources += [
 280       "ffmpeg/ffmpeg_common.cc",
 281       "ffmpeg/ffmpeg_common.h",
 282       "filters/audio_file_reader.cc",
 283       "filters/audio_file_reader.h",
 284       "filters/blocking_url_protocol.cc",
 285       "filters/blocking_url_protocol.h",
 286       "filters/ffmpeg_audio_decoder.cc",
 287       "filters/ffmpeg_audio_decoder.h",
 288       "filters/ffmpeg_bitstream_converter.h",
 289       "filters/ffmpeg_demuxer.cc",
 290       "filters/ffmpeg_demuxer.h",
 291       "filters/ffmpeg_glue.cc",
 292       "filters/ffmpeg_glue.h",
 293       "filters/ffmpeg_video_decoder.cc",
 294       "filters/ffmpeg_video_decoder.h",
 295       "filters/in_memory_url_protocol.cc",
 296       "filters/in_memory_url_protocol.h",
 297     ]
 298     if (proprietary_codecs) {
 299       sources += [
 300         "filters/ffmpeg_aac_bitstream_converter.cc",
 301         "filters/ffmpeg_aac_bitstream_converter.h",
 302         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.cc",
 303         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.h",
 304       ]
 305     }
 306   }
 307
 308   if (current_cpu == "arm" && arm_use_neon) {
 309     defines += [ "USE_NEON" ]
 310   }
 311
 312   if (media_use_libvpx) {
 313     sources += [
 314       "filters/vpx_video_decoder.cc",
 315       "filters/vpx_video_decoder.h",
 316     ]
 317     deps += [ "//third_party/libvpx" ]
 318   }
 319
 320   if (!is_android) {
 321     sources += [
 322       "filters/opus_audio_decoder.cc",
 323       "filters/opus_audio_decoder.h",
 324       "renderers/default_renderer_factory.cc",
 325       "renderers/default_renderer_factory.h",
 326     ]
 327   } else {
 328     sources += [
 329       "midi/midi_manager_android.cc",
 330       "midi/usb_midi_device_android.cc",
 331       "midi/usb_midi_device_android.h",
 332       "midi/usb_midi_device_factory_android.cc",
 333       "midi/usb_midi_device_factory_android.h",
 334       "video/capture/android/video_capture_device_android.cc",
 335       "video/capture/android/video_capture_device_android.h",
 336       "video/capture/android/video_capture_device_factory_android.cc",
 337       "video/capture/android/video_capture_device_factory_android.h",
 338     ]
 339     deps += [
 340       "//media/base/android",
 341       "//media/base/android:media_jni_headers",
 342       "//media/base/android:video_capture_jni_headers",
 343     ]
 344     if (!is_android_webview_build) {
 345       deps += [ "//media/base/android:media_java" ]
 346     }
 347   }
 348
 349   if (current_cpu != "arm" && is_chromeos) {
 350     sources += [
 351       "filters/h264_bitstream_buffer.cc",
 352       "filters/h264_bitstream_buffer.h",
 353     ]
 354   }
 355
 356   if (use_alsa) {
 357     libs += [ "asound" ]
 358     sources += [
 359       "midi/midi_manager_alsa.cc",
 360       "midi/midi_manager_alsa.h",
 361     ]
 362   }
 363
 364   if (use_udev) {
 365     deps += [ "//device/udev_linux" ]
 366   }
 367
 368   # A simple WebM encoder for animated avatars on ChromeOS.
 369
 370   if (use_ozone) {
 371     # Used for the generated listing header (ui/ozone/platform_list.h)
 372     include_dirs += [ target_gen_dir ]
 373
 374     sources += [
 375                  "ozone/media_ozone_platform.cc",
 376                  "ozone/media_ozone_platform.h",
 377                ] + get_target_outputs(":generate_ozone_constructor_list")
 378
 379     deps += [
 380       ":generate_ozone_constructor_list",
 381       "//ui/ozone",
 382     ]
 383   }
 384
 385   if (is_mac) {
 386     deps += [
 387       "//media/base/mac",
 388       "//third_party/decklink",
 389     ]
 390     libs += [
 391       "CoreMIDI.framework",
 392       "CoreVideo.framework",
 393       "OpenGL.framework",
 394       "QTKit.framework",
 395     ]
 396   }
 397
 398   if (is_ios) {
 399     deps += [ "//media/base/mac" ]
 400   }
 401
 402   if (is_win) {
 403     libs += [
 404       "mf.lib",
 405       "mfplat.lib",
 406       "mfreadwrite.lib",
 407       "mfuuid.lib",
 408     ]
 409   }
 410
 411   if (proprietary_codecs) {
 412     sources += [
 413       "filters/h264_to_annex_b_bitstream_converter.cc",
 414       "filters/h264_to_annex_b_bitstream_converter.h",
 415       "formats/mp2t/es_adapter_video.cc",
 416       "formats/mp2t/es_adapter_video.h",
 417       "formats/mp2t/es_parser.cc",
 418       "formats/mp2t/es_parser.h",
 419       "formats/mp2t/es_parser_adts.cc",
 420       "formats/mp2t/es_parser_adts.h",
 421       "formats/mp2t/es_parser_h264.cc",
 422       "formats/mp2t/es_parser_h264.h",
 423       "formats/mp2t/es_parser_mpeg1audio.cc",
 424       "formats/mp2t/es_parser_mpeg1audio.h",
 425       "formats/mp2t/mp2t_common.h",
 426       "formats/mp2t/mp2t_stream_parser.cc",
 427       "formats/mp2t/mp2t_stream_parser.h",
 428       "formats/mp2t/timestamp_unroller.cc",
 429       "formats/mp2t/timestamp_unroller.h",
 430       "formats/mp2t/ts_packet.cc",
 431       "formats/mp2t/ts_packet.h",
 432       "formats/mp2t/ts_section.h",
 433       "formats/mp2t/ts_section_pat.cc",
 434       "formats/mp2t/ts_section_pat.h",
 435       "formats/mp2t/ts_section_pes.cc",
 436       "formats/mp2t/ts_section_pes.h",
 437       "formats/mp2t/ts_section_pmt.cc",
 438       "formats/mp2t/ts_section_pmt.h",
 439       "formats/mp2t/ts_section_psi.cc",
 440       "formats/mp2t/ts_section_psi.h",
 441       "formats/mp4/aac.cc",
 442       "formats/mp4/aac.h",
 443       "formats/mp4/avc.cc",
 444       "formats/mp4/avc.h",
 445       "formats/mp4/box_definitions.cc",
 446       "formats/mp4/box_definitions.h",
 447       "formats/mp4/box_reader.cc",
 448       "formats/mp4/box_reader.h",
 449       "formats/mp4/cenc.cc",
 450       "formats/mp4/cenc.h",
 451       "formats/mp4/es_descriptor.cc",
 452       "formats/mp4/es_descriptor.h",
 453       "formats/mp4/mp4_stream_parser.cc",
 454       "formats/mp4/mp4_stream_parser.h",
 455       "formats/mp4/sample_to_group_iterator.cc",
 456       "formats/mp4/sample_to_group_iterator.h",
 457       "formats/mp4/track_run_iterator.cc",
 458       "formats/mp4/track_run_iterator.h",
 459       "formats/mpeg/adts_constants.cc",
 460       "formats/mpeg/adts_constants.h",
 461       "formats/mpeg/adts_stream_parser.cc",
 462       "formats/mpeg/adts_stream_parser.h",
 463       "formats/mpeg/mpeg1_audio_stream_parser.cc",
 464       "formats/mpeg/mpeg1_audio_stream_parser.h",
 465       "formats/mpeg/mpeg_audio_stream_parser_base.cc",
 466       "formats/mpeg/mpeg_audio_stream_parser_base.h",
 467     ]
 468   }
 469
 470   public_deps = [
 471     "//media/base",
 472     "//media/audio",
 473   ]
 474
 475   deps += [
 476     ":shared_memory_support",
 477     "//base",
 478     "//base:i18n",
 479     "//base/third_party/dynamic_annotations",
 480     "//crypto",
 481     "//crypto:platform",  # TODO(ajwong): This used to be provided by crypto.gyp via export_dependent_settings
 482     "//gpu/command_buffer/common",
 483     "//skia",
 484     "//third_party/libyuv",
 485     "//third_party/opus",
 486     "//ui/gfx/geometry",
 487     "//url",
 488   ]
 489
 490   # Add the sources and dependencies that need the X11 or fontconfig libraries.
 491   if (!is_ensemble) {
 492     sources += [
 493       "video/capture/fake_video_capture_device.cc",
 494       "video/capture/fake_video_capture_device.h",
 495       "video/capture/fake_video_capture_device_factory.cc",
 496       "video/capture/fake_video_capture_device_factory.h",
 497       "video/capture/file_video_capture_device_factory.cc",
 498       "video/capture/file_video_capture_device_factory.h",
 499       "video/capture/linux/video_capture_device_factory_linux.cc",
 500       "video/capture/linux/video_capture_device_factory_linux.h",
 501       "video/capture/video_capture_device_factory.cc",
 502       "video/capture/video_capture_device_factory.h",
 503     ]
 504
 505     deps += [
 506       "//ui/events:events_base",
 507       "//ui/gfx",
 508     ]
 509   }
 510 }
 511
 512 # Minimal media component for media/cast on iOS.
 513 if (is_ios) {
 514   component("media_for_cast_ios") {
 515     configs += [ ":media_config" ]
 516     all_dependent_configs = [ ":media_dependent_config" ]
 517     include_dirs = [ "." ]
 518     libs = [ "CoreVideo.framework" ]
 519
 520     deps = [
 521       ":shared_memory_support",
 522       "//base",
 523       "//media/base:base_for_cast_ios",
 524       "//media/base/mac",
 525       "//ui/gfx/geometry",
 526     ]
 527   }
 528 }
 529
 530 test("media_unittests") {
 531   sources = [
 532     "blink/skcanvas_video_renderer_unittest.cc",
 533     "cdm/aes_decryptor_unittest.cc",
 534     "cdm/cenc_utils_unittest.cc",
 535     "cdm/json_web_key_unittest.cc",
 536     "filters/audio_clock_unittest.cc",
 537     "filters/audio_decoder_selector_unittest.cc",
 538     "filters/audio_renderer_algorithm_unittest.cc",
 539     "filters/chunk_demuxer_unittest.cc",
 540     "filters/decrypting_audio_decoder_unittest.cc",
 541     "filters/decrypting_demuxer_stream_unittest.cc",
 542     "filters/decrypting_video_decoder_unittest.cc",
 543     "filters/fake_demuxer_stream.cc",
 544     "filters/fake_demuxer_stream.h",
 545     "filters/fake_demuxer_stream_unittest.cc",
 546     "filters/fake_video_decoder.cc",
 547     "filters/fake_video_decoder.h",
 548     "filters/fake_video_decoder_unittest.cc",
 549     "filters/file_data_source_unittest.cc",
 550     "filters/frame_processor_unittest.cc",
 551     "filters/h264_bit_reader_unittest.cc",
 552     "filters/h264_parser_unittest.cc",
 553     "filters/jpeg_parser_unittest.cc",
 554     "filters/source_buffer_stream_unittest.cc",
 555     "filters/video_decoder_selector_unittest.cc",
 556     "filters/video_frame_scheduler_impl_unittest.cc",
 557     "filters/video_frame_scheduler_unittest.cc",
 558     "filters/video_frame_stream_unittest.cc",
 559     "filters/vp8_bool_decoder_unittest.cc",
 560     "filters/vp8_parser_unittest.cc",
 561     "formats/common/offset_byte_queue_unittest.cc",
 562     "formats/webm/cluster_builder.cc",
 563     "formats/webm/cluster_builder.h",
 564     "formats/webm/opus_packet_builder.cc",
 565     "formats/webm/opus_packet_builder.h",
 566     "formats/webm/tracks_builder.cc",
 567     "formats/webm/tracks_builder.h",
 568     "formats/webm/webm_cluster_parser_unittest.cc",
 569     "formats/webm/webm_content_encodings_client_unittest.cc",
 570     "formats/webm/webm_parser_unittest.cc",
 571     "formats/webm/webm_tracks_parser_unittest.cc",
 572     "formats/webm/webm_webvtt_parser_unittest.cc",
 573     "midi/midi_manager_unittest.cc",
 574     "midi/midi_manager_usb_unittest.cc",
 575     "midi/midi_message_queue_unittest.cc",
 576     "midi/midi_message_util_unittest.cc",
 577     "midi/usb_midi_descriptor_parser_unittest.cc",
 578     "midi/usb_midi_input_stream_unittest.cc",
 579     "midi/usb_midi_output_stream_unittest.cc",
 580     "renderers/audio_renderer_impl_unittest.cc",
 581     "renderers/renderer_impl_unittest.cc",
 582     "renderers/video_renderer_impl_unittest.cc",
 583     "video/capture/fake_video_capture_device_unittest.cc",
 584     "video/capture/video_capture_device_unittest.cc",
 585     "video/h264_poc_unittest.cc",
 586   ]
 587
 588   # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 589   # See http://crbug.com/171009
 590   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 591
 592   deps = [
 593     ":media",
 594     ":test_support",
 595     "//base/allocator",
 596     "//base/test:test_support",
 597     "//media/audio:unittests",
 598     "//media/audio:test_support",
 599     "//media/base:unittests",
 600     "//media/base:test_support",
 601     "//media/test:pipeline_integration_tests",
 602     "//skia",  # Direct dependency required to inherit config.
 603     "//testing/gmock",
 604     "//testing/gtest",
 605     "//third_party/widevine/cdm:version_h",
 606     "//ui/gfx:test_support",
 607     "//url",
 608   ]
 609
 610   if (is_android) {
 611     deps += [
 612       "//media/base/android",
 613       # TODO(GYP)
 614       #"//testing/android:native_test_native_code"
 615     ]
 616   }
 617
 618   if (media_use_ffmpeg) {
 619     sources += [
 620       "ffmpeg/ffmpeg_common_unittest.cc",
 621       "filters/audio_decoder_unittest.cc",
 622       "filters/audio_file_reader_unittest.cc",
 623       "filters/blocking_url_protocol_unittest.cc",
 624       "filters/ffmpeg_demuxer_unittest.cc",
 625       "filters/ffmpeg_glue_unittest.cc",
 626       "filters/ffmpeg_video_decoder_unittest.cc",
 627       "filters/in_memory_url_protocol_unittest.cc",
 628     ]
 629   }
 630
 631   if (current_cpu != "arm" && is_chromeos) {
 632     sources += [ "filters/h264_bitstream_buffer_unittest.cc" ]
 633   }
 634
 635   if (proprietary_codecs) {
 636     sources += [
 637       "filters/ffmpeg_aac_bitstream_converter_unittest.cc",
 638       "filters/ffmpeg_h264_to_annex_b_bitstream_converter_unittest.cc",
 639       "filters/h264_to_annex_b_bitstream_converter_unittest.cc",
 640       "formats/common/stream_parser_test_base.cc",
 641       "formats/common/stream_parser_test_base.h",
 642       "formats/mp2t/es_adapter_video_unittest.cc",
 643       "formats/mp2t/es_parser_adts_unittest.cc",
 644       "formats/mp2t/es_parser_h264_unittest.cc",
 645       "formats/mp2t/es_parser_mpeg1audio_unittest.cc",
 646       "formats/mp2t/es_parser_test_base.cc",
 647       "formats/mp2t/es_parser_test_base.h",
 648       "formats/mp2t/mp2t_stream_parser_unittest.cc",
 649       "formats/mp2t/timestamp_unroller_unittest.cc",
 650       "formats/mp4/aac_unittest.cc",
 651       "formats/mp4/avc_unittest.cc",
 652       "formats/mp4/box_reader_unittest.cc",
 653       "formats/mp4/es_descriptor_unittest.cc",
 654       "formats/mp4/mp4_stream_parser_unittest.cc",
 655       "formats/mp4/sample_to_group_iterator_unittest.cc",
 656       "formats/mp4/track_run_iterator_unittest.cc",
 657       "formats/mpeg/adts_stream_parser_unittest.cc",
 658       "formats/mpeg/mpeg1_audio_stream_parser_unittest.cc",
 659     ]
 660   }
 661
 662   if (is_mac || is_ios) {
 663     deps += [ "//media/base/mac" ]
 664   }
 665
 666   if (is_mac) {
 667     sources += [
 668       "midi/midi_manager_mac_unittest.cc",
 669       "video/capture/mac/video_capture_device_factory_mac_unittest.mm",
 670     ]
 671   }
 672
 673   if (use_alsa) {
 674     sources += [ "midi/midi_manager_alsa_unittest.cc" ]
 675   }
 676
 677   #      include_dirs += [
 678   #        # Needed by media_drm_bridge.cc.
 679   #        target_gen_dir,
 680   #      ],
 681
 682   configs += [ ":media_config" ]
 683
 684   if (media_use_ffmpeg) {
 685     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 686   }
 687 }
 688
 689 test("media_perftests") {
 690   configs += [ ":media_config" ]
 691   deps = [
 692     ":media",
 693     ":shared_memory_support",
 694     ":test_support",
 695     "//base/test:test_support",
 696     "//media/audio:test_support",
 697     "//media/base:perftests",
 698     "//media/base:test_support",
 699     "//media/test:pipeline_integration_perftests",
 700     "//testing/gmock",
 701     "//testing/gtest",
 702     "//testing/perf",
 703     "//third_party/widevine/cdm:version_h",
 704     "//ui/gfx:test_support",
 705   ]
 706   if (is_android) {
 707     deps += [ "//ui/gl" ]
 708   }
 709   if (media_use_ffmpeg) {
 710     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 711   }
 712 }
 713
 714 source_set("test_support") {
 715   testonly = true
 716   sources = [
 717     "filters/clockless_video_frame_scheduler.cc",
 718     "filters/clockless_video_frame_scheduler.h",
 719     "filters/test_video_frame_scheduler.cc",
 720     "filters/test_video_frame_scheduler.h",
 721     "renderers/mock_gpu_video_accelerator_factories.cc",
 722     "renderers/mock_gpu_video_accelerator_factories.h",
 723     "video/mock_video_decode_accelerator.cc",
 724     "video/mock_video_decode_accelerator.h",
 725   ]
 726   deps = [
 727     ":media",
 728     ":shared_memory_support",
 729     "//base",
 730     "//skia",
 731     "//testing/gmock",
 732     "//testing/gtest",
 733   ]
 734 }
 735
 736 # TODO(dalecurtis): How to split this across audio/base directories??
 737 component("shared_memory_support") {
 738   sources = [
 739     "audio/audio_parameters.cc",
 740     "audio/audio_parameters.h",
 741     "base/audio_bus.cc",
 742     "base/audio_bus.h",
 743     "base/channel_layout.cc",
 744     "base/channel_layout.h",
 745     "base/limits.h",
 746     "base/media_export.h",
 747     "base/vector_math.cc",
 748     "base/vector_math.h",
 749   ]
 750   configs += [ ":media_config" ]
 751   defines = [ "MEDIA_IMPLEMENTATION" ]
 752   deps = [
 753     "//base",
 754   ]
 755 }
 756
 757 if (media_use_ffmpeg) {
 758   test("ffmpeg_regression_tests") {
 759     sources = [
 760       "base/run_all_unittests.cc",
 761       "ffmpeg/ffmpeg_regression_tests.cc",
 762     ]
 763
 764     configs += [ "//media:media_config" ]
 765
 766     deps = [
 767       "//base/test:test_support",
 768       "//media",
 769       "//media:test_support",
 770       "//media/audio:test_support",
 771       "//media/base:test_support",
 772       "//media/test:pipeline_integration_tests",
 773       "//testing/gmock",
 774       "//testing/gtest",
 775       "//third_party/ffmpeg",
 776       "//ui/gfx/geometry",
 777       "//ui/gfx:test_support",
 778     ]
 779   }
 780 }
 781
 782 if (use_x11) {
 783   executable("player_x11") {
 784     sources = [
 785       "tools/player_x11/data_source_logger.cc",
 786       "tools/player_x11/data_source_logger.h",
 787       "tools/player_x11/gl_video_renderer.cc",
 788       "tools/player_x11/gl_video_renderer.h",
 789       "tools/player_x11/player_x11.cc",
 790       "tools/player_x11/x11_video_renderer.cc",
 791       "tools/player_x11/x11_video_renderer.h",
 792     ]
 793     configs += [
 794       ":media_config",
 795       "//build/config/linux:x11",
 796       "//build/config/linux:xext",
 797
 798       # TODO(ajwong): Why does xext get a separate thing in //build/config/linux:BUILD.gn
 799       #  "//build/config/linux:xrender",
 800     ]
 801     deps = [
 802       ":media",
 803       ":shared_memory_support",
 804       "//base",
 805       "//ui/gl",
 806       "//ui/gfx",
 807       "//ui/gfx/geometry",
 808     ]
 809   }
 810 }