net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   public_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   public_deps = [
  91     "//crypto",
  92     "//crypto:platform"
  93   ]
  94   deps = [
  95    ":net_resources",
  96     "//base",
  97     "//base:i18n",
  98     "//base:prefs",
  99     "//base/third_party/dynamic_annotations",
 100     "//net/base/registry_controlled_domains",
 101     "//sdch",
 102     "//third_party/icu",
 103     "//third_party/zlib",
 104     "//url",
 105   ]
 106
 107   if (use_kerberos) {
 108     defines += [ "USE_KERBEROS" ]
 109     if (is_android) {
 110       include_dirs += [ "/usr/include/kerberosV" ]
 111     }
 112   } else {
 113     sources -= [
 114       "http/http_auth_gssapi_posix.cc",
 115       "http/http_auth_gssapi_posix.h",
 116       "http/http_auth_handler_negotiate.h",
 117       "http/http_auth_handler_negotiate.cc",
 118     ]
 119   }
 120
 121   if (is_posix) {
 122     if (posix_avoid_mmap) {
 123       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 124     } else {
 125       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 126     }
 127   }
 128
 129   if (disable_file_support) {
 130     sources -= [
 131       "base/directory_lister.cc",
 132       "base/directory_lister.h",
 133       "url_request/url_request_file_dir_job.cc",
 134       "url_request/url_request_file_dir_job.h",
 135       "url_request/url_request_file_job.cc",
 136       "url_request/url_request_file_job.h",
 137       "url_request/file_protocol_handler.cc",
 138       "url_request/file_protocol_handler.h",
 139     ]
 140   }
 141
 142   if (disable_ftp_support) {
 143     sources -= [
 144       "ftp/ftp_auth_cache.cc",
 145       "ftp/ftp_auth_cache.h",
 146       "ftp/ftp_ctrl_response_buffer.cc",
 147       "ftp/ftp_ctrl_response_buffer.h",
 148       "ftp/ftp_directory_listing_parser.cc",
 149       "ftp/ftp_directory_listing_parser.h",
 150       "ftp/ftp_directory_listing_parser_ls.cc",
 151       "ftp/ftp_directory_listing_parser_ls.h",
 152       "ftp/ftp_directory_listing_parser_netware.cc",
 153       "ftp/ftp_directory_listing_parser_netware.h",
 154       "ftp/ftp_directory_listing_parser_os2.cc",
 155       "ftp/ftp_directory_listing_parser_os2.h",
 156       "ftp/ftp_directory_listing_parser_vms.cc",
 157       "ftp/ftp_directory_listing_parser_vms.h",
 158       "ftp/ftp_directory_listing_parser_windows.cc",
 159       "ftp/ftp_directory_listing_parser_windows.h",
 160       "ftp/ftp_network_layer.cc",
 161       "ftp/ftp_network_layer.h",
 162       "ftp/ftp_network_session.cc",
 163       "ftp/ftp_network_session.h",
 164       "ftp/ftp_network_transaction.cc",
 165       "ftp/ftp_network_transaction.h",
 166       "ftp/ftp_request_info.h",
 167       "ftp/ftp_response_info.cc",
 168       "ftp/ftp_response_info.h",
 169       "ftp/ftp_server_type_histograms.cc",
 170       "ftp/ftp_server_type_histograms.h",
 171       "ftp/ftp_transaction.h",
 172       "ftp/ftp_transaction_factory.h",
 173       "ftp/ftp_util.cc",
 174       "ftp/ftp_util.h",
 175       "url_request/ftp_protocol_handler.cc",
 176       "url_request/ftp_protocol_handler.h",
 177       "url_request/url_request_ftp_job.cc",
 178       "url_request/url_request_ftp_job.h",
 179     ]
 180   }
 181
 182   if (enable_built_in_dns) {
 183     defines += [ "ENABLE_BUILT_IN_DNS" ]
 184   } else {
 185     sources -= [
 186       "dns/address_sorter_posix.cc",
 187       "dns/address_sorter_posix.h",
 188       "dns/dns_client.cc",
 189     ]
 190   }
 191
 192   if (use_openssl) {
 193     sources -= [
 194       "base/nss_memio.c",
 195       "base/nss_memio.h",
 196       "cert/ct_log_verifier_nss.cc",
 197       "cert/ct_objects_extractor_nss.cc",
 198       "cert/jwk_serializer_nss.cc",
 199       "cert/scoped_nss_types.h",
 200       "cert/test_root_certs_nss.cc",
 201       "cert/x509_util_nss.cc",
 202       "cert/x509_util_nss.h",
 203       "ocsp/nss_ocsp.cc",
 204       "ocsp/nss_ocsp.h",
 205       "quic/crypto/aead_base_decrypter_nss.cc",
 206       "quic/crypto/aead_base_encrypter_nss.cc",
 207       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 208       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 209       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 210       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 211       "quic/crypto/channel_id_nss.cc",
 212       "quic/crypto/p256_key_exchange_nss.cc",
 213       "socket/nss_ssl_util.cc",
 214       "socket/nss_ssl_util.h",
 215       "socket/ssl_client_socket_nss.cc",
 216       "socket/ssl_client_socket_nss.h",
 217       "socket/ssl_server_socket_nss.cc",
 218       "socket/ssl_server_socket_nss.h",
 219     ]
 220     if (is_chromeos) {
 221       sources -= [
 222         "cert/nss_cert_database_chromeos.cc",
 223         "cert/nss_cert_database_chromeos.h",
 224         "cert/nss_profile_filter_chromeos.cc",
 225         "cert/nss_profile_filter_chromeos.h",
 226       ]
 227     }
 228     if (is_linux) {
 229       # These are always removed for non-Linux cases below.
 230       sources -= [
 231         "base/crypto_module_nss.cc",
 232         "base/keygen_handler_nss.cc",
 233         "cert/cert_database_nss.cc",
 234         "cert/nss_cert_database.cc",
 235         "cert/nss_cert_database.h",
 236         "cert/x509_certificate_nss.cc",
 237         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 238         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 239         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 240         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 241         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 242         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 243       ]
 244     }
 245     if (is_ios) {
 246       # Always removed for !ios below.
 247       sources -= [
 248         "cert/cert_verify_proc_nss.cc",
 249         "cert/cert_verify_proc_nss.h",
 250       ]
 251     }
 252   } else {
 253     sources -= [
 254       "base/crypto_module_openssl.cc",
 255       "cert/ct_log_verifier_openssl.cc",
 256       "cert/ct_objects_extractor_openssl.cc",
 257       "cert/jwk_serializer_openssl.cc",
 258       "cert/x509_util_openssl.cc",
 259       "cert/x509_util_openssl.h",
 260       "quic/crypto/aead_base_decrypter_openssl.cc",
 261       "quic/crypto/aead_base_encrypter_openssl.cc",
 262       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 263       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 264       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 265       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 266       "quic/crypto/channel_id_openssl.cc",
 267       "quic/crypto/p256_key_exchange_openssl.cc",
 268       "quic/crypto/scoped_evp_aead_ctx.cc",
 269       "quic/crypto/scoped_evp_aead_ctx.h",
 270       "socket/ssl_client_socket_openssl.cc",
 271       "socket/ssl_client_socket_openssl.h",
 272       "socket/ssl_server_socket_openssl.cc",
 273       "socket/ssl_server_socket_openssl.h",
 274       "socket/ssl_session_cache_openssl.cc",
 275       "socket/ssl_session_cache_openssl.h",
 276       "ssl/openssl_platform_key.h",
 277       "ssl/openssl_ssl_util.cc",
 278       "ssl/openssl_ssl_util.h",
 279     ]
 280     if (is_mac) {
 281       sources -= [
 282         "ssl/openssl_platform_key_mac.cc",
 283       ]
 284     }
 285     if (is_win) {
 286       sources -= [
 287         "ssl/openssl_platform_key_win.cc",
 288       ]
 289     }
 290   }
 291
 292   if (!use_openssl_certs) {
 293     sources -= [
 294       "base/keygen_handler_openssl.cc",
 295       "base/openssl_private_key_store.h",
 296       "base/openssl_private_key_store_memory.cc",
 297       "cert/cert_database_openssl.cc",
 298       "cert/cert_verify_proc_openssl.cc",
 299       "cert/cert_verify_proc_openssl.h",
 300       "cert/test_root_certs_openssl.cc",
 301       "cert/x509_certificate_openssl.cc",
 302       "ssl/openssl_client_key_store.cc",
 303       "ssl/openssl_client_key_store.h",
 304     ]
 305     if (is_android) {
 306       sources -= [
 307         "base/openssl_private_key_store_android.cc",
 308       ]
 309     }
 310   } else if (is_android) {
 311     # Android doesn't use these even when using OpenSSL.
 312     sources -= [
 313       "base/openssl_private_key_store_memory.cc",
 314       "cert/cert_database_openssl.cc",
 315       "cert/cert_verify_proc_openssl.cc",
 316       "cert/test_root_certs_openssl.cc",
 317     ]
 318   }
 319
 320   if (use_glib && !is_chromeos) {
 321     configs += [ "//build/config/linux:gconf" ]
 322     deps += [ "//build/config/linux:gio" ]
 323   }
 324
 325   if (is_linux) {
 326     configs += [ "//build/config/linux:libresolv" ]
 327   } else {
 328     sources -= [
 329       "base/crypto_module_nss.cc",
 330       "base/keygen_handler_nss.cc",
 331       "cert/cert_database_nss.cc",
 332       "cert/nss_cert_database.cc",
 333       "cert/nss_cert_database.h",
 334       "cert/x509_certificate_nss.cc",
 335       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 336       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 337       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 338       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 339       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 340       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 341     ]
 342
 343     if (!is_ios && !use_openssl) {
 344       # These files are part of the partial implementation of NSS on iOS so
 345       # keep them in that case.
 346       sources -= [
 347         "cert/test_root_certs_nss.cc",
 348         "ocsp/nss_ocsp.cc",
 349         "ocsp/nss_ocsp.h",
 350       ]
 351     }
 352   }
 353
 354   if (!use_nss_certs) {
 355     sources -= [
 356       "ssl/client_cert_store_nss.cc",
 357       "ssl/client_cert_store_nss.h",
 358     ]
 359     if (!is_ios) {
 360       # These files are part of the partial implementation of NSS on iOS so
 361       # keep them in that case (even though use_nss_certs is not set).
 362       sources -= [
 363         "cert/cert_verify_proc_nss.cc",
 364         "cert/cert_verify_proc_nss.h",
 365       ]
 366     }
 367     if (is_chromeos) {
 368       # These were already removed on non-ChromeOS.
 369       sources -= [
 370         "ssl/client_cert_store_chromeos.cc",
 371         "ssl/client_cert_store_chromeos.h",
 372       ]
 373     }
 374   }
 375
 376   if (!enable_websockets) {
 377     sources -= [
 378       "socket_stream/socket_stream.cc",
 379       "socket_stream/socket_stream.h",
 380       "socket_stream/socket_stream_job.cc",
 381       "socket_stream/socket_stream_job.h",
 382       "socket_stream/socket_stream_job_manager.cc",
 383       "socket_stream/socket_stream_job_manager.h",
 384       "socket_stream/socket_stream_metrics.cc",
 385       "socket_stream/socket_stream_metrics.h",
 386       "spdy/spdy_websocket_stream.cc",
 387       "spdy/spdy_websocket_stream.h",
 388       "websockets/websocket_basic_handshake_stream.cc",
 389       "websockets/websocket_basic_handshake_stream.h",
 390       "websockets/websocket_basic_stream.cc",
 391       "websockets/websocket_basic_stream.h",
 392       "websockets/websocket_channel.cc",
 393       "websockets/websocket_channel.h",
 394       "websockets/websocket_deflate_predictor.h",
 395       "websockets/websocket_deflate_predictor_impl.cc",
 396       "websockets/websocket_deflate_predictor_impl.h",
 397       "websockets/websocket_deflate_stream.cc",
 398       "websockets/websocket_deflate_stream.h",
 399       "websockets/websocket_deflater.cc",
 400       "websockets/websocket_deflater.h",
 401       "websockets/websocket_errors.cc",
 402       "websockets/websocket_errors.h",
 403       "websockets/websocket_extension.cc",
 404       "websockets/websocket_extension.h",
 405       "websockets/websocket_extension_parser.cc",
 406       "websockets/websocket_extension_parser.h",
 407       "websockets/websocket_frame.cc",
 408       "websockets/websocket_frame.h",
 409       "websockets/websocket_frame_parser.cc",
 410       "websockets/websocket_frame_parser.h",
 411       "websockets/websocket_handshake_constants.cc",
 412       "websockets/websocket_handshake_constants.h",
 413       "websockets/websocket_handshake_handler.cc",
 414       "websockets/websocket_handshake_handler.h",
 415       "websockets/websocket_handshake_request_info.cc",
 416       "websockets/websocket_handshake_request_info.h",
 417       "websockets/websocket_handshake_response_info.cc",
 418       "websockets/websocket_handshake_response_info.h",
 419       "websockets/websocket_handshake_stream_base.h",
 420       "websockets/websocket_handshake_stream_create_helper.cc",
 421       "websockets/websocket_handshake_stream_create_helper.h",
 422       "websockets/websocket_inflater.cc",
 423       "websockets/websocket_inflater.h",
 424       "websockets/websocket_job.cc",
 425       "websockets/websocket_job.h",
 426       "websockets/websocket_mux.h",
 427       "websockets/websocket_net_log_params.cc",
 428       "websockets/websocket_net_log_params.h",
 429       "websockets/websocket_stream.cc",
 430       "websockets/websocket_stream.h",
 431       "websockets/websocket_throttle.cc",
 432       "websockets/websocket_throttle.h",
 433     ]
 434   }
 435
 436   if (!enable_mdns) {
 437     sources -= [
 438       "dns/mdns_cache.cc",
 439       "dns/mdns_cache.h",
 440       "dns/mdns_client.cc",
 441       "dns/mdns_client.h",
 442       "dns/mdns_client_impl.cc",
 443       "dns/mdns_client_impl.h",
 444       "dns/record_parsed.cc",
 445       "dns/record_parsed.h",
 446       "dns/record_rdata.cc",
 447       "dns/record_rdata.h",
 448     ]
 449   }
 450
 451   if (is_win) {
 452     sources -= [
 453       "http/http_auth_handler_ntlm_portable.cc",
 454       "socket/socket_libevent.cc",
 455       "socket/socket_libevent.h",
 456       "socket/tcp_socket_libevent.cc",
 457       "socket/tcp_socket_libevent.h",
 458       "udp/udp_socket_libevent.cc",
 459       "udp/udp_socket_libevent.h",
 460     ]
 461   } else {  # !is_win
 462     sources -= [
 463       "base/winsock_init.cc",
 464       "base/winsock_init.h",
 465       "base/winsock_util.cc",
 466       "base/winsock_util.h",
 467       "proxy/proxy_resolver_winhttp.cc",
 468       "proxy/proxy_resolver_winhttp.h",
 469     ]
 470   }
 471
 472   if (is_mac) {
 473     libs = [
 474       "Foundation.framework",
 475       "Security.framework",
 476       "SystemConfiguration.framework",
 477       "resolv",
 478     ]
 479   }
 480
 481   if (is_ios) {
 482     # Add back some sources that were otherwise filtered out. iOS additionally
 483     # doesn't set USE_NSS but needs some of the files.
 484     set_sources_assignment_filter([])
 485     sources += [
 486       "base/network_change_notifier_mac.cc",
 487       "base/network_config_watcher_mac.cc",
 488       "base/platform_mime_util_mac.mm",
 489       "cert/cert_verify_proc_nss.cc",
 490       "cert/cert_verify_proc_nss.h",
 491       "cert/test_root_certs_nss.cc",
 492       "cert/x509_util_nss.cc",
 493       "cert/x509_util_nss.h",
 494       "proxy/proxy_resolver_mac.cc",
 495       "proxy/proxy_server_mac.cc",
 496       "ocsp/nss_ocsp.cc",
 497       "ocsp/nss_ocsp.h",
 498     ]
 499     set_sources_assignment_filter(sources_assignment_filter)
 500
 501     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 502     libs = [
 503       "CFNetwork.framework",
 504       "MobileCoreServices.framework",
 505       "Security.framework",
 506       "SystemConfiguration.framework",
 507       "resolv",
 508     ]
 509   }
 510
 511   if (is_android) {
 512     # Add some Linux sources that were excluded by the filter, but which
 513     # are needed.
 514     set_sources_assignment_filter([])
 515     sources += [
 516       "base/platform_mime_util_linux.cc",
 517       "base/address_tracker_linux.cc",
 518       "base/address_tracker_linux.h",
 519     ]
 520     set_sources_assignment_filter(sources_assignment_filter)
 521
 522     if (!is_android_webview_build) {
 523       deps += [ ":net_jni_headers" ]
 524     }
 525   }
 526
 527   if (use_icu_alternatives_on_android) {
 528     deps -= [
 529       "//base:i18n",
 530       "//third_party/icu",
 531     ]
 532     sources -= [
 533       "base/filename_util_icu.cc",
 534       "base/net_string_util_icu.cc",
 535       "base/net_util_icu.cc",
 536     ]
 537     sources += [
 538       "base/net_string_util_icu_alternatives_android.cc",
 539       "base/net_string_util_icu_alternatives_android.h",
 540     ]
 541   }
 542 }
 543
 544 grit("net_resources") {
 545   source = "base/net_resources.grd"
 546   use_qualified_include = true
 547   outputs = [
 548     "grit/net_resources.h",
 549     "net_resources.pak",
 550     "net_resources.rc",
 551   ]
 552 }
 553
 554 static_library("extras") {
 555   sources = gypi_values.net_extras_sources
 556   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 557   deps = [
 558     ":net",
 559     "//sql:sql",
 560   ]
 561 }
 562
 563 static_library("http_server") {
 564   sources = [
 565     "server/http_connection.cc",
 566     "server/http_connection.h",
 567     "server/http_server.cc",
 568     "server/http_server.h",
 569     "server/http_server_request_info.cc",
 570     "server/http_server_request_info.h",
 571     "server/http_server_response_info.cc",
 572     "server/http_server_response_info.h",
 573     "server/web_socket.cc",
 574     "server/web_socket.h",
 575   ]
 576   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 577   deps = [
 578     ":net",
 579     "//base",
 580   ]
 581 }
 582
 583 executable("dump_cache") {
 584   testonly = true
 585   sources = [
 586     "tools/dump_cache/cache_dumper.cc",
 587     "tools/dump_cache/cache_dumper.h",
 588     "tools/dump_cache/dump_cache.cc",
 589     "tools/dump_cache/dump_files.cc",
 590     "tools/dump_cache/dump_files.h",
 591     "tools/dump_cache/simple_cache_dumper.cc",
 592     "tools/dump_cache/simple_cache_dumper.h",
 593     "tools/dump_cache/url_to_filename_encoder.cc",
 594     "tools/dump_cache/url_to_filename_encoder.h",
 595     "tools/dump_cache/url_utilities.h",
 596     "tools/dump_cache/url_utilities.cc",
 597   ]
 598
 599   configs += [ ":net_win_size_truncation" ]
 600
 601   deps = [
 602     "//base",
 603     ":net",
 604     ":test_support",
 605   ]
 606 }
 607
 608 source_set("test_support") {
 609   testonly = true
 610   sources = [
 611     "base/capturing_net_log.cc",
 612     "base/capturing_net_log.h",
 613     "base/load_timing_info_test_util.cc",
 614     "base/load_timing_info_test_util.h",
 615     "base/mock_file_stream.cc",
 616     "base/mock_file_stream.h",
 617     "base/test_completion_callback.cc",
 618     "base/test_completion_callback.h",
 619     "base/test_data_directory.cc",
 620     "base/test_data_directory.h",
 621     "cert/mock_cert_verifier.cc",
 622     "cert/mock_cert_verifier.h",
 623     "cookies/cookie_monster_store_test.cc",
 624     "cookies/cookie_monster_store_test.h",
 625     "cookies/cookie_store_test_callbacks.cc",
 626     "cookies/cookie_store_test_callbacks.h",
 627     "cookies/cookie_store_test_helpers.cc",
 628     "cookies/cookie_store_test_helpers.h",
 629     "disk_cache/disk_cache_test_base.cc",
 630     "disk_cache/disk_cache_test_base.h",
 631     "disk_cache/disk_cache_test_util.cc",
 632     "disk_cache/disk_cache_test_util.h",
 633     "dns/dns_test_util.cc",
 634     "dns/dns_test_util.h",
 635     "dns/mock_host_resolver.cc",
 636     "dns/mock_host_resolver.h",
 637     "dns/mock_mdns_socket_factory.cc",
 638     "dns/mock_mdns_socket_factory.h",
 639     "http/http_transaction_test_util.cc",
 640     "http/http_transaction_test_util.h",
 641     "proxy/mock_proxy_resolver.cc",
 642     "proxy/mock_proxy_resolver.h",
 643     "proxy/mock_proxy_script_fetcher.cc",
 644     "proxy/mock_proxy_script_fetcher.h",
 645     "proxy/proxy_config_service_common_unittest.cc",
 646     "proxy/proxy_config_service_common_unittest.h",
 647     "socket/socket_test_util.cc",
 648     "socket/socket_test_util.h",
 649     "test/cert_test_util.cc",
 650     "test/cert_test_util.h",
 651     "test/cert_test_util_nss.cc",
 652     "test/ct_test_util.cc",
 653     "test/ct_test_util.h",
 654     "test/embedded_test_server/embedded_test_server.cc",
 655     "test/embedded_test_server/embedded_test_server.h",
 656     "test/embedded_test_server/http_connection.cc",
 657     "test/embedded_test_server/http_connection.h",
 658     "test/embedded_test_server/http_request.cc",
 659     "test/embedded_test_server/http_request.h",
 660     "test/embedded_test_server/http_response.cc",
 661     "test/embedded_test_server/http_response.h",
 662     "test/net_test_suite.cc",
 663     "test/net_test_suite.h",
 664     "test/python_utils.cc",
 665     "test/python_utils.h",
 666     "test/spawned_test_server/base_test_server.cc",
 667     "test/spawned_test_server/base_test_server.h",
 668     "test/spawned_test_server/local_test_server_posix.cc",
 669     "test/spawned_test_server/local_test_server_win.cc",
 670     "test/spawned_test_server/local_test_server.cc",
 671     "test/spawned_test_server/local_test_server.h",
 672     "test/spawned_test_server/remote_test_server.cc",
 673     "test/spawned_test_server/remote_test_server.h",
 674     "test/spawned_test_server/spawned_test_server.h",
 675     "test/spawned_test_server/spawner_communicator.cc",
 676     "test/spawned_test_server/spawner_communicator.h",
 677     "url_request/test_url_fetcher_factory.cc",
 678     "url_request/test_url_fetcher_factory.h",
 679     "url_request/test_url_request_interceptor.cc",
 680     "url_request/test_url_request_interceptor.h",
 681     "url_request/url_request_test_util.cc",
 682     "url_request/url_request_test_util.h",
 683   ]
 684
 685   configs += [ ":net_win_size_truncation" ]
 686
 687   public_deps = [
 688     "//base",
 689     "//base/test:test_support",
 690     "//crypto",
 691     "//net",
 692     "//net/tools/tld_cleanup",
 693     "//testing/gmock",
 694     "//testing/gtest",
 695     "//url",
 696   ]
 697
 698   if (!use_openssl && (use_nss_certs || is_ios)) {
 699     public_deps += ["//crypto:platform" ]
 700   }
 701
 702   if (!is_android) {
 703     sources -= [
 704       "test/spawned_test_server/remote_test_server.cc",
 705       "test/spawned_test_server/remote_test_server.h",
 706       "test/spawned_test_server/spawner_communicator.cc",
 707       "test/spawned_test_server/spawner_communicator.h",
 708     ]
 709   }
 710
 711   if (use_v8_in_net) {
 712     public_deps += [ ":net_with_v8" ]
 713   }
 714
 715   if (!enable_mdns) {
 716     sources -= [
 717       "dns/mock_mdns_socket_factory.cc",
 718       "dns/mock_mdns_socket_factory.h",
 719     ]
 720   }
 721
 722   if (!use_nss_certs) {
 723     sources -= [
 724       "test/cert_test_util_nss.cc",
 725     ]
 726   }
 727 }
 728
 729 source_set("balsa") {
 730   sources = [
 731     "tools/balsa/balsa_enums.h",
 732     "tools/balsa/balsa_frame.cc",
 733     "tools/balsa/balsa_frame.h",
 734     "tools/balsa/balsa_headers.cc",
 735     "tools/balsa/balsa_headers.h",
 736     "tools/balsa/balsa_headers_token_utils.cc",
 737     "tools/balsa/balsa_headers_token_utils.h",
 738     "tools/balsa/balsa_visitor_interface.h",
 739     "tools/balsa/http_message_constants.cc",
 740     "tools/balsa/http_message_constants.h",
 741     "tools/balsa/noop_balsa_visitor.h",
 742     "tools/balsa/simple_buffer.cc",
 743     "tools/balsa/simple_buffer.h",
 744     "tools/balsa/split.cc",
 745     "tools/balsa/split.h",
 746     "tools/balsa/string_piece_utils.h",
 747     "tools/quic/spdy_utils.cc",
 748     "tools/quic/spdy_utils.h",
 749   ]
 750   deps = [
 751     ":net",
 752     "//base",
 753     "//url",
 754   ]
 755 }
 756
 757 if (use_v8_in_net) {
 758   component("net_with_v8") {
 759     sources = [
 760       "proxy/proxy_resolver_v8.cc",
 761       "proxy/proxy_resolver_v8.h",
 762       "proxy/proxy_resolver_v8_tracing.cc",
 763       "proxy/proxy_resolver_v8_tracing.h",
 764       "proxy/proxy_service_v8.cc",
 765       "proxy/proxy_service_v8.h",
 766     ]
 767
 768     defines = [ "NET_IMPLEMENTATION" ]
 769     configs += [
 770       ":net_win_size_truncation",
 771       "//build/config/compiler:wexit_time_destructors",
 772     ]
 773
 774     public_deps = [
 775       ":net",
 776     ]
 777     deps = [
 778       "//base",
 779       "//gin",
 780       "//url",
 781       "//v8",
 782     ]
 783   }
 784 }
 785
 786 if (!is_ios && !is_android) {
 787   executable("crash_cache") {
 788     testonly = true
 789     sources = [ "tools/crash_cache/crash_cache.cc" ]
 790     configs += [ ":net_win_size_truncation" ]
 791     deps = [
 792       ":net",
 793       ":test_support",
 794       "//base",
 795     ]
 796   }
 797
 798   executable("crl_set_dump") {
 799     testonly = true
 800     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 801     configs += [ ":net_win_size_truncation" ]
 802     deps = [
 803       ":net",
 804       "//base",
 805     ]
 806   }
 807
 808   executable("dns_fuzz_stub") {
 809     testonly = true
 810     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 811     configs += [ ":net_win_size_truncation" ]
 812     deps = [
 813       ":net",
 814       "//base",
 815     ]
 816   }
 817
 818   executable("gdig") {
 819     testonly = true
 820     sources = [
 821       "tools/gdig/file_net_log.cc",
 822       "tools/gdig/gdig.cc",
 823     ]
 824     deps = [
 825       ":net",
 826       "//base",
 827     ]
 828   }
 829
 830   executable("get_server_time") {
 831     testonly = true
 832     sources = [ "tools/get_server_time/get_server_time.cc" ]
 833     configs += [ ":net_win_size_truncation" ]
 834     deps = [
 835       ":net",
 836       "//base",
 837       "//base:i18n",
 838       "//url",
 839     ]
 840   }
 841
 842   if (use_v8_in_net) {
 843     executable("net_watcher") {
 844       testonly = true
 845       sources = [ "tools/net_watcher/net_watcher.cc" ]
 846       deps = [
 847         ":net",
 848         ":net_with_v8",
 849         "//base",
 850       ]
 851
 852       if (is_desktop_linux) {
 853         configs += [
 854           "//build/config/linux:gconf",
 855           "//build/config/linux:glib",
 856         ]
 857         deps += [ "//build/config/linux:gio" ]
 858       }
 859     }
 860   }
 861
 862   executable("run_testserver") {
 863     testonly = true
 864     sources = [ "tools/testserver/run_testserver.cc" ]
 865     deps = [
 866       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 867                # in the GYP build, and can be removed when the bug is fixed.
 868       ":test_support",
 869       "//base",
 870       "//base/test:test_support",
 871       "//testing/gtest",
 872     ]
 873   }
 874
 875   executable("stress_cache") {
 876     testonly = true
 877     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 878     configs += [ ":net_win_size_truncation" ]
 879     deps = [
 880       ":net",
 881       ":test_support",
 882       "//base",
 883     ]
 884   }
 885
 886   executable("tld_cleanup") {
 887     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 888     configs += [ ":net_win_size_truncation" ]
 889     deps = [
 890       "//base",
 891       "//base:i18n",
 892       "//net/tools/tld_cleanup",
 893     ]
 894   }
 895 }
 896
 897 if (is_linux) {
 898   static_library("epoll_server") {
 899     sources = [
 900       "tools/epoll_server/epoll_server.cc",
 901       "tools/epoll_server/epoll_server.h",
 902     ]
 903     deps = [
 904       ":net",
 905       "//base",
 906     ]
 907   }
 908
 909   static_library("flip_in_mem_edsm_server_base") {
 910     testonly = true
 911     sources = [
 912       "tools/dump_cache/url_to_filename_encoder.cc",
 913       "tools/dump_cache/url_to_filename_encoder.h",
 914       "tools/dump_cache/url_utilities.h",
 915       "tools/dump_cache/url_utilities.cc",
 916       "tools/flip_server/acceptor_thread.h",
 917       "tools/flip_server/acceptor_thread.cc",
 918       "tools/flip_server/create_listener.cc",
 919       "tools/flip_server/create_listener.h",
 920       "tools/flip_server/constants.h",
 921       "tools/flip_server/flip_config.cc",
 922       "tools/flip_server/flip_config.h",
 923       "tools/flip_server/http_interface.cc",
 924       "tools/flip_server/http_interface.h",
 925       "tools/flip_server/loadtime_measurement.h",
 926       "tools/flip_server/mem_cache.h",
 927       "tools/flip_server/mem_cache.cc",
 928       "tools/flip_server/output_ordering.cc",
 929       "tools/flip_server/output_ordering.h",
 930       "tools/flip_server/ring_buffer.cc",
 931       "tools/flip_server/ring_buffer.h",
 932       "tools/flip_server/sm_connection.cc",
 933       "tools/flip_server/sm_connection.h",
 934       "tools/flip_server/sm_interface.h",
 935       "tools/flip_server/spdy_ssl.cc",
 936       "tools/flip_server/spdy_ssl.h",
 937       "tools/flip_server/spdy_interface.cc",
 938       "tools/flip_server/spdy_interface.h",
 939       "tools/flip_server/spdy_util.cc",
 940       "tools/flip_server/spdy_util.h",
 941       "tools/flip_server/streamer_interface.cc",
 942       "tools/flip_server/streamer_interface.h",
 943     ]
 944     deps = [
 945       ":balsa",
 946       ":epoll_server",
 947       ":net",
 948       "//base",
 949       "//third_party/boringssl",
 950     ]
 951   }
 952
 953   executable("flip_in_mem_edsm_server_unittests") {
 954     testonly = true
 955     sources = [
 956       "tools/flip_server/flip_test_utils.cc",
 957       "tools/flip_server/flip_test_utils.h",
 958       "tools/flip_server/http_interface_test.cc",
 959       "tools/flip_server/mem_cache_test.cc",
 960       "tools/flip_server/run_all_tests.cc",
 961       "tools/flip_server/spdy_interface_test.cc",
 962     ]
 963     deps = [
 964       ":flip_in_mem_edsm_server_base",
 965       ":net",
 966       ":test_support",
 967       "//testing/gtest",
 968       "//testing/gmock",
 969       "//third_party/boringssl",
 970     ]
 971   }
 972
 973   executable("flip_in_mem_edsm_server") {
 974     testonly = true
 975     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 976     deps = [
 977       ":flip_in_mem_edsm_server_base",
 978       ":net",
 979       "//base",
 980     ]
 981   }
 982
 983   source_set("quic_base") {
 984     sources = [
 985       "tools/quic/quic_client.cc",
 986       "tools/quic/quic_client.h",
 987       "tools/quic/quic_client_session.cc",
 988       "tools/quic/quic_client_session.h",
 989       "tools/quic/quic_default_packet_writer.cc",
 990       "tools/quic/quic_default_packet_writer.h",
 991       "tools/quic/quic_dispatcher.h",
 992       "tools/quic/quic_dispatcher.cc",
 993       "tools/quic/quic_epoll_clock.cc",
 994       "tools/quic/quic_epoll_clock.h",
 995       "tools/quic/quic_epoll_connection_helper.cc",
 996       "tools/quic/quic_epoll_connection_helper.h",
 997       "tools/quic/quic_in_memory_cache.cc",
 998       "tools/quic/quic_in_memory_cache.h",
 999       "tools/quic/quic_packet_writer_wrapper.cc",
1000       "tools/quic/quic_packet_writer_wrapper.h",
1001       "tools/quic/quic_per_connection_packet_writer.cc",
1002       "tools/quic/quic_per_connection_packet_writer.h",
1003       "tools/quic/quic_server.cc",
1004       "tools/quic/quic_server.h",
1005       "tools/quic/quic_server_session.cc",
1006       "tools/quic/quic_server_session.h",
1007       "tools/quic/quic_socket_utils.cc",
1008       "tools/quic/quic_socket_utils.h",
1009       "tools/quic/quic_spdy_client_stream.cc",
1010       "tools/quic/quic_spdy_client_stream.h",
1011       "tools/quic/quic_spdy_server_stream.cc",
1012       "tools/quic/quic_spdy_server_stream.h",
1013       "tools/quic/quic_time_wait_list_manager.h",
1014       "tools/quic/quic_time_wait_list_manager.cc",
1015     ]
1016     deps = [
1017       ":balsa",
1018       ":epoll_server",
1019       ":net",
1020       "//base",
1021       "//base/third_party/dynamic_annotations",
1022       "//crypto",
1023       "//third_party/boringssl",
1024       "//url",
1025     ]
1026   }
1027
1028   executable("quic_client") {
1029     sources = [ "tools/quic/quic_client_bin.cc" ]
1030     deps = [
1031       ":quic_base",
1032       ":net",
1033       "//base",
1034       "//third_party/boringssl",
1035     ]
1036   }
1037 }
1038
1039 if (is_android) {
1040   generate_jni("net_jni_headers") {
1041     sources = [
1042       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1043       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1044       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1045       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1046       "android/java/src/org/chromium/net/GURLUtils.java",
1047       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1048       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1049       "android/java/src/org/chromium/net/X509Util.java",
1050     ]
1051     jni_package = "net"
1052   }
1053   generate_jni("net_test_jni_headers") {
1054     sources = [
1055       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1056     ]
1057     jni_package = "net"
1058   }
1059 }
1060
1061 if (is_android || is_linux) {
1062   executable("disk_cache_memory_test") {
1063     testonly = true
1064     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1065     deps = [
1066       ":net",
1067       "//base",
1068     ]
1069   }
1070 }
1071
1072 # TODO(GYP) make this compile on Android, we need some native test deps done.
1073 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1074 if (!is_android && !is_win) {
1075
1076 source_set("quic_tools") {
1077   sources = [
1078     "quic/quic_dispatcher.cc",
1079     "quic/quic_dispatcher.h",
1080     "quic/quic_in_memory_cache.cc",
1081     "quic/quic_in_memory_cache.h",
1082     "quic/quic_per_connection_packet_writer.cc",
1083     "quic/quic_per_connection_packet_writer.h",
1084     "quic/quic_server.cc",
1085     "quic/quic_server.h",
1086     "quic/quic_server_packet_writer.cc",
1087     "quic/quic_server_packet_writer.h",
1088     "quic/quic_server_session.cc",
1089     "quic/quic_server_session.h",
1090     "quic/quic_spdy_server_stream.cc",
1091     "quic/quic_spdy_server_stream.h",
1092     "quic/quic_time_wait_list_manager.cc",
1093     "quic/quic_time_wait_list_manager.h",
1094   ]
1095   deps = [
1096     ":net",
1097     "//base",
1098     "//base/third_party/dynamic_annotations",
1099     "//url",
1100   ]
1101 }
1102
1103 test("net_unittests") {
1104   sources = gypi_values.net_test_sources
1105
1106   configs += [ ":net_win_size_truncation" ]
1107   defines = []
1108
1109   deps = [
1110     ":extras",
1111     ":http_server",
1112     ":net",
1113     ":quic_tools",
1114     ":test_support",
1115     "//base",
1116     "//base:i18n",
1117     "//base:prefs_test_support",
1118     "//base/allocator",
1119     "//base/third_party/dynamic_annotations",
1120     "//crypto",
1121     "//crypto:platform",
1122     "//crypto:test_support",
1123     "//net/base/registry_controlled_domains",
1124     "//testing/gmock",
1125     "//testing/gtest",
1126     "//third_party/zlib",
1127     "//url",
1128   ]
1129
1130   if (is_linux) {
1131     sources += gypi_values.net_linux_test_sources
1132     deps += [
1133       ":balsa",
1134       ":epoll_server",
1135       ":flip_in_mem_edsm_server_base",
1136       ":quic_base",
1137     ]
1138   }
1139
1140   if (is_chromeos) {
1141     sources -= [
1142       "proxy/proxy_config_service_linux_unittest.cc",
1143     ]
1144   }
1145
1146   if (is_android) {
1147     sources -= [
1148       # See bug http://crbug.com/344533.
1149       "disk_cache/blockfile/index_table_v3_unittest.cc",
1150       # No res_ninit() et al on Android, so this doesn't make a lot of
1151       # sense.
1152       "dns/dns_config_service_posix_unittest.cc",
1153     ]
1154     deps += [
1155       ":net_javatests",  # FIXME(brettw)
1156       ":net_test_jni_headers",
1157     ]
1158   }
1159
1160   if (!use_nss_certs) {
1161     sources -= [
1162       "ssl/client_cert_store_nss_unittest.cc",
1163     ]
1164     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1165       sources -= [
1166         "ssl/client_cert_store_chromeos_unittest.cc",
1167       ]
1168     }
1169   }
1170
1171   if (use_openssl) {
1172     # When building for OpenSSL, we need to exclude NSS specific tests
1173     # or functionality not supported by OpenSSL yet.
1174     # TODO(bulach): Add equivalent tests when the underlying
1175     #               functionality is ported to OpenSSL.
1176     sources -= [
1177       "cert/nss_cert_database_unittest.cc",
1178       "cert/x509_util_nss_unittest.cc",
1179       "quic/test_tools/crypto_test_utils_nss.cc",
1180     ]
1181     if (is_chromeos) {
1182       # These were already removed in the non-ChromeOS case.
1183       sources -= [
1184         "cert/nss_cert_database_chromeos_unittest.cc",
1185         "cert/nss_profile_filter_chromeos_unittest.cc",
1186       ]
1187     }
1188   } else {
1189     sources -= [
1190       "cert/x509_util_openssl_unittest.cc",
1191       "quic/test_tools/crypto_test_utils_openssl.cc",
1192       "socket/ssl_client_socket_openssl_unittest.cc",
1193       "socket/ssl_session_cache_openssl_unittest.cc",
1194     ]
1195     if (!is_desktop_linux && !is_chromeos) {
1196       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1197     }
1198   }
1199
1200   if (use_kerberos) {
1201     defines += [ "USE_KERBEROS" ]
1202   } else {
1203     sources -= [
1204       "http/http_auth_gssapi_posix_unittest.cc",
1205       "http/http_auth_handler_negotiate_unittest.cc",
1206       "http/mock_gssapi_library_posix.cc",
1207       "http/mock_gssapi_library_posix.h",
1208     ]
1209   }
1210
1211   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1212     # Only include this test when on Posix and using NSS for
1213     # cert verification or on iOS (which also uses NSS for certs).
1214     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1215   }
1216
1217   if (!use_openssl_certs) {
1218     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1219   }
1220
1221   if (!enable_websockets) {
1222     sources -= [
1223       "socket_stream/socket_stream_metrics_unittest.cc",
1224       "socket_stream/socket_stream_unittest.cc",
1225       "spdy/spdy_websocket_stream_unittest.cc",
1226       "websockets/websocket_basic_stream_test.cc",
1227       "websockets/websocket_channel_test.cc",
1228       "websockets/websocket_deflate_predictor_impl_test.cc",
1229       "websockets/websocket_deflate_stream_test.cc",
1230       "websockets/websocket_deflater_test.cc",
1231       "websockets/websocket_errors_test.cc",
1232       "websockets/websocket_extension_parser_test.cc",
1233       "websockets/websocket_frame_parser_test.cc",
1234       "websockets/websocket_frame_test.cc",
1235       "websockets/websocket_handshake_handler_spdy_test.cc",
1236       "websockets/websocket_handshake_handler_test.cc",
1237       "websockets/websocket_handshake_stream_create_helper_test.cc",
1238       "websockets/websocket_inflater_test.cc",
1239       "websockets/websocket_job_test.cc",
1240       "websockets/websocket_net_log_params_test.cc",
1241       "websockets/websocket_stream_test.cc",
1242       "websockets/websocket_test_util.cc",
1243       "websockets/websocket_test_util.h",
1244       "websockets/websocket_throttle_test.cc",
1245     ]
1246   }
1247
1248   if (disable_file_support) {
1249     sources -= [
1250       "base/directory_lister_unittest.cc",
1251       "url_request/url_request_file_job_unittest.cc",
1252     ]
1253   }
1254
1255   if (disable_ftp_support) {
1256     sources -= [
1257       "ftp/ftp_auth_cache_unittest.cc",
1258       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1259       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1260       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1261       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1262       "ftp/ftp_directory_listing_parser_unittest.cc",
1263       "ftp/ftp_directory_listing_parser_unittest.h",
1264       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1265       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1266       "ftp/ftp_network_transaction_unittest.cc",
1267       "ftp/ftp_util_unittest.cc",
1268       "url_request/url_request_ftp_job_unittest.cc",
1269     ]
1270   }
1271
1272   if (!enable_built_in_dns) {
1273     sources -= [
1274       "dns/address_sorter_posix_unittest.cc",
1275       "dns/address_sorter_unittest.cc",
1276     ]
1277   }
1278
1279   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1280   # net_unittest's dependency on v8 when using icu alternatives instead of
1281   # setting use_v8_in_net to 0.
1282   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1283     deps += [ ":net_with_v8" ]
1284   } else {
1285     sources -= [
1286       "proxy/proxy_resolver_v8_unittest.cc",
1287       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1288     ]
1289   }
1290
1291   if (!enable_mdns) {
1292     sources -= [
1293       "dns/mdns_cache_unittest.cc",
1294       "dns/mdns_client_unittest.cc",
1295       "dns/record_parsed_unittest.cc",
1296       "dns/record_rdata_unittest.cc",
1297     ]
1298   }
1299
1300   if (is_ios) {
1301     # TODO(GYP)
1302     #  'actions': [
1303     #    {
1304     #      'action_name': 'copy_test_data',
1305     #      'variables': {
1306     #        'test_data_files': [
1307     #          'data/ssl/certificates/',
1308     #          'data/test.html',
1309     #          'data/url_request_unittest/',
1310     #        ],
1311     #        'test_data_prefix': 'net',
1312     #      },
1313     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1314     #    },
1315     #  ],
1316     sources -= [
1317       # TODO(droger): The following tests are disabled because the
1318       # implementation is missing or incomplete.
1319       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1320       "base/keygen_handler_unittest.cc",
1321       "disk_cache/backend_unittest.cc",
1322       "disk_cache/blockfile/block_files_unittest.cc",
1323       # Need to read input data files.
1324       "filter/gzip_filter_unittest.cc",
1325       "socket/ssl_server_socket_unittest.cc",
1326       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1327       # Need TestServer.
1328       "proxy/proxy_script_fetcher_impl_unittest.cc",
1329       "socket/ssl_client_socket_unittest.cc",
1330       "url_request/url_fetcher_impl_unittest.cc",
1331       "url_request/url_request_context_builder_unittest.cc",
1332       # Needs GetAppOutput().
1333       "test/python_utils_unittest.cc",
1334
1335       # The following tests are disabled because they don't apply to
1336       # iOS.
1337       # OS is not "linux" or "freebsd" or "openbsd".
1338       "socket/unix_domain_client_socket_posix_unittest.cc",
1339       "socket/unix_domain_listen_socket_posix_unittest.cc",
1340       "socket/unix_domain_server_socket_posix_unittest.cc",
1341
1342       # See bug http://crbug.com/344533.
1343       "disk_cache/blockfile/index_table_v3_unittest.cc",
1344     ]
1345   }
1346
1347   if (is_android) {
1348     sources -= [
1349       "dns/dns_config_service_posix_unittest.cc",
1350     ]
1351     # TODO(GYP)
1352     # # TODO(mmenke):  This depends on test_support_base, which depends on
1353     # #                icu.  Figure out a way to remove that dependency.
1354     # 'dependencies': [
1355     #   '../testing/android/native_test.gyp:native_test_native_code',
1356     # ]
1357
1358     set_sources_assignment_filter([])
1359     sources += [ "base/address_tracker_linux_unittest.cc" ]
1360     set_sources_assignment_filter(sources_assignment_filter)
1361   }
1362
1363   if (use_icu_alternatives_on_android) {
1364     sources -= [
1365       "base/filename_util_unittest.cc",
1366       "base/net_util_icu_unittest.cc",
1367     ]
1368     deps -= [ "//base:i18n" ]
1369   }
1370 }
1371
1372 executable("quic_server") {
1373   sources = [ "quic/quic_server_bin.cc" ]
1374   deps = [
1375     ":quic_tools",
1376     ":net",
1377     "//base",
1378     "//third_party/boringssl",
1379   ]
1380 }
1381
1382 }  # !is_android