chrome/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/crypto.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/ui.gni")
   9 import("//third_party/protobuf/proto_library.gni")
  10
  11 # //build/config/android/rules.gni imports //tools/grit/grit_rule.gni, which
  12 # produces a conflict for the "grit" template so we have to only include one.
  13 if (is_android) {
  14   import("//build/config/android/rules.gni")
  15 } else {
  16   import("//tools/grit/grit_rule.gni")
  17 }
  18 if (is_desktop_linux) {
  19   import("//build/config/linux/pkg_config.gni")
  20 }
  21
  22 declare_args() {
  23   # 'Ok Google' hotwording is disabled by default. Set to true to enable. (This
  24   # will download a closed-source NaCl module at startup.) Chrome-branded
  25   # ChromeOS builds have this enabled by default.
  26   enable_hotwording = is_chrome_branded && is_chromeos
  27 }
  28
  29 about_credits_file = "$target_gen_dir/about_credits.html"
  30 additional_modules_list_file =
  31     "$root_gen_dir/chrome/browser/internal/additional_modules_list.txt"
  32
  33 gypi_values = exec_script("//build/gypi_to_gn.py",
  34                           [ rebase_path("../chrome_browser.gypi") ],
  35                           "scope",
  36                           [ "../chrome_browser.gypi" ])
  37
  38 if (is_desktop_linux) {
  39   # Gnome-keyring is normally dynamically loaded. The gnome_keyring config
  40   # will set this up.
  41   pkg_config("gnome_keyring") {
  42     packages = [ "gnome-keyring-1" ]
  43     defines = [
  44       "USE_GNOME_KEYRING",
  45       "DLOPEN_GNOME_KEYRING",
  46     ]
  47     ignore_libs = true
  48   }
  49
  50   # If you want to link gnome-keyring directly (use only for unit tests)
  51   # ADDITIONALLY add this config on top of ":gnome_keyring". pkg-config is a
  52   # bit slow, so prefer not to run it again. In practice, gnome-keyring's libs
  53   # are just itself and common gnome ones we link already, so we can get away
  54   # with additionally just coding the library name here.
  55   config("gnome_keyring_direct") {
  56     libs = [ "gnome-keyring" ]
  57   }
  58 }
  59
  60 source_set("browser") {
  61   configs += [
  62     "//build/config/compiler:wexit_time_destructors",
  63     "//build/config:precompiled_headers",
  64     "//third_party/WebKit/public:debug_devtools",
  65   ]
  66   defines = []
  67   sources = []
  68   libs = []
  69   ldflags = []
  70
  71   # iOS/non-iOS shared deps. New dependencies should generally be added in the
  72   # non-iOS deps below.
  73   public_deps = [
  74     "//components/autofill/core/browser",
  75     "//content/public/browser",
  76     "//sql",
  77     "//sync",
  78   ]
  79   deps = [
  80     "//base/allocator",
  81     "//chrome:extra_resources",
  82     "//chrome:resources",
  83     "//chrome:strings",
  84     "//chrome/app:generated_resources_map",
  85     "//chrome/app/resources:platform_locale_settings",
  86     "//chrome/app/theme:theme_resources",
  87     "//chrome/browser/net:encrypted_cert_logger_proto",
  88     "//chrome/browser/net:probe_message_proto",
  89     "//chrome/browser/ssl:cert_logger_proto",
  90     "//chrome/browser/ui",
  91     "//chrome/common",
  92     "//chrome/common/net",
  93     "//components/autofill/core/browser",
  94     "//components/bookmarks/browser",
  95     "//components/bookmarks/managed",
  96     "//components/captive_portal",
  97     "//components/cloud_devices/common",
  98     "//components/component_updater",
  99     "//components/content_settings/content/common",
 100     "//components/content_settings/core/browser",
 101     "//components/content_settings/core/common",
 102     "//components/crx_file",
 103     "//components/data_reduction_proxy/core/browser",
 104     "//components/device_event_log",
 105     "//components/domain_reliability",
 106     "//components/enhanced_bookmarks",
 107     "//components/favicon/core",
 108     "//components/favicon_base",
 109     "//components/gcm_driver",
 110     "//components/gcm_driver/instance_id",
 111     "//components/google/core/browser",
 112     "//components/guest_view/browser",
 113     "//components/handoff",
 114     "//components/history/core/browser",
 115     "//components/history/core/common",
 116     "//components/infobars/core",
 117     "//components/invalidation/impl",
 118     "//components/metrics:gpu",
 119     "//components/metrics:net",
 120     "//components/metrics:profiler",
 121     "//components/metrics/proto:proto",
 122     "//components/mime_util",
 123     "//components/navigation_metrics",
 124     "//components/network_time",
 125     "//components/offline_pages",
 126     "//components/omnibox/browser",
 127     "//components/os_crypt",
 128     "//components/packed_ct_ev_whitelist",
 129     "//components/password_manager/core/browser",
 130     "//components/password_manager/core/common",
 131     "//components/policy:policy_component",
 132     "//components/proxy_config",
 133     "//components/query_parser",
 134     "//components/rappor",
 135     "//components/renderer_context_menu",
 136     "//components/search",
 137     "//components/search_engines",
 138     "//components/search_provider_logos",
 139     "//components/security_interstitials/core",
 140     "//components/signin/core/browser",
 141     "//components/startup_metric_utils",
 142     "//components/strings",
 143     "//components/suggestions",
 144     "//components/sync_driver",
 145     "//components/translate/core/browser",
 146     "//components/translate/core/common",
 147     "//components/ui/zoom:ui_zoom",
 148     "//components/undo",
 149     "//components/update_client",
 150     "//components/url_formatter",
 151     "//components/user_prefs",
 152     "//components/user_prefs/tracked:user_prefs_tracked",
 153     "//components/variations",
 154     "//components/variations/net",
 155     "//components/webdata/common",
 156     "//components/webdata_services",
 157     "//components/web_resource",
 158     "//content/public/browser",
 159     "//content/public/common",
 160     "//courgette:courgette_lib",
 161     "//crypto",
 162     "//google_apis",
 163     "//gpu/config",
 164     "//skia",
 165     "//sql",
 166     "//sync",
 167     "//third_party/cacheinvalidation",
 168     "//third_party/icu",
 169     "//third_party/libxml",
 170     "//third_party/libjingle",
 171     "//third_party/widevine/cdm:version_h",
 172     "//third_party/zlib",
 173     "//third_party/zlib:minizip",
 174     "//third_party/zlib:zip",
 175     "//ui/base",
 176     "//ui/events:events_base",
 177     "//ui/gfx",
 178     "//ui/gfx/geometry",
 179     "//ui/message_center",
 180     "//ui/shell_dialogs",
 181     "//ui/strings",
 182     "//ui/resources",
 183   ]
 184
 185   sources +=
 186       rebase_path(gypi_values.chrome_browser_undo_sources, ".", "//chrome")
 187
 188   if (!is_ios) {
 189     sources +=
 190         rebase_path(gypi_values.chrome_browser_non_ios_sources, ".", "//chrome")
 191     sources += rebase_path(gypi_values.chrome_browser_autocomplete_sources,
 192                            ".",
 193                            "//chrome")
 194     sources += rebase_path(gypi_values.chrome_browser_bookmark_sources,
 195                            ".",
 196                            "//chrome")
 197     sources += rebase_path(gypi_values.chrome_browser_browser_process_sources,
 198                            ".",
 199                            "//chrome")
 200     sources += rebase_path(gypi_values.chrome_browser_content_settings_sources,
 201                            ".",
 202                            "//chrome")
 203     sources += rebase_path(gypi_values.chrome_browser_engagement_sources,
 204                            ".",
 205                            "//chrome")
 206     sources +=
 207         rebase_path(gypi_values.chrome_browser_favicon_sources, ".", "//chrome")
 208     sources +=
 209         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 210     sources +=
 211         rebase_path(gypi_values.chrome_browser_history_sources, ".", "//chrome")
 212     sources +=
 213         rebase_path(gypi_values.chrome_browser_metrics_sources, ".", "//chrome")
 214     sources +=
 215         rebase_path(gypi_values.chrome_browser_net_sources, ".", "//chrome")
 216     sources += rebase_path(gypi_values.chrome_browser_password_manager_sources,
 217                            ".",
 218                            "//chrome")
 219     sources += rebase_path(gypi_values.chrome_browser_permissions_sources,
 220                            ".",
 221                            "//chrome")
 222     sources += rebase_path(gypi_values.chrome_browser_predictor_sources,
 223                            ".",
 224                            "//chrome")
 225     sources +=
 226         rebase_path(gypi_values.chrome_browser_pref_sources, ".", "//chrome")
 227     sources += rebase_path(gypi_values.chrome_browser_profiles_sources,
 228                            ".",
 229                            "//chrome")
 230     sources += rebase_path(gypi_values.chrome_browser_search_engines_sources,
 231                            ".",
 232                            "//chrome")
 233     sources += rebase_path(gypi_values.chrome_browser_services_sources,
 234                            ".",
 235                            "//chrome")
 236     sources +=
 237         rebase_path(gypi_values.chrome_browser_session_sources, ".", "//chrome")
 238     sources +=
 239         rebase_path(gypi_values.chrome_browser_signin_sources, ".", "//chrome")
 240     sources +=
 241         rebase_path(gypi_values.chrome_browser_ssl_sources, ".", "//chrome")
 242     sources +=
 243         rebase_path(gypi_values.chrome_browser_sync_sources, ".", "//chrome")
 244     sources += rebase_path(gypi_values.chrome_browser_web_resource_sources,
 245                            ".",
 246                            "//chrome")
 247
 248     deps += [
 249       "//apps",
 250       "//cc",
 251       "//chrome/app:generated_resources_map",
 252       "//chrome/app/theme:theme_resources",
 253       "//chrome/browser/devtools",
 254       "//chrome/browser/resources:component_extension_resources",
 255       "//chrome/installer/util",
 256       "//components/about_handler",
 257       "//components/app_modal",
 258       "//components/autofill/content/browser",
 259       "//components/browsing_data",
 260       "//components/data_reduction_proxy/content/browser",
 261       "//components/devtools_discovery",
 262       "//components/devtools_http_handler",
 263       "//components/dom_distiller/content:content_browser",
 264       "//components/favicon/content",
 265       "//components/history/content/browser",
 266       "//components/keyed_service/content",
 267       "//components/navigation_interception",
 268       "//components/password_manager/content/browser",
 269       "//components/password_manager/sync/browser",
 270       "//components/plugins/common",
 271       "//components/safe_json",
 272       "//components/sessions",
 273       "//components/storage_monitor",
 274       "//components/translate/content/browser",
 275       "//components/upload_list",
 276       "//components/url_matcher",
 277       "//components/visitedlink/browser",
 278       "//components/visitedlink/common",
 279       "//components/web_cache/browser",
 280       "//components/web_modal",
 281       "//content/app/resources",
 282       "//media",
 283       "//mojo/application/public/cpp",
 284       "//mojo/common",
 285       "//mojo/environment:chromium",
 286       "//net:extras",
 287       "//net:net_with_v8",
 288       "//storage/browser",
 289       "//storage/common",
 290       "//third_party/WebKit/public:image_resources",
 291       "//third_party/WebKit/public:resources",
 292       "//third_party/leveldatabase",
 293       "//third_party/libaddressinput",
 294       "//third_party/libyuv",
 295       "//third_party/mojo/src/mojo/edk/system",
 296       "//third_party/mojo/src/mojo/public/cpp/bindings",
 297       "//third_party/mojo/src/mojo/public/js",
 298       "//third_party/re2",
 299       "//third_party/smhasher:cityhash",
 300       "//third_party/webrtc/modules/desktop_capture",
 301       "//ui/base/ime",
 302       "//ui/gl",
 303       "//ui/resources",
 304       "//ui/surface",
 305       "//ui/web_dialogs",
 306       "//v8",
 307     ]
 308
 309     if (toolkit_views) {
 310       deps += [ "//ui/views" ]
 311     }
 312   } else {  # iOS
 313     sources +=
 314         rebase_path(gypi_values.chrome_browser_ios_sources, ".", "//chrome")
 315     sources +=
 316         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 317     deps += [ "//net" ]
 318     libs += [
 319       "CoreTelephony.framework",
 320       "CoreText.framework",
 321       "MobileCoreServices.framework",
 322       "QuartzCore.framework",
 323     ]
 324     ldflags += [
 325       "-weak_framework",
 326       "CoreImage",
 327     ]
 328   }
 329
 330   if (is_win || is_mac) {
 331     sources +=
 332         rebase_path(gypi_values.chrome_browser_win_mac_sources, ".", "//chrome")
 333   }
 334   if (!is_android && !is_ios && !is_chromeos && enable_configuration_policy) {
 335     sources += [
 336       "net/disk_cache_dir_policy_handler.cc",
 337       "net/disk_cache_dir_policy_handler.h",
 338     ]
 339   }
 340   if (!is_android && !is_ios && enable_configuration_policy) {
 341     sources += [
 342       "download/download_dir_policy_handler.cc",
 343       "download/download_dir_policy_handler.h",
 344     ]
 345   }
 346   if (is_mac) {
 347     sources +=
 348         rebase_path(gypi_values.chrome_browser_mac_sources, ".", "//chrome")
 349     deps += [
 350       #"app_shim"  TODO(GYP) bug 512600
 351       #"browser_app_shim"  TODO(GYP) bug 512600
 352     ]
 353   }
 354   if (enable_extensions) {
 355     public_deps += [ "//chrome/browser/extensions" ]
 356     deps += [
 357       "//chrome/browser/sync_file_system/drive_backend:sync_file_system_drive_proto",
 358       "//chrome/common/extensions/api",
 359       "//chrome/common/extensions/api:api_registration",
 360       "//components/drive:drive",
 361       "//components/proximity_auth/ble",
 362       "//components/proximity_auth/cryptauth",
 363       "//extensions/components/javascript_dialog_extensions_client",
 364       "//media/cast:net",
 365     ]
 366     sources += rebase_path(gypi_values.chrome_browser_extensions_sources,
 367                            ".",
 368                            "//chrome")
 369   }
 370   if (enable_background) {
 371     sources += rebase_path(gypi_values.chrome_browser_background_sources,
 372                            ".",
 373                            "//chrome")
 374     if (!use_aura || is_win || is_chromeos) {
 375       sources -= [ "background/background_mode_manager_aura.cc" ]
 376     }
 377   }
 378   if (enable_task_manager) {
 379     sources += rebase_path(gypi_values.chrome_browser_task_manager_sources,
 380                            ".",
 381                            "//chrome")
 382   }
 383   if (enable_spellcheck) {
 384     sources += rebase_path(gypi_values.chrome_browser_spellchecker_sources,
 385                            ".",
 386                            "//chrome")
 387     if (!is_android) {
 388       deps += [ "//third_party/hunspell" ]
 389     }
 390   }
 391   if (enable_nacl) {
 392     sources +=
 393         rebase_path(gypi_values.chrome_browser_nacl_sources, ".", "//chrome")
 394     deps += [ "//components/nacl:nacl_browser" ]
 395   }
 396
 397   if (enable_configuration_policy) {
 398     sources +=
 399         rebase_path(gypi_values.chrome_browser_policy_shared_with_ios_sources,
 400                     ".",
 401                     "//chrome")
 402     deps += [
 403       "//components/policy",
 404       "//components/policy/proto",
 405     ]
 406     if (!is_ios) {
 407       sources += rebase_path(gypi_values.chrome_browser_policy_non_ios_sources,
 408                              ".",
 409                              "//chrome")
 410     }
 411     if (!is_chromeos) {
 412       sources += rebase_path(
 413               gypi_values.chrome_browser_policy_shared_with_ios_not_chromeos_sources,
 414               ".",
 415               "//chrome")
 416     }
 417     if (is_win || is_mac || is_desktop_linux) {
 418       sources += rebase_path(gypi_values.chrome_browser_policy_desktop_sources,
 419                              ".",
 420                              "//chrome")
 421     }
 422     if (is_android || is_ios) {
 423       sources += rebase_path(gypi_values.chrome_browser_policy_mobile_sources,
 424                              ".",
 425                              "//chrome")
 426     } else {
 427       deps += [
 428         "//chrome/browser/policy:path_parser",
 429         "//net:net_browser_services",
 430       ]
 431     }
 432   } else {
 433     # Configuration policy disabled.
 434     sources += rebase_path(gypi_values.chrome_browser_policy_disabled_sources,
 435                            ".",
 436                            "//chrome")
 437   }
 438
 439   if (enable_plugins) {
 440     sources +=
 441         rebase_path(gypi_values.chrome_browser_plugins_sources, ".", "//chrome")
 442     deps += [
 443       "//components/pdf/browser",
 444       "//ppapi/proxy:ipc",
 445       "//third_party/adobe/flash:flapper_version_h",
 446     ]
 447   }
 448   if (safe_browsing_mode != 0) {
 449     sources +=
 450         rebase_path(gypi_values.chrome_browser_safe_browsing_basic_sources,
 451                     ".",
 452                     "//chrome")
 453     deps += [
 454       "//chrome/browser/safe_browsing:chunk_proto",
 455       "//chrome/browser/safe_browsing:metadata_proto",
 456       "//chrome/browser/safe_browsing:report_proto",
 457     ]
 458     if (safe_browsing_mode == 1) {
 459       sources +=
 460           rebase_path(gypi_values.chrome_browser_safe_browsing_full_sources,
 461                       ".",
 462                       "//chrome")
 463       deps += [ "//chrome/common/safe_browsing:proto" ]
 464     } else if (safe_browsing_mode == 3) {
 465       sources += rebase_path(
 466               gypi_values.chrome_browser_safe_browsing_mobile_extended_sources,
 467               ".",
 468               "//chrome")
 469     }
 470   }
 471
 472   if (enable_hotwording) {
 473     defines += [ "ENABLE_HOTWORDING" ]
 474   }
 475
 476   if (is_linux) {
 477     deps += [
 478       "//device/media_transfer_protocol",
 479       "//device/udev_linux",
 480     ]
 481   }
 482   if (is_linux && !is_chromeos) {
 483     deps += [ "//third_party/speech-dispatcher" ]
 484   }
 485
 486   if (is_chromeos) {
 487     sources += rebase_path(gypi_values.chrome_browser_chromeos_sources,
 488                            ".",
 489                            "//chrome")
 490     deps += [ "//chrome/browser/chromeos" ]
 491   } else {
 492     # Non-ChromeOS.
 493     sources += rebase_path(gypi_values.chrome_browser_non_chromeos_sources,
 494                            ".",
 495                            "//chrome")
 496   }
 497
 498   if (is_ios) {
 499     sources -= [
 500       "metrics/signin_status_metrics_provider_base.cc",
 501       "metrics/signin_status_metrics_provider_base.h",
 502     ]
 503   }
 504
 505   if (is_chromeos || is_ios) {
 506     sources -= [
 507       "metrics/signin_status_metrics_provider.cc",
 508       "metrics/signin_status_metrics_provider.h",
 509     ]
 510   }
 511
 512   if (use_cups) {
 513     configs += [ "//printing:cups" ]
 514   }
 515   if (is_desktop_linux) {
 516     sources += rebase_path(gypi_values.chrome_browser_gnome_keyring_sources,
 517                            ".",
 518                            "//chrome")
 519     configs += [ ":gnome_keyring" ]
 520   }
 521   if (is_desktop_linux) {
 522     sources += rebase_path(gypi_values.chrome_browser_libsecret_sources,
 523                            ".",
 524                            "//chrome")
 525     defines += [ "USE_LIBSECRET" ]
 526   }
 527   if (use_aura) {
 528     sources +=
 529         rebase_path(gypi_values.chrome_browser_aura_sources, ".", "//chrome")
 530     deps += [
 531       "//ui/aura",
 532       "//ui/compositor",
 533       "//ui/keyboard",
 534     ]
 535   }
 536   if (ui_compositor_image_transport) {
 537     deps += [ "//ui/gl" ]
 538   }
 539
 540   if (use_ash) {
 541     sources +=
 542         rebase_path(gypi_values.chrome_browser_ash_sources, ".", "//chrome")
 543   }
 544
 545   if (use_x11) {
 546     sources +=
 547         rebase_path(gypi_values.chrome_browser_x11_sources, ".", "//chrome")
 548   } else {
 549     sources -= [ "password_manager/password_store_x.cc" ]
 550   }
 551   if (is_posix && !is_mac && !is_ios) {
 552     sources += [
 553       "//chrome/app/chrome_crash_reporter_client.cc",
 554       "//chrome/app/chrome_crash_reporter_client.h",
 555     ]
 556     deps += [
 557       "//components/crash/app",
 558       "//components/crash/browser",
 559     ]
 560   }
 561   if (use_nss_certs) {
 562     sources +=
 563         rebase_path(gypi_values.chrome_browser_nss_sources, ".", "//chrome")
 564     if (is_chromeos) {
 565       sources -= [ "net/nss_context_linux.cc" ]
 566     }
 567   }
 568   if (enable_notifications) {
 569     sources += rebase_path(gypi_values.chrome_browser_notifications_sources,
 570                            ".",
 571                            "//chrome")
 572     if (!is_android) {
 573       sources += rebase_path(
 574               gypi_values.chrome_browser_notifications_non_android_sources,
 575               ".",
 576               "//chrome")
 577     }
 578   }
 579   if (enable_themes) {
 580     sources +=
 581         rebase_path(gypi_values.chrome_browser_themes_sources, ".", "//chrome")
 582   }
 583
 584   if (enable_basic_printing || enable_print_preview) {
 585     # Some form of printing support.
 586     sources += rebase_path(gypi_values.chrome_browser_printing_basic_sources,
 587                            ".",
 588                            "//chrome")
 589     deps += [
 590       "//printing",
 591       "//components/printing/browser:printing_browser",
 592     ]
 593
 594     if (is_win) {
 595       sources += rebase_path(gypi_values.chrome_browser_printing_emf_sources,
 596                              ".",
 597                              "//chrome")
 598     }
 599     if (enable_print_preview) {
 600       # Full printing on top of the above.
 601       sources += rebase_path(gypi_values.chrome_browser_printing_full_sources,
 602                              ".",
 603                              "//chrome")
 604     } else {
 605       # Partial-only printing support.
 606       sources +=
 607           rebase_path(gypi_values.chrome_browser_printing_basic_only_sources,
 608                       ".",
 609                       "//chrome")
 610     }
 611   }
 612   if (enable_captive_portal_detection) {
 613     sources += rebase_path(gypi_values.chrome_browser_captive_portal_sources,
 614                            ".",
 615                            "//chrome")
 616   }
 617   if (enable_session_service) {
 618     sources += rebase_path(gypi_values.chrome_browser_session_service_sources,
 619                            ".",
 620                            "//chrome")
 621   }
 622
 623   if (!is_android && !is_ios && !is_chromeos) {
 624     sources +=
 625         rebase_path(gypi_values.chrome_browser_desktop_sources, ".", "//chrome")
 626   }
 627
 628   if (is_android || is_ios) {
 629     # Mobile.
 630     sources +=
 631         rebase_path(gypi_values.chrome_browser_mobile_sources, ".", "//chrome")
 632   } else {
 633     # Non-mobile.
 634     sources += rebase_path(gypi_values.chrome_browser_non_mobile_sources,
 635                            ".",
 636                            "//chrome")
 637     deps += [
 638       "//components/feedback",
 639       "//device/core",
 640       "//device/devices_app/public/cpp",
 641       "//device/devices_app/public/cpp:factory",
 642       "//device/usb",
 643     ]
 644   }
 645
 646   if (!is_official_build) {
 647     sources += [
 648       "search/local_files_ntp_source.cc",
 649       "search/local_files_ntp_source.h",
 650     ]
 651   }
 652
 653   if (is_android) {
 654     sources +=
 655         rebase_path(gypi_values.chrome_browser_android_sources, ".", "//chrome")
 656     sources += rebase_path(gypi_values.chrome_browser_bookmark_android_sources,
 657                            ".",
 658                            "//chrome")
 659     deps += [
 660       ":client_discourse_context_proto",
 661       ":delta_file_proto",
 662       ":jni_headers",
 663       "//components/cdm/browser",
 664       "//components/enhanced_bookmarks",
 665       "//components/precache/content",
 666       "//components/precache/core",
 667       "//components/resources:components_resources",
 668       "//components/service_tab_launcher",
 669       "//components/toolbar",
 670       "//components/web_contents_delegate_android",
 671       "//third_party/android_opengl/etc1",
 672       "//third_party/android_tools:cpu_features",
 673       "//third_party/libaddressinput:util",
 674     ]
 675     deps -= [
 676       "//third_party/libaddressinput",
 677       "//components/storage_monitor",
 678       "//components/web_modal",
 679     ]
 680     defines += [ "ENABLE_DATA_REDUCTION_PROXY_DEBUGGING" ]
 681
 682     if (use_seccomp_bpf) {
 683       defines += [ "USE_SECCOMP_BPF" ]
 684       deps += [ "//sandbox/linux:seccomp_bpf" ]
 685     }
 686   }
 687
 688   if (is_mac) {
 689     deps += [
 690       "//third_party/google_toolbox_for_mac",
 691       "//third_party/mozilla",
 692     ]
 693     libs += [
 694       "Accelerate.framework",
 695       "AddressBook.framework",
 696       "AudioUnit.framework",
 697       "DiskArbitration.framework",
 698       "IOKit.framework",
 699       "ImageCaptureCore.framework",
 700       "OpenGL.framework",
 701       "QuartzCore.framework",
 702       "SecurityInterface.framework",
 703     ]
 704   }
 705
 706   if (enable_rlz) {
 707     deps += [ ":rlz" ]
 708   }
 709
 710   # TODO(GYP)
 711   # Temporary fix to break the browser target into smaller chunks so it
 712   # will link with goma builds.
 713   #["OS=="win" and chromium_win_pch==0", {
 714   #  "msvs_shard": 4,
 715   #}],
 716
 717   if (is_win) {
 718     sources +=
 719         rebase_path(gypi_values.chrome_browser_win_sources, ".", "//chrome")
 720     public_deps += [
 721       "//ui/views",
 722       "//ui/views/controls/webview",
 723     ]
 724     deps += [
 725       ":chrome_process_finder",
 726       "//chrome:version_header",
 727       "//chrome/installer/util:strings",
 728       "//chrome_elf",
 729       "//chrome_elf:constants",
 730       "//chrome_elf:dll_hash",
 731       "//components/browser_watcher",
 732       "//components/browser_watcher:browser_watcher_client",
 733       "//google_update",
 734       "//third_party/iaccessible2",
 735       "//third_party/isimpledom",
 736       "//third_party/wtl",
 737       "//ui/metro_viewer",
 738       "//win8:metro_viewer",
 739     ]
 740     libs += [
 741       "credui.lib",
 742       "netapi32.lib",
 743     ]
 744     if (!is_chrome_branded) {
 745       deps -= [ "//google_update" ]
 746       sources -= [
 747         "google/did_run_updater_win.cc",
 748         "google/did_run_updater_win.h",
 749         "google/google_update_win.cc",
 750         "google/google_update_win.h",
 751       ]
 752     }
 753   } else {
 754     # Non-Windows.
 755     sources +=
 756         rebase_path(gypi_values.chrome_browser_non_win_sources, ".", "//chrome")
 757     if (toolkit_views) {
 758       deps += [
 759         "//ui/views",
 760         "//ui/views/controls/webview",
 761       ]
 762     }
 763   }
 764
 765   if (is_linux) {
 766     sources +=
 767         rebase_path(gypi_values.chrome_browser_linux_sources, ".", "//chrome")
 768     if (use_aura) {
 769       configs += [
 770         "//build/config/linux:dbus",
 771         "//build/config/linux:fontconfig",
 772       ]
 773       deps += [ "//dbus" ]
 774     }
 775     if (use_x11) {
 776       configs += [ "//build/config/linux:x11" ]
 777       deps += [ "//ui/gfx/x" ]
 778     }
 779   }
 780
 781   if (is_desktop_linux) {
 782     sources += rebase_path(gypi_values.chrome_browser_linux_desktop_sources,
 783                            ".",
 784                            "//chrome")
 785   }
 786   if (enable_plugin_installation) {
 787     sources +=
 788         rebase_path(gypi_values.chrome_browser_plugin_installation_sources,
 789                     ".",
 790                     "//chrome")
 791   }
 792   if (enable_app_list) {
 793     deps += [ "//ui/app_list" ]
 794   }
 795   if (enable_supervised_users) {
 796     sources += rebase_path(gypi_values.chrome_browser_supervised_user_sources,
 797                            ".",
 798                            "//chrome")
 799   }
 800   if (enable_supervised_users && !is_android && !is_ios) {
 801     sources +=
 802         rebase_path(gypi_values.chrome_browser_supervised_user_legacy_sources,
 803                     ".",
 804                     "//chrome")
 805   }
 806   if (enable_supervised_users && enable_themes) {
 807     sources += rebase_path(
 808             gypi_values.chrome_browser_supervised_user_and_themes_sources,
 809             ".",
 810             "//chrome")
 811   }
 812   if (enable_webrtc) {
 813     sources +=
 814         rebase_path(gypi_values.chrome_browser_webrtc_sources, ".", "//chrome")
 815   }
 816   if (enable_service_discovery) {
 817     sources += rebase_path(gypi_values.chrome_browser_service_discovery_sources,
 818                            ".",
 819                            "//chrome")
 820   }
 821   if (enable_mdns) {
 822     sources +=
 823         rebase_path(gypi_values.chrome_browser_mdns_sources, ".", "//chrome")
 824   }
 825   if (!enable_autofill_dialog || is_android || is_ios) {
 826     sources -= [
 827       "autofill/validation_rules_storage_factory.cc",
 828       "autofill/validation_rules_storage_factory.h",
 829     ]
 830   }
 831   if (enable_wifi_bootstrapping) {
 832     sources +=
 833         rebase_path(gypi_values.chrome_browser_wifi_bootstrapping_sources,
 834                     ".",
 835                     "//chrome")
 836     if (is_win || is_mac) {
 837       # TODO(brettw) as of this writing wifi bootstrapping is set on Windows
 838       # and Mac, so this test is meaningless. Can we merge these lists?
 839       sources += rebase_path(
 840               gypi_values.chrome_browser_wifi_bootstrapping_win_mac_sources,
 841               ".",
 842               "//chrome")
 843     }
 844   }
 845   if (enable_media_router) {
 846     deps += [ "//chrome/browser/media/router" ]
 847   }
 848 }
 849
 850 if (is_android) {
 851   # GYP version: chrome/chrome_browser.gypi:chrome_browser_jni_headers
 852   generate_jni("jni_headers") {
 853     sources =
 854         rebase_path(gypi_values.chrome_browser_jni_sources, ".", "//chrome")
 855     jni_package = "chrome"
 856   }
 857
 858   #GYP: '//chrome/chrome_browser.gypi:client_discourse_context_proto'
 859   proto_library("client_discourse_context_proto") {
 860     sources = [
 861       "android/proto/client_discourse_context.proto",
 862     ]
 863   }
 864
 865   #GYP: '//chrome/chrome_browser.gypi:delta_file_proto'
 866   proto_library("delta_file_proto") {
 867     sources = [
 868       "android/proto/delta_file.proto",
 869     ]
 870   }
 871 }
 872
 873 if (is_win) {
 874   source_set("chrome_process_finder") {
 875     sources = [
 876       "chrome_process_finder_win.cc",
 877       "chrome_process_finder_win.h",
 878     ]
 879     deps = [
 880       "//base",
 881       "//chrome/browser/metro_utils",
 882       "//chrome/common:constants",
 883     ]
 884     if (enable_configuration_policy) {
 885       deps += [ "//chrome/browser/policy:path_parser" ]
 886     }
 887   }
 888 }
 889
 890 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 891 # (generate_browser_resources action)
 892 grit("resources") {
 893   source = "browser_resources.grd"
 894   output_dir = "$root_gen_dir/chrome"
 895   outputs = [
 896     "grit/browser_resources.h",
 897     "browser_resources.pak",
 898   ]
 899
 900   omnibox_mojom_file =
 901       "$root_gen_dir/chrome/browser/ui/webui/omnibox/omnibox.mojom.js"
 902
 903   grit_flags = [
 904     "-E",
 905     "about_credits_file=" + rebase_path(about_credits_file, root_build_dir),
 906     "-E",
 907     "additional_modules_list_file=" +
 908         rebase_path(additional_modules_list_file, root_build_dir),
 909     "-E",
 910     "omnibox_mojom_file=" + rebase_path(omnibox_mojom_file, root_build_dir),
 911   ]
 912
 913   deps = [
 914     ":about_credits",
 915     ":chrome_internal_resources_gen",
 916
 917     # Depend only on the generated mojo bindings since we read the .mojom.js
 918     # file, rather than the whole mojo target which will link the C++ bindings.
 919     "//chrome/browser/ui/webui/omnibox:mojo_bindings__generator",
 920   ]
 921   inputs = [
 922     omnibox_mojom_file,
 923   ]
 924 }
 925
 926 # GYP version: chrome/chrome_resource.gyp:about_credits
 927 action("about_credits") {
 928   script = "//tools/licenses.py"
 929
 930   inputs = [
 931     # This is not a complete list. TODO(phajdan.jr, dbeam): licenses.py needs to
 932     # generate a .d file with all the licenses/credits that about:credits uses.
 933     # Then about:credits will automatically rebuild when one of them changes.
 934     # See: depfile in gn's documentation (gn help depfile).
 935     "resources/about_credits.tmpl",
 936     "resources/about_credits_entry.tmpl",
 937   ]
 938
 939   outputs = [
 940     about_credits_file,
 941   ]
 942
 943   args = [
 944     "credits",
 945     rebase_path(about_credits_file, root_build_dir),
 946   ]
 947 }
 948
 949 # GYP version: chrome/chrome_resource.gyp:chrome_internal_resources_gen
 950 if (is_chrome_branded) {
 951   action("chrome_internal_resources_gen") {
 952     script = "internal/transform_additional_modules_list.py"
 953     sources = [
 954       "internal/resources/additional_modules_list.input",
 955     ]
 956     outputs = [
 957       additional_modules_list_file,
 958     ]
 959     args = rebase_path(sources, root_build_dir) +
 960            rebase_path(outputs, root_build_dir)
 961   }
 962 } else {
 963   group("chrome_internal_resources_gen") {
 964     # Empty placeholder.
 965   }
 966 }
 967
 968 # In GYP this is part of test_support_common.
 969 source_set("test_support") {
 970   testonly = true
 971
 972   # Always include this via the main test support target.
 973   visibility = [ "//chrome/test:test_support" ]
 974
 975   sources = [
 976     "browsing_data/mock_browsing_data_appcache_helper.cc",
 977     "browsing_data/mock_browsing_data_appcache_helper.h",
 978     "browsing_data/mock_browsing_data_channel_id_helper.cc",
 979     "browsing_data/mock_browsing_data_channel_id_helper.h",
 980     "browsing_data/mock_browsing_data_cookie_helper.cc",
 981     "browsing_data/mock_browsing_data_cookie_helper.h",
 982     "browsing_data/mock_browsing_data_database_helper.cc",
 983     "browsing_data/mock_browsing_data_database_helper.h",
 984     "browsing_data/mock_browsing_data_file_system_helper.cc",
 985     "browsing_data/mock_browsing_data_file_system_helper.h",
 986     "browsing_data/mock_browsing_data_flash_lso_helper.cc",
 987     "browsing_data/mock_browsing_data_flash_lso_helper.h",
 988     "browsing_data/mock_browsing_data_indexed_db_helper.cc",
 989     "browsing_data/mock_browsing_data_indexed_db_helper.h",
 990     "browsing_data/mock_browsing_data_local_storage_helper.cc",
 991     "browsing_data/mock_browsing_data_local_storage_helper.h",
 992     "browsing_data/mock_browsing_data_quota_helper.cc",
 993     "browsing_data/mock_browsing_data_quota_helper.h",
 994     "browsing_data/mock_browsing_data_service_worker_helper.cc",
 995     "browsing_data/mock_browsing_data_service_worker_helper.h",
 996     "download/download_test_file_activity_observer.cc",
 997     "download/download_test_file_activity_observer.h",
 998     "download/test_download_shelf.cc",
 999     "download/test_download_shelf.h",
1000     "invalidation/fake_invalidation_service.cc",
1001     "invalidation/fake_invalidation_service.h",
1002     "media/fake_desktop_media_list.cc",
1003     "media/fake_desktop_media_list.h",
1004     "net/dns_probe_test_util.cc",
1005     "net/dns_probe_test_util.h",
1006     "net/url_request_mock_util.cc",
1007     "net/url_request_mock_util.h",
1008     "notifications/notification_test_util.cc",
1009     "notifications/notification_test_util.h",
1010     "password_manager/mock_password_store_service.cc",
1011     "password_manager/mock_password_store_service.h",
1012     "password_manager/null_password_store_service.cc",
1013     "password_manager/null_password_store_service.h",
1014     "password_manager/password_manager_test_base.cc",
1015     "password_manager/password_manager_test_base.h",
1016     "password_manager/test_password_store_service.cc",
1017     "password_manager/test_password_store_service.h",
1018     "prefs/pref_service_mock_factory.cc",
1019     "prefs/pref_service_mock_factory.h",
1020     "profile_resetter/profile_resetter_test_base.cc",
1021     "profile_resetter/profile_resetter_test_base.h",
1022     "search_engines/template_url_service_factory_test_util.cc",
1023     "search_engines/template_url_service_factory_test_util.h",
1024     "search_engines/template_url_service_test_util.cc",
1025     "search_engines/template_url_service_test_util.h",
1026     "sessions/session_restore_test_helper.cc",
1027     "sessions/session_restore_test_helper.h",
1028     "sessions/session_service_test_helper.cc",
1029     "sessions/session_service_test_helper.h",
1030     "signin/fake_account_fetcher_service_builder.cc",
1031     "signin/fake_account_fetcher_service_builder.h",
1032     "signin/fake_gaia_cookie_manager_service.cc",
1033     "signin/fake_gaia_cookie_manager_service.h",
1034     "signin/fake_profile_oauth2_token_service_builder.cc",
1035     "signin/fake_profile_oauth2_token_service_builder.h",
1036     "signin/fake_signin_manager_builder.cc",
1037     "signin/fake_signin_manager_builder.h",
1038     "ssl/ssl_client_auth_requestor_mock.cc",
1039     "ssl/ssl_client_auth_requestor_mock.h",
1040     "sync/profile_sync_components_factory_mock.cc",
1041     "sync/profile_sync_components_factory_mock.h",
1042     "sync/profile_sync_service_mock.cc",
1043     "sync/profile_sync_service_mock.h",
1044     "ui/webui/signin/login_ui_test_utils.cc",
1045     "ui/webui/signin/login_ui_test_utils.h",
1046   ]
1047
1048   configs += [ "//build/config:precompiled_headers" ]
1049
1050   public_deps = [
1051     ":browser",
1052     "//chrome/browser/ui:test_support",
1053   ]
1054   deps = [
1055     "//base:prefs_test_support",
1056     "//chrome/browser",
1057     "//chrome/common",
1058     "//chrome/common/safe_browsing:proto",
1059     "//components/invalidation/impl",
1060     "//components/invalidation/impl:test_support",
1061     "//components/password_manager/core/browser:test_support",
1062     "//components/search_engines:test_support",
1063     "//components/user_prefs/tracked:user_prefs_tracked_test_support",
1064     "//content/test:test_support",
1065     "//chrome/app/theme:theme_resources",
1066     "//net:test_support",
1067     "//skia",
1068     "//testing/gmock",
1069     "//testing/gtest",
1070     "//ui/gfx",
1071   ]
1072
1073   if (!is_ios) {
1074     deps += [
1075       "//components/sessions:test_support",
1076       "//google_apis:test_support",
1077     ]
1078   }
1079
1080   if (enable_extensions) {
1081     sources += [
1082       "extensions/extension_action_test_util.cc",
1083       "extensions/extension_action_test_util.h",
1084     ]
1085     deps += [ "//extensions:test_support" ]
1086   }
1087
1088   if (is_chromeos) {
1089     sources += [
1090       "chromeos/app_mode/fake_cws.cc",
1091       "chromeos/app_mode/fake_cws.h",
1092       "chromeos/file_manager/fake_disk_mount_manager.cc",
1093       "chromeos/file_manager/fake_disk_mount_manager.h",
1094       "chromeos/input_method/mock_candidate_window_controller.cc",
1095       "chromeos/input_method/mock_candidate_window_controller.h",
1096       "chromeos/input_method/mock_input_method_engine.cc",
1097       "chromeos/input_method/mock_input_method_engine.h",
1098       "chromeos/input_method/mock_input_method_manager.cc",
1099       "chromeos/input_method/mock_input_method_manager.h",
1100       "chromeos/login/screens/mock_device_disabled_screen_actor.cc",
1101       "chromeos/login/screens/mock_device_disabled_screen_actor.h",
1102       "chromeos/login/session/user_session_manager_test_api.cc",
1103       "chromeos/login/session/user_session_manager_test_api.h",
1104       "chromeos/login/test/js_checker.cc",
1105       "chromeos/login/test/js_checker.h",
1106       "chromeos/login/test/oobe_screen_waiter.cc",
1107       "chromeos/login/test/oobe_screen_waiter.h",
1108       "chromeos/login/ui/mock_login_display.cc",
1109       "chromeos/login/ui/mock_login_display.h",
1110       "chromeos/login/ui/mock_login_display_host.cc",
1111       "chromeos/login/ui/mock_login_display_host.h",
1112       "chromeos/login/users/avatar/mock_user_image_manager.cc",
1113       "chromeos/login/users/avatar/mock_user_image_manager.h",
1114       "chromeos/login/users/fake_chrome_user_manager.cc",
1115       "chromeos/login/users/fake_chrome_user_manager.h",
1116       "chromeos/login/users/fake_supervised_user_manager.cc",
1117       "chromeos/login/users/fake_supervised_user_manager.h",
1118       "chromeos/login/users/mock_user_manager.cc",
1119       "chromeos/login/users/mock_user_manager.h",
1120       "chromeos/net/network_portal_detector_test_utils.cc",
1121       "chromeos/net/network_portal_detector_test_utils.h",
1122       "chromeos/policy/cloud_external_data_manager_base_test_util.cc",
1123       "chromeos/policy/cloud_external_data_manager_base_test_util.h",
1124       "chromeos/policy/device_policy_builder.cc",
1125       "chromeos/policy/device_policy_builder.h",
1126       "chromeos/policy/fake_consumer_management_service.cc",
1127       "chromeos/policy/fake_consumer_management_service.h",
1128       "chromeos/policy/fake_device_cloud_policy_initializer.cc",
1129       "chromeos/policy/fake_device_cloud_policy_initializer.h",
1130       "chromeos/policy/fake_device_cloud_policy_manager.cc",
1131       "chromeos/policy/fake_device_cloud_policy_manager.h",
1132       "chromeos/policy/stub_enterprise_install_attributes.cc",
1133       "chromeos/policy/stub_enterprise_install_attributes.h",
1134       "chromeos/settings/device_settings_test_helper.cc",
1135       "chromeos/settings/device_settings_test_helper.h",
1136       "chromeos/system/fake_input_device_settings.cc",
1137       "chromeos/system/fake_input_device_settings.h",
1138     ]
1139     configs += [ "//build/config/linux:dbus" ]
1140     deps += [ "//chromeos:test_support" ]
1141   }
1142
1143   if (enable_configuration_policy) {
1144     sources += [
1145       "policy/test/local_policy_test_server.cc",
1146       "policy/test/local_policy_test_server.h",
1147     ]
1148     public_deps += [
1149       "//components/policy:policy_component_test_support",
1150       "//components/policy:test_support",
1151     ]
1152   }
1153
1154   if (safe_browsing_mode == 1) {
1155     sources += [
1156       "extensions/fake_safe_browsing_database_manager.cc",
1157       "extensions/fake_safe_browsing_database_manager.h",
1158     ]
1159   }
1160
1161   if (enable_extensions) {
1162     sources += [
1163       "extensions/api/messaging/native_messaging_test_util.cc",
1164       "extensions/api/messaging/native_messaging_test_util.h",
1165       "extensions/extension_notification_observer.cc",
1166       "extensions/extension_notification_observer.h",
1167       "extensions/mock_extension_special_storage_policy.cc",
1168       "extensions/mock_extension_special_storage_policy.h",
1169       "extensions/test_blacklist.cc",
1170       "extensions/test_blacklist.h",
1171       "extensions/test_blacklist_state_fetcher.cc",
1172       "extensions/test_blacklist_state_fetcher.h",
1173       "extensions/test_extension_dir.cc",
1174       "extensions/test_extension_dir.h",
1175       "extensions/test_extension_environment.cc",
1176       "extensions/test_extension_environment.h",
1177       "extensions/test_extension_prefs.cc",
1178       "extensions/test_extension_prefs.h",
1179       "extensions/test_extension_service.cc",
1180       "extensions/test_extension_service.h",
1181       "extensions/test_extension_system.cc",
1182       "extensions/test_extension_system.h",
1183       "media_galleries/media_galleries_test_util.cc",
1184       "media_galleries/media_galleries_test_util.h",
1185     ]
1186     deps += [
1187       "//components/drive:test_support",
1188       "//components/storage_monitor:test_support",
1189     ]
1190   }
1191
1192   if (enable_mdns) {
1193     sources += [
1194       "local_discovery/test_service_discovery_client.cc",
1195       "local_discovery/test_service_discovery_client.h",
1196     ]
1197   }
1198
1199   if (enable_app_list) {
1200     sources += [
1201       "ui/app_list/test/chrome_app_list_test_support.cc",
1202       "ui/app_list/test/chrome_app_list_test_support.h",
1203       "ui/app_list/test/test_app_list_controller_delegate.cc",
1204       "ui/app_list/test/test_app_list_controller_delegate.h",
1205     ]
1206   }
1207
1208   if (enable_wifi_bootstrapping) {
1209     sources += [
1210       "local_discovery/wifi/mock_wifi_manager.cc",
1211       "local_discovery/wifi/mock_wifi_manager.h",
1212     ]
1213   }
1214 }
1215
1216 if (enable_rlz_support) {
1217   source_set("rlz") {
1218     sources =
1219         rebase_path(gypi_values.chrome_browser_rlz_sources, ".", "//chrome")
1220     deps = [
1221       "//components/google/core/browser",
1222       "//components/omnibox/browser",
1223       "//components/rlz",
1224       "//components/search_engines",
1225       "//rlz:rlz_lib",
1226     ]
1227   }
1228 }