build/config/arm.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 if (cpu_arch == "arm") {
   6   declare_args() {
   7     # Version of the ARM processor when compiling on ARM. Ignored on non-ARM
   8     # platforms.
   9     arm_version = 7
  10
  11     # The ARM floating point mode. This is either the string "hard", "soft", or
  12     # "softfp". An empty string means to use the default one for the
  13     # arm_version.
  14     arm_float_abi = ""
  15
  16     # The ARM variant-specific tuning mode. This will be a string like "armv6"
  17     # or "cortex-a15". An empty string means to use the default for the
  18     # arm_version.
  19     arm_tune = ""
  20
  21     # Whether to use the neon FPU instruction set or not.
  22     arm_use_neon = true
  23
  24     # Whether to enable optional NEON code paths.
  25     arm_optionally_use_neon = false
  26
  27     if (is_android) {
  28       arm_use_neon = false
  29       arm_optionally_use_neon = true
  30     }
  31   }
  32
  33   assert(arm_float_abi == "" || arm_float_abi == "hard" ||
  34          arm_float_abi == "soft" || arm_float_abi == "softfp")
  35
  36   if (arm_version == 6) {
  37     arm_arch = "armv6"
  38     if (arm_tune != "") {
  39       arm_tune = ""
  40     }
  41     if (arm_float_abi == "") {
  42       arm_float_abi = "softfp"
  43     }
  44     arm_fpu = "vfp"
  45
  46     # Thumb is a reduced instruction set available on some ARM processors that
  47     # has increased code density.
  48     arm_use_thumb = false
  49   } else if (arm_version == 7) {
  50     arm_arch = "armv7-a"
  51     if (arm_tune == "") {
  52       arm_tune = "generic-armv7-a"
  53     }
  54
  55     if (arm_float_abi == "") {
  56       arm_float_abi = "softfp"
  57     }
  58
  59     arm_use_thumb = true
  60
  61     if (arm_use_neon) {
  62       arm_fpu = "neon"
  63     } else {
  64       arm_fpu = "vfpv3-d16"
  65     }
  66   }
  67 }