| blob | 0424ca519355d5e86ede6373cc6e72b56a5eb0d9 |
1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
2 # Use of this source code is governed by a BSD-style license that can be
3 # found in the LICENSE file.
5 import("//build/config/android/config.gni")
6 import("//build/config/chrome_build.gni")
7 if (current_cpu == "arm") {
8 import("//build/config/arm.gni")
9 }
10 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
11 import("//build/config/mips.gni")
12 }
13 if (is_posix) {
14 import("//build/config/gcc/gcc_version.gni")
15 }
16 if (is_win) {
17 import("//build/config/win/visual_studio_version.gni")
18 }
20 import("//build/toolchain/ccache.gni")
21 import("//build/config/sanitizers/sanitizers.gni")
23 declare_args() {
24 # Normally, Android builds are lightly optimized, even for debug builds, to
25 # keep binary size down. Setting this flag to true disables such optimization
26 android_full_debug = false
28 # Whether to use the binary binutils checked into third_party/binutils.
29 # These are not multi-arch so cannot be used except on x86 and x86-64 (the
30 # only two architectures that are currently checked in). Turn this off when
31 # you are using a custom toolchain and need to control -B in cflags.
32 linux_use_bundled_binutils = is_linux && current_cpu == "x64"
33 binutils_path = rebase_path("//third_party/binutils/Linux_x64/Release/bin",
34 root_build_dir)
36 # Compile in such a way as to enable profiling of the generated code. For
37 # example, don't omit the frame pointer and leave in symbols.
38 enable_profiling = false
40 # Compile in such a way as to make it possible for the profiler to unwind full
41 # stack frames. Setting this flag has a large effect on the performance of the
42 # generated code than just setting profiling, but gives the profiler more
43 # information to analyze.
44 # Requires profiling to be set to true.
45 enable_full_stack_frames_for_profiling = false
47 # Use gold for linking on 64-bit Linux only (on 32-bit it runs out of
48 # address space, and it doesn't support cross-compiling).
49 use_gold = is_linux && current_cpu == "x64"
51 # When we are going to use gold we need to find it.
52 if (use_gold) {
53 gold_path = rebase_path("//third_party/binutils/Linux_x64/Release/bin",
54 root_build_dir)
55 } else {
56 gold_path = ""
57 }
59 # use_debug_fission: whether to use split DWARF debug info
60 # files. This can reduce link time significantly, but is incompatible
61 # with some utilities such as icecc and ccache. Requires gold and
62 # gcc >= 4.8 or clang.
63 # http://gcc.gnu.org/wiki/DebugFission
64 use_debug_fission = is_debug && !is_win && use_gold &&
65 linux_use_bundled_binutils && !use_ccache
67 if (is_win) {
68 # Whether the VS xtree header has been patched to disable warning 4702. If
69 # it has, then we don't need to disable 4702 (unreachable code warning).
70 # The patch is preapplied to the internal toolchain and hence all bots.
71 msvs_xtree_patched = false
72 }
73 }
75 # default_include_dirs ---------------------------------------------------------
76 #
77 # This is a separate config so that third_party code (which would not use the
78 # source root and might have conflicting versions of some headers) can remove
79 # this and specify their own include paths.
80 config("default_include_dirs") {
81 include_dirs = [
82 "//",
83 root_gen_dir,
84 ]
85 }
87 # TODO(GYP): is_ubsan, is_ubsan_vptr
88 if (!is_win) {
89 using_sanitizer = is_asan || is_lsan || is_tsan || is_msan
90 }
92 # compiler ---------------------------------------------------------------------
93 #
94 # Base compiler configuration.
95 #
96 # See also "runtime_library" below for related stuff and a discussion about
97 # where stuff should go. Put warning related stuff in the "warnings" config.
99 config("compiler") {
100 cflags = []
101 cflags_c = []
102 cflags_cc = []
103 cflags_objc = []
104 cflags_objcc = []
105 ldflags = []
106 defines = []
108 # In general, Windows is totally different, but all the other builds share
109 # some common GCC configuration. This section sets up Windows and the common
110 # GCC flags, and then we handle the other non-Windows platforms specifically
111 # below.
112 if (is_win) {
113 # Windows compiler flags setup.
114 # -----------------------------
115 cflags += [
116 "/Gy", # Enable function-level linking.
117 "/GS", # Enable buffer security checking.
118 "/FS", # Preserve previous PDB behavior.
119 "/bigobj", # Some of our files are bigger than the regular limits.
120 ]
122 # Force C/C++ mode for the given GN detected file type. This is necessary
123 # for precompiled headers where the same source file is compiled in both
124 # modes.
125 cflags_c += [ "/TC" ]
126 cflags_cc += [ "/TP" ]
128 # Building with Clang on Windows is a work in progress and very
129 # experimental. See crbug.com/82385.
130 # Keep this in sync with the similar block in build/common.gypi
131 if (is_clang) {
132 cflags += [
133 # Many files use intrinsics without including this header.
134 # TODO(hans): Fix those files, or move this to sub-GYPs.
135 "/FIIntrin.h",
136 ]
138 if (visual_studio_version == "2013") {
139 cflags += [ "-fmsc-version=1800" ]
140 } else if (visual_studio_version == "2015") {
141 cflags += [ "-fmsc-version=1900" ]
142 }
144 if (current_cpu == "x86") {
145 cflags += [ "-m32" ]
146 } else {
147 cflags += [ "-m64" ]
148 }
150 if (exec_script("//build/win/use_ansi_codes.py", [], "trim string") ==
151 "True") {
152 cflags += [
153 # cmd.exe doesn't understand ANSI escape codes by default,
154 # so only enable them if something emulating them is around.
155 "-fansi-escape-codes",
156 ]
157 }
158 }
160 if (is_syzyasan) {
161 # SyzyAsan needs /PROFILE turned on to produce appropriate pdbs.
162 assert(!is_win_fastlink, "/PROFILE and /DEBUG:FASTLINK are incompatible")
163 ldflags += [ "/PROFILE" ]
164 }
165 } else {
166 # Common GCC compiler flags setup.
167 # --------------------------------
168 cflags += [ "-fno-strict-aliasing" ] # See http://crbug.com/32204
169 cflags_cc += [
170 "-fno-threadsafe-statics",
172 # Not exporting C++ inline functions can generally be applied anywhere
173 # so we do so here. Normal function visibility is controlled by
174 # //build/config/gcc:symbol_visibility_hidden.
175 "-fvisibility-inlines-hidden",
176 ]
178 # Stack protection.
179 if (is_mac) {
180 cflags += [ "-fstack-protector-all" ]
181 } else if (is_posix && !is_chromeos && !is_nacl) {
182 # TODO(phajdan.jr): Use -fstack-protector-strong when our gcc supports it.
183 cflags += [ "--param=ssp-buffer-size=4" ]
184 if (is_android && (current_cpu == "arm64" || current_cpu == "x86")) {
185 cflags += [ "-fno-stack-protector" ]
186 } else {
187 cflags += [ "-fstack-protector" ]
188 }
189 }
191 # Linker warnings.
192 if (!(is_chromeos && current_cpu == "arm") && !is_mac && !is_ios) {
193 # TODO(jochen): Enable this on chromeos on arm. http://crbug.com/356580
194 ldflags += [ "-Wl,--fatal-warnings" ]
195 }
197 # Common options for AddressSanitizer, LeakSanitizer, ThreadSanitizer and
198 # MemorySanitizer
199 if (using_sanitizer) {
200 cflags += [
201 "-fno-omit-frame-pointer",
202 "-gline-tables-only",
203 ]
204 }
205 if (is_asan) {
206 asan_blacklist_path =
207 rebase_path("//tools/memory/asan/blacklist.txt", root_build_dir)
208 cflags += [
209 "-fsanitize=address",
210 "-fsanitize-blacklist=$asan_blacklist_path",
211 ]
212 if (is_mac) {
213 cflags += [ "-mllvm -asan-globals=0" ] # http://crbug.com/352073
214 # TODO(GYP): deal with mac_bundles.
215 }
216 }
217 if (is_lsan) {
218 cflags += [ "-fsanitize=leak" ]
219 }
220 if (is_tsan) {
221 tsan_blacklist_path =
222 rebase_path("//tools/memory/tsan_v2/ignores.txt", root_build_dir)
223 cflags += [
224 "-fsanitize=thread",
225 "-fsanitize-blacklist=$tsan_blacklist_path",
226 ]
227 }
228 if (is_msan) {
229 msan_blacklist_path =
230 rebase_path("//tools/msan/blacklist.txt", root_build_dir)
231 cflags += [
232 "-fsanitize=memory",
233 "-fsanitize-memory-track-origins=$msan_track_origins",
234 "-fsanitize-blacklist=$msan_blacklist_path",
235 ]
236 }
238 if (use_custom_libcxx) {
239 cflags_cc += [ "-nostdinc++" ]
240 include_dirs = [
241 "//buildtools/third_party/libc++/trunk/include",
242 "//buildtools/third_party/libc++abi/trunk/include",
243 ]
244 }
245 }
247 if (is_clang && is_debug) {
248 # Allow comparing the address of references and 'this' against 0
249 # in debug builds. Technically, these can never be null in
250 # well-defined C/C++ and Clang can optimize such checks away in
251 # release builds, but they may be used in asserts in debug builds.
252 cflags_cc += [
253 "-Wno-undefined-bool-conversion",
254 "-Wno-tautological-undefined-compare",
255 ]
256 }
258 if (is_clang && !is_nacl) {
259 # This is here so that all files get recompiled after a clang roll and
260 # when turning clang on or off. (defines are passed via the command line,
261 # and build system rebuild things when their commandline changes). Nothing
262 # should ever read this define.
263 defines +=
264 [ "CR_CLANG_REVISION=" + exec_script("//tools/clang/scripts/update.py",
265 [ "--print-revision" ],
266 "trim string") ]
267 }
269 # Mac-specific compiler flags setup.
270 # ----------------------------------
271 if (is_mac || is_ios) {
272 # These flags are shared between the C compiler and linker.
273 common_mac_flags = []
275 # CPU architecture.
276 if (current_cpu == "x64") {
277 common_mac_flags += [
278 "-arch",
279 "x86_64",
280 ]
281 } else if (current_cpu == "x86") {
282 common_mac_flags += [
283 "-arch",
284 "i386",
285 ]
286 } else if (current_cpu == "arm") {
287 common_mac_flags += [
288 "-arch",
289 "armv7",
290 ]
291 }
293 cflags += common_mac_flags
295 # Without this, the constructors and destructors of a C++ object inside
296 # an Objective C struct won't be called, which is very bad.
297 cflags_objcc += [ "-fobjc-call-cxx-cdtors" ]
299 cflags_c += [ "-std=c99" ]
301 ldflags += common_mac_flags
302 } else if (is_posix) {
303 # Non-Mac Posix compiler flags setup.
304 # -----------------------------------
305 if (enable_profiling && !is_debug) {
306 # The GYP build spams this define into every compilation unit, as we do
307 # here, but it only appears to be used in base and a couple other places.
308 # TODO(abarth): Should we move this define closer to where it's used?
309 defines += [ "ENABLE_PROFILING" ]
311 cflags += [
312 "-fno-omit-frame-pointer",
313 "-g",
314 ]
316 if (enable_full_stack_frames_for_profiling) {
317 cflags += [
318 "-fno-inline",
319 "-fno-optimize-sibling-calls",
320 ]
321 }
322 }
324 # CPU architecture. We may or may not be doing a cross compile now, so for
325 # simplicity we always explicitly set the architecture.
326 if (current_cpu == "x64") {
327 cflags += [
328 "-m64",
329 "-march=x86-64",
330 ]
331 ldflags += [ "-m64" ]
332 } else if (current_cpu == "x86") {
333 cflags += [ "-m32" ]
334 ldflags += [ "-m32" ]
335 if (is_clang) {
336 cflags += [
337 # Else building libyuv gives clang's register allocator issues,
338 # see llvm.org/PR15798 / crbug.com/233709
339 "-momit-leaf-frame-pointer",
341 # Align the stack on 16-byte boundaries, http://crbug.com/418554.
342 "-mstack-alignment=16",
343 "-mstackrealign",
344 ]
345 }
346 } else if (current_cpu == "arm") {
347 cflags += [
348 "-march=$arm_arch",
349 "-mfloat-abi=$arm_float_abi",
350 ]
351 if (arm_tune != "") {
352 cflags += [ "-mtune=$arm_tune" ]
353 }
354 if (arm_use_thumb) {
355 cflags += [ "-mthumb" ]
356 if (is_android && !is_clang) { # Clang doesn't support this option.
357 cflags += [ "-mthumb-interwork" ]
358 }
359 }
360 if (!is_clang) {
361 # Clang doesn't support these flags.
362 cflags += [
363 # The tree-sra optimization (scalar replacement for
364 # aggregates enabling subsequent optimizations) leads to
365 # invalid code generation when using the Android NDK's
366 # compiler (r5-r7). This can be verified using
367 # webkit_unit_tests' WTF.Checked_int8_t test.
368 "-fno-tree-sra",
370 # The following option is disabled to improve binary
371 # size and performance in gcc 4.9.
372 "-fno-caller-saves",
373 ]
374 }
375 } else if (current_cpu == "mipsel") {
376 if (mips_arch_variant == "r6") {
377 cflags += [
378 "-mips32r6",
379 "-Wa,-mips32r6",
380 ]
381 if (is_android) {
382 ldflags += [
383 "-mips32r6",
384 "-Wl,-melf32ltsmip",
385 ]
386 }
387 } else if (mips_arch_variant == "r2") {
388 cflags += [
389 "-mips32r2",
390 "-Wa,-mips32r2",
391 ]
392 if (mips_float_abi == "hard" && mips_fpu_mode != "") {
393 cflags += [ "-m$mips_fpu_mode" ]
394 }
395 } else if (mips_arch_variant == "r1") {
396 cflags += [
397 "-mips32",
398 "-Wa,-mips32",
399 ]
400 }
402 if (mips_dsp_rev == 1) {
403 cflags += [ "-mdsp" ]
404 } else if (mips_dsp_rev == 2) {
405 cflags += [ "-mdspr2" ]
406 }
408 cflags += [ "-m${mips_float_abi}-float" ]
409 } else if (current_cpu == "mips64el") {
410 if (mips_arch_variant == "r6") {
411 cflags += [
412 "-mips64r6",
413 "-Wa,-mips64r6",
414 ]
415 ldflags += [ "-mips64r6" ]
416 } else if (mips_arch_variant == "r2") {
417 cflags += [
418 "-mips64r2",
419 "-Wa,-mips64r2",
420 ]
421 ldflags += [ "-mips64r2" ]
422 }
423 }
425 defines += [ "_FILE_OFFSET_BITS=64" ]
427 if (!is_android) {
428 defines += [
429 "_LARGEFILE_SOURCE",
430 "_LARGEFILE64_SOURCE",
431 ]
432 }
434 # Omit unwind support in official builds to save space. We can use breakpad
435 # for these builds.
436 if (is_chrome_branded && is_official_build) {
437 cflags += [
438 "-fno-unwind-tables",
439 "-fno-asynchronous-unwind-tables",
440 ]
441 defines += [ "NO_UNWIND_TABLES" ]
442 } else {
443 cflags += [ "-funwind-tables" ]
444 }
445 }
447 # Linux/Android common flags setup.
448 # ---------------------------------
449 if (is_linux || is_android) {
450 cflags += [
451 "-fPIC",
452 "-pipe", # Use pipes for communicating between sub-processes. Faster.
453 ]
455 ldflags += [
456 "-fPIC",
457 "-Wl,-z,noexecstack",
458 "-Wl,-z,now",
459 "-Wl,-z,relro",
460 ]
461 if (!using_sanitizer) {
462 ldflags += [ "-Wl,-z,defs" ]
463 }
464 }
466 # Linux-specific compiler flags setup.
467 # ------------------------------------
468 if (is_linux) {
469 cflags += [ "-pthread" ]
470 ldflags += [ "-pthread" ]
471 }
472 if (use_gold) {
473 ldflags += [
474 "-B$gold_path",
476 # Newer gccs and clangs support -fuse-ld, use the flag to force gold
477 # selection.
478 # gcc -- http://gcc.gnu.org/onlinedocs/gcc-4.8.0/gcc/Optimize-Options.html
479 "-fuse-ld=gold",
481 # Experimentation found that using four linking threads
482 # saved ~20% of link time.
483 # https://groups.google.com/a/chromium.org/group/chromium-dev/browse_thread/thread/281527606915bb36
484 # Only apply this to the target linker, since the host
485 # linker might not be gold, but isn't used much anyway.
486 # TODO(raymes): Disable threading because gold is frequently
487 # crashing on the bots: crbug.com/161942.
488 #"-Wl,--threads",
489 #"-Wl,--thread-count=4",
490 ]
492 if (!is_asan && !is_msan && !is_lsan && !is_tsan) {
493 # TODO(brettw) common.gypi has this only for target toolset.
494 ldflags += [ "-Wl,--icf=all" ]
495 }
497 # TODO(thestig): Make this flag work with GN.
498 #if (!is_official_build && !is_chromeos && !(is_asan || is_lsan || is_tsan || is_msan)) {
499 # ldflags += [
500 # "-Wl,--detect-odr-violations",
501 # ]
502 #}
503 }
505 if (linux_use_bundled_binutils) {
506 cflags += [ "-B$binutils_path" ]
507 }
509 # Clang-specific compiler flags setup.
510 # ------------------------------------
511 if (is_clang) {
512 cflags += [ "-fcolor-diagnostics" ]
513 }
515 # C++11 compiler flags setup.
516 # ---------------------------
517 if (is_linux || is_android || is_nacl) {
518 # gnu++11 instead of c++11 is needed because some code uses typeof() (a
519 # GNU extension).
520 # TODO(thakis): Eventually switch this to c++11 instead,
521 # http://crbug.com/427584
522 cflags_cc += [ "-std=gnu++11" ]
523 } else if (!is_win) {
524 cflags_cc += [ "-std=c++11" ]
525 }
527 # Android-specific flags setup.
528 # -----------------------------
529 if (is_android) {
530 cflags += [
531 "-ffunction-sections",
532 "-funwind-tables",
533 "-fno-short-enums",
534 ]
535 if (is_clang) {
536 rebased_android_toolchain_root =
537 rebase_path(android_toolchain_root, root_build_dir)
538 cflags += [
539 # TODO(hans) Enable integrated-as (crbug.com/124610).
540 "-no-integrated-as",
541 "-B${rebased_android_toolchain_root}/bin", # Else /usr/bin/as gets picked up.
542 ]
543 } else {
544 # Clang doesn't support these flags.
545 cflags += [ "-finline-limit=64" ]
546 }
547 if (is_asan) {
548 # Android build relies on -Wl,--gc-sections removing unreachable code.
549 # ASan instrumentation for globals inhibits this and results in a library
550 # with unresolvable relocations.
551 # TODO(eugenis): find a way to reenable this.
552 cflags += [ "-mllvm -asan-globals=0" ]
553 }
555 defines += [ "ANDROID" ]
557 # The NDK has these things, but doesn't define the constants
558 # to say that it does. Define them here instead.
559 defines += [ "HAVE_SYS_UIO_H" ]
561 # Use gold for Android for most CPU architectures.
562 if (current_cpu == "x86" || current_cpu == "x64" || current_cpu == "arm") {
563 ldflags += [ "-fuse-ld=gold" ]
564 if (is_clang) {
565 # Let clang find the ld.gold in the NDK.
566 ldflags += [ "--gcc-toolchain=$rebased_android_toolchain_root" ]
567 }
568 }
570 ldflags += [
571 "-Wl,--no-undefined",
573 # Don't allow visible symbols from libgcc or libc++ to be
574 # re-exported.
575 "-Wl,--exclude-libs=libgcc.a",
576 "-Wl,--exclude-libs=libc++_static.a",
578 # Don't allow visible symbols from libraries that contain
579 # assembly code with symbols that aren't hidden properly.
580 # http://crbug.com/448386
581 "-Wl,--exclude-libs=libvpx_assembly_arm.a",
582 ]
583 if (current_cpu == "arm") {
584 ldflags += [
585 # Enable identical code folding to reduce size.
586 "-Wl,--icf=safe",
587 ]
588 }
590 if (is_clang) {
591 if (current_cpu == "arm") {
592 cflags += [
593 "-target",
594 "arm-linux-androideabi",
595 ]
596 ldflags += [
597 "-target",
598 "arm-linux-androideabi",
599 ]
600 } else if (current_cpu == "x86") {
601 cflags += [
602 "-target",
603 "i686-linux-androideabi",
604 ]
605 ldflags += [
606 "-target",
607 "i686-linux-androideabi",
608 ]
609 }
610 }
611 }
613 # Pass the same C/C++ flags to the objective C/C++ compiler.
614 cflags_objc += cflags_c
615 cflags_objcc += cflags_cc
616 }
618 config("compiler_arm_fpu") {
619 if (current_cpu == "arm" && !is_ios) {
620 cflags = [ "-mfpu=$arm_fpu" ]
621 }
622 }
624 # runtime_library -------------------------------------------------------------
625 #
626 # Sets the runtime library and associated options.
627 #
628 # How do you determine what should go in here vs. "compiler" above? Consider if
629 # a target might choose to use a different runtime library (ignore for a moment
630 # if this is possible or reasonable on your system). If such a target would want
631 # to change or remove your option, put it in the runtime_library config. If a
632 # target wants the option regardless, put it in the compiler config.
634 config("runtime_library") {
635 cflags = []
636 defines = []
637 ldflags = []
638 lib_dirs = []
639 libs = []
641 if (is_component_build) {
642 # Component mode: dynamic CRT.
643 defines += [ "COMPONENT_BUILD" ]
644 if (is_win) {
645 # Since the library is shared, it requires exceptions or will give errors
646 # about things not matching, so keep exceptions on.
647 if (is_debug) {
648 cflags += [ "/MDd" ]
649 } else {
650 cflags += [ "/MD" ]
651 }
652 }
653 } else {
654 if (is_win && current_os != "win") {
655 # WindowsRT: use the dynamic CRT.
656 if (is_debug) {
657 cflags += [ "/MDd" ]
658 } else {
659 cflags += [ "/MD" ]
660 }
661 } else if (is_win) {
662 # Desktop Windows: static CRT.
663 if (is_debug) {
664 cflags += [ "/MTd" ]
665 } else {
666 cflags += [ "/MT" ]
667 }
668 }
669 }
671 if (is_win) {
672 defines += [
673 "__STD_C",
674 "_CRT_RAND_S",
675 "_CRT_SECURE_NO_DEPRECATE",
676 "_HAS_EXCEPTIONS=0",
677 "_SCL_SECURE_NO_DEPRECATE",
678 ]
679 }
681 # Android standard library setup.
682 if (is_android) {
683 if (is_clang) {
684 # Work around incompatibilities between bionic and clang headers.
685 defines += [
686 "__compiler_offsetof=__builtin_offsetof",
687 "nan=__builtin_nan",
688 ]
689 }
691 defines += [ "__GNU_SOURCE=1" ] # Necessary for clone().
693 # TODO(jdduke) Re-enable on mips after resolving linking
694 # issues with libc++ (crbug.com/456380).
695 if (current_cpu != "mipsel" && current_cpu != "mips64el") {
696 ldflags += [ "-Wl,--warn-shared-textrel" ]
697 }
698 ldflags += [ "-nostdlib" ]
700 # NOTE: The libc++ header include paths below are specified in cflags
701 # rather than include_dirs because they need to come after include_dirs.
702 # Think of them like system headers, but don't use '-isystem' because the
703 # arm-linux-androideabi-4.4.3 toolchain (circa Gingerbread) will exhibit
704 # strange errors. The include ordering here is important; change with
705 # caution.
706 cflags += [
707 "-isystem" +
708 rebase_path("$android_libcpp_root/libcxx/include", root_build_dir),
709 "-isystem" + rebase_path(
710 "$android_ndk_root/sources/cxx-stl/llvm-libc++abi/libcxxabi/include",
711 root_build_dir),
712 "-isystem" +
713 rebase_path("$android_ndk_root/sources/android/support/include",
714 root_build_dir),
715 ]
717 lib_dirs += [ "$android_libcpp_root/libs/$android_app_abi" ]
718 libs += [ "$android_libcpp_library" ]
720 if (current_cpu == "mipsel") {
721 libs += [
722 # ld linker is used for mips Android, and ld does not accept library
723 # absolute path prefixed by "-l"; Since libgcc does not exist in mips
724 # sysroot the proper library will be linked.
725 # TODO(gordanac): Remove once gold linker is used for mips Android.
726 "gcc",
727 ]
728 } else {
729 libs += [
730 # Manually link the libgcc.a that the cross compiler uses. This is
731 # absolute because the linker will look inside the sysroot if it's not.
732 rebase_path(android_libgcc_file),
733 ]
734 }
736 libs += [
737 "c",
738 "dl",
739 "m",
740 ]
742 # Clang with libc++ does not require an explicit atomic library reference.
743 if (!is_clang) {
744 libs += [ "atomic" ]
745 }
746 }
747 }
749 # default_warning_flags collects all warning flags that are used by default.
750 # This is in a variable instead of a config so that it can be used in
751 # both chromium_code and no_chromium_code. This way these flags are guaranteed
752 # to appear on the compile command line after -Wall.
754 default_warning_flags = []
755 default_warning_flags_cc = []
756 if (is_win) {
757 default_warning_flags += [
758 # Treat warnings as errors.
759 "/WX",
761 # Warnings permanently disabled:
763 # C4127: conditional expression is constant
764 # This warning can in theory catch dead code and other problems, but
765 # triggers in far too many desirable cases where the conditional
766 # expression is either set by macros or corresponds some legitimate
767 # compile-time constant expression (due to constant template args,
768 # conditionals comparing the sizes of different types, etc.). Some of
769 # these can be worked around, but it's not worth it.
770 "/wd4127",
772 # C4251: 'identifier' : class 'type' needs to have dll-interface to be
773 # used by clients of class 'type2'
774 # This is necessary for the shared library build.
775 "/wd4251",
777 # C4351: new behavior: elements of array 'array' will be default
778 # initialized
779 # This is a silly "warning" that basically just alerts you that the
780 # compiler is going to actually follow the language spec like it's
781 # supposed to, instead of not following it like old buggy versions did.
782 # There's absolutely no reason to turn this on.
783 "/wd4351",
785 # C4355: 'this': used in base member initializer list
786 # It's commonly useful to pass |this| to objects in a class' initializer
787 # list. While this warning can catch real bugs, most of the time the
788 # constructors in question don't attempt to call methods on the passed-in
789 # pointer (until later), and annotating every legit usage of this is
790 # simply more hassle than the warning is worth.
791 "/wd4355",
793 # C4503: 'identifier': decorated name length exceeded, name was
794 # truncated
795 # This only means that some long error messages might have truncated
796 # identifiers in the presence of lots of templates. It has no effect on
797 # program correctness and there's no real reason to waste time trying to
798 # prevent it.
799 "/wd4503",
801 # Warning C4589 says: "Constructor of abstract class ignores
802 # initializer for virtual base class." Disable this warning because it
803 # is flaky in VS 2015 RTM. It triggers on compiler generated
804 # copy-constructors in some cases.
805 "/wd4589",
807 # C4611: interaction between 'function' and C++ object destruction is
808 # non-portable
809 # This warning is unavoidable when using e.g. setjmp/longjmp. MSDN
810 # suggests using exceptions instead of setjmp/longjmp for C++, but
811 # Chromium code compiles without exception support. We therefore have to
812 # use setjmp/longjmp for e.g. JPEG decode error handling, which means we
813 # have to turn off this warning (and be careful about how object
814 # destruction happens in such cases).
815 "/wd4611",
817 # Warnings to evaluate and possibly fix/reenable later:
819 "/wd4100", # Unreferenced formal function parameter.
820 "/wd4121", # Alignment of a member was sensitive to packing.
821 "/wd4244", # Conversion: possible loss of data.
822 "/wd4481", # Nonstandard extension: override specifier.
823 "/wd4505", # Unreferenced local function has been removed.
824 "/wd4510", # Default constructor could not be generated.
825 "/wd4512", # Assignment operator could not be generated.
826 "/wd4610", # Class can never be instantiated, constructor required.
827 "/wd4995", # 'X': name was marked as #pragma deprecated
828 "/wd4996", # Deprecated function warning.
829 ]
831 # VS xtree header file needs to be patched or 4702 (unreachable code
832 # warning) is reported if _HAS_EXCEPTIONS=0. Disable the warning if xtree is
833 # not patched.
834 if (!msvs_xtree_patched &&
835 exec_script("../../win_is_xtree_patched.py", [], "value") == 0) {
836 default_warning_flags += [ "/wd4702" ] # Unreachable code.
837 }
839 # Building with Clang on Windows is a work in progress and very
840 # experimental. See crbug.com/82385.
841 # Keep this in sync with the similar block in build/common.gypi
842 if (is_clang) {
843 default_warning_flags += [
844 # TODO(hans): Make this list shorter eventually, http://crbug.com/504657
845 "-Qunused-arguments", # http://crbug.com/504658
846 "-Wno-microsoft", # http://crbug.com/505296
847 "-Wno-switch", # http://crbug.com/505308
848 "-Wno-unknown-pragmas", # http://crbug.com/505314
849 "-Wno-unused-function", # http://crbug.com/505316
850 "-Wno-unused-value", # http://crbug.com/505318
851 ]
852 }
853 } else {
854 # Common GCC warning setup.
855 default_warning_flags += [
856 # Enables.
857 "-Wendif-labels", # Weird old-style text after an #endif.
858 "-Werror", # Warnings as errors.
860 # Disables.
861 "-Wno-missing-field-initializers", # "struct foo f = {0};"
862 "-Wno-unused-parameter", # Unused function parameters.
863 ]
865 if (is_mac) {
866 default_warning_flags += [ "-Wnewline-eof" ]
867 if (!is_nacl) {
868 # When compiling Objective-C, warns if a method is used whose
869 # availability is newer than the deployment target. This is not
870 # required when compiling Chrome for iOS.
871 default_warning_flags += [ "-Wpartial-availability" ]
872 }
873 }
875 if (gcc_version >= 48) {
876 default_warning_flags_cc += [
877 # See comment for -Wno-c++11-narrowing.
878 "-Wno-narrowing",
879 ]
880 if (!is_clang) {
881 default_warning_flags_cc += [
882 # TODO(thakis): Remove, http://crbug.com/263960
883 "-Wno-literal-suffix",
884 ]
885 }
886 }
888 # Suppress warnings about ABI changes on ARM (Clang doesn't give this
889 # warning).
890 if (current_cpu == "arm" && !is_clang) {
891 default_warning_flags += [ "-Wno-psabi" ]
892 }
894 if (is_android) {
895 # Disable any additional warnings enabled by the Android build system but
896 # which chromium does not build cleanly with (when treating warning as
897 # errors).
898 default_warning_flags += [
899 "-Wno-extra",
900 "-Wno-ignored-qualifiers",
901 "-Wno-type-limits",
902 ]
903 default_warning_flags_cc += [
904 # Disabling c++0x-compat should be handled in WebKit, but
905 # this currently doesn't work because gcc_version is not set
906 # correctly when building with the Android build system.
907 # TODO(torne): Fix this in WebKit.
908 "-Wno-error=c++0x-compat",
910 # Other things unrelated to -Wextra:
911 "-Wno-non-virtual-dtor",
912 "-Wno-sign-promo",
913 ]
914 }
916 if (gcc_version >= 48) {
917 # Don't warn about the "typedef 'foo' locally defined but not used"
918 # for gcc 4.8.
919 # TODO: remove this flag once all builds work. See crbug.com/227506
920 default_warning_flags += [ "-Wno-unused-local-typedefs" ]
921 }
922 }
923 if (is_clang) {
924 default_warning_flags += [
925 # This warns on using ints as initializers for floats in
926 # initializer lists (e.g. |int a = f(); CGSize s = { a, a };|),
927 # which happens in several places in chrome code. Not sure if
928 # this is worth fixing.
929 "-Wno-c++11-narrowing",
931 # Don't die on dtoa code that uses a char as an array index.
932 # This is required solely for base/third_party/dmg_fp/dtoa.cc.
933 # TODO(brettw) move this to that project then!
934 "-Wno-char-subscripts",
936 # Warns on switches on enums that cover all enum values but
937 # also contain a default: branch. Chrome is full of that.
938 "-Wno-covered-switch-default",
940 # Clang considers the `register` keyword as deprecated, but e.g.
941 # code generated by flex (used in angle) contains that keyword.
942 # http://crbug.com/255186
943 "-Wno-deprecated-register",
945 # TODO(thakis): This used to be implied by -Wno-unused-function,
946 # which we no longer use. Check if it makes sense to remove
947 # this as well. http://crbug.com/316352
948 "-Wno-unneeded-internal-declaration",
950 # TODO(thakis): Remove, http://crbug.com/263960
951 "-Wno-reserved-user-defined-literal",
952 ]
954 # NaCl's Clang compiler and Chrome's hermetic Clang compiler will almost
955 # always have different versions. Certain flags may not be recognized by
956 # one version or the other.
957 if (!is_nacl) {
958 # Flags NaCl does not recognize.
959 default_warning_flags += [
960 # TODO(hans): Get this cleaned up, http://crbug.com/428099
961 "-Wno-inconsistent-missing-override",
963 # TODO(thakis): Enable this, crbug.com/507717
964 "-Wno-shift-negative-value",
965 ]
966 }
967 }
969 # chromium_code ---------------------------------------------------------------
970 #
971 # Toggles between higher and lower warnings for code that is (or isn't)
972 # part of Chromium.
974 config("chromium_code") {
975 if (is_win) {
976 cflags = [ "/W4" ] # Warning level 4.
977 } else {
978 cflags = [
979 "-Wall",
981 # GCC turns on -Wsign-compare for C++ under -Wall, but clang doesn't,
982 # so we specify it explicitly.
983 # TODO(fischman): remove this if http://llvm.org/PR10448 obsoletes it.
984 # http://code.google.com/p/chromium/issues/detail?id=90453
985 "-Wsign-compare",
986 ]
988 # In Chromium code, we define __STDC_foo_MACROS in order to get the
989 # C99 macros on Mac and Linux.
990 defines = [
991 "__STDC_CONSTANT_MACROS",
992 "__STDC_FORMAT_MACROS",
993 ]
995 if (!using_sanitizer && (!is_linux || !is_clang || is_official_build)) {
996 # _FORTIFY_SOURCE isn't really supported by Clang now, see
997 # http://llvm.org/bugs/show_bug.cgi?id=16821.
998 # It seems to work fine with Ubuntu 12 headers though, so use it in
999 # official builds.
1000 #
1001 # Non-chromium code is not guaranteed to compile cleanly with
1002 # _FORTIFY_SOURCE. Also, fortified build may fail when optimizations are
1003 # disabled, so only do that for Release build.
1004 defines += [ "_FORTIFY_SOURCE=2" ]
1005 }
1006 }
1007 cflags += default_warning_flags
1008 cflags_cc = default_warning_flags_cc
1009 }
1010 config("no_chromium_code") {
1011 cflags = []
1012 cflags_cc = []
1013 defines = []
1015 if (is_win) {
1016 cflags += [
1017 "/W3", # Warning level 3.
1018 "/wd4800", # Disable warning when forcing value to bool.
1019 "/wd4267", # TODO(jschuh): size_t to int.
1020 "/wd4996", # Deprecated function warning.
1021 ]
1022 defines += [
1023 "_CRT_NONSTDC_NO_WARNINGS",
1024 "_CRT_NONSTDC_NO_DEPRECATE",
1025 ]
1026 }
1028 if (is_linux) {
1029 # Don't warn about ignoring the return value from e.g. close(). This is
1030 # off by default in some gccs but on by default in others. BSD systems do
1031 # not support this option, since they are usually using gcc 4.2.1, which
1032 # does not have this flag yet.
1033 cflags += [ "-Wno-unused-result" ]
1034 }
1036 if (is_clang) {
1037 cflags += [
1038 # TODO(mgiuca): Move this suppression into individual third-party
1039 # libraries as required. http://crbug.com/505301.
1040 "-Wno-overloaded-virtual",
1042 # Lots of third-party libraries have unused variables. Instead of
1043 # suppressing them individually, we just blanket suppress them here.
1044 "-Wno-unused-variable",
1045 ]
1046 }
1048 if (is_linux || is_android) {
1049 cflags += [
1050 # Don't warn about printf format problems. This is off by default in gcc
1051 # but on in Ubuntu's gcc(!).
1052 "-Wno-format",
1053 ]
1054 cflags_cc += [
1055 # Don't warn about hash_map in third-party code.
1056 "-Wno-deprecated",
1057 ]
1058 }
1059 cflags += default_warning_flags
1060 cflags_cc += default_warning_flags_cc
1061 }
1063 # rtti ------------------------------------------------------------------------
1064 #
1065 # Allows turning Run-Time Type Identification on or off.
1067 config("rtti") {
1068 if (is_win) {
1069 cflags_cc = [ "/GR" ]
1070 }
1071 }
1072 config("no_rtti") {
1073 if (is_win) {
1074 cflags_cc = [ "/GR-" ]
1075 } else {
1076 cflags_cc = [ "-fno-rtti" ]
1077 cflags_objcc = cflags_cc
1078 }
1079 }
1081 # Warnings ---------------------------------------------------------------------
1083 # This will generate warnings when using Clang if code generates exit-time
1084 # destructors, which will slow down closing the program.
1085 # TODO(thakis): Make this a blacklist instead, http://crbug.com/101600
1086 config("wexit_time_destructors") {
1087 # TODO: Enable on Windows too, http://crbug.com/404525
1088 if (is_clang && !is_win) {
1089 cflags = [ "-Wexit-time-destructors" ]
1090 }
1091 }
1093 # On Windows compiling on x64, VC will issue a warning when converting
1094 # size_t to int because it will truncate the value. Our code should not have
1095 # these warnings and one should use a static_cast or a checked_cast for the
1096 # conversion depending on the case. However, a lot of code still needs to be
1097 # fixed. Apply this config to such targets to disable the warning.
1098 #
1099 # Note that this can be applied regardless of platform and architecture to
1100 # clean up the call sites. This will only apply the flag when necessary.
1101 #
1102 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
1103 config("no_size_t_to_int_warning") {
1104 if (is_win && current_cpu == "x64") {
1105 cflags = [ "/wd4267" ]
1106 }
1107 }
1109 # Some code presumes that pointers to structures/objects are compatible
1110 # regardless of whether what they point to is already known to be valid.
1111 # gcc 4.9 and earlier had no way of suppressing this warning without
1112 # supressing the rest of them. Here we centralize the identification of
1113 # the gcc 4.9 toolchains.
1114 config("no_incompatible_pointer_warnings") {
1115 cflags = []
1116 if (is_clang) {
1117 cflags += [ "-Wno-incompatible-pointer-types" ]
1118 } else if (current_cpu == "mipsel") {
1119 cflags += [ "-w" ]
1120 } else if (is_chromeos && current_cpu == "arm") {
1121 cflags += [ "-w" ]
1122 }
1123 }
1125 # Optimization -----------------------------------------------------------------
1126 #
1127 # Note that BUILDCONFIG.gn sets up a variable "default_optimization_config"
1128 # which it will assign to the config it implicitly applies to every target. If
1129 # you want to override the optimization level for your target, remove this
1130 # config (which will expand differently for debug or release builds), and then
1131 # add back the one you want to override it with:
1132 #
1133 # configs -= default_optimization_config
1134 # configs += [ "//build/config/compiler/optimize_max" ]
1136 # Shared settings for both "optimize" and "optimize_max" configs.
1137 # IMPORTANT: On Windows "/O1" and "/O2" must go before the common flags.
1138 if (is_win) {
1139 common_optimize_on_cflags = [
1140 "/Ob2", # Both explicit and auto inlining.
1141 "/Oy-", # Disable omitting frame pointers, must be after /O2.
1142 ]
1143 if (!is_asan) {
1144 common_optimize_on_cflags += [
1145 # Put data in separate COMDATs. This allows the linker
1146 # to put bit-identical constants at the same address even if
1147 # they're unrelated constants, which saves binary size.
1148 # This optimization can't be used when ASan is enabled because
1149 # it is not compatible with the ASan ODR checker.
1150 "/Gw",
1151 ]
1152 }
1153 common_optimize_on_ldflags = [ "/OPT:REF" ]
1154 } else {
1155 common_optimize_on_cflags = [
1156 # Don't emit the GCC version ident directives, they just end up in the
1157 # .comment section taking up binary size.
1158 "-fno-ident",
1160 # Put data and code in their own sections, so that unused symbols
1161 # can be removed at link time with --gc-sections.
1162 "-fdata-sections",
1163 "-ffunction-sections",
1164 ]
1165 common_optimize_on_ldflags = []
1167 if (is_android) {
1168 if (!using_sanitizer) {
1169 common_optimize_on_cflags += [ "-fomit-frame-pointer" ]
1170 }
1172 # TODO(jdduke) Re-enable on mips after resolving linking
1173 # issues with libc++ (crbug.com/456380).
1174 if (current_cpu != "mipsel" && current_cpu != "mips64el") {
1175 common_optimize_on_ldflags += [
1176 # Warn in case of text relocations.
1177 "-Wl,--warn-shared-textrel",
1178 ]
1179 }
1180 }
1182 if (is_mac) {
1183 if (symbol_level == 2) {
1184 # Mac dead code stripping requires symbols.
1185 common_optimize_on_ldflags += [ "-Wl,-dead_strip" ]
1186 }
1187 } else {
1188 # Non-Mac Posix linker flags.
1189 common_optimize_on_ldflags += [
1190 # Specifically tell the linker to perform optimizations.
1191 # See http://lwn.net/Articles/192624/ .
1192 "-Wl,-O1",
1193 "-Wl,--gc-sections",
1194 ]
1196 if (!using_sanitizer) {
1197 # Functions interposed by the sanitizers can make ld think
1198 # that some libraries aren't needed when they actually are,
1199 # http://crbug.com/234010. As workaround, disable --as-needed.
1200 common_optimize_on_ldflags += [ "-Wl,--as-needed" ]
1201 }
1202 }
1203 }
1205 # Default "optimization on" config. On Windows, this favors size over speed.
1206 config("optimize") {
1207 if (is_win) {
1208 # Favor size over speed, /O1 must be before the common flags. The GYP
1209 # build also specifies /Os and /GF but these are implied by /O1.
1210 cflags = [ "/O1" ] + common_optimize_on_cflags + [ "/Oi" ]
1211 } else if (is_android || is_ios) {
1212 cflags = [ "-Os" ] + common_optimize_on_cflags # Favor size over speed.
1213 } else {
1214 cflags = [ "-O2" ] + common_optimize_on_cflags
1215 }
1216 ldflags = common_optimize_on_ldflags
1217 }
1219 # Turn off optimizations.
1220 config("no_optimize") {
1221 if (is_win) {
1222 cflags = [
1223 "/Od", # Disable optimization.
1224 "/Ob0", # Disable all inlining (on by default).
1225 "/RTC1", # Runtime checks for stack frame and uninitialized variables.
1226 ]
1227 } else if (is_android && !android_full_debug) {
1228 # On Android we kind of optimize some things that don't affect debugging
1229 # much even when optimization is disabled to get the binary size down.
1230 cflags = [
1231 "-Os",
1232 "-fdata-sections",
1233 "-ffunction-sections",
1234 ]
1235 if (!using_sanitizer) {
1236 cflags += [ "-fomit-frame-pointer" ]
1237 }
1238 ldflags = common_optimize_on_ldflags
1239 } else {
1240 cflags = [ "-O0" ]
1241 }
1242 }
1244 # Turns up the optimization level. On Windows, this implies whole program
1245 # optimization and link-time code generation which is very expensive and should
1246 # be used sparingly.
1247 config("optimize_max") {
1248 ldflags = common_optimize_on_ldflags
1249 if (is_win) {
1250 # Favor speed over size, /O2 must be before the common flags. The GYP
1251 # build also specifies /Ot, /Oi, and /GF, but these are implied by /O2.
1252 cflags = [ "/O2" ] + common_optimize_on_cflags
1253 if (is_official_build) {
1254 # TODO(GYP): TODO(dpranke): Should these only be on in an official
1255 # build, or on all the time? For now we'll require official build so
1256 # that the compile is clean.
1257 cflags += [
1258 "/GL", # Whole program optimization.
1260 # Disable Warning 4702 ("Unreachable code") for the WPO/PGO builds.
1261 # Probably anything that this would catch that wouldn't be caught in a
1262 # normal build isn't going to actually be a bug, so the incremental
1263 # value of C4702 for PGO builds is likely very small.
1264 "/wd4702",
1265 ]
1266 ldflags += [ "/LTCG" ]
1267 }
1268 } else {
1269 cflags = [ "-O2" ] + common_optimize_on_cflags
1270 }
1271 }
1273 # Symbols ----------------------------------------------------------------------
1275 config("symbols") {
1276 if (is_win) {
1277 import("//build/toolchain/goma.gni")
1278 if (use_goma) {
1279 cflags = [ "/Z7" ] # No PDB file
1280 } else {
1281 cflags = [ "/Zi" ] # Produce PDB file, no edit and continue.
1282 }
1283 if (is_win_fastlink) {
1284 # Tell VS 2015+ to create a PDB that references debug
1285 # information in .obj and .lib files instead of copying
1286 # it all. This flag is incompatible with /PROFILE
1287 ldflags = [ "/DEBUG:FASTLINK" ]
1288 } else {
1289 ldflags = [ "/DEBUG" ]
1290 }
1291 } else {
1292 cflags = [ "-g2" ]
1293 if (use_debug_fission) {
1294 cflags += [ "-gsplit-dwarf" ]
1295 }
1296 }
1297 }
1299 config("minimal_symbols") {
1300 if (is_win) {
1301 # Linker symbols for backtraces only.
1302 if (is_win_fastlink) {
1303 # Tell VS 2015+ to create a PDB that references debug
1304 # information in .obj and .lib files instead of copying
1305 # it all. This flag is incompatible with /PROFILE
1306 ldflags = [ "/DEBUG:FASTLINK" ]
1307 } else {
1308 ldflags = [ "/DEBUG" ]
1309 }
1310 } else {
1311 cflags = [ "-g1" ]
1312 if (use_debug_fission) {
1313 cflags += [ "-gsplit-dwarf" ]
1314 }
1315 }
1316 }
1318 config("no_symbols") {
1319 if (!is_win) {
1320 cflags = [ "-g0" ]
1321 }
1322 }