build/config/sysroot.gni

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This header file defines the "sysroot" variable which is the absolute path
   6 # of the sysroot. If no sysroot applies, the variable will be an empty string.
   7
   8 declare_args() {
   9   # The absolute path of the sysroot that is applied when compiling using
  10   # the target toolchain.
  11   target_sysroot = ""
  12 }
  13
  14 if (current_toolchain == default_toolchain && target_sysroot != "") {
  15   sysroot = target_sysroot
  16 } else if (is_android) {
  17   import("//build/config/android/config.gni")
  18   if (current_cpu == "x86") {
  19     sysroot = rebase_path("$android_ndk_root/$x86_android_sysroot_subdir")
  20   } else if (current_cpu == "arm") {
  21     sysroot = rebase_path("$android_ndk_root/$arm_android_sysroot_subdir")
  22   } else if (current_cpu == "mipsel") {
  23     sysroot = rebase_path("$android_ndk_root/$mips_android_sysroot_subdir")
  24   } else if (current_cpu == "x64") {
  25     sysroot = rebase_path("$android_ndk_root/$x86_64_android_sysroot_subdir")
  26   } else if (current_cpu == "arm64") {
  27     sysroot = rebase_path("$android_ndk_root/$arm64_android_sysroot_subdir")
  28   } else if (current_cpu == "mips64") {
  29     sysroot = rebase_path("$android_ndk_root/$mips64_android_sysroot_subdir")
  30   } else {
  31     sysroot = ""
  32   }
  33 } else if (is_linux && is_chrome_branded && is_official_build && !is_chromeos) {
  34   # For official builds, use the sysroot checked into the internal source repo
  35   # so that the builds work on older versions of Linux.
  36   if (current_cpu == "x64") {
  37     sysroot =
  38         rebase_path("//chrome/installer/linux/debian_wheezy_amd64-sysroot")
  39   } else if (current_cpu == "x86") {
  40     sysroot = rebase_path("//chrome/installer/linux/debian_wheezy_i386-sysroot")
  41   } else {
  42     # Any other builds don't use a sysroot.
  43     sysroot = ""
  44   }
  45 } else if (is_linux && !is_chromeos) {
  46   if (current_cpu == "mipsel") {
  47     sysroot = rebase_path("//mipsel-sysroot/sysroot")
  48   } else {
  49     sysroot = ""
  50   }
  51 } else if (is_mac) {
  52   import("//build/config/mac/mac_sdk.gni")
  53
  54   sysroot = mac_sdk_path
  55 } else if (is_ios) {
  56   import("//build/config/ios/ios_sdk.gni")
  57   sysroot = ios_sdk_path
  58 } else {
  59   sysroot = ""
  60 }