chrome/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/locales.gni")
   7 import("//build/config/ui.gni")
   8 import("//chrome/chrome_repack_locales.gni")
   9 import("//chrome/version.gni")
  10
  11 if (is_android) {
  12   import("//build/config/android/rules.gni")
  13 }
  14
  15 if (!is_android && !(is_chromeos && !use_ozone)) {
  16
  17 # TODO(GYP) for Windows need to the the reorder-imports step which probably
  18 # means adding another target and renaming this to chrome_initial like in GYP.
  19 executable("chrome") {
  20   # Because the sources list varies so significantly per-platform, generally
  21   # each platform lists its own files rather than relying on filtering or
  22   # removing unused files.
  23   sources = [
  24     "app/chrome_exe_resource.h",
  25   ]
  26   deps = []
  27   datadeps = []
  28
  29   # TODO(GYP) mac_bundle_resources, xcode_settings
  30
  31   # TODO(GYP) order_profiling, order_text_section
  32
  33   if (is_win) {
  34     sources += [
  35       "app/chrome_exe_main_win.cc",
  36       "app/client_util.cc",
  37       "app/client_util.h",
  38       "app/signature_validator_win.cc",
  39       "app/signature_validator_win.h",
  40       "//content/app/startup_helper_win.cc",
  41     ]
  42     deps += [ "//ui/gfx" ]
  43   } else if (use_aura) {
  44     # Non-Windows aura entrypoint.
  45     sources += [ "app/chrome_exe_main_aura.cc" ]
  46   }
  47
  48   if (is_linux) {
  49     # TODO(GYP) manpage action
  50
  51     sources += [
  52       "app/chrome_dll_resource.h",
  53       "app/chrome_main.cc",
  54       "app/chrome_main_delegate.cc",
  55       "app/chrome_main_delegate.h",
  56     ]
  57
  58     deps += [
  59       # On Linux, link the dependencies (libraries) that make up actual
  60       # Chromium functionality directly into the executable.
  61       ":browser_dependencies",
  62       ":child_dependencies",
  63
  64       "//base/allocator",
  65       # Needed to use the master_preferences functions
  66       "//chrome/installer/util",
  67       "//content/public/app:both",
  68     ]
  69
  70     # Needed for chrome_main.cc initialization of libraries.
  71     configs += [ "//build/config/linux:pangocairo" ]
  72
  73     # TODO(GYP) ['profiling==0 and linux_disable_pie==0', {
  74     #   'ldflags': [
  75     #      '-pie',
  76     #   ],
  77     #}],
  78
  79     if (use_x11) {
  80       configs += [
  81         "//build/config/linux:x11",
  82         "//build/config/linux:xext",
  83       ]
  84     }
  85   }
  86
  87   if (is_mac) {
  88     sources += [
  89       "app/chrome_exe_main_mac.cc",
  90     ]
  91     # TODO(GYP) lots more stuff in the is_mac block.
  92   } else {  # Non-Mac.
  93     deps += [
  94       ":packed_extra_resources",
  95       ":packed_resources",
  96
  97       # Copy Flash Player files to PRODUCT_DIR if applicable. Let the .gyp
  98       # file decide what to do on a per-OS basis; on Mac, internal plugins
  99       # go inside the framework, so this dependency is in chrome_dll.gypi.
 100       #'../third_party/adobe/flash/flash_player.gyp:flapper_binaries',  TODO(GYP)
 101
 102       # Copy CDM files to PRODUCT_DIR if applicable. Let the .gyp
 103       # file decide what to do on a per-OS basis; on Mac, internal plugins
 104       # go inside the framework, so this dependency is in chrome_dll.gypi.
 105       #'../third_party/widevine/cdm/widevine_cdm.gyp:widevinecdmadapter',  TODO(GYP)
 106     ]
 107
 108     # TODO(GYP) some stuff from GYP including chrome_multiple_dll.
 109
 110   }
 111
 112
 113   if (!is_mac) {
 114     # On Mac this is done in chrome_dll.gypi.
 115     datadeps += [ "//pdf" ]
 116
 117     # TODO(GYP) pdf linux symbols
 118   }
 119 }
 120
 121 }  # !is_android
 122
 123 shared_library("main_dll") {
 124   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 125
 126   deps = [
 127     ":browser_dependencies",
 128     "//base/allocator",
 129   ]
 130   if (is_win) {
 131     output_name = "chrome"
 132
 133     sources = [
 134       "app/chrome_command_ids.h",
 135       "app/chrome_dll.rc",
 136       "app/chrome_dll_resource.h",
 137       "app/chrome_main.cc",
 138       "app/chrome_main_delegate.cc",
 139       "app/chrome_main_delegate.h",
 140       "app/close_handle_hook_win.cc",
 141       "app/close_handle_hook_win.h",
 142       "app/delay_load_hook_win.cc",
 143       "app/delay_load_hook_win.h",
 144       "//base/win/dllmain.cc",
 145     ]
 146
 147     deps += [
 148       # On Windows, link the dependencies (libraries) that make up actual
 149       # Chromium functionality into this .dll.
 150       #'chrome_version_resources',  TODO(GYP)
 151       "//chrome/app/theme:chrome_unscaled_resources",
 152       "//content/app/resources",
 153       "//crypto",
 154       "//net:net_resources",
 155       "//third_party/wtl",
 156       "//ui/views",
 157       #'<(DEPTH)/chrome_elf/chrome_elf.gyp:chrome_elf' ]  TODO(GYP)
 158     ]
 159     if (enable_configuration_policy) {
 160       deps += [ "//components/policy" ]
 161     }
 162     if (cpu_arch == "x86") {
 163       # Add a dependency to custom import library for user32 delay imports only
 164       # in x86 builds.
 165       #deps += [ 'chrome_user32_delay_imports' ]  TODO(GYP)
 166     }
 167
 168     # TODO(GYP) incremental linking flags in debug builds
 169     #'LinkIncremental': '<(msvs_large_module_debug_link_mode)',
 170
 171     # TODO(GYP) Lots of VCLinkerTool stuff on Windows.
 172
 173     # TODO(GYP) chrome_pgo_phase on Windows.
 174   }
 175
 176   if (use_aura) {
 177     deps += [ "//ui/compositor" ]
 178   }
 179
 180   #TODO(GYP) add chrome_multiple_dll support
 181   if (false) {  #chrome_multiple_dll) {
 182     defines = [ "CHROME_MULTIPLE_DLL_BROWSER" ]
 183     deps += [
 184       "//content/public/app:browser",
 185     ]
 186   } else {
 187     deps += [
 188       ":child_dependencies",
 189       "//content/public/app:both",
 190     ]
 191   }
 192
 193   if (cld_version == 0 || cld_version == 2) {
 194     deps += [
 195       "//third_party/cld_2",
 196     ]
 197   }
 198
 199   if (is_mac) {
 200     #['OS=="mac" and component!="shared_library"', {  TODO(GYP)
 201     #  'includes': [ 'chrome_dll_bundle.gypi' ],
 202     #}],
 203
 204     # TODO(GYP) Lots of other stuff in the OS=="mac" block.
 205   }
 206 }
 207
 208 # GYP version: chromium_browser_dependencies variable in chrome.gyp
 209 group("browser_dependencies") {
 210   deps = [
 211     "//chrome/browser",
 212     "//chrome/common",
 213     "//sync",
 214   ]
 215   if (!is_ios) {
 216     deps += [
 217       "//ppapi:ppapi_host",
 218     ]
 219   }
 220
 221   if (enable_basic_printing || enable_print_preview) {
 222     deps += [ "//printing" ]
 223     if (enable_print_preview) {
 224       deps += [ "//chrome/service" ]
 225     }
 226   }
 227 }
 228
 229 # GYP version: chromium_child_dependencies variable in chrome.gyp
 230 group("child_dependencies") {
 231   deps = [
 232     "//chrome/common",
 233     "//sync",
 234   ]
 235   if (!is_ios) {
 236     deps += [
 237       "//chrome/browser/devtools",
 238       "//chrome/plugin",
 239       "//chrome/renderer",
 240       "//chrome/utility",
 241       "//content/public/child",
 242       "//third_party/WebKit/public:blink_devtools_frontend_resources",
 243     ]
 244   }
 245   if (cld_version == 0 || cld_version == 2) {
 246     deps += [
 247       "//third_party/cld_2:cld2_platform_impl",
 248     ]
 249   }
 250 }
 251
 252 if (is_win) {
 253   # TODO(brettw) this duplicates "//chrome/common:version" which applies to
 254   # Linux.
 255   process_version("version_header") {
 256     # TODO(brettW) this should have more reduced visibility, but chrome/browser
 257     # currently depends on this.
 258     #visibility = [ ":*" ]
 259     source = "version.h.in"
 260     # TODO(brettw) this should move to $target_gen_dir/version.h and
 261     # source files including it should reference it via "chrome/version.h"
 262     output = "$root_gen_dir/version.h"
 263   }
 264 }
 265
 266 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 267 group("resources") {
 268   deps = [
 269     # Note: GYP lists some dependencies in addition to these actions. However,
 270     # these are just dependencies for the actions themselves, which our actions
 271     # list individually when needed.
 272     "//chrome/browser:resources",
 273     "//chrome/common:resources",
 274     "//chrome/renderer:resources",
 275   ]
 276
 277   if (enable_extensions) {
 278     deps += [ "//chrome/common:extensions_api_resources" ]
 279   }
 280 }
 281
 282 # GYP version: chrome/chrome_resources.gyp:chrome_extra_resources
 283 group("extra_resources") {
 284   deps = [
 285     "//chrome/browser/resources:invalidations_resources",
 286     "//chrome/browser/resources:memory_internals_resources",
 287     "//chrome/browser/resources:net_internals_resources",
 288     "//chrome/browser/resources:password_manager_internals_resources",
 289     "//chrome/browser/resources:signin_internals_resources",
 290     "//chrome/browser/resources:sync_internals_resources",
 291     "//chrome/browser/resources:translate_internals_resources",
 292   ]
 293   if (!is_ios) {
 294     deps += [
 295       "//chrome/browser/resources:component_extension_resources",
 296       "//chrome/browser/resources:options_resources",
 297     ]
 298   }
 299
 300   if (enable_chromevox_next) {
 301     deps += [
 302       #'browser/resources/chromeos/chromevox2/chromevox.gyp:chromevox2',  TODO(GYP)
 303     ]
 304   } else {
 305     deps += [
 306       #'browser/resources/chromeos/chromevox/chromevox.gyp:chromevox',  TODO(GYP)
 307     ]
 308   }
 309
 310   if (enable_extensions) {
 311     deps += [
 312       "//chrome/browser/resources:quota_internals_resources",
 313       "//chrome/browser/resources:sync_file_system_internals_resources",
 314     ]
 315   }
 316 }
 317
 318 group("packed_resources") {
 319   deps = [
 320     ":repack_locales_pack",
 321     ":repack_pseudo_locales_pack",
 322     ":repack_chrome_100_percent",
 323   ]
 324
 325   # TODO(GYP) if (is_chrome_branded) {
 326   # ... copy default_apps from default_apps_list
 327
 328   if (enable_hidpi) {
 329     deps += [ ":repack_chrome_200_percent" ]
 330   }
 331 }
 332
 333 repack("packed_extra_resources") {
 334   visibility = [ "./*" ]
 335   sources = [
 336     "$root_gen_dir/chrome/browser_resources.pak",
 337     "$root_gen_dir/chrome/chrome_unscaled_resources.pak",
 338     "$root_gen_dir/chrome/common_resources.pak",
 339     "$root_gen_dir/chrome/invalidations_resources.pak",
 340     "$root_gen_dir/chrome/memory_internals_resources.pak",
 341     "$root_gen_dir/chrome/net_internals_resources.pak",
 342     "$root_gen_dir/chrome/password_manager_internals_resources.pak",
 343     "$root_gen_dir/chrome/signin_internals_resources.pak",
 344     "$root_gen_dir/chrome/sync_internals_resources.pak",
 345     "$root_gen_dir/chrome/translate_internals_resources.pak",
 346     "$root_gen_dir/components/components_resources.pak",
 347     "$root_gen_dir/net/net_resources.pak",
 348     "$root_gen_dir/ui/resources/webui_resources.pak",
 349   ]
 350   deps = [
 351     "//chrome/browser:resources",
 352     "//chrome/app/theme:chrome_unscaled_resources",
 353     "//chrome/common:resources",
 354     "//chrome/browser/resources:invalidations_resources",
 355     "//chrome/browser/resources:memory_internals_resources",
 356     "//chrome/browser/resources:net_internals_resources",
 357     "//chrome/browser/resources:password_manager_internals_resources",
 358     "//chrome/browser/resources:signin_internals_resources",
 359     "//chrome/browser/resources:sync_internals_resources",
 360     "//chrome/browser/resources:translate_internals_resources",
 361     "//components/resources",
 362     "//net:net_resources",
 363     "//ui/resources",
 364   ]
 365
 366   if (!is_ios && !is_android) {
 367     # New paks should be added here by default.
 368     sources += [
 369       "$root_gen_dir/webkit/devtools_resources.pak",
 370       "$root_gen_dir/chrome/component_extension_resources.pak",
 371       "$root_gen_dir/chrome/options_resources.pak",
 372       "$root_gen_dir/chrome/quota_internals_resources.pak",
 373       "$root_gen_dir/chrome/sync_file_system_internals_resources.pak",
 374     ]
 375     deps += [
 376       "//content/browser/devtools:devtools_resources",
 377       "//chrome/browser/resources:component_extension_resources",
 378       "//chrome/browser/resources:options_resources",
 379       "//chrome/browser/resources:quota_internals_resources",
 380       "//chrome/browser/resources:sync_file_system_internals_resources",
 381     ]
 382   }
 383   if (!is_ios) {
 384     sources += [
 385       "$root_gen_dir/blink/public/resources/blink_resources.pak",
 386       "$root_gen_dir/content/browser/tracing/tracing_resources.pak",
 387       "$root_gen_dir/content/content_resources.pak",
 388     ]
 389   }
 390   if (is_chromeos) {
 391     sources += [ "$root_gen_dir/ui/file_manager/file_manager_resources.pak" ]
 392     deps += [ "//ui/file_manager:resources" ]
 393   }
 394   if (enable_extensions) {
 395     sources += [
 396       "$root_gen_dir/chrome/extensions_api_resources.pak",
 397       "$root_gen_dir/extensions/extensions_renderer_resources.pak",
 398       "$root_gen_dir/extensions/extensions_resources.pak",
 399     ]
 400     deps += [ "//chrome/common:extensions_api_resources" ]
 401   }
 402
 403   # GYP outputs the file in the gen/repack directory. On non-Mac/iOS platforms
 404   # it them copies it. This skipes the copy step and writes it to the final
 405   # location.
 406   if (is_mac || is_ios) {
 407     output = "$root_gen_dir/repack/resources.pak"
 408   } else {
 409     output = "$root_out_dir/resources.pak"
 410   }
 411 }
 412
 413 # GYP version: chrome/chrome_resources.gyp:browser_tests_pak
 414 repack("browser_tests_pak") {
 415   sources = [
 416     "$root_gen_dir/chrome/options_test_resources.pak",
 417   ]
 418   output = "$root_out_dir/browser_tests.pak"
 419 }
 420
 421 # Collects per-locale grit files from many sources into global per-locale files.
 422 chrome_repack_locales("repack_locales_pack") {
 423   visibility = [ ":*" ]
 424
 425   input_locales = locales
 426
 427   if (is_mac) {
 428     output_locales = locales_as_mac_outputs
 429   } else {
 430     output_locales = locales
 431   }
 432 }
 433
 434 chrome_repack_locales("repack_pseudo_locales_pack") {
 435   visibility = [ ":*" ]
 436
 437   input_locales = [ "fake-bidi" ]
 438
 439   if (is_mac) {
 440     output_locales = [ "fake_bidi" ]  # Mac uses underscores.
 441   } else {
 442     output_locales = [ "fake-bidi" ]
 443   }
 444 }
 445
 446 # Generates a rule to repack a set of resources, substituting a given string
 447 # in for the percentage (e.g. "100", "200"). It generates the repacked files in
 448 # the "gen" directory, and then introduces a copy rule to copy it to the root
 449 # build directory.
 450 #
 451 # It's not clear why this two-step dance is necessary as opposed to just
 452 # generating the file in the destination. However, this is what the GYP build
 453 # does, and for maintenance purposes, this keeps the same files in the same
 454 # place between the two builds when possible.
 455 #
 456 # Argument:
 457 #   percent [required]
 458 #      String to substitute for the percentage.
 459 template("chrome_repack_percent") {
 460   percent = invoker.percent
 461
 462   repack_name = "${target_name}_repack"
 463   repack_output_file = "$root_gen_dir/repack/chrome_${percent}_percent.pak"
 464
 465   copy_name = target_name
 466
 467   repack(repack_name) {
 468     visibility = [ ":$copy_name" ]
 469     # All sources should also have deps for completeness.
 470     sources = [
 471       "$root_gen_dir/components/components_resources_${percent}_percent.pak",
 472       "$root_gen_dir/ui/resources/ui_resources_${percent}_percent.pak",
 473       "$root_gen_dir/chrome/renderer_resources_${percent}_percent.pak",
 474       "$root_gen_dir/chrome/theme_resources_${percent}_percent.pak",
 475     ]
 476
 477     deps = [
 478       "//chrome/app/theme:theme_resources",
 479       "//chrome/renderer:resources",
 480       "//components/strings",
 481       "//net:net_resources",
 482     ]
 483
 484     if (!is_ios) {
 485       sources += [
 486         "$root_gen_dir/content/app/resources/content_resources_${percent}_percent.pak",
 487       ]
 488       deps += [ "//content:resources" ]
 489     }
 490     if (use_ash) {
 491       sources += [ "$root_gen_dir/ash/resources/ash_resources_${percent}_percent.pak" ]
 492       deps += [ "//ash/resources" ]
 493     }
 494     if (use_athena) {
 495       sources += [
 496         "$root_gen_dir/athena/resources/athena_resources_${percent}_percent.pak",
 497       ]
 498       deps += [ "//athena/resources" ]
 499     }
 500     if (is_chromeos) {
 501       sources += [
 502         "$root_gen_dir/ui/chromeos/resources/ui_chromeos_resources_${percent}_percent.pak",
 503       ]
 504       deps += [ "//ui/chromeos/resources" ]
 505     }
 506     if (enable_extensions) {
 507       sources += [
 508         "$root_gen_dir/extensions/extensions_browser_resources_${percent}_percent.pak",
 509       ]
 510     }
 511
 512     output = repack_output_file
 513   }
 514
 515   copy(copy_name) {
 516     visibility = [ ":*" ]
 517     deps = [ ":$repack_name" ]
 518     sources = [ repack_output_file ]
 519     outputs = [ "$root_build_dir/chrome_${percent}_percent.pak" ]
 520   }
 521 }
 522
 523 chrome_repack_percent("repack_chrome_100_percent") {
 524   percent = "100"
 525 }
 526
 527 if (enable_hidpi) {
 528   chrome_repack_percent("repack_chrome_200_percent") {
 529     percent = "200"
 530   }
 531 }
 532
 533 # GYP version: chrome/chrome_resources.gyp:chrome_strings
 534 group("strings") {
 535   deps = [
 536     "//chrome/app:chromium_strings",
 537     "//chrome/app:generated_resources",
 538     "//chrome/app:google_chrome_strings",
 539     "//chrome/app/resources:locale_settings",
 540   ]
 541 }
 542
 543 if (is_android) {
 544
 545 # GYP: //chrome/chrome.gyp:content_setting_java
 546 java_cpp_enum("content_setting_javagen") {
 547   sources = [
 548     "../components/content_settings/core/common/content_settings.h"
 549   ]
 550   outputs = [
 551     "org/chromium/chrome/browser/ContentSetting.java",
 552   ]
 553 }
 554
 555 # GYP: //chrome/chrome.gyp:content_settings_type_java
 556 java_cpp_enum("content_settings_type_javagen") {
 557   sources = [
 558     "../components/content_settings/core/common/content_settings_types.h"
 559   ]
 560   outputs = [
 561     "org/chromium/chrome/browser/ContentSettingsType.java",
 562   ]
 563 }
 564
 565 # GYP: //chrome/chrome.gyp:page_info_connection_type_java
 566 java_cpp_enum("page_info_connection_type_javagen") {
 567   sources = [
 568     "browser/ui/android/website_settings_popup_android.h"
 569   ]
 570   outputs = [
 571     "org/chromium/chrome/browser/PageInfoConnectionType.java",
 572   ]
 573 }
 574
 575 # GYP: //chrome/chrome_android.gypi:chrome_android_core
 576 static_library("chrome_android_core") {
 577   sources = [
 578     "app/android/chrome_android_initializer.cc",
 579     "app/android/chrome_android_initializer.h",
 580     "app/android/chrome_main_delegate_android.cc",
 581     "app/android/chrome_main_delegate_android.h",
 582     "app/chrome_main_delegate.cc",
 583     "app/chrome_main_delegate.h",
 584   ]
 585
 586   include_dirs = [
 587     android_ndk_include_dir,
 588   ]
 589
 590   libs = [
 591     "android",
 592     "jnigraphics",
 593   ]
 594
 595   deps = [
 596     "//chrome/browser",
 597     "//chrome/browser/ui",
 598     "//chrome/plugin",
 599     "//chrome/renderer",
 600     "//chrome/utility",
 601     "//components/enhanced_bookmarks",
 602     "//content/public/app:browser",
 603   ]
 604 }
 605
 606 }