skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11
  12 skia_support_gpu = !is_ios
  13 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  14
  15 # The list of Skia defines that are to be set for blink.
  16 gypi_blink_skia_defines =
  17     exec_script("//build/gypi_to_gn.py",
  18                 [
  19                   rebase_path(
  20                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  21                   "--replace=<(skia_include_path)=//third_party/skia/include",
  22                   "--replace=<(skia_src_path)=//third_party/skia/src",
  23                 ],
  24                 "scope",
  25                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  26
  27 # The list of Skia defines that are to be set for chromium.
  28 gypi_skia_defines =
  29     exec_script("//build/gypi_to_gn.py",
  30                 [
  31                   rebase_path(
  32                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  33                   "--replace=<(skia_include_path)=//third_party/skia/include",
  34                   "--replace=<(skia_src_path)=//third_party/skia/src",
  35                 ],
  36                 "scope",
  37                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  38
  39 # The list of Skia core sources that are to be set for chromium.
  40 gypi_skia_core =
  41     exec_script("//build/gypi_to_gn.py",
  42                 [
  43                   rebase_path("//third_party/skia/gyp/core.gypi"),
  44                   "--replace=<(skia_include_path)=//third_party/skia/include",
  45                   "--replace=<(skia_src_path)=//third_party/skia/src",
  46                 ],
  47                 "scope",
  48                 [ "//third_party/skia/gyp/core.gypi" ])
  49
  50 # The list of Skia gpu sources that are to be set for chromium.
  51 gypi_skia_gpu =
  52     exec_script("//build/gypi_to_gn.py",
  53                 [
  54                   rebase_path("//third_party/skia/gyp/gpu.gypi"),
  55                   "--replace=<(skia_include_path)=//third_party/skia/include",
  56                   "--replace=<(skia_src_path)=//third_party/skia/src",
  57                 ],
  58                 "scope",
  59                 [ "//third_party/skia/gyp/gpu.gypi" ])
  60
  61 # The list of Skia pdf sources that are to be set for chromium.
  62 gypi_skia_pdf =
  63     exec_script("//build/gypi_to_gn.py",
  64                 [
  65                   rebase_path("//third_party/skia/gyp/pdf.gypi"),
  66                   "--replace=<(skia_include_path)=//third_party/skia/include",
  67                   "--replace=<(skia_src_path)=//third_party/skia/src",
  68                 ],
  69                 "scope",
  70                 [ "//third_party/skia/gyp/pdf.gypi" ])
  71
  72 # The list of Skia effects that are to be set for chromium.
  73 gypi_skia_effects =
  74     exec_script("//build/gypi_to_gn.py",
  75                 [
  76                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  77                   "--replace=<(skia_include_path)=//third_party/skia/include",
  78                   "--replace=<(skia_src_path)=//third_party/skia/src",
  79                 ],
  80                 "scope",
  81                 [ "//third_party/skia/gyp/effects.gypi" ])
  82
  83 # The list of Skia utils that are to be set for chromium.
  84 gypi_skia_utils =
  85     exec_script("//build/gypi_to_gn.py",
  86                 [
  87                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  88                   "--replace=<(skia_include_path)=//third_party/skia/include",
  89                   "--replace=<(skia_src_path)=//third_party/skia/src",
  90                 ],
  91                 "scope",
  92                 [ "//third_party/skia/gyp/utils.gypi" ])
  93
  94 gypi_skia_opts =
  95     exec_script("//build/gypi_to_gn.py",
  96                 [
  97                   rebase_path("//third_party/skia/gyp/opts.gypi"),
  98                   "--replace=<(skia_include_path)=//third_party/skia/include",
  99                   "--replace=<(skia_src_path)=//third_party/skia/src",
 100                 ],
 101                 "scope",
 102                 [ "//third_party/skia/gyp/opts.gypi" ])
 103
 104 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 105 gypi_values =
 106     exec_script("//build/gypi_to_gn.py",
 107                 [
 108                   rebase_path("skia_gn_files.gypi"),
 109                   "--replace=<(skia_include_path)=//third_party/skia/include",
 110                   "--replace=<(skia_src_path)=//third_party/skia/src",
 111                 ],
 112                 "scope",
 113                 [ "skia_gn_files.gypi" ])
 114
 115 # External-facing config for dependent code.
 116 config("skia_config") {
 117   include_dirs = [
 118     "config",
 119     "ext",
 120     "//third_party/skia/include/c",
 121     "//third_party/skia/include/config",
 122     "//third_party/skia/include/core",
 123     "//third_party/skia/include/effects",
 124     "//third_party/skia/include/images",
 125     "//third_party/skia/include/lazy",
 126     "//third_party/skia/include/pathops",
 127     "//third_party/skia/include/pdf",
 128     "//third_party/skia/include/pipe",
 129     "//third_party/skia/include/ports",
 130     "//third_party/skia/include/utils",
 131
 132     # need to move this to internal. see crbug.com/457691
 133     "//third_party/skia/src/core",
 134   ]
 135
 136   defines = gypi_blink_skia_defines.blink_skia_defines
 137   defines += gypi_skia_defines.skia_for_chromium_defines
 138
 139   defines += []
 140
 141   if (component_mode == "shared_library") {
 142     defines += [
 143       "SKIA_DLL",
 144       "GR_GL_IGNORE_ES3_MSAA=0",
 145     ]
 146   }
 147
 148   if (skia_support_gpu) {
 149     include_dirs += [
 150       "//third_party/skia/include/gpu",
 151       "//third_party/skia/src/gpu",
 152     ]
 153     defines += [ "SK_SUPPORT_GPU=1" ]
 154   } else {
 155     defines += [ "SK_SUPPORT_GPU=0" ]
 156   }
 157
 158   if (is_android) {
 159     defines += [
 160       "SK_BUILD_FOR_ANDROID",
 161       "USE_CHROMIUM_SKIA",
 162     ]
 163   }
 164
 165   if (is_mac) {
 166     defines += [ "SK_BUILD_FOR_MAC" ]
 167   }
 168 }
 169
 170 # Internal-facing config for Skia library code.
 171 config("skia_library_config") {
 172   # These include directories are only included for Skia code and are not
 173   # exported to dependents. It's not clear if this is on purpose, but this
 174   # matches the GYP build.
 175   include_dirs = [
 176     "//third_party/skia/src/image",
 177     "//third_party/skia/src/opts",
 178     "//third_party/skia/src/pdf",
 179     "//third_party/skia/src/ports",
 180     "//third_party/skia/src/sfnt",
 181     "//third_party/skia/src/utils",
 182     "//third_party/skia/src/lazy",
 183   ]
 184   if (is_mac || is_ios) {
 185     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 186   }
 187   if (is_mac) {
 188     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 189   }
 190
 191   defines = []
 192
 193   if (component_mode == "shared_library") {
 194     defines += [ "SKIA_IMPLEMENTATION=1" ]
 195   }
 196
 197   if (current_cpu == "arm") {
 198     if (arm_use_neon) {
 199       defines += [ "SK_ARM_HAS_NEON" ]
 200     }
 201     if (arm_optionally_use_neon) {
 202       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 203     }
 204   }
 205
 206   # Settings for text blitting, chosen to approximate the system browser.
 207   if (is_linux) {
 208     defines += [
 209       "SK_GAMMA_EXPONENT=1.2",
 210       "SK_GAMMA_CONTRAST=0.2",
 211       "SK_HIGH_QUALITY_IS_LANCZOS",
 212     ]
 213   } else if (is_android) {
 214     defines += [
 215       "SK_GAMMA_APPLY_TO_A8",
 216       "SK_GAMMA_EXPONENT=1.4",
 217       "SK_GAMMA_CONTRAST=0.0",
 218     ]
 219   } else if (is_win) {
 220     defines += [
 221       "SK_GAMMA_SRGB",
 222       "SK_GAMMA_CONTRAST=0.5",
 223       "SK_HIGH_QUALITY_IS_LANCZOS",
 224     ]
 225   } else if (is_mac) {
 226     defines += [
 227       "SK_GAMMA_SRGB",
 228       "SK_GAMMA_CONTRAST=0.0",
 229       "SK_HIGH_QUALITY_IS_LANCZOS",
 230     ]
 231   }
 232
 233   if (is_android) {
 234     defines += [
 235       # Android devices are typically more memory constrained, so default to a
 236       # smaller glyph cache (it may be overriden at runtime when the renderer
 237       # starts up, depending on the actual device memory).
 238       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 239     ]
 240   } else {
 241     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 242   }
 243
 244   if (is_win) {
 245     include_dirs += [
 246       "//third_party/skia/include/utils/win",
 247       "//third_party/skia/src/utils/win",
 248     ]
 249
 250     defines += [
 251       # On windows, GDI handles are a scarse system-wide resource so we have to
 252       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 253       # fairly small size. http://crbug.com/314387
 254       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 255     ]
 256
 257     cflags = [
 258       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 259       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 260       "/wd4341",  # signed value is out of range for enum constant.
 261       "/wd4345",  # Object is default-initialized if initialization is omitted.
 262       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 263       "/wd4554",  # 'operator' : check operator precedence for possible error
 264       "/wd4748",  # compiler will disable optimizations if a function has inline
 265                   # assembly code contains flow control(jmp or jcc) statements.
 266
 267       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 268     ]
 269   }
 270 }
 271
 272 component("skia") {
 273   sources = [
 274     # Chrome sources.
 275     "config/SkUserConfig.h",
 276     "ext/SkDiscardableMemory_chrome.cc",
 277     "ext/SkDiscardableMemory_chrome.h",
 278     "ext/SkMemory_new_handler.cpp",
 279     "ext/analysis_canvas.cc",
 280     "ext/analysis_canvas.h",
 281     "ext/benchmarking_canvas.cc",
 282     "ext/benchmarking_canvas.h",
 283     "ext/bitmap_platform_device.h",
 284     "ext/convolver.cc",
 285     "ext/convolver.h",
 286     "ext/event_tracer_impl.cc",
 287     "ext/event_tracer_impl.h",
 288     "ext/fontmgr_default_win.cc",
 289     "ext/fontmgr_default_win.h",
 290     "ext/google_logging.cc",
 291     "ext/image_operations.cc",
 292     "ext/image_operations.h",
 293     "ext/opacity_draw_filter.cc",
 294     "ext/opacity_draw_filter.h",
 295     "ext/pixel_ref_utils.cc",
 296     "ext/pixel_ref_utils.h",
 297     "ext/platform_canvas.cc",
 298     "ext/platform_canvas.h",
 299     "ext/platform_device.cc",
 300     "ext/platform_device.h",
 301     "ext/platform_device_linux.cc",
 302     "ext/platform_device_mac.cc",
 303     "ext/platform_device_win.cc",
 304     "ext/recursive_gaussian_convolution.cc",
 305     "ext/recursive_gaussian_convolution.h",
 306     "ext/refptr.h",
 307     "ext/skia_utils_base.cc",
 308     "ext/skia_utils_base.h",
 309     "ext/skia_utils_ios.h",
 310     "ext/skia_utils_ios.mm",
 311     "ext/skia_utils_mac.h",
 312     "ext/skia_utils_mac.mm",
 313     "ext/skia_utils_win.cc",
 314     "ext/skia_utils_win.h",
 315   ]
 316
 317   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 318   sources += gypi_skia_core.sources
 319   sources += gypi_skia_effects.sources
 320   sources += gypi_skia_utils.sources
 321   sources += gypi_values.skia_library_sources
 322
 323   # This and skia_opts are really the same conceptual target so share headers.
 324   allow_circular_includes_from = [ ":skia_opts" ]
 325
 326   if (current_cpu == "arm") {
 327     sources += [
 328       "//third_party/skia/src/core/SkUtilsArm.cpp",
 329       "//third_party/skia/src/core/SkUtilsArm.h",
 330     ]
 331   }
 332
 333   # GPU
 334   if (skia_support_gpu) {
 335     sources += gypi_skia_gpu.skgpu_sources
 336     sources += gypi_skia_gpu.skgpu_null_gl_sources
 337   }
 338
 339   # Remove unused util files include in utils.gypi
 340   sources -= [
 341     "//third_party/skia/include/utils/SkBoundaryPatch.h",
 342     "//third_party/skia/include/utils/SkCamera.h",
 343     "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 344     "//third_party/skia/include/utils/SkCubicInterval.h",
 345     "//third_party/skia/include/utils/SkCullPoints.h",
 346     "//third_party/skia/include/utils/SkDebugUtils.h",
 347     "//third_party/skia/include/utils/SkDumpCanvas.h",
 348     "//third_party/skia/include/utils/SkEventTracer.h",
 349     "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 350     "//third_party/skia/include/utils/SkInterpolator.h",
 351     "//third_party/skia/include/utils/SkLayer.h",
 352     "//third_party/skia/include/utils/SkMeshUtils.h",
 353     "//third_party/skia/include/utils/SkNinePatch.h",
 354     "//third_party/skia/include/utils/SkParsePaint.h",
 355     "//third_party/skia/include/utils/SkParsePath.h",
 356     "//third_party/skia/include/utils/SkRandom.h",
 357     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 358     "//third_party/skia/src/utils/SkBitmapHasher.h",
 359     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 360     "//third_party/skia/src/utils/SkCamera.cpp",
 361     "//third_party/skia/src/utils/SkCanvasStack.h",
 362     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 363     "//third_party/skia/src/utils/SkCullPoints.cpp",
 364     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 365     "//third_party/skia/src/utils/SkFloatUtils.h",
 366     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 367     "//third_party/skia/src/utils/SkInterpolator.cpp",
 368     "//third_party/skia/src/utils/SkLayer.cpp",
 369     "//third_party/skia/src/utils/SkMD5.cpp",
 370     "//third_party/skia/src/utils/SkMD5.h",
 371     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 372     "//third_party/skia/src/utils/SkNinePatch.cpp",
 373     "//third_party/skia/src/utils/SkOSFile.cpp",
 374     "//third_party/skia/src/utils/SkParsePath.cpp",
 375     "//third_party/skia/src/utils/SkPathUtils.cpp",
 376     "//third_party/skia/src/utils/SkSHA1.cpp",
 377     "//third_party/skia/src/utils/SkSHA1.h",
 378     "//third_party/skia/src/utils/SkTFitsIn.h",
 379     "//third_party/skia/src/utils/SkTLogic.h",
 380
 381     # We don't currently need to change thread affinity, so leave out this complexity for now.
 382     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 383     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 384
 385     #testing
 386     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 387     "//third_party/skia/src/fonts/SkGScalerContext.h",
 388   ]
 389
 390   if (is_win) {
 391     sources -= [
 392       # Keeping _win.cpp
 393       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 394       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 395     ]
 396   } else {
 397     sources -= [
 398       # Keeping _pthread.cpp and _pthread_other.cpp.
 399       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 400     ]
 401   }
 402
 403   # need separate win section to handle chromes auto gn filter
 404   # (build/config/BUILDCONFIG.gn)
 405   if (is_win) {
 406     sources -= [
 407       #windows
 408       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 409       "//third_party/skia/include/utils/win/SkHRESULT.h",
 410       "//third_party/skia/include/utils/win/SkIStream.h",
 411       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 412       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 413       "//third_party/skia/src/utils/win/SkIStream.cpp",
 414       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 415     ]
 416   }
 417
 418   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 419     sources -= [ "ext/skia_utils_base.cc" ]
 420   }
 421
 422   # Fixup skia library sources.
 423   if (is_win) {
 424     sources -= [
 425       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 426       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 427       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 428     ]
 429   } else {
 430     sources -= [
 431       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 432       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 433       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 434       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 435       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 436       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 437       "//third_party/skia/src/ports/SkTLS_win.cpp",
 438       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 439       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 440     ]
 441   }
 442   if (!is_android) {
 443     sources -= [
 444       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 445       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 446     ]
 447   }
 448   if (!is_mac) {
 449     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 450   }
 451
 452   if (!is_linux) {
 453     sources -= [
 454       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 455       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 456       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 457     ]
 458   }
 459
 460   if (!is_linux && !is_android) {
 461     sources -= [
 462       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 463       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 464     ]
 465   }
 466
 467   # Select the right BitmapPlatformDevice.
 468   if (is_win) {
 469     sources += [
 470       "ext/bitmap_platform_device_win.cc",
 471       "ext/bitmap_platform_device_win.h",
 472     ]
 473   } else if (is_mac) {
 474     sources += [
 475       "ext/bitmap_platform_device_mac.cc",
 476       "ext/bitmap_platform_device_mac.h",
 477     ]
 478   } else if (use_cairo) {
 479     sources += [
 480       "ext/bitmap_platform_device_cairo.cc",
 481       "ext/bitmap_platform_device_cairo.h",
 482     ]
 483   } else {
 484     sources += [
 485       "ext/bitmap_platform_device_skia.cc",
 486       "ext/bitmap_platform_device_skia.h",
 487     ]
 488   }
 489
 490   if (is_clang) {
 491     # Skia won't compile with some of the more strict clang warnings.
 492     # e.g. it does:
 493     #  SkASSERT(!"sk_out_of_memory");
 494     configs -= [ "//build/config/clang:extra_warnings" ]
 495   }
 496
 497   configs -= [ "//build/config/compiler:chromium_code" ]
 498   configs += [
 499     ":skia_library_config",
 500     "//build/config/compiler:no_chromium_code",
 501   ]
 502   public_configs = [ ":skia_config" ]
 503
 504   deps = [
 505     ":skia_opts",
 506     "//base",
 507     "//base/third_party/dynamic_annotations",
 508     "//third_party/zlib",
 509   ]
 510
 511   if (is_linux) {
 512     configs += [
 513       "//build/config/linux:fontconfig",
 514       "//build/config/linux:freetype2",
 515     ]
 516     if (use_pango) {
 517       configs += [ "//build/config/linux:pangocairo" ]
 518     }
 519     deps += [ "//third_party/icu:icuuc" ]
 520   }
 521
 522   if (is_android) {
 523     set_sources_assignment_filter([])
 524     sources += [ "ext/platform_device_linux.cc" ]
 525     set_sources_assignment_filter(sources_assignment_filter)
 526     deps += [
 527       "//third_party/expat",
 528       "//third_party/freetype",
 529       "//third_party/android_tools:cpu_features",
 530     ]
 531   }
 532
 533   if (skia_support_pdf) {
 534     deps += [ "//third_party/sfntly" ]
 535     sources += gypi_skia_pdf.sources
 536   }
 537
 538   if (is_android && !is_debug) {
 539     configs -= [ "//build/config/compiler:optimize" ]
 540     configs += [ "//build/config/compiler:optimize_max" ]
 541   }
 542 }
 543
 544 # Separated out so it can be compiled with different flags for SSE.
 545 source_set("skia_opts") {
 546   cflags = []
 547   defines = []
 548
 549   if (current_cpu == "x86" || current_cpu == "x64") {
 550     sources = gypi_skia_opts.sse2_sources + gypi_skia_opts.ssse3_sources +
 551               gypi_skia_opts.sse41_sources +
 552               [
 553                 # Chrome-specific.
 554                 "ext/convolver_SSE2.cc",
 555               ]
 556
 557     if (is_linux || is_mac) {
 558       cflags += [ "-msse4.1" ]
 559     }
 560   } else if (current_cpu == "arm") {
 561     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 562     # ARM), the compiler doesn't like that.
 563     cflags += [ "-fomit-frame-pointer" ]
 564
 565     if (arm_version >= 7) {
 566       sources = gypi_skia_opts.armv7_sources
 567       if (arm_use_neon || arm_optionally_use_neon) {
 568         sources += gypi_skia_opts.neon_sources
 569
 570         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 571         # when running this.
 572         if (!arm_use_neon) {
 573           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 574           cflags += [ "-mfpu=neon" ]
 575         }
 576       }
 577     } else {
 578       sources = gypi_skia_opts.none_sourcees
 579     }
 580   } else if (current_cpu == "mipsel") {
 581     cflags += [ "-fomit-frame-pointer" ]
 582     sources = gypi_skia_opts.none_sources
 583   } else {
 584     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 585   }
 586
 587   if (is_android && !is_debug) {
 588     configs -= [ "//build/config/compiler:optimize" ]
 589     configs += [ "//build/config/compiler:optimize_max" ]
 590   }
 591
 592   configs -= [ "//build/config/compiler:chromium_code" ]
 593   configs += [
 594     ":skia_config",
 595     ":skia_library_config",
 596     "//build/config/compiler:no_chromium_code",
 597   ]
 598
 599   deps = [
 600     "//base",
 601   ]
 602
 603   visibility = [ ":skia" ]
 604 }
 605
 606 test("skia_unittests") {
 607   sources = [
 608     "ext/analysis_canvas_unittest.cc",
 609     "ext/bitmap_platform_device_mac_unittest.cc",
 610     "ext/convolver_unittest.cc",
 611     "ext/image_operations_unittest.cc",
 612     "ext/pixel_ref_utils_unittest.cc",
 613     "ext/platform_canvas_unittest.cc",
 614     "ext/recursive_gaussian_convolution_unittest.cc",
 615     "ext/refptr_unittest.cc",
 616     "ext/skia_utils_ios_unittest.mm",
 617     "ext/skia_utils_mac_unittest.mm",
 618   ]
 619
 620   if (!is_win && !is_mac) {
 621     sources -= [ "ext/platform_canvas_unittest.cc" ]
 622   }
 623
 624   deps = [
 625     ":skia",
 626     "//base",
 627     "//base/test:run_all_unittests",
 628     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 629     "//testing/gtest",
 630     "//ui/gfx",
 631     "//ui/gfx/geometry",
 632   ]
 633 }
 634
 635 if (is_linux && !is_chromeos) {
 636   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 637   executable("image_operations_bench") {
 638     sources = [
 639       "ext/image_operations_bench.cc",
 640     ]
 641
 642     deps = [
 643       ":skia",
 644       "//base",
 645     ]
 646   }
 647
 648   executable("filter_fuzz_stub") {
 649     sources = [
 650       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 651     ]
 652
 653     deps = [
 654       ":skia",
 655       "//base",
 656     ]
 657   }
 658 }