build/config/win/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/win/visual_studio_version.gni")
   6
   7 # Compiler setup for the Windows SDK. Applied to all targets.
   8 config("sdk") {
   9   # The include path is the stuff returned by the script.
  10   #include_dirs = msvc_config[0]  TODO(brettw) make this work.
  11
  12   defines = [
  13     "_ATL_NO_OPENGL",
  14     "_WINDOWS",
  15     "CERT_CHAIN_PARA_HAS_EXTRA_FIELDS",
  16     "NTDDI_VERSION=0x06030000",
  17     "PSAPI_VERSION=1",
  18     "WIN32",
  19     "_SECURE_ATL",
  20
  21     # This is required for ATL to use XP-safe versions of its functions.
  22     "_USING_V110_SDK71_",
  23   ]
  24 }
  25
  26 # Sets the default Windows build version. This is separated because some
  27 # targets need to manually override it for their compiles.
  28 config("winver") {
  29   defines = [
  30     "_WIN32_WINNT=0x0603",
  31     "WINVER=0x0603",
  32   ]
  33 }
  34
  35 # Linker flags for Windows SDK setup, this is applied only to EXEs and DLLs.
  36 config("sdk_link") {
  37   if (current_cpu == "x64") {
  38     ldflags = [ "/MACHINE:X64" ]
  39     lib_dirs = [
  40       "$windows_sdk_path\Lib\winv6.3\um\x64",
  41       "$visual_studio_path\VC\lib\amd64",
  42       "$visual_studio_path\VC\atlmfc\lib\amd64",
  43     ]
  44   } else {
  45     ldflags = [
  46       "/MACHINE:X86",
  47       "/SAFESEH",  # Not compatible with x64 so use only for x86.
  48     ]
  49     lib_dirs = [
  50       "$windows_sdk_path\Lib\winv6.3\um\x86",
  51       "$visual_studio_path\VC\lib",
  52       "$visual_studio_path\VC\atlmfc\lib",
  53     ]
  54     if (!is_asan) {
  55       ldflags += [ "/largeaddressaware" ]
  56     }
  57   }
  58 }
  59
  60 # This default linker setup is provided separately from the SDK setup so
  61 # targets who want different library configurations can remove this and specify
  62 # their own.
  63 config("common_linker_setup") {
  64   ldflags = [
  65     "/FIXED:NO",
  66     "/ignore:4199",
  67     "/ignore:4221",
  68     "/NXCOMPAT",
  69
  70     # Suggested by Microsoft Devrel to avoid
  71     #   LINK : fatal error LNK1248: image size (80000000)
  72     #   exceeds maximum allowable size (80000000)
  73     # which started happening more regularly after VS2013 Update 4.
  74     "/maxilksize:2147483647",
  75   ]
  76
  77   # ASLR makes debugging with windbg difficult because Chrome.exe and
  78   # Chrome.dll share the same base name. As result, windbg will name the
  79   # Chrome.dll module like chrome_<base address>, where <base address>
  80   # typically changes with each launch. This in turn means that breakpoints in
  81   # Chrome.dll don't stick from one launch to the next. For this reason, we
  82   # turn ASLR off in debug builds.
  83   if (is_debug) {
  84     ldflags += [ "/DYNAMICBASE:NO" ]
  85   } else {
  86     ldflags += [ "/DYNAMICBASE" ]
  87   }
  88
  89   # Delay loaded DLLs.
  90   ldflags += [
  91     "/DELAYLOAD:dbghelp.dll",
  92     "/DELAYLOAD:dwmapi.dll",
  93     "/DELAYLOAD:shell32.dll",
  94     "/DELAYLOAD:uxtheme.dll",
  95   ]
  96 }
  97
  98 # Subsystem --------------------------------------------------------------------
  99
 100 config("console") {
 101   ldflags = [ "/SUBSYSTEM:CONSOLE" ]
 102 }
 103 config("windowed") {
 104   ldflags = [ "/SUBSYSTEM:WINDOWS" ]
 105 }
 106
 107 # Incremental linking ----------------------------------------------------------
 108
 109 incremental_linking_on_switch = [ "/INCREMENTAL" ]
 110 incremental_linking_off_switch = [ "/INCREMENTAL:NO" ]
 111 if (is_debug) {
 112   default_incremental_linking_switch = incremental_linking_on_switch
 113 } else {
 114   default_incremental_linking_switch = incremental_linking_off_switch
 115 }
 116
 117 # Applies incremental linking or not depending on the current configuration.
 118 config("default_incremental_linking") {
 119   ldflags = default_incremental_linking_switch
 120 }
 121
 122 # Explicitly on or off incremental linking
 123 config("incremental_linking") {
 124   ldflags = incremental_linking_on_switch
 125 }
 126 config("no_incremental_linking") {
 127   ldflags = incremental_linking_off_switch
 128 }
 129
 130 # Some large modules can't handle incremental linking in some situations. This
 131 # config should be applied to large modules to turn off incremental linking
 132 # when it won't work.
 133 config("default_large_module_incremental_linking") {
 134   if (symbol_level > 0 && (current_cpu == "x86" || !is_component_build)) {
 135     # When symbols are on, things get so large that the tools fail due to the
 136     # size of the .ilk files.
 137     ldflags = incremental_linking_off_switch
 138   } else {
 139     # Otherwise just do the default incremental linking for this build type.
 140     ldflags = default_incremental_linking_switch
 141   }
 142 }
 143
 144 # Character set ----------------------------------------------------------------
 145
 146 # Not including this config means "ansi" (8-bit system codepage).
 147 config("unicode") {
 148   defines = [
 149     "_UNICODE",
 150     "UNICODE",
 151   ]
 152 }
 153
 154 # Lean and mean ----------------------------------------------------------------
 155
 156 # Some third party code might not compile with WIN32_LEAN_AND_MEAN so we have
 157 # to have a separate config for it. Remove this config from your target to
 158 # get the "bloaty and accomodating" version of windows.h.
 159 config("lean_and_mean") {
 160   defines = [ "WIN32_LEAN_AND_MEAN" ]
 161 }
 162
 163 # Nominmax --------------------------------------------------------------------
 164
 165 # Some third party code defines NOMINMAX before including windows.h, which
 166 # then causes warnings when it's been previously defined on the command line.
 167 # For such targets, this config can be removed.
 168
 169 config("nominmax") {
 170   defines = [ "NOMINMAX" ]
 171 }