ipc/BUILD.gn

   1 # Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//testing/test.gni")
   6
   7 component("ipc") {
   8   sources = [
   9     "attachment_broker.cc",
  10     "attachment_broker.h",
  11     "attachment_broker_messages.h",
  12     "attachment_broker_privileged.cc",
  13     "attachment_broker_privileged.h",
  14     "attachment_broker_privileged_win.cc",
  15     "attachment_broker_privileged_win.h",
  16     "attachment_broker_unprivileged.cc",
  17     "attachment_broker_unprivileged.h",
  18     "attachment_broker_unprivileged_win.cc",
  19     "attachment_broker_unprivileged_win.h",
  20     "brokerable_attachment.cc",
  21     "brokerable_attachment.h",
  22     "handle_attachment_win.cc",
  23     "handle_attachment_win.h",
  24     "handle_win.cc",
  25     "handle_win.h",
  26     "ipc_channel.cc",
  27     "ipc_channel.h",
  28     "ipc_channel_common.cc",
  29     "ipc_channel_factory.cc",
  30     "ipc_channel_factory.h",
  31     "ipc_channel_handle.h",
  32     "ipc_channel_nacl.cc",
  33     "ipc_channel_nacl.h",
  34     "ipc_channel_posix.cc",
  35     "ipc_channel_posix.h",
  36     "ipc_channel_proxy.cc",
  37     "ipc_channel_proxy.h",
  38     "ipc_channel_reader.cc",
  39     "ipc_channel_reader.h",
  40     "ipc_channel_win.cc",
  41     "ipc_channel_win.h",
  42     "ipc_descriptors.h",
  43     "ipc_endpoint.cc",
  44     "ipc_endpoint.h",
  45     "ipc_export.h",
  46     "ipc_handle_win.cc",
  47     "ipc_handle_win.h",
  48     "ipc_listener.h",
  49     "ipc_logging.cc",
  50     "ipc_logging.h",
  51     "ipc_message.cc",
  52     "ipc_message.h",
  53     "ipc_message_attachment.cc",
  54     "ipc_message_attachment.h",
  55     "ipc_message_attachment_set.cc",
  56     "ipc_message_attachment_set.h",
  57     "ipc_message_generator.cc",
  58     "ipc_message_generator.h",
  59     "ipc_message_macros.h",
  60     "ipc_message_start.h",
  61     "ipc_message_utils.cc",
  62     "ipc_message_utils.h",
  63     "ipc_param_traits.h",
  64     "ipc_platform_file.cc",
  65     "ipc_platform_file.h",
  66     "ipc_platform_file_attachment_posix.cc",
  67     "ipc_platform_file_attachment_posix.h",
  68     "ipc_sender.h",
  69     "ipc_switches.cc",
  70     "ipc_switches.h",
  71     "ipc_sync_channel.cc",
  72     "ipc_sync_channel.h",
  73     "ipc_sync_message.cc",
  74     "ipc_sync_message.h",
  75     "ipc_sync_message_filter.cc",
  76     "ipc_sync_message_filter.h",
  77     "message_filter.cc",
  78     "message_filter.h",
  79     "message_filter_router.cc",
  80     "message_filter_router.h",
  81     "param_traits_log_macros.h",
  82     "param_traits_macros.h",
  83     "param_traits_read_macros.h",
  84     "param_traits_write_macros.h",
  85     "struct_constructor_macros.h",
  86     "struct_destructor_macros.h",
  87     "unix_domain_socket_util.cc",
  88     "unix_domain_socket_util.h",
  89   ]
  90
  91   if (is_nacl) {
  92     sources -= [
  93       "ipc_channel.cc",
  94       "ipc_channel_posix.cc",
  95       "unix_domain_socket_util.cc",
  96     ]
  97   } else {
  98     sources -= [
  99       "ipc_channel_nacl.cc",
 100       "ipc_channel_nacl.h",
 101     ]
 102   }
 103
 104   if (is_win || is_ios) {
 105     sources -= [ "unix_domain_socket_util.cc" ]
 106   }
 107
 108   defines = [ "IPC_IMPLEMENTATION" ]
 109
 110   deps = [
 111     "//base",
 112
 113     # TODO(viettrungluu): Needed for base/lazy_instance.h, which is suspect.
 114     "//base/third_party/dynamic_annotations",
 115     "//crypto:crypto",
 116   ]
 117 }
 118
 119 # TODO(GYP): crbug.com/360936. Get this to build and run on Android.
 120 if (!is_android) {
 121   group("ipc_tests_run") {
 122     testonly = true
 123     deps = [
 124       ":ipc_tests",
 125     ]
 126   }
 127
 128   test("ipc_tests") {
 129     sources = [
 130       "attachment_broker_privileged_win_unittest.cc",
 131       "attachment_broker_unprivileged_win_unittest.cc",
 132       "ipc_channel_posix_unittest.cc",
 133       "ipc_channel_reader_unittest.cc",
 134       "ipc_channel_unittest.cc",
 135       "ipc_fuzzing_tests.cc",
 136       "ipc_message_attachment_set_posix_unittest.cc",
 137       "ipc_message_unittest.cc",
 138       "ipc_message_utils_unittest.cc",
 139       "ipc_send_fds_test.cc",
 140       "ipc_sync_channel_unittest.cc",
 141       "ipc_sync_message_unittest.cc",
 142       "ipc_sync_message_unittest.h",
 143       "sync_socket_unittest.cc",
 144       "unix_domain_socket_util_unittest.cc",
 145     ]
 146
 147     if (is_win || is_ios) {
 148       sources -= [ "unix_domain_socket_util_unittest.cc" ]
 149     }
 150
 151     # TODO(brettw) hook up Android testing.
 152     #if (is_android && gtest_target_type == "shared_library") {
 153     #  deps += "/testing/android/native_test.gyp:native_testNative_code"
 154     #}
 155
 156     # TODO(brettw) hook up tcmalloc to this target.
 157     #if (is_posix && !is_mac && !is_android) {
 158     #  if (use_allocator!="none") {
 159     #    deps += "/base/allocator"
 160     #  }
 161     #}
 162
 163     deps = [
 164       ":ipc",
 165       ":test_support",
 166       "//base",
 167       "//base:i18n",
 168       "//base/test:run_all_unittests",
 169       "//base/test:test_support",
 170       "//testing/gtest",
 171     ]
 172   }
 173
 174   test("ipc_perftests") {
 175     sources = [
 176       "ipc_perftests.cc",
 177     ]
 178
 179     # TODO(brettw) hook up Android testing.
 180     #if (is_android && gtest_target_type == "shared_library") {
 181     #  deps += "/testing/android/native_test.gyp:native_testNative_code"
 182     #}
 183
 184     # TODO(brettw) hook up tcmalloc to this target.
 185     #if (is_posix && !is_mac && !is_android) {
 186     #  if (use_allocator!="none") {
 187     #    deps += "//base/allocator"
 188     #  }
 189     #}
 190     deps = [
 191       ":ipc",
 192       ":test_support",
 193       "//base",
 194       "//base:i18n",
 195       "//base/test:test_support",
 196       "//base/test:test_support_perf",
 197       "//testing/gtest",
 198     ]
 199   }
 200 }
 201
 202 static_library("test_support") {
 203   testonly = true
 204   sources = [
 205     "ipc_multiprocess_test.cc",
 206     "ipc_multiprocess_test.h",
 207     "ipc_perftest_support.cc",
 208     "ipc_perftest_support.h",
 209     "ipc_security_test_util.cc",
 210     "ipc_security_test_util.h",
 211     "ipc_test_base.cc",
 212     "ipc_test_base.h",
 213     "ipc_test_channel_listener.cc",
 214     "ipc_test_channel_listener.h",
 215     "ipc_test_sink.cc",
 216     "ipc_test_sink.h",
 217   ]
 218   deps = [
 219     ":ipc",
 220     "//base",
 221     "//base/test:test_support",
 222     "//testing/gtest",
 223   ]
 224 }