remoting/signaling/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//remoting/remoting_srcs.gni")
   6
   7 source_set("signaling") {
   8   sources = rebase_path(remoting_srcs_gypi_values.remoting_signaling_sources,
   9                         ".",
  10                         "//remoting")
  11
  12   configs += [
  13     "//build/config/compiler:no_size_t_to_int_warning",
  14     "//build/config/compiler:wexit_time_destructors",
  15   ]
  16
  17   public_deps = [
  18     "//remoting/proto",
  19     "//third_party/libjingle",
  20   ]
  21
  22   deps = [
  23     "//base",
  24     "//crypto",
  25     "//jingle:jingle_glue",
  26     "//net",
  27     "//remoting/base",
  28   ]
  29
  30   if (is_nacl) {
  31     sources -= [
  32       "log_to_server.cc",
  33       "server_log_entry.cc",
  34       "xmpp_signal_strategy.cc",
  35     ]
  36   }
  37 }
  38
  39 source_set("test_support") {
  40   testonly = true
  41
  42   sources = [
  43     "fake_signal_strategy.cc",
  44     "fake_signal_strategy.h",
  45     "mock_signal_strategy.cc",
  46     "mock_signal_strategy.h",
  47   ]
  48
  49   public_deps = [
  50     ":signaling",
  51     "//testing/gmock",
  52   ]
  53 }
  54
  55 source_set("unit_tests") {
  56   testonly = true
  57
  58   sources = [
  59     "iq_sender_unittest.cc",
  60     "jid_util_unittest.cc",
  61     "log_to_server_unittest.cc",
  62     "push_notification_subscriber_unittest.cc",
  63     "server_log_entry_unittest.cc",
  64     "server_log_entry_unittest.h",
  65     "xmpp_login_handler_unittest.cc",
  66     "xmpp_signal_strategy_unittest.cc",
  67     "xmpp_stream_parser_unittest.cc",
  68   ]
  69
  70   deps = [
  71     ":test_support",
  72     "//testing/gmock",
  73     "//testing/gtest",
  74   ]
  75 }