ui/resources/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//tools/grit/grit_rule.gni")
   6 import("//tools/grit/repack.gni")
   7
   8 declare_args() {
   9   # Enable to include Polymer 0.8 in the binary.
  10   enable_polymer_v08 = false
  11 }
  12
  13 # GYP version: ui/resources/ui_resources.gyp:ui_resources
  14 group("resources") {
  15   deps = [
  16     ":ui_resources_grd",
  17     ":ui_unscaled_resources_grd",
  18     ":webui_resources_grd",
  19   ]
  20 }
  21
  22 grit("ui_resources_grd") {
  23   source = "ui_resources.grd"
  24   outputs = [
  25     "grit/ui_resources.h",
  26     "grit/ui_resources_map.cc",
  27     "grit/ui_resources_map.h",
  28     "ui_resources_100_percent.pak",
  29     "ui_resources_200_percent.pak",
  30     "ui_resources_300_percent.pak",
  31   ]
  32 }
  33
  34 grit("ui_unscaled_resources_grd") {
  35   source = "ui_unscaled_resources.grd"
  36   use_qualified_include = true
  37   outputs = [
  38     "grit/ui_unscaled_resources.h",
  39     "ui_unscaled_resources.rc",
  40   ]
  41 }
  42
  43 webui_grit_defines = []
  44 if (enable_polymer_v08) {
  45   webui_grit_defines += [ "enable_polymer_v08" ]
  46 }
  47
  48 grit("webui_resources_grd") {
  49   source = "../webui/resources/webui_resources.grd"
  50   outputs = [
  51     "grit/webui_resources.h",
  52     "grit/webui_resources_map.cc",
  53     "grit/webui_resources_map.h",
  54     "webui_resources.pak",
  55   ]
  56   defines = webui_grit_defines
  57 }
  58
  59 if (!is_mac) {
  60   copy("copy_ui_resources_100_percent") {
  61     sources = [
  62       "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
  63     ]
  64     outputs = [
  65       "$root_out_dir/ui_resources_100_percent.pak",
  66     ]
  67     deps = [
  68       "//ui/resources",
  69     ]
  70   }
  71 }
  72
  73 # On iOS and Mac the string resources need to go into a locale subfolder, which
  74 # introduces an extra dependency.
  75 #
  76 # GYP version: ui/resources/ui_resources.gyp:ui_test_pak
  77 #              (copy_ui_test_pak action)
  78 if (is_ios || is_mac) {
  79   group("ui_test_pak") {
  80     deps = [
  81       ":repack_ui_test_pak",
  82       ":repack_ui_test_mac_locale_pack",
  83     ]
  84   }
  85 } else {
  86   copy("ui_test_pak") {
  87     sources = [
  88       "$root_out_dir/ui_test.pak",
  89     ]
  90     outputs = [
  91       "$root_out_dir/ui/en-US.pak",
  92     ]
  93     deps = [
  94       ":repack_ui_test_pak",
  95     ]
  96   }
  97 }
  98
  99 # GYP version: ui/resources/ui_resources.gyp:ui_test_pak
 100 repack("repack_ui_test_pak") {
 101   # Depend on ui_test_pak instead of this one.
 102   visibility = [ ":ui_test_pak" ]
 103
 104   sources = [
 105     "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
 106     "$root_gen_dir/ui/resources/webui_resources.pak",
 107     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
 108     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
 109   ]
 110
 111   if (is_chromeos) {
 112     sources += [
 113       "$root_gen_dir/ui/chromeos/resources/ui_chromeos_resources_100_percent.pak",
 114       "$root_gen_dir/ui/chromeos/strings/ui_chromeos_strings_en-US.pak",
 115     ]
 116   }
 117
 118   output = "$root_out_dir/ui_test.pak"
 119
 120   deps = [
 121     "//ui/resources",
 122     "//ui/strings",
 123   ]
 124
 125   if (!is_mac) {
 126     deps += [ ":copy_ui_resources_100_percent" ]
 127   }
 128
 129   if (is_chromeos) {
 130     deps += [
 131       "//ui/chromeos/resources",
 132       "//ui/chromeos/strings",
 133     ]
 134   }
 135 }
 136
 137 # Repack just the strings for the framework locales on Mac and iOS. This
 138 # emulates repack_locales.py, but just for en-US. Note ui_test.pak is not simply
 139 # copied, because it causes leaks from allocations within system libraries when
 140 # trying to load non-string resources. http://crbug.com/413034.
 141 repack("repack_ui_test_mac_locale_pack") {
 142   visibility = [
 143     ":ui_test_pak",
 144     "//:gn_visibility",  # TODO(GYP): this shouldn't be necessary.
 145   ]
 146
 147   sources = [
 148     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
 149     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
 150   ]
 151
 152   output = "$root_out_dir/ui/en.lproj/locale.pak"
 153
 154   deps = [
 155     "//ui/strings",
 156   ]
 157 }