ui/gfx/platform_font_ios.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "ui/gfx/platform_font_ios.h"
   6
   7 #import <UIKit/UIKit.h>
   8
   9 #include "base/basictypes.h"
  10 #include "base/strings/sys_string_conversions.h"
  11 #include "base/strings/utf_string_conversions.h"
  12 #include "ui/gfx/font.h"
  13
  14 namespace gfx {
  15
  16 ////////////////////////////////////////////////////////////////////////////////
  17 // PlatformFontIOS, public:
  18
  19 PlatformFontIOS::PlatformFontIOS() {
  20   font_size_ = [UIFont systemFontSize];
  21   style_ = gfx::Font::NORMAL;
  22   UIFont* system_font = [UIFont systemFontOfSize:font_size_];
  23   font_name_ = base::SysNSStringToUTF8([system_font fontName]);
  24   CalculateMetrics();
  25 }
  26
  27 PlatformFontIOS::PlatformFontIOS(NativeFont native_font) {
  28   std::string font_name = base::SysNSStringToUTF8([native_font fontName]);
  29   InitWithNameSizeAndStyle(font_name,
  30                            [native_font pointSize],
  31                            gfx::Font::NORMAL);
  32 }
  33
  34 PlatformFontIOS::PlatformFontIOS(const std::string& font_name,
  35                                  int font_size) {
  36   InitWithNameSizeAndStyle(font_name, font_size, gfx::Font::NORMAL);
  37 }
  38
  39 ////////////////////////////////////////////////////////////////////////////////
  40 // PlatformFontIOS, PlatformFont implementation:
  41
  42 Font PlatformFontIOS::DeriveFont(int size_delta, int style) const {
  43   return Font(new PlatformFontIOS(font_name_, font_size_ + size_delta, style));
  44 }
  45
  46 int PlatformFontIOS::GetHeight() const {
  47   return height_;
  48 }
  49
  50 int PlatformFontIOS::GetBaseline() const {
  51   return ascent_;
  52 }
  53
  54 int PlatformFontIOS::GetCapHeight() const {
  55   return cap_height_;
  56 }
  57
  58 int PlatformFontIOS::GetAverageCharacterWidth() const {
  59   return average_width_;
  60 }
  61
  62 int PlatformFontIOS::GetStringWidth(const base::string16& text) const {
  63   NSString* ns_text = base::SysUTF16ToNSString(text);
  64   return [ns_text sizeWithFont:GetNativeFont()].width;
  65 }
  66
  67 int PlatformFontIOS::GetExpectedTextWidth(int length) const {
  68   return length * average_width_;
  69 }
  70
  71 int PlatformFontIOS::GetStyle() const {
  72   return style_;
  73 }
  74
  75 std::string PlatformFontIOS::GetFontName() const {
  76   return font_name_;
  77 }
  78
  79 int PlatformFontIOS::GetFontSize() const {
  80   return font_size_;
  81 }
  82
  83 NativeFont PlatformFontIOS::GetNativeFont() const {
  84   return [UIFont fontWithName:base::SysUTF8ToNSString(font_name_)
  85                          size:font_size_];
  86 }
  87
  88 ////////////////////////////////////////////////////////////////////////////////
  89 // PlatformFontIOS, private:
  90
  91 PlatformFontIOS::PlatformFontIOS(const std::string& font_name,
  92                                  int font_size,
  93                                  int style) {
  94   InitWithNameSizeAndStyle(font_name, font_size, style);
  95 }
  96
  97 void PlatformFontIOS::InitWithNameSizeAndStyle(const std::string& font_name,
  98                                                int font_size,
  99                                                int style) {
 100   font_name_ = font_name;
 101   font_size_ = font_size;
 102   style_ = style;
 103   CalculateMetrics();
 104 }
 105
 106 void PlatformFontIOS::CalculateMetrics() {
 107   UIFont* font = GetNativeFont();
 108   height_ = font.lineHeight;
 109   ascent_ = font.ascender;
 110   cap_height_ = font.capHeight;
 111   average_width_ = [@"x" sizeWithFont:font].width;
 112 }
 113
 114 ////////////////////////////////////////////////////////////////////////////////
 115 // PlatformFont, public:
 116
 117 // static
 118 PlatformFont* PlatformFont::CreateDefault() {
 119   return new PlatformFontIOS;
 120 }
 121
 122 // static
 123 PlatformFont* PlatformFont::CreateFromNativeFont(NativeFont native_font) {
 124   return new PlatformFontIOS(native_font);
 125 }
 126
 127 // static
 128 PlatformFont* PlatformFont::CreateFromNameAndSize(const std::string& font_name,
 129                                                   int font_size) {
 130   return new PlatformFontIOS(font_name, font_size);
 131 }
 132
 133 }  // namespace gfx