content/child/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//content/child/child.gni")
   9
  10 source_set("child") {
  11   # Only the public target should depend on this. All other targets (even
  12   # internal content ones) should depend on the public one.
  13   visibility = [ "//content/public/child:child_sources" ]
  14
  15   sources = rebase_path(content_child_gypi_values.private_child_sources,
  16                         ".",
  17                         "//content")
  18
  19   public_deps = [
  20     "//third_party/mojo/src/mojo/edk/system",
  21   ]
  22
  23   deps = [
  24     "//base",
  25     "//components/mime_util",
  26     "//components/tracing",
  27     "//components/webcrypto",
  28     "//content/common:mojo_bindings",
  29     "//mojo/application/public/interfaces",
  30     "//mojo/common",
  31     "//mojo/environment:chromium",
  32     "//skia",
  33     "//third_party/icu",
  34     "//ui/base",
  35     "//ui/events/gestures/blink",
  36     "//ui/gfx",
  37     "//ui/gfx/geometry",
  38     "//ui/native_theme",
  39     "//url",
  40   ]
  41
  42   if (!use_default_render_theme) {
  43     sources -= [
  44       "webthemeengine_impl_default.cc",
  45       "webthemeengine_impl_default.h",
  46     ]
  47   }
  48
  49   if (is_android) {
  50     deps += [ "//third_party/android_tools:cpu_features" ]
  51   }
  52
  53   if (enable_plugins) {
  54     deps += [ "//ppapi/proxy" ]
  55   } else {
  56     sources -= [
  57       "browser_font_resource_trusted.cc",
  58       "npapi/plugin_host.cc",
  59       "npapi/plugin_host.h",
  60       "npapi/plugin_instance.cc",
  61       "npapi/plugin_instance.h",
  62       "npapi/plugin_lib.cc",
  63       "npapi/plugin_lib.h",
  64       "npapi/plugin_stream.cc",
  65       "npapi/plugin_stream.h",
  66       "npapi/plugin_stream_posix.cc",
  67       "npapi/plugin_stream_url.cc",
  68       "npapi/plugin_stream_url.h",
  69       "npapi/plugin_string_stream.cc",
  70       "npapi/plugin_string_stream.h",
  71       "npapi/plugin_url_fetcher.cc",
  72       "npapi/plugin_url_fetcher.h",
  73       "npapi/webplugin.h",
  74       "npapi/webplugin_delegate.h",
  75       "npapi/webplugin_delegate_impl.cc",
  76       "npapi/webplugin_delegate_impl.h",
  77       "npapi/webplugin_resource_client.h",
  78     ]
  79
  80     if (is_mac) {
  81       sources -= [
  82         "npapi/plugin_instance_mac.mm",
  83         "npapi/plugin_web_event_converter_mac.h",
  84         "npapi/plugin_web_event_converter_mac.mm",
  85         "npapi/webplugin_accelerated_surface_mac.h",
  86         "npapi/webplugin_delegate_impl_mac.mm",
  87       ]
  88     } else if (is_win) {
  89       sources -= [
  90         "npapi/plugin_stream_win.cc",
  91         "npapi/webplugin_delegate_impl_win.cc",
  92         "npapi/webplugin_ime_win.cc",
  93         "npapi/webplugin_ime_win.h",
  94       ]
  95     } else if (is_android) {
  96       sources -= [ "npapi/webplugin_delegate_impl_android.cc" ]
  97     }
  98     if (use_aura) {
  99       sources -= [ "npapi/webplugin_delegate_impl_aura.cc" ]
 100     }
 101   }
 102
 103   configs += [
 104     "//content:content_implementation",
 105     "//build/config/compiler:no_size_t_to_int_warning",
 106   ]
 107
 108   if (is_ios) {
 109     # iOS only needs a small portion of content; exclude all the
 110     # implementation, and re-include what is used.
 111     sources = []
 112   } else {
 113     deps += [
 114       "//components/scheduler:scheduler",
 115       "//content/app/resources",
 116       "//content/app/strings",
 117       "//crypto:platform",
 118       "//storage/common",
 119       "//third_party/WebKit/public:blink",
 120       "//third_party/WebKit/public:image_resources",
 121       "//third_party/WebKit/public:resources",
 122       "//third_party/npapi",
 123     ]
 124   }
 125
 126   if (use_aura && is_mac) {
 127     # This file is already excluded on non-Mac.
 128     sources -= [ "npapi/webplugin_delegate_impl_mac.mm" ]
 129   }
 130
 131   if (is_win || !use_aura) {
 132     sources -= [ "npapi/webplugin_delegate_impl_aura.cc" ]
 133   }
 134 }