net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script("//build/gypi_to_gn.py",
  26                           [ rebase_path("net.gypi") ],
  27                           "scope",
  28                           [ "net.gypi" ])
  29
  30 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  31 # configuration (krb5.conf and so on).
  32 use_kerberos = !is_chromeos && !is_android && !is_ios
  33
  34 # The way the cache uses mmap() is inefficient on some Android devices. If
  35 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  36 # pretty confident that mmap-ing the index would not hurt any existing x86
  37 # android devices, but we cannot be so sure about the variety of ARM devices.
  38 # So enable it for x86 only for now.
  39 posix_avoid_mmap = is_android && cpu_arch != "x86"
  40
  41 # WebSockets and socket stream code are used everywhere except iOS.
  42 enable_websockets = !is_ios
  43 use_v8_in_net = !is_ios
  44 enable_built_in_dns = !is_ios
  45 disable_ftp_support = is_ios
  46
  47 declare_args() {
  48   # Disables support for file URLs.  File URL support requires use of icu.
  49   disable_file_support = false
  50 }
  51
  52 config("net_config") {
  53   defines = []
  54   if (posix_avoid_mmap) {
  55     defines += [ "POSIX_AVOID_MMAP" ]
  56   }
  57   if (disable_file_support) {
  58     defines += [ "DISABLE_FILE_SUPPORT" ]
  59   }
  60 }
  61
  62 # Disables Windows warning about size to int truncations.
  63 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  64 config("net_win_size_truncation") {
  65   if (is_win) {
  66     cflags = [ "/wd4267" ]
  67   }
  68 }
  69
  70 component("net") {
  71   sources =
  72       gypi_values.net_nacl_common_sources + gypi_values.net_non_nacl_sources
  73
  74   cflags = []
  75   defines = [
  76     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  77     # 0) which implies that we run pkg_config on kerberos and link to that
  78     # rather than setting this define which will dynamically open it. That
  79     # doesn't seem to be set in the regular builds, so we're skipping this
  80     # capability here.
  81     "DLOPEN_KERBEROS",
  82     "NET_IMPLEMENTATION",
  83   ]
  84   configs += [ ":net_win_size_truncation" ]
  85   public_configs = [ ":net_config" ]
  86   include_dirs = []
  87
  88   public_deps = [
  89     "//crypto",
  90     "//crypto:platform",
  91   ]
  92   deps = [
  93     ":net_resources",
  94     "//base",
  95     "//base:i18n",
  96     "//base:prefs",
  97     "//base/third_party/dynamic_annotations",
  98     "//net/base/registry_controlled_domains",
  99     "//sdch",
 100     "//third_party/icu",
 101     "//third_party/zlib",
 102     "//url",
 103   ]
 104
 105   if (use_kerberos) {
 106     defines += [ "USE_KERBEROS" ]
 107     if (is_android) {
 108       include_dirs += [ "/usr/include/kerberosV" ]
 109     }
 110   } else {
 111     sources -= [
 112       "http/http_auth_gssapi_posix.cc",
 113       "http/http_auth_gssapi_posix.h",
 114       "http/http_auth_handler_negotiate.h",
 115       "http/http_auth_handler_negotiate.cc",
 116     ]
 117   }
 118
 119   if (is_posix) {
 120     if (posix_avoid_mmap) {
 121       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 122     } else {
 123       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 124     }
 125   }
 126
 127   if (disable_file_support) {
 128     sources -= [
 129       "base/directory_lister.cc",
 130       "base/directory_lister.h",
 131       "url_request/url_request_file_dir_job.cc",
 132       "url_request/url_request_file_dir_job.h",
 133       "url_request/url_request_file_job.cc",
 134       "url_request/url_request_file_job.h",
 135       "url_request/file_protocol_handler.cc",
 136       "url_request/file_protocol_handler.h",
 137     ]
 138   }
 139
 140   if (disable_ftp_support) {
 141     sources -= [
 142       "ftp/ftp_auth_cache.cc",
 143       "ftp/ftp_auth_cache.h",
 144       "ftp/ftp_ctrl_response_buffer.cc",
 145       "ftp/ftp_ctrl_response_buffer.h",
 146       "ftp/ftp_directory_listing_parser.cc",
 147       "ftp/ftp_directory_listing_parser.h",
 148       "ftp/ftp_directory_listing_parser_ls.cc",
 149       "ftp/ftp_directory_listing_parser_ls.h",
 150       "ftp/ftp_directory_listing_parser_netware.cc",
 151       "ftp/ftp_directory_listing_parser_netware.h",
 152       "ftp/ftp_directory_listing_parser_os2.cc",
 153       "ftp/ftp_directory_listing_parser_os2.h",
 154       "ftp/ftp_directory_listing_parser_vms.cc",
 155       "ftp/ftp_directory_listing_parser_vms.h",
 156       "ftp/ftp_directory_listing_parser_windows.cc",
 157       "ftp/ftp_directory_listing_parser_windows.h",
 158       "ftp/ftp_network_layer.cc",
 159       "ftp/ftp_network_layer.h",
 160       "ftp/ftp_network_session.cc",
 161       "ftp/ftp_network_session.h",
 162       "ftp/ftp_network_transaction.cc",
 163       "ftp/ftp_network_transaction.h",
 164       "ftp/ftp_request_info.h",
 165       "ftp/ftp_response_info.cc",
 166       "ftp/ftp_response_info.h",
 167       "ftp/ftp_server_type_histograms.cc",
 168       "ftp/ftp_server_type_histograms.h",
 169       "ftp/ftp_transaction.h",
 170       "ftp/ftp_transaction_factory.h",
 171       "ftp/ftp_util.cc",
 172       "ftp/ftp_util.h",
 173       "url_request/ftp_protocol_handler.cc",
 174       "url_request/ftp_protocol_handler.h",
 175       "url_request/url_request_ftp_job.cc",
 176       "url_request/url_request_ftp_job.h",
 177     ]
 178   }
 179
 180   if (enable_built_in_dns) {
 181     defines += [ "ENABLE_BUILT_IN_DNS" ]
 182   } else {
 183     sources -= [
 184       "dns/address_sorter_posix.cc",
 185       "dns/address_sorter_posix.h",
 186       "dns/dns_client.cc",
 187     ]
 188   }
 189
 190   if (use_openssl) {
 191     sources -= [
 192       "base/nss_memio.c",
 193       "base/nss_memio.h",
 194       "cert/ct_log_verifier_nss.cc",
 195       "cert/ct_objects_extractor_nss.cc",
 196       "cert/jwk_serializer_nss.cc",
 197       "cert/scoped_nss_types.h",
 198       "cert/test_root_certs_nss.cc",
 199       "cert/x509_util_nss.cc",
 200       "cert/x509_util_nss.h",
 201       "ocsp/nss_ocsp.cc",
 202       "ocsp/nss_ocsp.h",
 203       "quic/crypto/aead_base_decrypter_nss.cc",
 204       "quic/crypto/aead_base_encrypter_nss.cc",
 205       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 206       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 207       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 208       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 209       "quic/crypto/channel_id_nss.cc",
 210       "quic/crypto/p256_key_exchange_nss.cc",
 211       "socket/nss_ssl_util.cc",
 212       "socket/nss_ssl_util.h",
 213       "socket/ssl_client_socket_nss.cc",
 214       "socket/ssl_client_socket_nss.h",
 215       "socket/ssl_server_socket_nss.cc",
 216       "socket/ssl_server_socket_nss.h",
 217     ]
 218     if (is_chromeos) {
 219       sources -= [
 220         "cert/nss_cert_database_chromeos.cc",
 221         "cert/nss_cert_database_chromeos.h",
 222         "cert/nss_profile_filter_chromeos.cc",
 223         "cert/nss_profile_filter_chromeos.h",
 224       ]
 225     }
 226     if (is_linux) {
 227       # These are always removed for non-Linux cases below.
 228       sources -= [
 229         "base/crypto_module_nss.cc",
 230         "base/keygen_handler_nss.cc",
 231         "cert/cert_database_nss.cc",
 232         "cert/nss_cert_database.cc",
 233         "cert/nss_cert_database.h",
 234         "cert/x509_certificate_nss.cc",
 235         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 236         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 237         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 238         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 239         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 240         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 241       ]
 242     }
 243     if (is_ios) {
 244       # Always removed for !ios below.
 245       sources -= [
 246         "cert/cert_verify_proc_nss.cc",
 247         "cert/cert_verify_proc_nss.h",
 248       ]
 249     }
 250     if (is_win) {
 251       sources -= [ "cert/sha256_legacy_support_nss_win.cc" ]
 252     }
 253   } else {
 254     sources -= [
 255       "base/crypto_module_openssl.cc",
 256       "cert/ct_log_verifier_openssl.cc",
 257       "cert/ct_objects_extractor_openssl.cc",
 258       "cert/jwk_serializer_openssl.cc",
 259       "cert/x509_util_openssl.cc",
 260       "cert/x509_util_openssl.h",
 261       "quic/crypto/aead_base_decrypter_openssl.cc",
 262       "quic/crypto/aead_base_encrypter_openssl.cc",
 263       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 264       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 265       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 266       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 267       "quic/crypto/channel_id_openssl.cc",
 268       "quic/crypto/p256_key_exchange_openssl.cc",
 269       "quic/crypto/scoped_evp_aead_ctx.cc",
 270       "quic/crypto/scoped_evp_aead_ctx.h",
 271       "socket/ssl_client_socket_openssl.cc",
 272       "socket/ssl_client_socket_openssl.h",
 273       "socket/ssl_server_socket_openssl.cc",
 274       "socket/ssl_server_socket_openssl.h",
 275       "socket/ssl_session_cache_openssl.cc",
 276       "socket/ssl_session_cache_openssl.h",
 277       "ssl/openssl_platform_key.h",
 278       "ssl/openssl_ssl_util.cc",
 279       "ssl/openssl_ssl_util.h",
 280     ]
 281     if (is_mac) {
 282       sources -= [ "ssl/openssl_platform_key_mac.cc" ]
 283     }
 284     if (is_win) {
 285       sources -= [
 286         "cert/sha256_legacy_support_openssl_win.cc",
 287         "ssl/openssl_platform_key_win.cc",
 288       ]
 289     }
 290   }
 291
 292   if (!use_openssl_certs) {
 293     sources -= [
 294       "base/keygen_handler_openssl.cc",
 295       "base/openssl_private_key_store.h",
 296       "base/openssl_private_key_store_memory.cc",
 297       "cert/cert_database_openssl.cc",
 298       "cert/cert_verify_proc_openssl.cc",
 299       "cert/cert_verify_proc_openssl.h",
 300       "cert/test_root_certs_openssl.cc",
 301       "cert/x509_certificate_openssl.cc",
 302       "ssl/openssl_client_key_store.cc",
 303       "ssl/openssl_client_key_store.h",
 304     ]
 305     if (is_android) {
 306       sources -= [ "base/openssl_private_key_store_android.cc" ]
 307     }
 308   } else if (is_android) {
 309     # Android doesn't use these even when using OpenSSL.
 310     sources -= [
 311       "base/openssl_private_key_store_memory.cc",
 312       "cert/cert_database_openssl.cc",
 313       "cert/cert_verify_proc_openssl.cc",
 314       "cert/test_root_certs_openssl.cc",
 315     ]
 316   }
 317
 318   if (use_glib && !is_chromeos) {
 319     configs += [ "//build/config/linux:gconf" ]
 320     deps += [ "//build/config/linux:gio" ]
 321   }
 322
 323   if (is_linux) {
 324     configs += [ "//build/config/linux:libresolv" ]
 325   } else {
 326     sources -= [
 327       "base/crypto_module_nss.cc",
 328       "base/keygen_handler_nss.cc",
 329       "cert/cert_database_nss.cc",
 330       "cert/nss_cert_database.cc",
 331       "cert/nss_cert_database.h",
 332       "cert/x509_certificate_nss.cc",
 333       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 334       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 335       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 336       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 337       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 338       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 339     ]
 340
 341     if (!is_ios && !use_openssl) {
 342       # These files are part of the partial implementation of NSS on iOS so
 343       # keep them in that case.
 344       sources -= [
 345         "cert/test_root_certs_nss.cc",
 346         "ocsp/nss_ocsp.cc",
 347         "ocsp/nss_ocsp.h",
 348       ]
 349     }
 350   }
 351
 352   if (!use_nss_certs) {
 353     sources -= [
 354       "ssl/client_cert_store_nss.cc",
 355       "ssl/client_cert_store_nss.h",
 356     ]
 357     if (!is_ios) {
 358       # These files are part of the partial implementation of NSS on iOS so
 359       # keep them in that case (even though use_nss_certs is not set).
 360       sources -= [
 361         "cert/cert_verify_proc_nss.cc",
 362         "cert/cert_verify_proc_nss.h",
 363       ]
 364     }
 365     if (is_chromeos) {
 366       # These were already removed on non-ChromeOS.
 367       sources -= [
 368         "ssl/client_cert_store_chromeos.cc",
 369         "ssl/client_cert_store_chromeos.h",
 370       ]
 371     }
 372   }
 373
 374   if (!enable_websockets) {
 375     sources -= [
 376       "websockets/websocket_basic_handshake_stream.cc",
 377       "websockets/websocket_basic_handshake_stream.h",
 378       "websockets/websocket_basic_stream.cc",
 379       "websockets/websocket_basic_stream.h",
 380       "websockets/websocket_channel.cc",
 381       "websockets/websocket_channel.h",
 382       "websockets/websocket_deflate_predictor.h",
 383       "websockets/websocket_deflate_predictor_impl.cc",
 384       "websockets/websocket_deflate_predictor_impl.h",
 385       "websockets/websocket_deflate_stream.cc",
 386       "websockets/websocket_deflate_stream.h",
 387       "websockets/websocket_deflater.cc",
 388       "websockets/websocket_deflater.h",
 389       "websockets/websocket_errors.cc",
 390       "websockets/websocket_errors.h",
 391       "websockets/websocket_extension.cc",
 392       "websockets/websocket_extension.h",
 393       "websockets/websocket_extension_parser.cc",
 394       "websockets/websocket_extension_parser.h",
 395       "websockets/websocket_frame.cc",
 396       "websockets/websocket_frame.h",
 397       "websockets/websocket_frame_parser.cc",
 398       "websockets/websocket_frame_parser.h",
 399       "websockets/websocket_handshake_constants.cc",
 400       "websockets/websocket_handshake_constants.h",
 401       "websockets/websocket_handshake_challenge.cc",
 402       "websockets/websocket_handshake_challenge.h",
 403       "websockets/websocket_handshake_request_info.cc",
 404       "websockets/websocket_handshake_request_info.h",
 405       "websockets/websocket_handshake_response_info.cc",
 406       "websockets/websocket_handshake_response_info.h",
 407       "websockets/websocket_handshake_stream_base.h",
 408       "websockets/websocket_handshake_stream_create_helper.cc",
 409       "websockets/websocket_handshake_stream_create_helper.h",
 410       "websockets/websocket_inflater.cc",
 411       "websockets/websocket_inflater.h",
 412       "websockets/websocket_mux.h",
 413       "websockets/websocket_stream.cc",
 414       "websockets/websocket_stream.h",
 415     ]
 416   }
 417
 418   if (!enable_mdns) {
 419     sources -= [
 420       "dns/mdns_cache.cc",
 421       "dns/mdns_cache.h",
 422       "dns/mdns_client.cc",
 423       "dns/mdns_client.h",
 424       "dns/mdns_client_impl.cc",
 425       "dns/mdns_client_impl.h",
 426       "dns/record_parsed.cc",
 427       "dns/record_parsed.h",
 428       "dns/record_rdata.cc",
 429       "dns/record_rdata.h",
 430     ]
 431   }
 432
 433   if (is_win) {
 434     sources -= [
 435       "http/http_auth_handler_ntlm_portable.cc",
 436       "socket/socket_libevent.cc",
 437       "socket/socket_libevent.h",
 438       "socket/tcp_socket_libevent.cc",
 439       "socket/tcp_socket_libevent.h",
 440       "udp/udp_socket_libevent.cc",
 441       "udp/udp_socket_libevent.h",
 442     ]
 443   } else {  # !is_win
 444     sources -= [
 445       "base/winsock_init.cc",
 446       "base/winsock_init.h",
 447       "base/winsock_util.cc",
 448       "base/winsock_util.h",
 449       "proxy/proxy_resolver_winhttp.cc",
 450       "proxy/proxy_resolver_winhttp.h",
 451     ]
 452   }
 453
 454   if (is_mac) {
 455     libs = [
 456       "Foundation.framework",
 457       "Security.framework",
 458       "SystemConfiguration.framework",
 459       "resolv",
 460     ]
 461   }
 462
 463   if (is_ios) {
 464     # Add back some sources that were otherwise filtered out. iOS additionally
 465     # doesn't set USE_NSS but needs some of the files.
 466     set_sources_assignment_filter([])
 467     sources += [
 468       "base/net_util_mac.cc",
 469       "base/net_util_mac.h",
 470       "base/network_change_notifier_mac.cc",
 471       "base/network_config_watcher_mac.cc",
 472       "base/platform_mime_util_mac.mm",
 473       "cert/cert_verify_proc_nss.cc",
 474       "cert/cert_verify_proc_nss.h",
 475       "cert/test_root_certs_nss.cc",
 476       "cert/x509_util_nss.cc",
 477       "cert/x509_util_nss.h",
 478       "proxy/proxy_resolver_mac.cc",
 479       "proxy/proxy_server_mac.cc",
 480       "ocsp/nss_ocsp.cc",
 481       "ocsp/nss_ocsp.h",
 482     ]
 483     set_sources_assignment_filter(sources_assignment_filter)
 484
 485     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 486     libs = [
 487       "CFNetwork.framework",
 488       "MobileCoreServices.framework",
 489       "Security.framework",
 490       "SystemConfiguration.framework",
 491       "resolv",
 492     ]
 493   }
 494
 495   if (is_ios || is_mac) {
 496     sources += gypi_values.net_base_mac_ios_sources
 497   }
 498
 499   if (is_android) {
 500     # Add some Linux sources that were excluded by the filter, but which
 501     # are needed.
 502     set_sources_assignment_filter([])
 503     sources += [
 504       "base/platform_mime_util_linux.cc",
 505       "base/address_tracker_linux.cc",
 506       "base/address_tracker_linux.h",
 507       "base/net_util_linux.cc",
 508       "base/net_util_linux.h",
 509     ]
 510     set_sources_assignment_filter(sources_assignment_filter)
 511
 512     if (!is_android_webview_build) {
 513       deps += [ ":net_jni_headers" ]
 514     }
 515   }
 516
 517   if (use_icu_alternatives_on_android) {
 518     deps -= [
 519       "//base:i18n",
 520       "//third_party/icu",
 521     ]
 522     sources -= [
 523       "base/filename_util_icu.cc",
 524       "base/net_string_util_icu.cc",
 525       "base/net_util_icu.cc",
 526     ]
 527     sources += [
 528       "base/net_string_util_icu_alternatives_android.cc",
 529       "base/net_string_util_icu_alternatives_android.h",
 530     ]
 531   }
 532 }
 533
 534 grit("net_resources") {
 535   source = "base/net_resources.grd"
 536   use_qualified_include = true
 537   outputs = [
 538     "grit/net_resources.h",
 539     "net_resources.pak",
 540     "net_resources.rc",
 541   ]
 542 }
 543
 544 static_library("extras") {
 545   sources = gypi_values.net_extras_sources
 546   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 547   deps = [
 548     ":net",
 549     "//sql:sql",
 550   ]
 551 }
 552
 553 static_library("http_server") {
 554   sources = [
 555     "server/http_connection.cc",
 556     "server/http_connection.h",
 557     "server/http_server.cc",
 558     "server/http_server.h",
 559     "server/http_server_request_info.cc",
 560     "server/http_server_request_info.h",
 561     "server/http_server_response_info.cc",
 562     "server/http_server_response_info.h",
 563     "server/web_socket.cc",
 564     "server/web_socket.h",
 565     "server/web_socket_encoder.cc",
 566     "server/web_socket_encoder.h",
 567   ]
 568   configs += [
 569     "//build/config/compiler:wexit_time_destructors",
 570     ":net_win_size_truncation",
 571   ]
 572   deps = [
 573     ":net",
 574     "//base",
 575   ]
 576 }
 577
 578 executable("dump_cache") {
 579   testonly = true
 580   sources = [
 581     "tools/dump_cache/cache_dumper.cc",
 582     "tools/dump_cache/cache_dumper.h",
 583     "tools/dump_cache/dump_cache.cc",
 584     "tools/dump_cache/dump_files.cc",
 585     "tools/dump_cache/dump_files.h",
 586     "tools/dump_cache/simple_cache_dumper.cc",
 587     "tools/dump_cache/simple_cache_dumper.h",
 588     "tools/dump_cache/url_to_filename_encoder.cc",
 589     "tools/dump_cache/url_to_filename_encoder.h",
 590     "tools/dump_cache/url_utilities.h",
 591     "tools/dump_cache/url_utilities.cc",
 592   ]
 593
 594   configs += [ ":net_win_size_truncation" ]
 595
 596   deps = [
 597     "//base",
 598     ":net",
 599     ":test_support",
 600   ]
 601 }
 602
 603 source_set("test_support") {
 604   testonly = true
 605   sources = [
 606     "base/captured_net_log_entry.cc",
 607     "base/captured_net_log_entry.h",
 608     "base/capturing_net_log.cc",
 609     "base/capturing_net_log.h",
 610     "base/capturing_net_log_observer.cc",
 611     "base/capturing_net_log_observer.h",
 612     "base/load_timing_info_test_util.cc",
 613     "base/load_timing_info_test_util.h",
 614     "base/mock_file_stream.cc",
 615     "base/mock_file_stream.h",
 616     "base/test_completion_callback.cc",
 617     "base/test_completion_callback.h",
 618     "base/test_data_directory.cc",
 619     "base/test_data_directory.h",
 620     "cert/mock_cert_verifier.cc",
 621     "cert/mock_cert_verifier.h",
 622     "cookies/cookie_monster_store_test.cc",
 623     "cookies/cookie_monster_store_test.h",
 624     "cookies/cookie_store_test_callbacks.cc",
 625     "cookies/cookie_store_test_callbacks.h",
 626     "cookies/cookie_store_test_helpers.cc",
 627     "cookies/cookie_store_test_helpers.h",
 628     "disk_cache/disk_cache_test_base.cc",
 629     "disk_cache/disk_cache_test_base.h",
 630     "disk_cache/disk_cache_test_util.cc",
 631     "disk_cache/disk_cache_test_util.h",
 632     "dns/dns_test_util.cc",
 633     "dns/dns_test_util.h",
 634     "dns/mock_host_resolver.cc",
 635     "dns/mock_host_resolver.h",
 636     "dns/mock_mdns_socket_factory.cc",
 637     "dns/mock_mdns_socket_factory.h",
 638     "http/http_transaction_test_util.cc",
 639     "http/http_transaction_test_util.h",
 640     "proxy/mock_proxy_resolver.cc",
 641     "proxy/mock_proxy_resolver.h",
 642     "proxy/mock_proxy_script_fetcher.cc",
 643     "proxy/mock_proxy_script_fetcher.h",
 644     "proxy/proxy_config_service_common_unittest.cc",
 645     "proxy/proxy_config_service_common_unittest.h",
 646     "socket/socket_test_util.cc",
 647     "socket/socket_test_util.h",
 648     "test/cert_test_util.cc",
 649     "test/cert_test_util.h",
 650     "test/cert_test_util_nss.cc",
 651     "test/ct_test_util.cc",
 652     "test/ct_test_util.h",
 653     "test/embedded_test_server/embedded_test_server.cc",
 654     "test/embedded_test_server/embedded_test_server.h",
 655     "test/embedded_test_server/http_connection.cc",
 656     "test/embedded_test_server/http_connection.h",
 657     "test/embedded_test_server/http_request.cc",
 658     "test/embedded_test_server/http_request.h",
 659     "test/embedded_test_server/http_response.cc",
 660     "test/embedded_test_server/http_response.h",
 661     "test/net_test_suite.cc",
 662     "test/net_test_suite.h",
 663     "test/python_utils.cc",
 664     "test/python_utils.h",
 665     "test/spawned_test_server/base_test_server.cc",
 666     "test/spawned_test_server/base_test_server.h",
 667     "test/spawned_test_server/local_test_server_posix.cc",
 668     "test/spawned_test_server/local_test_server_win.cc",
 669     "test/spawned_test_server/local_test_server.cc",
 670     "test/spawned_test_server/local_test_server.h",
 671     "test/spawned_test_server/remote_test_server.cc",
 672     "test/spawned_test_server/remote_test_server.h",
 673     "test/spawned_test_server/spawned_test_server.h",
 674     "test/spawned_test_server/spawner_communicator.cc",
 675     "test/spawned_test_server/spawner_communicator.h",
 676     "test/url_request/url_request_failed_job.cc",
 677     "test/url_request/url_request_failed_job.h",
 678     "test/url_request/url_request_mock_http_job.cc",
 679     "test/url_request/url_request_mock_http_job.h",
 680     "url_request/test_url_fetcher_factory.cc",
 681     "url_request/test_url_fetcher_factory.h",
 682     "url_request/test_url_request_interceptor.cc",
 683     "url_request/test_url_request_interceptor.h",
 684     "url_request/url_request_test_util.cc",
 685     "url_request/url_request_test_util.h",
 686   ]
 687
 688   configs += [ ":net_win_size_truncation" ]
 689
 690   public_deps = [
 691     "//base",
 692     "//base/test:test_support",
 693     "//crypto",
 694     "//net",
 695     "//net/tools/tld_cleanup",
 696     "//testing/gmock",
 697     "//testing/gtest",
 698     "//url",
 699   ]
 700
 701   if (!use_openssl && (use_nss_certs || is_ios)) {
 702     public_deps += [ "//crypto:platform" ]
 703   }
 704
 705   if (!is_android) {
 706     sources -= [
 707       "test/spawned_test_server/remote_test_server.cc",
 708       "test/spawned_test_server/remote_test_server.h",
 709       "test/spawned_test_server/spawner_communicator.cc",
 710       "test/spawned_test_server/spawner_communicator.h",
 711     ]
 712   }
 713
 714   if (use_v8_in_net) {
 715     public_deps += [ ":net_with_v8" ]
 716   }
 717
 718   if (!enable_mdns) {
 719     sources -= [
 720       "dns/mock_mdns_socket_factory.cc",
 721       "dns/mock_mdns_socket_factory.h",
 722     ]
 723   }
 724
 725   if (!use_nss_certs) {
 726     sources -= [ "test/cert_test_util_nss.cc" ]
 727   }
 728 }
 729
 730 source_set("balsa") {
 731   sources = [
 732     "tools/balsa/balsa_enums.h",
 733     "tools/balsa/balsa_frame.cc",
 734     "tools/balsa/balsa_frame.h",
 735     "tools/balsa/balsa_headers.cc",
 736     "tools/balsa/balsa_headers.h",
 737     "tools/balsa/balsa_headers_token_utils.cc",
 738     "tools/balsa/balsa_headers_token_utils.h",
 739     "tools/balsa/balsa_visitor_interface.h",
 740     "tools/balsa/http_message_constants.cc",
 741     "tools/balsa/http_message_constants.h",
 742     "tools/balsa/noop_balsa_visitor.h",
 743     "tools/balsa/simple_buffer.cc",
 744     "tools/balsa/simple_buffer.h",
 745     "tools/balsa/split.cc",
 746     "tools/balsa/split.h",
 747     "tools/balsa/string_piece_utils.h",
 748     "tools/quic/spdy_utils.cc",
 749     "tools/quic/spdy_utils.h",
 750   ]
 751   deps = [
 752     ":net",
 753     "//base",
 754     "//url",
 755   ]
 756 }
 757
 758 if (use_v8_in_net) {
 759   component("net_with_v8") {
 760     sources = [
 761       "proxy/proxy_resolver_v8.cc",
 762       "proxy/proxy_resolver_v8.h",
 763       "proxy/proxy_resolver_v8_tracing.cc",
 764       "proxy/proxy_resolver_v8_tracing.h",
 765       "proxy/proxy_service_v8.cc",
 766       "proxy/proxy_service_v8.h",
 767     ]
 768
 769     defines = [ "NET_IMPLEMENTATION" ]
 770     configs += [
 771       ":net_win_size_truncation",
 772       "//build/config/compiler:wexit_time_destructors",
 773     ]
 774
 775     public_deps = [
 776       ":net",
 777     ]
 778     deps = [
 779       "//base",
 780       "//gin",
 781       "//url",
 782       "//v8",
 783     ]
 784   }
 785 }
 786
 787 if (!is_ios && !is_android) {
 788   executable("crash_cache") {
 789     testonly = true
 790     sources = [
 791       "tools/crash_cache/crash_cache.cc",
 792     ]
 793     configs += [ ":net_win_size_truncation" ]
 794     deps = [
 795       ":net",
 796       ":test_support",
 797       "//base",
 798     ]
 799   }
 800
 801   executable("crl_set_dump") {
 802     testonly = true
 803     sources = [
 804       "tools/crl_set_dump/crl_set_dump.cc",
 805     ]
 806     configs += [ ":net_win_size_truncation" ]
 807     deps = [
 808       ":net",
 809       "//base",
 810     ]
 811   }
 812
 813   executable("dns_fuzz_stub") {
 814     testonly = true
 815     sources = [
 816       "tools/dns_fuzz_stub/dns_fuzz_stub.cc",
 817     ]
 818     configs += [ ":net_win_size_truncation" ]
 819     deps = [
 820       ":net",
 821       "//base",
 822     ]
 823   }
 824
 825   executable("gdig") {
 826     testonly = true
 827     sources = [
 828       "tools/gdig/file_net_log.cc",
 829       "tools/gdig/gdig.cc",
 830     ]
 831     deps = [
 832       ":net",
 833       "//base",
 834     ]
 835   }
 836
 837   executable("get_server_time") {
 838     testonly = true
 839     sources = [
 840       "tools/get_server_time/get_server_time.cc",
 841     ]
 842     configs += [ ":net_win_size_truncation" ]
 843     deps = [
 844       ":net",
 845       "//base",
 846       "//base:i18n",
 847       "//url",
 848     ]
 849   }
 850
 851   if (use_v8_in_net) {
 852     executable("net_watcher") {
 853       testonly = true
 854       sources = [
 855         "tools/net_watcher/net_watcher.cc",
 856       ]
 857       deps = [
 858         ":net",
 859         ":net_with_v8",
 860         "//base",
 861       ]
 862
 863       if (is_desktop_linux) {
 864         configs += [
 865           "//build/config/linux:gconf",
 866           "//build/config/linux:glib",
 867         ]
 868         deps += [ "//build/config/linux:gio" ]
 869       }
 870     }
 871   }
 872
 873   executable("run_testserver") {
 874     testonly = true
 875     sources = [
 876       "tools/testserver/run_testserver.cc",
 877     ]
 878     deps = [
 879       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 880                # in the GYP build, and can be removed when the bug is fixed.
 881       ":test_support",
 882       "//base",
 883       "//base/test:test_support",
 884       "//testing/gtest",
 885     ]
 886   }
 887
 888   executable("stress_cache") {
 889     testonly = true
 890     sources = [
 891       "disk_cache/blockfile/stress_cache.cc",
 892     ]
 893     configs += [ ":net_win_size_truncation" ]
 894     deps = [
 895       ":net",
 896       ":test_support",
 897       "//base",
 898     ]
 899   }
 900
 901   executable("tld_cleanup") {
 902     sources = [
 903       "tools/tld_cleanup/tld_cleanup.cc",
 904     ]
 905     configs += [ ":net_win_size_truncation" ]
 906     deps = [
 907       "//base",
 908       "//base:i18n",
 909       "//net/tools/tld_cleanup",
 910     ]
 911   }
 912 }
 913
 914 if (is_linux) {
 915   static_library("epoll_server") {
 916     sources = [
 917       "tools/epoll_server/epoll_server.cc",
 918       "tools/epoll_server/epoll_server.h",
 919     ]
 920     deps = [
 921       ":net",
 922       "//base",
 923     ]
 924   }
 925
 926   static_library("flip_in_mem_edsm_server_base") {
 927     testonly = true
 928     sources = [
 929       "tools/dump_cache/url_to_filename_encoder.cc",
 930       "tools/dump_cache/url_to_filename_encoder.h",
 931       "tools/dump_cache/url_utilities.h",
 932       "tools/dump_cache/url_utilities.cc",
 933       "tools/flip_server/acceptor_thread.h",
 934       "tools/flip_server/acceptor_thread.cc",
 935       "tools/flip_server/create_listener.cc",
 936       "tools/flip_server/create_listener.h",
 937       "tools/flip_server/constants.h",
 938       "tools/flip_server/flip_config.cc",
 939       "tools/flip_server/flip_config.h",
 940       "tools/flip_server/http_interface.cc",
 941       "tools/flip_server/http_interface.h",
 942       "tools/flip_server/loadtime_measurement.h",
 943       "tools/flip_server/mem_cache.h",
 944       "tools/flip_server/mem_cache.cc",
 945       "tools/flip_server/output_ordering.cc",
 946       "tools/flip_server/output_ordering.h",
 947       "tools/flip_server/ring_buffer.cc",
 948       "tools/flip_server/ring_buffer.h",
 949       "tools/flip_server/sm_connection.cc",
 950       "tools/flip_server/sm_connection.h",
 951       "tools/flip_server/sm_interface.h",
 952       "tools/flip_server/spdy_ssl.cc",
 953       "tools/flip_server/spdy_ssl.h",
 954       "tools/flip_server/spdy_interface.cc",
 955       "tools/flip_server/spdy_interface.h",
 956       "tools/flip_server/spdy_util.cc",
 957       "tools/flip_server/spdy_util.h",
 958       "tools/flip_server/streamer_interface.cc",
 959       "tools/flip_server/streamer_interface.h",
 960     ]
 961     deps = [
 962       ":balsa",
 963       ":epoll_server",
 964       ":net",
 965       "//base",
 966       "//third_party/boringssl",
 967     ]
 968   }
 969
 970   executable("flip_in_mem_edsm_server_unittests") {
 971     testonly = true
 972     sources = [
 973       "tools/flip_server/flip_test_utils.cc",
 974       "tools/flip_server/flip_test_utils.h",
 975       "tools/flip_server/http_interface_test.cc",
 976       "tools/flip_server/mem_cache_test.cc",
 977       "tools/flip_server/run_all_tests.cc",
 978       "tools/flip_server/spdy_interface_test.cc",
 979     ]
 980     deps = [
 981       ":flip_in_mem_edsm_server_base",
 982       ":net",
 983       ":test_support",
 984       "//testing/gtest",
 985       "//testing/gmock",
 986       "//third_party/boringssl",
 987     ]
 988   }
 989
 990   executable("flip_in_mem_edsm_server") {
 991     testonly = true
 992     sources = [
 993       "tools/flip_server/flip_in_mem_edsm_server.cc",
 994     ]
 995     deps = [
 996       ":flip_in_mem_edsm_server_base",
 997       ":net",
 998       "//base",
 999     ]
1000   }
1001
1002   source_set("quic_base") {
1003     sources = [
1004       "tools/quic/quic_client.cc",
1005       "tools/quic/quic_client.h",
1006       "tools/quic/quic_client_session.cc",
1007       "tools/quic/quic_client_session.h",
1008       "tools/quic/quic_default_packet_writer.cc",
1009       "tools/quic/quic_default_packet_writer.h",
1010       "tools/quic/quic_dispatcher.h",
1011       "tools/quic/quic_dispatcher.cc",
1012       "tools/quic/quic_epoll_clock.cc",
1013       "tools/quic/quic_epoll_clock.h",
1014       "tools/quic/quic_epoll_connection_helper.cc",
1015       "tools/quic/quic_epoll_connection_helper.h",
1016       "tools/quic/quic_in_memory_cache.cc",
1017       "tools/quic/quic_in_memory_cache.h",
1018       "tools/quic/quic_packet_writer_wrapper.cc",
1019       "tools/quic/quic_packet_writer_wrapper.h",
1020       "tools/quic/quic_per_connection_packet_writer.cc",
1021       "tools/quic/quic_per_connection_packet_writer.h",
1022       "tools/quic/quic_server.cc",
1023       "tools/quic/quic_server.h",
1024       "tools/quic/quic_server_session.cc",
1025       "tools/quic/quic_server_session.h",
1026       "tools/quic/quic_socket_utils.cc",
1027       "tools/quic/quic_socket_utils.h",
1028       "tools/quic/quic_spdy_client_stream.cc",
1029       "tools/quic/quic_spdy_client_stream.h",
1030       "tools/quic/quic_spdy_server_stream.cc",
1031       "tools/quic/quic_spdy_server_stream.h",
1032       "tools/quic/quic_time_wait_list_manager.h",
1033       "tools/quic/quic_time_wait_list_manager.cc",
1034     ]
1035     deps = [
1036       ":balsa",
1037       ":epoll_server",
1038       ":net",
1039       "//base",
1040       "//base/third_party/dynamic_annotations",
1041       "//crypto",
1042       "//third_party/boringssl",
1043       "//url",
1044     ]
1045   }
1046
1047   executable("quic_client") {
1048     sources = [
1049       "tools/quic/quic_client_bin.cc",
1050     ]
1051     deps = [
1052       ":quic_base",
1053       ":net",
1054       "//base",
1055       "//third_party/boringssl",
1056     ]
1057   }
1058 }
1059
1060 if (is_android) {
1061   generate_jni("net_jni_headers") {
1062     sources = [
1063       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1064       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1065       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1066       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1067       "android/java/src/org/chromium/net/GURLUtils.java",
1068       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1069       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1070       "android/java/src/org/chromium/net/X509Util.java",
1071     ]
1072     jni_package = "net"
1073   }
1074   generate_jni("net_test_jni_headers") {
1075     sources = [
1076       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1077     ]
1078     jni_package = "net"
1079   }
1080 }
1081
1082 if (is_android || is_linux) {
1083   executable("disk_cache_memory_test") {
1084     testonly = true
1085     sources = [
1086       "tools/disk_cache_memory_test/disk_cache_memory_test.cc",
1087     ]
1088     deps = [
1089       ":net",
1090       "//base",
1091     ]
1092   }
1093 }
1094
1095 # TODO(GYP) make this compile on Android, we need some native test deps done.
1096 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1097 # TODO(GYP) Also doesn't work on Mac, need to figure out why not.
1098 if (!is_android && !is_win && !is_mac) {
1099   source_set("quic_tools") {
1100     sources = [
1101       "quic/quic_dispatcher.cc",
1102       "quic/quic_dispatcher.h",
1103       "quic/quic_in_memory_cache.cc",
1104       "quic/quic_in_memory_cache.h",
1105       "quic/quic_per_connection_packet_writer.cc",
1106       "quic/quic_per_connection_packet_writer.h",
1107       "quic/quic_server.cc",
1108       "quic/quic_server.h",
1109       "quic/quic_server_packet_writer.cc",
1110       "quic/quic_server_packet_writer.h",
1111       "quic/quic_server_session.cc",
1112       "quic/quic_server_session.h",
1113       "quic/quic_spdy_server_stream.cc",
1114       "quic/quic_spdy_server_stream.h",
1115       "quic/quic_time_wait_list_manager.cc",
1116       "quic/quic_time_wait_list_manager.h",
1117     ]
1118     deps = [
1119       ":net",
1120       "//base",
1121       "//base/third_party/dynamic_annotations",
1122       "//url",
1123     ]
1124   }
1125
1126   test("net_unittests") {
1127     sources = gypi_values.net_test_sources
1128
1129     configs += [ ":net_win_size_truncation" ]
1130     defines = []
1131
1132     deps = [
1133       ":extras",
1134       ":http_server",
1135       ":net",
1136       ":quic_tools",
1137       ":test_support",
1138       "//base",
1139       "//base:i18n",
1140       "//base:prefs_test_support",
1141       "//base/allocator",
1142       "//base/third_party/dynamic_annotations",
1143       "//crypto",
1144       "//crypto:platform",
1145       "//crypto:test_support",
1146       "//net/base/registry_controlled_domains",
1147       "//testing/gmock",
1148       "//testing/gtest",
1149       "//third_party/zlib",
1150       "//url",
1151     ]
1152
1153     if (is_linux) {
1154       sources += gypi_values.net_linux_test_sources
1155       deps += [
1156         ":balsa",
1157         ":epoll_server",
1158         ":flip_in_mem_edsm_server_base",
1159         ":quic_base",
1160       ]
1161     }
1162
1163     if (is_mac || is_ios) {
1164       sources += gypi_values.net_base_test_mac_ios_sources
1165     }
1166
1167     if (is_chromeos) {
1168       sources -= [ "proxy/proxy_config_service_linux_unittest.cc" ]
1169     }
1170
1171     if (is_android) {
1172       sources -= [
1173         # See bug http://crbug.com/344533.
1174         "disk_cache/blockfile/index_table_v3_unittest.cc",
1175
1176         # No res_ninit() et al on Android, so this doesn't make a lot of
1177         # sense.
1178         "dns/dns_config_service_posix_unittest.cc",
1179       ]
1180       deps += [
1181         ":net_javatests",  # FIXME(brettw)
1182         ":net_test_jni_headers",
1183       ]
1184     }
1185
1186     if (!use_nss_certs) {
1187       sources -= [ "ssl/client_cert_store_nss_unittest.cc" ]
1188       if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1189         sources -= [ "ssl/client_cert_store_chromeos_unittest.cc" ]
1190       }
1191     }
1192
1193     if (use_openssl) {
1194       # When building for OpenSSL, we need to exclude NSS specific tests
1195       # or functionality not supported by OpenSSL yet.
1196       # TODO(bulach): Add equivalent tests when the underlying
1197       #               functionality is ported to OpenSSL.
1198       sources -= [
1199         "cert/nss_cert_database_unittest.cc",
1200         "cert/x509_util_nss_unittest.cc",
1201         "quic/test_tools/crypto_test_utils_nss.cc",
1202       ]
1203       if (is_chromeos) {
1204         # These were already removed in the non-ChromeOS case.
1205         sources -= [
1206           "cert/nss_cert_database_chromeos_unittest.cc",
1207           "cert/nss_profile_filter_chromeos_unittest.cc",
1208         ]
1209       }
1210     } else {
1211       sources -= [
1212         "cert/x509_util_openssl_unittest.cc",
1213         "quic/test_tools/crypto_test_utils_openssl.cc",
1214         "socket/ssl_client_socket_openssl_unittest.cc",
1215         "socket/ssl_session_cache_openssl_unittest.cc",
1216       ]
1217       if (!is_desktop_linux && !is_chromeos) {
1218         sources -= [ "cert/nss_cert_database_unittest.cc" ]
1219       }
1220     }
1221
1222     if (use_kerberos) {
1223       defines += [ "USE_KERBEROS" ]
1224     } else {
1225       sources -= [
1226         "http/http_auth_gssapi_posix_unittest.cc",
1227         "http/http_auth_handler_negotiate_unittest.cc",
1228         "http/mock_gssapi_library_posix.cc",
1229         "http/mock_gssapi_library_posix.h",
1230       ]
1231     }
1232
1233     if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1234       # Only include this test when on Posix and using NSS for
1235       # cert verification or on iOS (which also uses NSS for certs).
1236       sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1237     }
1238
1239     if (!use_openssl_certs) {
1240       sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1241     }
1242
1243     if (!enable_websockets) {
1244       sources -= [
1245         "server/http_connection_unittest.cc",
1246         "server/http_server_response_info_unittest.cc",
1247         "server/http_server_unittest.cc",
1248         "server/web_socket_encoder_unittest.cc",
1249         "websockets/websocket_basic_stream_test.cc",
1250         "websockets/websocket_channel_test.cc",
1251         "websockets/websocket_deflate_predictor_impl_test.cc",
1252         "websockets/websocket_deflate_stream_test.cc",
1253         "websockets/websocket_deflater_test.cc",
1254         "websockets/websocket_errors_test.cc",
1255         "websockets/websocket_extension_parser_test.cc",
1256         "websockets/websocket_frame_parser_test.cc",
1257         "websockets/websocket_frame_test.cc",
1258         "websockets/websocket_handshake_challenge_test.cc",
1259         "websockets/websocket_handshake_stream_create_helper_test.cc",
1260         "websockets/websocket_inflater_test.cc",
1261         "websockets/websocket_stream_test.cc",
1262         "websockets/websocket_test_util.cc",
1263         "websockets/websocket_test_util.h",
1264       ]
1265       deps -= [ ":http_server" ]
1266     }
1267
1268     if (disable_file_support) {
1269       sources -= [
1270         "base/directory_lister_unittest.cc",
1271         "url_request/url_request_file_job_unittest.cc",
1272       ]
1273     }
1274
1275     if (disable_ftp_support) {
1276       sources -= [
1277         "ftp/ftp_auth_cache_unittest.cc",
1278         "ftp/ftp_ctrl_response_buffer_unittest.cc",
1279         "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1280         "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1281         "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1282         "ftp/ftp_directory_listing_parser_unittest.cc",
1283         "ftp/ftp_directory_listing_parser_unittest.h",
1284         "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1285         "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1286         "ftp/ftp_network_transaction_unittest.cc",
1287         "ftp/ftp_util_unittest.cc",
1288         "url_request/url_request_ftp_job_unittest.cc",
1289       ]
1290     }
1291
1292     if (!enable_built_in_dns) {
1293       sources -= [
1294         "dns/address_sorter_posix_unittest.cc",
1295         "dns/address_sorter_unittest.cc",
1296       ]
1297     }
1298
1299     # Always need use_v8_in_net to be 1 to run on Android, so just remove
1300     # net_unittest's dependency on v8 when using icu alternatives instead of
1301     # setting use_v8_in_net to 0.
1302     if (use_v8_in_net && !use_icu_alternatives_on_android) {
1303       deps += [ ":net_with_v8" ]
1304     } else {
1305       sources -= [
1306         "proxy/proxy_resolver_v8_unittest.cc",
1307         "proxy/proxy_resolver_v8_tracing_unittest.cc",
1308       ]
1309     }
1310
1311     if (!enable_mdns) {
1312       sources -= [
1313         "dns/mdns_cache_unittest.cc",
1314         "dns/mdns_client_unittest.cc",
1315         "dns/record_parsed_unittest.cc",
1316         "dns/record_rdata_unittest.cc",
1317       ]
1318     }
1319
1320     if (is_ios) {
1321       # TODO(GYP)
1322       #  'actions': [
1323       #    {
1324       #      'action_name': 'copy_test_data',
1325       #      'variables': {
1326       #        'test_data_files': [
1327       #          'data/ssl/certificates/',
1328       #          'data/test.html',
1329       #          'data/url_request_unittest/',
1330       #        ],
1331       #        'test_data_prefix': 'net',
1332       #      },
1333       #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1334       #    },
1335       #  ],
1336       sources -= [
1337         # TODO(droger): The following tests are disabled because the
1338         # implementation is missing or incomplete.
1339         # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1340         "base/keygen_handler_unittest.cc",
1341         "disk_cache/backend_unittest.cc",
1342         "disk_cache/blockfile/block_files_unittest.cc",
1343
1344         # Need to read input data files.
1345         "filter/gzip_filter_unittest.cc",
1346         "socket/ssl_server_socket_unittest.cc",
1347         "spdy/fuzzing/hpack_fuzz_util_test.cc",
1348
1349         # Need TestServer.
1350         "proxy/proxy_script_fetcher_impl_unittest.cc",
1351         "socket/ssl_client_socket_unittest.cc",
1352         "url_request/url_fetcher_impl_unittest.cc",
1353         "url_request/url_request_context_builder_unittest.cc",
1354
1355         # Needs GetAppOutput().
1356         "test/python_utils_unittest.cc",
1357
1358         # The following tests are disabled because they don't apply to
1359         # iOS.
1360         # OS is not "linux" or "freebsd" or "openbsd".
1361         "socket/unix_domain_client_socket_posix_unittest.cc",
1362         "socket/unix_domain_listen_socket_posix_unittest.cc",
1363         "socket/unix_domain_server_socket_posix_unittest.cc",
1364
1365         # See bug http://crbug.com/344533.
1366         "disk_cache/blockfile/index_table_v3_unittest.cc",
1367       ]
1368     }
1369
1370     if (is_android) {
1371       sources -= [ "dns/dns_config_service_posix_unittest.cc" ]
1372
1373       # TODO(GYP)
1374       # # TODO(mmenke):  This depends on test_support_base, which depends on
1375       # #                icu.  Figure out a way to remove that dependency.
1376       # 'dependencies': [
1377       #   '../testing/android/native_test.gyp:native_test_native_code',
1378       # ]
1379
1380       set_sources_assignment_filter([])
1381       sources += [ "base/address_tracker_linux_unittest.cc" ]
1382       set_sources_assignment_filter(sources_assignment_filter)
1383     }
1384
1385     if (use_icu_alternatives_on_android) {
1386       sources -= [
1387         "base/filename_util_unittest.cc",
1388         "base/net_util_icu_unittest.cc",
1389       ]
1390       deps -= [ "//base:i18n" ]
1391     }
1392   }
1393
1394   executable("quic_server") {
1395     sources = [
1396       "quic/quic_server_bin.cc",
1397     ]
1398     deps = [
1399       ":quic_tools",
1400       ":net",
1401       "//base",
1402       "//third_party/boringssl",
1403     ]
1404   }
1405 }  # !is_android && !is_win && !is_mac