net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   public_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   public_deps = [
  91     "//crypto",
  92     "//crypto:platform"
  93   ]
  94   deps = [
  95    ":net_resources",
  96     "//base",
  97     "//base:i18n",
  98     "//base:prefs",
  99     "//base/third_party/dynamic_annotations",
 100     "//net/base/registry_controlled_domains",
 101     "//sdch",
 102     "//third_party/icu",
 103     "//third_party/zlib",
 104     "//url",
 105   ]
 106
 107   if (use_kerberos) {
 108     defines += [ "USE_KERBEROS" ]
 109     if (is_android) {
 110       include_dirs += [ "/usr/include/kerberosV" ]
 111     }
 112   } else {
 113     sources -= [
 114       "http/http_auth_gssapi_posix.cc",
 115       "http/http_auth_gssapi_posix.h",
 116       "http/http_auth_handler_negotiate.h",
 117       "http/http_auth_handler_negotiate.cc",
 118     ]
 119   }
 120
 121   if (is_posix) {
 122     if (posix_avoid_mmap) {
 123       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 124     } else {
 125       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 126     }
 127   }
 128
 129   if (disable_file_support) {
 130     sources -= [
 131       "base/directory_lister.cc",
 132       "base/directory_lister.h",
 133       "url_request/url_request_file_dir_job.cc",
 134       "url_request/url_request_file_dir_job.h",
 135       "url_request/url_request_file_job.cc",
 136       "url_request/url_request_file_job.h",
 137       "url_request/file_protocol_handler.cc",
 138       "url_request/file_protocol_handler.h",
 139     ]
 140   }
 141
 142   if (disable_ftp_support) {
 143     sources -= [
 144       "ftp/ftp_auth_cache.cc",
 145       "ftp/ftp_auth_cache.h",
 146       "ftp/ftp_ctrl_response_buffer.cc",
 147       "ftp/ftp_ctrl_response_buffer.h",
 148       "ftp/ftp_directory_listing_parser.cc",
 149       "ftp/ftp_directory_listing_parser.h",
 150       "ftp/ftp_directory_listing_parser_ls.cc",
 151       "ftp/ftp_directory_listing_parser_ls.h",
 152       "ftp/ftp_directory_listing_parser_netware.cc",
 153       "ftp/ftp_directory_listing_parser_netware.h",
 154       "ftp/ftp_directory_listing_parser_os2.cc",
 155       "ftp/ftp_directory_listing_parser_os2.h",
 156       "ftp/ftp_directory_listing_parser_vms.cc",
 157       "ftp/ftp_directory_listing_parser_vms.h",
 158       "ftp/ftp_directory_listing_parser_windows.cc",
 159       "ftp/ftp_directory_listing_parser_windows.h",
 160       "ftp/ftp_network_layer.cc",
 161       "ftp/ftp_network_layer.h",
 162       "ftp/ftp_network_session.cc",
 163       "ftp/ftp_network_session.h",
 164       "ftp/ftp_network_transaction.cc",
 165       "ftp/ftp_network_transaction.h",
 166       "ftp/ftp_request_info.h",
 167       "ftp/ftp_response_info.cc",
 168       "ftp/ftp_response_info.h",
 169       "ftp/ftp_server_type_histograms.cc",
 170       "ftp/ftp_server_type_histograms.h",
 171       "ftp/ftp_transaction.h",
 172       "ftp/ftp_transaction_factory.h",
 173       "ftp/ftp_util.cc",
 174       "ftp/ftp_util.h",
 175       "url_request/ftp_protocol_handler.cc",
 176       "url_request/ftp_protocol_handler.h",
 177       "url_request/url_request_ftp_job.cc",
 178       "url_request/url_request_ftp_job.h",
 179     ]
 180   }
 181
 182   if (enable_built_in_dns) {
 183     defines += [ "ENABLE_BUILT_IN_DNS" ]
 184   } else {
 185     sources -= [
 186       "dns/address_sorter_posix.cc",
 187       "dns/address_sorter_posix.h",
 188       "dns/dns_client.cc",
 189     ]
 190   }
 191
 192   if (use_openssl) {
 193     sources -= [
 194       "base/nss_memio.c",
 195       "base/nss_memio.h",
 196       "cert/ct_log_verifier_nss.cc",
 197       "cert/ct_objects_extractor_nss.cc",
 198       "cert/jwk_serializer_nss.cc",
 199       "cert/scoped_nss_types.h",
 200       "cert/x509_util_nss.cc",
 201       "cert/x509_util_nss.h",
 202       "quic/crypto/aead_base_decrypter_nss.cc",
 203       "quic/crypto/aead_base_encrypter_nss.cc",
 204       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 205       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 206       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 207       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 208       "quic/crypto/channel_id_nss.cc",
 209       "quic/crypto/p256_key_exchange_nss.cc",
 210       "socket/nss_ssl_util.cc",
 211       "socket/nss_ssl_util.h",
 212       "socket/ssl_client_socket_nss.cc",
 213       "socket/ssl_client_socket_nss.h",
 214       "socket/ssl_server_socket_nss.cc",
 215       "socket/ssl_server_socket_nss.h",
 216     ]
 217     if (is_chromeos) {
 218       sources -= [
 219         "cert/nss_cert_database_chromeos.cc",
 220         "cert/nss_cert_database_chromeos.h",
 221         "cert/nss_profile_filter_chromeos.cc",
 222         "cert/nss_profile_filter_chromeos.h",
 223       ]
 224     }
 225     if (is_linux) {
 226       # These are always removed for non-Linux cases below.
 227       sources -= [
 228         "base/crypto_module_nss.cc",
 229         "base/keygen_handler_nss.cc",
 230         "cert/cert_database_nss.cc",
 231         "cert/nss_cert_database.cc",
 232         "cert/nss_cert_database.h",
 233         "cert/x509_certificate_nss.cc",
 234         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 235         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 236         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 237         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 238         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 239         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 240       ]
 241     }
 242     if (is_ios) {
 243       # Always removed for !ios below.
 244       sources -= [
 245         "cert/cert_verify_proc_nss.cc",
 246         "cert/cert_verify_proc_nss.h",
 247         "cert/test_root_certs_nss.cc",
 248         "ocsp/nss_ocsp.cc",
 249         "ocsp/nss_ocsp.h",
 250       ]
 251     }
 252   } else {
 253     sources -= [
 254       "base/crypto_module_openssl.cc",
 255       "base/keygen_handler_openssl.cc",
 256       "cert/ct_log_verifier_openssl.cc",
 257       "cert/ct_objects_extractor_openssl.cc",
 258       "cert/jwk_serializer_openssl.cc",
 259       "cert/x509_util_openssl.cc",
 260       "cert/x509_util_openssl.h",
 261       "quic/crypto/aead_base_decrypter_openssl.cc",
 262       "quic/crypto/aead_base_encrypter_openssl.cc",
 263       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 264       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 265       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 266       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 267       "quic/crypto/channel_id_openssl.cc",
 268       "quic/crypto/p256_key_exchange_openssl.cc",
 269       "quic/crypto/scoped_evp_aead_ctx.cc",
 270       "quic/crypto/scoped_evp_aead_ctx.h",
 271       "socket/ssl_client_socket_openssl.cc",
 272       "socket/ssl_client_socket_openssl.h",
 273       "socket/ssl_server_socket_openssl.cc",
 274       "socket/ssl_server_socket_openssl.h",
 275       "socket/ssl_session_cache_openssl.cc",
 276       "socket/ssl_session_cache_openssl.h",
 277       "ssl/openssl_platform_key.h",
 278       "ssl/openssl_ssl_util.cc",
 279       "ssl/openssl_ssl_util.h",
 280     ]
 281     if (is_mac) {
 282       sources -= [
 283         "ssl/openssl_platform_key_mac.cc",
 284       ]
 285     }
 286     if (is_win) {
 287       sources -= [
 288         "ssl/openssl_platform_key_win.cc",
 289       ]
 290     }
 291   }
 292
 293   if (!use_openssl_certs) {
 294     sources -= [
 295       "base/openssl_private_key_store.h",
 296       "base/openssl_private_key_store_memory.cc",
 297       "cert/cert_database_openssl.cc",
 298       "cert/cert_verify_proc_openssl.cc",
 299       "cert/cert_verify_proc_openssl.h",
 300       "cert/test_root_certs_openssl.cc",
 301       "cert/x509_certificate_openssl.cc",
 302       "ssl/openssl_client_key_store.cc",
 303       "ssl/openssl_client_key_store.h",
 304     ]
 305     if (is_android) {
 306       sources -= [
 307         "base/openssl_private_key_store_android.cc",
 308       ]
 309     }
 310   } else if (is_android) {
 311     # Android doesn't use these even when using OpenSSL.
 312     sources -= [
 313       "base/openssl_private_key_store_memory.cc",
 314       "cert/cert_database_openssl.cc",
 315       "cert/cert_verify_proc_openssl.cc",
 316       "cert/test_root_certs_openssl.cc",
 317     ]
 318   }
 319
 320   if (use_glib) {
 321     configs += [ "//build/config/linux:gconf" ]
 322     deps += [ "//build/config/linux:gio" ]
 323   }
 324
 325   if (is_linux) {
 326     configs += [ "//build/config/linux:libresolv" ]
 327   } else {
 328     sources -= [
 329       "base/crypto_module_nss.cc",
 330       "base/keygen_handler_nss.cc",
 331       "cert/cert_database_nss.cc",
 332       "cert/nss_cert_database.cc",
 333       "cert/nss_cert_database.h",
 334       "cert/x509_certificate_nss.cc",
 335       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 336       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 337       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 338       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 339       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 340       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 341     ]
 342
 343     if (!is_ios) {
 344       # These files are part of the partial implementation of NSS on iOS so
 345       # keep them in that case.
 346       sources -= [
 347         "cert/test_root_certs_nss.cc",
 348         "ocsp/nss_ocsp.cc",
 349         "ocsp/nss_ocsp.h",
 350       ]
 351     }
 352   }
 353
 354   if (!use_nss_certs) {
 355     sources -= [
 356       "ssl/client_cert_store_nss.cc",
 357       "ssl/client_cert_store_nss.h",
 358     ]
 359     if (!is_ios) {
 360       # These files are part of the partial implementation of NSS on iOS so
 361       # keep them in that case (even though use_nss_certs is not set).
 362       sources -= [
 363         "cert/cert_verify_proc_nss.cc",
 364         "cert/cert_verify_proc_nss.h",
 365       ]
 366     }
 367     if (is_chromeos) {
 368       # These were already removed on non-ChromeOS.
 369       sources -= [
 370         "ssl/client_cert_store_chromeos.cc",
 371         "ssl/client_cert_store_chromeos.h",
 372       ]
 373     }
 374   }
 375
 376   if (!enable_websockets) {
 377     sources -= [
 378       "socket_stream/socket_stream.cc",
 379       "socket_stream/socket_stream.h",
 380       "socket_stream/socket_stream_job.cc",
 381       "socket_stream/socket_stream_job.h",
 382       "socket_stream/socket_stream_job_manager.cc",
 383       "socket_stream/socket_stream_job_manager.h",
 384       "socket_stream/socket_stream_metrics.cc",
 385       "socket_stream/socket_stream_metrics.h",
 386       "spdy/spdy_websocket_stream.cc",
 387       "spdy/spdy_websocket_stream.h",
 388       "websockets/websocket_basic_handshake_stream.cc",
 389       "websockets/websocket_basic_handshake_stream.h",
 390       "websockets/websocket_basic_stream.cc",
 391       "websockets/websocket_basic_stream.h",
 392       "websockets/websocket_channel.cc",
 393       "websockets/websocket_channel.h",
 394       "websockets/websocket_deflate_predictor.h",
 395       "websockets/websocket_deflate_predictor_impl.cc",
 396       "websockets/websocket_deflate_predictor_impl.h",
 397       "websockets/websocket_deflate_stream.cc",
 398       "websockets/websocket_deflate_stream.h",
 399       "websockets/websocket_deflater.cc",
 400       "websockets/websocket_deflater.h",
 401       "websockets/websocket_errors.cc",
 402       "websockets/websocket_errors.h",
 403       "websockets/websocket_extension.cc",
 404       "websockets/websocket_extension.h",
 405       "websockets/websocket_extension_parser.cc",
 406       "websockets/websocket_extension_parser.h",
 407       "websockets/websocket_frame.cc",
 408       "websockets/websocket_frame.h",
 409       "websockets/websocket_frame_parser.cc",
 410       "websockets/websocket_frame_parser.h",
 411       "websockets/websocket_handshake_constants.cc",
 412       "websockets/websocket_handshake_constants.h",
 413       "websockets/websocket_handshake_handler.cc",
 414       "websockets/websocket_handshake_handler.h",
 415       "websockets/websocket_handshake_request_info.cc",
 416       "websockets/websocket_handshake_request_info.h",
 417       "websockets/websocket_handshake_response_info.cc",
 418       "websockets/websocket_handshake_response_info.h",
 419       "websockets/websocket_handshake_stream_base.h",
 420       "websockets/websocket_handshake_stream_create_helper.cc",
 421       "websockets/websocket_handshake_stream_create_helper.h",
 422       "websockets/websocket_inflater.cc",
 423       "websockets/websocket_inflater.h",
 424       "websockets/websocket_job.cc",
 425       "websockets/websocket_job.h",
 426       "websockets/websocket_mux.h",
 427       "websockets/websocket_net_log_params.cc",
 428       "websockets/websocket_net_log_params.h",
 429       "websockets/websocket_stream.cc",
 430       "websockets/websocket_stream.h",
 431       "websockets/websocket_throttle.cc",
 432       "websockets/websocket_throttle.h",
 433     ]
 434   }
 435
 436   if (!enable_mdns) {
 437     sources -= [
 438       "dns/mdns_cache.cc",
 439       "dns/mdns_cache.h",
 440       "dns/mdns_client.cc",
 441       "dns/mdns_client.h",
 442       "dns/mdns_client_impl.cc",
 443       "dns/mdns_client_impl.h",
 444       "dns/record_parsed.cc",
 445       "dns/record_parsed.h",
 446       "dns/record_rdata.cc",
 447       "dns/record_rdata.h",
 448     ]
 449   }
 450
 451   if (is_win) {
 452     sources -= [
 453       "http/http_auth_handler_ntlm_portable.cc",
 454       "socket/socket_libevent.cc",
 455       "socket/socket_libevent.h",
 456       "socket/tcp_socket_libevent.cc",
 457       "socket/tcp_socket_libevent.h",
 458       "udp/udp_socket_libevent.cc",
 459       "udp/udp_socket_libevent.h",
 460     ]
 461     deps += [
 462       "//third_party/nss:nspr",
 463       "//third_party/nss",
 464     ]
 465   } else {  # !is_win
 466     sources -= [
 467       "base/winsock_init.cc",
 468       "base/winsock_init.h",
 469       "base/winsock_util.cc",
 470       "base/winsock_util.h",
 471       "proxy/proxy_resolver_winhttp.cc",
 472       "proxy/proxy_resolver_winhttp.h",
 473     ]
 474   }
 475
 476   if (is_mac) {
 477     deps += [
 478       "//third_party/nss:nspr",
 479       "//third_party/nss",
 480     ]
 481     libs = [
 482       "Foundation.framework",
 483       "Security.framework",
 484       "SystemConfiguration.framework",
 485       "resolv",
 486     ]
 487   }
 488
 489   if (is_ios) {
 490     # Add back some sources that were otherwise filtered out. iOS additionally
 491     # doesn't set USE_NSS but needs some of the files.
 492     set_sources_assignment_filter([])
 493     sources += [
 494       "base/network_change_notifier_mac.cc",
 495       "base/network_config_watcher_mac.cc",
 496       "base/platform_mime_util_mac.mm",
 497       "cert/cert_verify_proc_nss.cc",
 498       "cert/cert_verify_proc_nss.h",
 499       "cert/test_root_certs_nss.cc",
 500       "cert/x509_util_nss.cc",
 501       "cert/x509_util_nss.h",
 502       "proxy/proxy_resolver_mac.cc",
 503       "proxy/proxy_server_mac.cc",
 504       "ocsp/nss_ocsp.cc",
 505       "ocsp/nss_ocsp.h",
 506     ]
 507     set_sources_assignment_filter(sources_assignment_filter)
 508
 509     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 510     deps += [
 511       "//third_party/nss",
 512     ]
 513     libs = [
 514       "CFNetwork.framework",
 515       "MobileCoreServices.framework",
 516       "Security.framework",
 517       "SystemConfiguration.framework",
 518       "resolv",
 519     ]
 520   }
 521
 522   if (is_android) {
 523     # Add some Linux sources that were excluded by the filter, but which
 524     # are needed.
 525     set_sources_assignment_filter([])
 526     sources += [
 527       "base/platform_mime_util_linux.cc",
 528       "base/address_tracker_linux.cc",
 529       "base/address_tracker_linux.h",
 530     ]
 531     set_sources_assignment_filter(sources_assignment_filter)
 532
 533     if (!is_android_webview_build) {
 534       deps += [ ":net_jni_headers" ]
 535     }
 536   }
 537
 538   if (use_icu_alternatives_on_android) {
 539     deps -= [
 540       "//base:i18n",
 541       "//third_party/icu",
 542     ]
 543     sources -= [
 544       "base/filename_util_icu.cc",
 545       "base/net_string_util_icu.cc",
 546       "base/net_util_icu.cc",
 547     ]
 548     sources += [
 549       "base/net_string_util_icu_alternatives_android.cc",
 550       "base/net_string_util_icu_alternatives_android.h",
 551     ]
 552   }
 553 }
 554
 555 grit("net_resources") {
 556   source = "base/net_resources.grd"
 557   use_qualified_include = true
 558   outputs = [
 559     "grit/net_resources.h",
 560     "net_resources.pak",
 561     "net_resources.rc",
 562   ]
 563 }
 564
 565 static_library("extras") {
 566   sources = gypi_values.net_extras_sources
 567   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 568   deps = [
 569     ":net",
 570     "//sql:sql",
 571   ]
 572 }
 573
 574 static_library("http_server") {
 575   sources = [
 576     "server/http_connection.cc",
 577     "server/http_connection.h",
 578     "server/http_server.cc",
 579     "server/http_server.h",
 580     "server/http_server_request_info.cc",
 581     "server/http_server_request_info.h",
 582     "server/http_server_response_info.cc",
 583     "server/http_server_response_info.h",
 584     "server/web_socket.cc",
 585     "server/web_socket.h",
 586   ]
 587   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 588   deps = [
 589     ":net",
 590     "//base",
 591   ]
 592 }
 593
 594 executable("dump_cache") {
 595   testonly = true
 596   sources = [
 597     "tools/dump_cache/cache_dumper.cc",
 598     "tools/dump_cache/cache_dumper.h",
 599     "tools/dump_cache/dump_cache.cc",
 600     "tools/dump_cache/dump_files.cc",
 601     "tools/dump_cache/dump_files.h",
 602     "tools/dump_cache/simple_cache_dumper.cc",
 603     "tools/dump_cache/simple_cache_dumper.h",
 604     "tools/dump_cache/url_to_filename_encoder.cc",
 605     "tools/dump_cache/url_to_filename_encoder.h",
 606     "tools/dump_cache/url_utilities.h",
 607     "tools/dump_cache/url_utilities.cc",
 608   ]
 609
 610   configs += [ ":net_win_size_truncation" ]
 611
 612   deps = [
 613     "//base",
 614     ":net",
 615     ":test_support",
 616   ]
 617 }
 618
 619 source_set("test_support") {
 620   testonly = true
 621   sources = [
 622     "base/capturing_net_log.cc",
 623     "base/capturing_net_log.h",
 624     "base/load_timing_info_test_util.cc",
 625     "base/load_timing_info_test_util.h",
 626     "base/mock_file_stream.cc",
 627     "base/mock_file_stream.h",
 628     "base/test_completion_callback.cc",
 629     "base/test_completion_callback.h",
 630     "base/test_data_directory.cc",
 631     "base/test_data_directory.h",
 632     "cert/mock_cert_verifier.cc",
 633     "cert/mock_cert_verifier.h",
 634     "cookies/cookie_monster_store_test.cc",
 635     "cookies/cookie_monster_store_test.h",
 636     "cookies/cookie_store_test_callbacks.cc",
 637     "cookies/cookie_store_test_callbacks.h",
 638     "cookies/cookie_store_test_helpers.cc",
 639     "cookies/cookie_store_test_helpers.h",
 640     "disk_cache/disk_cache_test_base.cc",
 641     "disk_cache/disk_cache_test_base.h",
 642     "disk_cache/disk_cache_test_util.cc",
 643     "disk_cache/disk_cache_test_util.h",
 644     "dns/dns_test_util.cc",
 645     "dns/dns_test_util.h",
 646     "dns/mock_host_resolver.cc",
 647     "dns/mock_host_resolver.h",
 648     "dns/mock_mdns_socket_factory.cc",
 649     "dns/mock_mdns_socket_factory.h",
 650     "http/http_transaction_test_util.cc",
 651     "http/http_transaction_test_util.h",
 652     "proxy/mock_proxy_resolver.cc",
 653     "proxy/mock_proxy_resolver.h",
 654     "proxy/mock_proxy_script_fetcher.cc",
 655     "proxy/mock_proxy_script_fetcher.h",
 656     "proxy/proxy_config_service_common_unittest.cc",
 657     "proxy/proxy_config_service_common_unittest.h",
 658     "socket/socket_test_util.cc",
 659     "socket/socket_test_util.h",
 660     "test/cert_test_util.cc",
 661     "test/cert_test_util.h",
 662     "test/cert_test_util_nss.cc",
 663     "test/ct_test_util.cc",
 664     "test/ct_test_util.h",
 665     "test/embedded_test_server/embedded_test_server.cc",
 666     "test/embedded_test_server/embedded_test_server.h",
 667     "test/embedded_test_server/http_connection.cc",
 668     "test/embedded_test_server/http_connection.h",
 669     "test/embedded_test_server/http_request.cc",
 670     "test/embedded_test_server/http_request.h",
 671     "test/embedded_test_server/http_response.cc",
 672     "test/embedded_test_server/http_response.h",
 673     "test/net_test_suite.cc",
 674     "test/net_test_suite.h",
 675     "test/python_utils.cc",
 676     "test/python_utils.h",
 677     "test/spawned_test_server/base_test_server.cc",
 678     "test/spawned_test_server/base_test_server.h",
 679     "test/spawned_test_server/local_test_server_posix.cc",
 680     "test/spawned_test_server/local_test_server_win.cc",
 681     "test/spawned_test_server/local_test_server.cc",
 682     "test/spawned_test_server/local_test_server.h",
 683     "test/spawned_test_server/remote_test_server.cc",
 684     "test/spawned_test_server/remote_test_server.h",
 685     "test/spawned_test_server/spawned_test_server.h",
 686     "test/spawned_test_server/spawner_communicator.cc",
 687     "test/spawned_test_server/spawner_communicator.h",
 688     "url_request/test_url_fetcher_factory.cc",
 689     "url_request/test_url_fetcher_factory.h",
 690     "url_request/test_url_request_interceptor.cc",
 691     "url_request/test_url_request_interceptor.h",
 692     "url_request/url_request_test_util.cc",
 693     "url_request/url_request_test_util.h",
 694   ]
 695
 696   configs += [ ":net_win_size_truncation" ]
 697
 698   public_deps = [
 699     "//base",
 700     "//base/test:test_support",
 701     "//crypto",
 702     "//net",
 703     "//net/tools/tld_cleanup",
 704     "//testing/gmock",
 705     "//testing/gtest",
 706     "//url",
 707   ]
 708
 709   if (is_ios) {
 710     public_deps += [ "//third_party/nss" ]
 711   }
 712
 713   if (!is_android) {
 714     sources -= [
 715       "test/spawned_test_server/remote_test_server.cc",
 716       "test/spawned_test_server/remote_test_server.h",
 717       "test/spawned_test_server/spawner_communicator.cc",
 718       "test/spawned_test_server/spawner_communicator.h",
 719     ]
 720   }
 721
 722   if (use_v8_in_net) {
 723     public_deps += [ ":net_with_v8" ]
 724   }
 725
 726   if (!enable_mdns) {
 727     sources -= [
 728       "dns/mock_mdns_socket_factory.cc",
 729       "dns/mock_mdns_socket_factory.h",
 730     ]
 731   }
 732
 733   if (use_nss_certs) {
 734     public_deps += ["//crypto:platform" ]
 735   } else {
 736     sources -= [
 737       "test/cert_test_util_nss.cc",
 738     ]
 739   }
 740 }
 741
 742 source_set("balsa") {
 743   sources = [
 744     "tools/balsa/balsa_enums.h",
 745     "tools/balsa/balsa_frame.cc",
 746     "tools/balsa/balsa_frame.h",
 747     "tools/balsa/balsa_headers.cc",
 748     "tools/balsa/balsa_headers.h",
 749     "tools/balsa/balsa_headers_token_utils.cc",
 750     "tools/balsa/balsa_headers_token_utils.h",
 751     "tools/balsa/balsa_visitor_interface.h",
 752     "tools/balsa/http_message_constants.cc",
 753     "tools/balsa/http_message_constants.h",
 754     "tools/balsa/noop_balsa_visitor.h",
 755     "tools/balsa/simple_buffer.cc",
 756     "tools/balsa/simple_buffer.h",
 757     "tools/balsa/split.cc",
 758     "tools/balsa/split.h",
 759     "tools/balsa/string_piece_utils.h",
 760     "tools/quic/spdy_utils.cc",
 761     "tools/quic/spdy_utils.h",
 762   ]
 763   deps = [
 764     ":net",
 765     "//base",
 766     "//url",
 767   ]
 768 }
 769
 770 if (use_v8_in_net) {
 771   component("net_with_v8") {
 772     sources = [
 773       "proxy/proxy_resolver_v8.cc",
 774       "proxy/proxy_resolver_v8.h",
 775       "proxy/proxy_resolver_v8_tracing.cc",
 776       "proxy/proxy_resolver_v8_tracing.h",
 777       "proxy/proxy_service_v8.cc",
 778       "proxy/proxy_service_v8.h",
 779     ]
 780
 781     defines = [ "NET_IMPLEMENTATION" ]
 782     configs += [
 783       ":net_win_size_truncation",
 784       "//build/config/compiler:wexit_time_destructors",
 785     ]
 786
 787     public_deps = [
 788       ":net",
 789     ]
 790     deps = [
 791       "//base",
 792       "//gin",
 793       "//url",
 794       "//v8",
 795     ]
 796   }
 797 }
 798
 799 if (!is_ios && !is_android) {
 800   executable("crash_cache") {
 801     testonly = true
 802     sources = [ "tools/crash_cache/crash_cache.cc" ]
 803     configs += [ ":net_win_size_truncation" ]
 804     deps = [
 805       ":net",
 806       ":test_support",
 807       "//base",
 808     ]
 809   }
 810
 811   executable("crl_set_dump") {
 812     testonly = true
 813     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 814     configs += [ ":net_win_size_truncation" ]
 815     deps = [
 816       ":net",
 817       "//base",
 818     ]
 819   }
 820
 821   executable("dns_fuzz_stub") {
 822     testonly = true
 823     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 824     configs += [ ":net_win_size_truncation" ]
 825     deps = [
 826       ":net",
 827       "//base",
 828     ]
 829   }
 830
 831   executable("gdig") {
 832     testonly = true
 833     sources = [
 834       "tools/gdig/file_net_log.cc",
 835       "tools/gdig/gdig.cc",
 836     ]
 837     deps = [
 838       ":net",
 839       "//base",
 840     ]
 841   }
 842
 843   executable("get_server_time") {
 844     testonly = true
 845     sources = [ "tools/get_server_time/get_server_time.cc" ]
 846     configs += [ ":net_win_size_truncation" ]
 847     deps = [
 848       ":net",
 849       "//base",
 850       "//base:i18n",
 851       "//url",
 852     ]
 853   }
 854
 855   if (use_v8_in_net) {
 856     executable("net_watcher") {
 857       testonly = true
 858       sources = [ "tools/net_watcher/net_watcher.cc" ]
 859       deps = [
 860         ":net",
 861         ":net_with_v8",
 862         "//base",
 863       ]
 864
 865       if (is_linux) {
 866         configs += [
 867           "//build/config/linux:gconf",
 868           "//build/config/linux:glib",
 869         ]
 870         deps += [ "//build/config/linux:gio" ]
 871       }
 872     }
 873   }
 874
 875   executable("run_testserver") {
 876     testonly = true
 877     sources = [ "tools/testserver/run_testserver.cc" ]
 878     deps = [
 879       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 880                # in the GYP build, and can be removed when the bug is fixed.
 881       ":test_support",
 882       "//base",
 883       "//base/test:test_support",
 884       "//testing/gtest",
 885     ]
 886   }
 887
 888   executable("stress_cache") {
 889     testonly = true
 890     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 891     configs += [ ":net_win_size_truncation" ]
 892     deps = [
 893       ":net",
 894       ":test_support",
 895       "//base",
 896     ]
 897   }
 898
 899   executable("tld_cleanup") {
 900     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 901     configs += [ ":net_win_size_truncation" ]
 902     deps = [
 903       "//base",
 904       "//base:i18n",
 905       "//net/tools/tld_cleanup",
 906     ]
 907   }
 908 }
 909
 910 if (is_linux) {
 911   static_library("epoll_server") {
 912     sources = [
 913       "tools/epoll_server/epoll_server.cc",
 914       "tools/epoll_server/epoll_server.h",
 915     ]
 916     deps = [
 917       ":net",
 918       "//base",
 919     ]
 920   }
 921
 922   static_library("flip_in_mem_edsm_server_base") {
 923     testonly = true
 924     sources = [
 925       "tools/dump_cache/url_to_filename_encoder.cc",
 926       "tools/dump_cache/url_to_filename_encoder.h",
 927       "tools/dump_cache/url_utilities.h",
 928       "tools/dump_cache/url_utilities.cc",
 929       "tools/flip_server/acceptor_thread.h",
 930       "tools/flip_server/acceptor_thread.cc",
 931       "tools/flip_server/create_listener.cc",
 932       "tools/flip_server/create_listener.h",
 933       "tools/flip_server/constants.h",
 934       "tools/flip_server/flip_config.cc",
 935       "tools/flip_server/flip_config.h",
 936       "tools/flip_server/http_interface.cc",
 937       "tools/flip_server/http_interface.h",
 938       "tools/flip_server/loadtime_measurement.h",
 939       "tools/flip_server/mem_cache.h",
 940       "tools/flip_server/mem_cache.cc",
 941       "tools/flip_server/output_ordering.cc",
 942       "tools/flip_server/output_ordering.h",
 943       "tools/flip_server/ring_buffer.cc",
 944       "tools/flip_server/ring_buffer.h",
 945       "tools/flip_server/sm_connection.cc",
 946       "tools/flip_server/sm_connection.h",
 947       "tools/flip_server/sm_interface.h",
 948       "tools/flip_server/spdy_ssl.cc",
 949       "tools/flip_server/spdy_ssl.h",
 950       "tools/flip_server/spdy_interface.cc",
 951       "tools/flip_server/spdy_interface.h",
 952       "tools/flip_server/spdy_util.cc",
 953       "tools/flip_server/spdy_util.h",
 954       "tools/flip_server/streamer_interface.cc",
 955       "tools/flip_server/streamer_interface.h",
 956     ]
 957     deps = [
 958       ":balsa",
 959       ":epoll_server",
 960       ":net",
 961       "//base",
 962       "//third_party/boringssl",
 963     ]
 964   }
 965
 966   executable("flip_in_mem_edsm_server_unittests") {
 967     testonly = true
 968     sources = [
 969       "tools/flip_server/flip_test_utils.cc",
 970       "tools/flip_server/flip_test_utils.h",
 971       "tools/flip_server/http_interface_test.cc",
 972       "tools/flip_server/mem_cache_test.cc",
 973       "tools/flip_server/run_all_tests.cc",
 974       "tools/flip_server/spdy_interface_test.cc",
 975     ]
 976     deps = [
 977       ":flip_in_mem_edsm_server_base",
 978       ":net",
 979       ":test_support",
 980       "//testing/gtest",
 981       "//testing/gmock",
 982       "//third_party/boringssl",
 983     ]
 984   }
 985
 986   executable("flip_in_mem_edsm_server") {
 987     testonly = true
 988     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 989     deps = [
 990       ":flip_in_mem_edsm_server_base",
 991       ":net",
 992       "//base",
 993     ]
 994   }
 995
 996   source_set("quic_base") {
 997     sources = [
 998       "tools/quic/quic_client.cc",
 999       "tools/quic/quic_client.h",
1000       "tools/quic/quic_client_session.cc",
1001       "tools/quic/quic_client_session.h",
1002       "tools/quic/quic_default_packet_writer.cc",
1003       "tools/quic/quic_default_packet_writer.h",
1004       "tools/quic/quic_dispatcher.h",
1005       "tools/quic/quic_dispatcher.cc",
1006       "tools/quic/quic_epoll_clock.cc",
1007       "tools/quic/quic_epoll_clock.h",
1008       "tools/quic/quic_epoll_connection_helper.cc",
1009       "tools/quic/quic_epoll_connection_helper.h",
1010       "tools/quic/quic_in_memory_cache.cc",
1011       "tools/quic/quic_in_memory_cache.h",
1012       "tools/quic/quic_packet_writer_wrapper.cc",
1013       "tools/quic/quic_packet_writer_wrapper.h",
1014       "tools/quic/quic_per_connection_packet_writer.cc",
1015       "tools/quic/quic_per_connection_packet_writer.h",
1016       "tools/quic/quic_server.cc",
1017       "tools/quic/quic_server.h",
1018       "tools/quic/quic_server_session.cc",
1019       "tools/quic/quic_server_session.h",
1020       "tools/quic/quic_socket_utils.cc",
1021       "tools/quic/quic_socket_utils.h",
1022       "tools/quic/quic_spdy_client_stream.cc",
1023       "tools/quic/quic_spdy_client_stream.h",
1024       "tools/quic/quic_spdy_server_stream.cc",
1025       "tools/quic/quic_spdy_server_stream.h",
1026       "tools/quic/quic_time_wait_list_manager.h",
1027       "tools/quic/quic_time_wait_list_manager.cc",
1028     ]
1029     deps = [
1030       ":balsa",
1031       ":epoll_server",
1032       ":net",
1033       "//base",
1034       "//base/third_party/dynamic_annotations",
1035       "//crypto",
1036       "//third_party/boringssl",
1037       "//url",
1038     ]
1039   }
1040
1041   executable("quic_client") {
1042     sources = [ "tools/quic/quic_client_bin.cc" ]
1043     deps = [
1044       ":quic_base",
1045       ":net",
1046       "//base",
1047       "//third_party/boringssl",
1048     ]
1049   }
1050 }
1051
1052 if (is_android) {
1053   generate_jni("net_jni_headers") {
1054     sources = [
1055       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1056       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1057       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1058       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1059       "android/java/src/org/chromium/net/GURLUtils.java",
1060       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1061       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1062       "android/java/src/org/chromium/net/X509Util.java",
1063     ]
1064     jni_package = "net"
1065   }
1066   generate_jni("net_test_jni_headers") {
1067     sources = [
1068       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1069     ]
1070     jni_package = "net"
1071   }
1072 }
1073
1074 if (is_android || is_linux) {
1075   executable("disk_cache_memory_test") {
1076     testonly = true
1077     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1078     deps = [
1079       ":net",
1080       "//base",
1081     ]
1082   }
1083 }
1084
1085 # TODO(GYP) make this compile on Android, we need some native test deps done.
1086 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1087 if (!is_android && !is_win) {
1088
1089 source_set("quic_tools") {
1090   sources = [
1091     "quic/quic_dispatcher.cc",
1092     "quic/quic_dispatcher.h",
1093     "quic/quic_in_memory_cache.cc",
1094     "quic/quic_in_memory_cache.h",
1095     "quic/quic_per_connection_packet_writer.cc",
1096     "quic/quic_per_connection_packet_writer.h",
1097     "quic/quic_server.cc",
1098     "quic/quic_server.h",
1099     "quic/quic_server_packet_writer.cc",
1100     "quic/quic_server_packet_writer.h",
1101     "quic/quic_server_session.cc",
1102     "quic/quic_server_session.h",
1103     "quic/quic_spdy_server_stream.cc",
1104     "quic/quic_spdy_server_stream.h",
1105     "quic/quic_time_wait_list_manager.cc",
1106     "quic/quic_time_wait_list_manager.h",
1107   ]
1108   deps = [
1109     ":net",
1110     "//base",
1111     "//base/third_party/dynamic_annotations",
1112     "//url",
1113   ]
1114 }
1115
1116 test("net_unittests") {
1117   sources = gypi_values.net_test_sources
1118
1119   configs += [ ":net_win_size_truncation" ]
1120   defines = []
1121
1122   deps = [
1123     ":extras",
1124     ":http_server",
1125     ":net",
1126     ":quic_tools",
1127     ":test_support",
1128     "//base",
1129     "//base:i18n",
1130     "//base:prefs_test_support",
1131     "//base/allocator",
1132     "//base/third_party/dynamic_annotations",
1133     "//crypto",
1134     "//crypto:platform",
1135     "//crypto:test_support",
1136     "//net/base/registry_controlled_domains",
1137     "//testing/gmock",
1138     "//testing/gtest",
1139     "//third_party/zlib",
1140     "//url",
1141   ]
1142
1143   if (is_linux) {
1144     sources += gypi_values.net_linux_test_sources
1145     deps += [
1146       ":balsa",
1147       ":epoll_server",
1148       ":flip_in_mem_edsm_server_base",
1149       ":quic_base",
1150     ]
1151   }
1152
1153   if (is_chromeos) {
1154     sources -= [
1155       "proxy/proxy_config_service_linux_unittest.cc",
1156     ]
1157   }
1158
1159   if (is_android) {
1160     sources -= [
1161       # See bug http://crbug.com/344533.
1162       "disk_cache/blockfile/index_table_v3_unittest.cc",
1163       # No res_ninit() et al on Android, so this doesn't make a lot of
1164       # sense.
1165       "dns/dns_config_service_posix_unittest.cc",
1166     ]
1167     deps += [
1168       ":net_javatests",  # FIXME(brettw)
1169       ":net_test_jni_headers",
1170     ]
1171   }
1172
1173   if (!use_nss_certs) {
1174     sources -= [
1175       "ssl/client_cert_store_nss_unittest.cc",
1176     ]
1177     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1178       sources -= [
1179         "ssl/client_cert_store_chromeos_unittest.cc",
1180       ]
1181     }
1182   }
1183
1184   if (use_openssl) {
1185     # When building for OpenSSL, we need to exclude NSS specific tests
1186     # or functionality not supported by OpenSSL yet.
1187     # TODO(bulach): Add equivalent tests when the underlying
1188     #               functionality is ported to OpenSSL.
1189     sources -= [
1190       "cert/nss_cert_database_unittest.cc",
1191       "cert/x509_util_nss_unittest.cc",
1192       "quic/test_tools/crypto_test_utils_nss.cc",
1193     ]
1194     if (is_chromeos) {
1195       # These were already removed in the non-ChromeOS case.
1196       sources -= [
1197         "cert/nss_cert_database_chromeos_unittest.cc",
1198         "cert/nss_profile_filter_chromeos_unittest.cc",
1199       ]
1200     }
1201   } else {
1202     sources -= [
1203       "cert/x509_util_openssl_unittest.cc",
1204       "quic/test_tools/crypto_test_utils_openssl.cc",
1205       "socket/ssl_client_socket_openssl_unittest.cc",
1206       "socket/ssl_session_cache_openssl_unittest.cc",
1207     ]
1208     if (!is_desktop_linux && !is_chromeos) {
1209       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1210     }
1211   }
1212
1213   if (use_kerberos) {
1214     defines += [ "USE_KERBEROS" ]
1215   } else {
1216     sources -= [
1217       "http/http_auth_gssapi_posix_unittest.cc",
1218       "http/http_auth_handler_negotiate_unittest.cc",
1219       "http/mock_gssapi_library_posix.cc",
1220       "http/mock_gssapi_library_posix.h",
1221     ]
1222   }
1223
1224   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1225     # Only include this test when on Posix and using NSS for
1226     # cert verification or on iOS (which also uses NSS for certs).
1227     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1228   }
1229
1230   if (!use_openssl_certs) {
1231     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1232   }
1233
1234   if (!enable_websockets) {
1235     sources -= [
1236       "socket_stream/socket_stream_metrics_unittest.cc",
1237       "socket_stream/socket_stream_unittest.cc",
1238       "spdy/spdy_websocket_stream_unittest.cc",
1239       "websockets/websocket_basic_stream_test.cc",
1240       "websockets/websocket_channel_test.cc",
1241       "websockets/websocket_deflate_predictor_impl_test.cc",
1242       "websockets/websocket_deflate_stream_test.cc",
1243       "websockets/websocket_deflater_test.cc",
1244       "websockets/websocket_errors_test.cc",
1245       "websockets/websocket_extension_parser_test.cc",
1246       "websockets/websocket_frame_parser_test.cc",
1247       "websockets/websocket_frame_test.cc",
1248       "websockets/websocket_handshake_handler_spdy_test.cc",
1249       "websockets/websocket_handshake_handler_test.cc",
1250       "websockets/websocket_handshake_stream_create_helper_test.cc",
1251       "websockets/websocket_inflater_test.cc",
1252       "websockets/websocket_job_test.cc",
1253       "websockets/websocket_net_log_params_test.cc",
1254       "websockets/websocket_stream_test.cc",
1255       "websockets/websocket_test_util.cc",
1256       "websockets/websocket_test_util.h",
1257       "websockets/websocket_throttle_test.cc",
1258     ]
1259   }
1260
1261   if (disable_file_support) {
1262     sources -= [
1263       "base/directory_lister_unittest.cc",
1264       "url_request/url_request_file_job_unittest.cc",
1265     ]
1266   }
1267
1268   if (disable_ftp_support) {
1269     sources -= [
1270       "ftp/ftp_auth_cache_unittest.cc",
1271       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1272       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1273       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1274       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1275       "ftp/ftp_directory_listing_parser_unittest.cc",
1276       "ftp/ftp_directory_listing_parser_unittest.h",
1277       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1278       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1279       "ftp/ftp_network_transaction_unittest.cc",
1280       "ftp/ftp_util_unittest.cc",
1281       "url_request/url_request_ftp_job_unittest.cc",
1282     ]
1283   }
1284
1285   if (!enable_built_in_dns) {
1286     sources -= [
1287       "dns/address_sorter_posix_unittest.cc",
1288       "dns/address_sorter_unittest.cc",
1289     ]
1290   }
1291
1292   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1293   # net_unittest's dependency on v8 when using icu alternatives instead of
1294   # setting use_v8_in_net to 0.
1295   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1296     deps += [ ":net_with_v8" ]
1297   } else {
1298     sources -= [
1299       "proxy/proxy_resolver_v8_unittest.cc",
1300       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1301     ]
1302   }
1303
1304   if (!enable_mdns) {
1305     sources -= [
1306       "dns/mdns_cache_unittest.cc",
1307       "dns/mdns_client_unittest.cc",
1308       "dns/record_parsed_unittest.cc",
1309       "dns/record_rdata_unittest.cc",
1310     ]
1311   }
1312
1313   if (is_ios) {
1314     # TODO(GYP)
1315     #  'actions': [
1316     #    {
1317     #      'action_name': 'copy_test_data',
1318     #      'variables': {
1319     #        'test_data_files': [
1320     #          'data/ssl/certificates/',
1321     #          'data/test.html',
1322     #          'data/url_request_unittest/',
1323     #        ],
1324     #        'test_data_prefix': 'net',
1325     #      },
1326     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1327     #    },
1328     #  ],
1329     sources -= [
1330       # TODO(droger): The following tests are disabled because the
1331       # implementation is missing or incomplete.
1332       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1333       "base/keygen_handler_unittest.cc",
1334       "disk_cache/backend_unittest.cc",
1335       "disk_cache/blockfile/block_files_unittest.cc",
1336       # Need to read input data files.
1337       "filter/gzip_filter_unittest.cc",
1338       "socket/ssl_server_socket_unittest.cc",
1339       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1340       # Need TestServer.
1341       "proxy/proxy_script_fetcher_impl_unittest.cc",
1342       "socket/ssl_client_socket_unittest.cc",
1343       "url_request/url_fetcher_impl_unittest.cc",
1344       "url_request/url_request_context_builder_unittest.cc",
1345       # Needs GetAppOutput().
1346       "test/python_utils_unittest.cc",
1347
1348       # The following tests are disabled because they don't apply to
1349       # iOS.
1350       # OS is not "linux" or "freebsd" or "openbsd".
1351       "socket/unix_domain_client_socket_posix_unittest.cc",
1352       "socket/unix_domain_listen_socket_posix_unittest.cc",
1353       "socket/unix_domain_server_socket_posix_unittest.cc",
1354
1355       # See bug http://crbug.com/344533.
1356       "disk_cache/blockfile/index_table_v3_unittest.cc",
1357     ]
1358   }
1359
1360   if (is_android) {
1361     sources -= [
1362       "dns/dns_config_service_posix_unittest.cc",
1363     ]
1364     # TODO(GYP)
1365     # # TODO(mmenke):  This depends on test_support_base, which depends on
1366     # #                icu.  Figure out a way to remove that dependency.
1367     # 'dependencies': [
1368     #   '../testing/android/native_test.gyp:native_test_native_code',
1369     # ]
1370
1371     set_sources_assignment_filter([])
1372     sources += [ "base/address_tracker_linux_unittest.cc" ]
1373     set_sources_assignment_filter(sources_assignment_filter)
1374   }
1375
1376   if (use_icu_alternatives_on_android) {
1377     sources -= [
1378       "base/filename_util_unittest.cc",
1379       "base/net_util_icu_unittest.cc",
1380     ]
1381     deps -= [ "//base:i18n" ]
1382   }
1383 }
1384
1385 executable("quic_server") {
1386   sources = [ "quic/quic_server_bin.cc" ]
1387   deps = [
1388     ":quic_tools",
1389     ":net",
1390     "//base",
1391     "//third_party/boringssl",
1392   ]
1393 }
1394
1395 }  # !is_android