ios/web/web_state/ui/crw_generic_content_view.mm

   1 // Copyright 2015 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "ios/web/public/web_state/ui/crw_generic_content_view.h"
   6
   7 #include "base/logging.h"
   8 #include "base/mac/scoped_nsobject.h"
   9
  10 @interface CRWGenericContentView () {
  11   // Backing objectect for |self.scrollView|.
  12   base::scoped_nsobject<UIScrollView> _scrollView;
  13   // Backing object for |self.view|.
  14   base::scoped_nsobject<UIView> _view;
  15 }
  16
  17 @end
  18
  19 @implementation CRWGenericContentView
  20
  21 - (instancetype)initWithView:(UIView*)view {
  22   self = [super initWithFrame:CGRectZero];
  23   if (self) {
  24     DCHECK(view);
  25     _view.reset([view retain]);
  26     _scrollView.reset([[UIScrollView alloc] initWithFrame:CGRectZero]);
  27     [self addSubview:_scrollView];
  28     [_scrollView addSubview:_view];
  29     [_scrollView setBackgroundColor:[_view backgroundColor]];
  30   }
  31   return self;
  32 }
  33
  34 - (instancetype)initWithCoder:(NSCoder*)decoder {
  35   NOTREACHED();
  36   return nil;
  37 }
  38
  39 - (instancetype)initWithFrame:(CGRect)frame {
  40   NOTREACHED();
  41   return nil;
  42 }
  43
  44 #pragma mark Accessors
  45
  46 - (UIScrollView*)scrollView {
  47   if (!_scrollView) {
  48     _scrollView.reset([[UIScrollView alloc] initWithFrame:CGRectZero]);
  49   }
  50   return _scrollView.get();
  51 }
  52
  53 - (UIView*)view {
  54   return _view.get();
  55 }
  56
  57 #pragma mark Layout
  58
  59 - (void)layoutSubviews {
  60   [super layoutSubviews];
  61
  62   // scrollView layout.
  63   self.scrollView.frame = self.bounds;
  64
  65   // view layout.
  66   CGRect contentRect =
  67       UIEdgeInsetsInsetRect(self.bounds, self.scrollView.contentInset);
  68   CGSize viewSize = [self.view sizeThatFits:contentRect.size];
  69   self.view.frame = CGRectMake(0.0, 0.0, viewSize.width, viewSize.height);
  70
  71   // UIScrollViews only scroll vertically if the content size's height is
  72   // creater than that of its content rect.
  73   if (viewSize.height <= CGRectGetHeight(contentRect)) {
  74     CGFloat singlePixel = 1.0f / [[UIScreen mainScreen] scale];
  75     viewSize.height = CGRectGetHeight(contentRect) + singlePixel;
  76   }
  77   self.scrollView.contentSize = viewSize;
  78 }
  79
  80 - (BOOL)isViewAlive {
  81   return YES;
  82 }
  83
  84 @end