build/android/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/rules.gni")
   6 import("//third_party/ijar/ijar.gni")
   7
   8 sun_tools_jar_path = "$root_gen_dir/sun_tools_jar/tools.jar"
   9
  10 action("find_sun_tools_jar") {
  11   script = "//build/android/gyp/find_sun_tools_jar.py"
  12   depfile = "$target_gen_dir/$target_name.d"
  13   outputs = [
  14     depfile,
  15     sun_tools_jar_path,
  16   ]
  17   args = [
  18     "--depfile",
  19     rebase_path(depfile, root_build_dir),
  20     "--output",
  21     rebase_path(sun_tools_jar_path, root_build_dir),
  22   ]
  23 }
  24
  25 java_prebuilt("sun_tools_java") {
  26   jar_path = sun_tools_jar_path
  27   jar_dep = ":find_sun_tools_jar"
  28 }
  29
  30 generate_interface_jar("android_ijar") {
  31   input_jar = android_sdk_jar
  32   output_jar = "$root_out_dir/lib.java/android.interface.jar"
  33 }
  34
  35 action("cpplib_stripped") {
  36   _strip_bin = "${android_tool_prefix}strip"
  37   _soname = "libc++_shared.so"
  38   _input_so = "${android_libcpp_root}/libs/${android_app_abi}/${_soname}"
  39   _output_so = "${root_shlib_dir}/${_soname}"
  40
  41   script = "//build/gn_run_binary.py"
  42   inputs = [
  43     _strip_bin,
  44   ]
  45   sources = [
  46     _input_so,
  47   ]
  48   outputs = [
  49     _output_so,
  50   ]
  51
  52   _rebased_strip_bin = rebase_path(_strip_bin, root_out_dir)
  53   _rebased_input_so = rebase_path(_input_so, root_out_dir)
  54   _rebased_output_so = rebase_path(_output_so, root_out_dir)
  55   args = [
  56     _rebased_strip_bin,
  57     "--strip-unneeded",
  58     "-o",
  59     _rebased_output_so,
  60     _rebased_input_so,
  61   ]
  62 }