mojo/services/network/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//third_party/mojo/src/mojo/public/mojo_application.gni")
   6
   7 if (is_android) {
   8   import("//build/config/android/rules.gni")
   9
  10   java_library_path = "$target_out_dir/java_library.dex.jar"
  11
  12   mojo_android_application("network") {
  13     output_name = "network_service"
  14     input_so = "$root_out_dir/lib.stripped/libnetwork_service.so"
  15     input_dex_jar = java_library_path
  16   }
  17
  18   shared_library("native_library") {
  19     output_name = "network_service"
  20
  21     sources = [
  22       "android_hooks.cc",
  23     ]
  24
  25     deps = [
  26       ":sources",
  27       "//base",
  28       "//net",
  29     ]
  30   }
  31
  32   android_standalone_library("java_library") {
  33     dex_path = java_library_path
  34
  35     deps = [
  36       "//net/android:net_java",
  37     ]
  38   }
  39 } else {
  40   mojo_native_application("network") {
  41     output_name = "network_service"
  42
  43     deps = [
  44       ":sources",
  45     ]
  46   }
  47 }
  48
  49 source_set("lib") {
  50   sources = [
  51     "cookie_store_impl.cc",
  52     "cookie_store_impl.h",
  53     "http_connection_impl.cc",
  54     "http_connection_impl.h",
  55     "http_server_impl.cc",
  56     "http_server_impl.h",
  57     "net_adapters.cc",
  58     "net_adapters.h",
  59     "net_address_type_converters.cc",
  60     "net_address_type_converters.h",
  61     "network_context.cc",
  62     "network_context.h",
  63     "network_service_delegate.cc",
  64     "network_service_delegate.h",
  65     "network_service_impl.cc",
  66     "network_service_impl.h",
  67     "tcp_bound_socket_impl.cc",
  68     "tcp_bound_socket_impl.h",
  69     "tcp_connected_socket_impl.cc",
  70     "tcp_connected_socket_impl.h",
  71     "tcp_server_socket_impl.cc",
  72     "tcp_server_socket_impl.h",
  73     "udp_socket_impl.cc",
  74     "udp_socket_impl.h",
  75     "url_loader_impl.cc",
  76     "url_loader_impl.h",
  77     "web_socket_impl.cc",
  78     "web_socket_impl.h",
  79   ]
  80
  81   deps = [
  82     "//base",
  83     "//mojo/application/public/cpp",
  84     "//mojo/services/network/public/cpp",
  85     "//mojo/services/network/public/interfaces",
  86     "//net",
  87     "//net:http_server",
  88     "//url",
  89   ]
  90 }
  91
  92 source_set("sources") {
  93   visibility = [ ":*" ]
  94
  95   sources = [
  96     "main.cc",
  97   ]
  98
  99   deps = [
 100     ":lib",
 101     "//base",
 102     "//mojo/application/public/cpp",
 103     "//mojo/services/network/public/cpp",
 104     "//mojo/services/network/public/interfaces",
 105     "//third_party/mojo/src/mojo/public/c/system:for_shared_library",
 106     "//third_party/mojo/src/mojo/public/cpp/bindings:bindings",
 107   ]
 108 }
 109
 110 mojo_native_application("apptests") {
 111   output_name = "network_service_apptests"
 112   testonly = true
 113
 114   sources = [
 115     "http_server_apptest.cc",
 116     "udp_socket_apptest.cc",
 117     "url_loader_impl_apptest.cc",
 118   ]
 119
 120   deps = [
 121     ":lib",
 122     ":network",
 123     "//base",
 124     "//mojo/application/public/cpp:test_support",
 125     "//mojo/services/network/public/cpp",
 126     "//mojo/services/network/public/interfaces",
 127     "//net",
 128     "//net:test_support",
 129     "//testing/gtest",
 130     "//third_party/mojo/src/mojo/public/cpp/bindings:callback",
 131   ]
 132 }