chrome/browser/ui/cocoa/extensions/device_permissions_dialog_controller.mm

   1 // Copyright 2014 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/extensions/device_permissions_dialog_controller.h"
   6
   7 #include "base/bind.h"
   8 #include "base/location.h"
   9 #include "base/single_thread_task_runner.h"
  10 #include "base/thread_task_runner_handle.h"
  11 #include "chrome/browser/extensions/api/chrome_device_permissions_prompt.h"
  12 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_sheet.h"
  13 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_window.h"
  14 #import "chrome/browser/ui/cocoa/extensions/device_permissions_view_controller.h"
  15 #include "device/usb/usb_device.h"
  16
  17 using extensions::DevicePermissionsPrompt;
  18
  19 DevicePermissionsDialogController::DevicePermissionsDialogController(
  20     content::WebContents* web_contents,
  21     DevicePermissionsPrompt::Delegate* delegate,
  22     scoped_refptr<DevicePermissionsPrompt::Prompt> prompt)
  23     : delegate_(delegate), prompt_(prompt) {
  24   view_controller_.reset(
  25       [[DevicePermissionsViewController alloc] initWithDelegate:this
  26                                                          prompt:prompt]);
  27
  28   prompt_->SetObserver(this);
  29
  30   base::scoped_nsobject<NSWindow> window([[ConstrainedWindowCustomWindow alloc]
  31       initWithContentRect:[[view_controller_ view] bounds]]);
  32   [[window contentView] addSubview:[view_controller_ view]];
  33
  34   base::scoped_nsobject<CustomConstrainedWindowSheet> sheet(
  35       [[CustomConstrainedWindowSheet alloc] initWithCustomWindow:window]);
  36   constrained_window_.reset(
  37       new ConstrainedWindowMac(this, web_contents, sheet));
  38 }
  39
  40 DevicePermissionsDialogController::~DevicePermissionsDialogController() {
  41   prompt_->SetObserver(nullptr);
  42 }
  43
  44 void DevicePermissionsDialogController::OnUsbDevicesChosen(
  45     const std::vector<scoped_refptr<device::UsbDevice>>& devices) {
  46   delegate_->OnUsbDevicesChosen(devices);
  47   delegate_ = nullptr;
  48   constrained_window_->CloseWebContentsModalDialog();
  49 }
  50
  51 void DevicePermissionsDialogController::OnDevicesChanged() {
  52   [view_controller_ devicesChanged];
  53 }
  54
  55 void DevicePermissionsDialogController::OnConstrainedWindowClosed(
  56     ConstrainedWindowMac* window) {
  57   if (delegate_) {
  58     std::vector<scoped_refptr<device::UsbDevice>> empty;
  59     delegate_->OnUsbDevicesChosen(empty);
  60   }
  61   base::ThreadTaskRunnerHandle::Get()->DeleteSoon(FROM_HERE, this);
  62 }
  63
  64 void ChromeDevicePermissionsPrompt::ShowDialog() {
  65   // These objects will delete themselves when the dialog closes.
  66   new DevicePermissionsDialogController(web_contents(), delegate(), prompt());
  67 }