skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
  12   import("//build/config/mips.gni")
  13 }
  14
  15 skia_support_gpu = !is_ios
  16 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  17
  18 # The list of Skia defines that are to be set for blink.
  19 gypi_blink_skia_defines =
  20     exec_script("//build/gypi_to_gn.py",
  21                 [
  22                   rebase_path(
  23                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  24                   "--replace=<(skia_include_path)=//third_party/skia/include",
  25                   "--replace=<(skia_src_path)=//third_party/skia/src",
  26                 ],
  27                 "scope",
  28                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  29
  30 # The list of Skia defines that are to be set for chromium.
  31 gypi_skia_defines =
  32     exec_script("//build/gypi_to_gn.py",
  33                 [
  34                   rebase_path(
  35                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  36                   "--replace=<(skia_include_path)=//third_party/skia/include",
  37                   "--replace=<(skia_src_path)=//third_party/skia/src",
  38                 ],
  39                 "scope",
  40                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  41
  42 # The list of Skia core sources that are to be set for chromium.
  43 gypi_skia_core =
  44     exec_script("//build/gypi_to_gn.py",
  45                 [
  46                   rebase_path("//third_party/skia/gyp/core.gypi"),
  47                   "--replace=<(skia_include_path)=//third_party/skia/include",
  48                   "--replace=<(skia_src_path)=//third_party/skia/src",
  49                 ],
  50                 "scope",
  51                 [ "//third_party/skia/gyp/core.gypi" ])
  52
  53 # The list of Skia gpu sources that are to be set for chromium.
  54 if (skia_support_gpu) {
  55   gypi_skia_gpu =
  56       exec_script("//build/gypi_to_gn.py",
  57                   [
  58                     rebase_path("//third_party/skia/gyp/gpu.gypi"),
  59                     "--replace=<(skia_include_path)=//third_party/skia/include",
  60                     "--replace=<(skia_src_path)=//third_party/skia/src",
  61                   ],
  62                   "scope",
  63                   [ "//third_party/skia/gyp/gpu.gypi" ])
  64 }
  65
  66 # The list of Skia pdf sources that are to be set for chromium.
  67 if (skia_support_pdf) {
  68   gypi_skia_pdf =
  69       exec_script("//build/gypi_to_gn.py",
  70                   [
  71                     rebase_path("//third_party/skia/gyp/pdf.gypi"),
  72                     "--replace=<(skia_include_path)=//third_party/skia/include",
  73                     "--replace=<(skia_src_path)=//third_party/skia/src",
  74                   ],
  75                   "scope",
  76                   [ "//third_party/skia/gyp/pdf.gypi" ])
  77 }
  78
  79 # The list of Skia effects that are to be set for chromium.
  80 gypi_skia_effects =
  81     exec_script("//build/gypi_to_gn.py",
  82                 [
  83                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  84                   "--replace=<(skia_include_path)=//third_party/skia/include",
  85                   "--replace=<(skia_src_path)=//third_party/skia/src",
  86                 ],
  87                 "scope",
  88                 [ "//third_party/skia/gyp/effects.gypi" ])
  89
  90 # The list of Skia utils that are to be set for chromium.
  91 gypi_skia_utils =
  92     exec_script("//build/gypi_to_gn.py",
  93                 [
  94                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  95                   "--replace=<(skia_include_path)=//third_party/skia/include",
  96                   "--replace=<(skia_src_path)=//third_party/skia/src",
  97                 ],
  98                 "scope",
  99                 [ "//third_party/skia/gyp/utils.gypi" ])
 100
 101 gypi_skia_opts =
 102     exec_script("//build/gypi_to_gn.py",
 103                 [
 104                   rebase_path("//third_party/skia/gyp/opts.gypi"),
 105                   "--replace=<(skia_include_path)=//third_party/skia/include",
 106                   "--replace=<(skia_src_path)=//third_party/skia/src",
 107                 ],
 108                 "scope",
 109                 [ "//third_party/skia/gyp/opts.gypi" ])
 110
 111 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 112 gypi_values =
 113     exec_script("//build/gypi_to_gn.py",
 114                 [
 115                   rebase_path("skia_gn_files.gypi"),
 116                   "--replace=<(skia_include_path)=//third_party/skia/include",
 117                   "--replace=<(skia_src_path)=//third_party/skia/src",
 118                 ],
 119                 "scope",
 120                 [ "skia_gn_files.gypi" ])
 121
 122 # External-facing config for dependent code.
 123 config("skia_config") {
 124   include_dirs = [
 125     "config",
 126     "ext",
 127     "//third_party/skia/include/c",
 128     "//third_party/skia/include/config",
 129     "//third_party/skia/include/core",
 130     "//third_party/skia/include/effects",
 131     "//third_party/skia/include/images",
 132     "//third_party/skia/include/lazy",
 133     "//third_party/skia/include/pathops",
 134     "//third_party/skia/include/pdf",
 135     "//third_party/skia/include/pipe",
 136     "//third_party/skia/include/ports",
 137     "//third_party/skia/include/utils",
 138   ]
 139
 140   defines = gypi_blink_skia_defines.blink_skia_defines
 141   defines += gypi_skia_defines.skia_for_chromium_defines
 142
 143   defines += []
 144
 145   if (component_mode == "shared_library") {
 146     defines += [
 147       "SKIA_DLL",
 148       "GR_GL_IGNORE_ES3_MSAA=0",
 149     ]
 150   }
 151
 152   if (skia_support_gpu) {
 153     include_dirs += [
 154       "//third_party/skia/include/gpu",
 155       "//third_party/skia/src/gpu",
 156     ]
 157     defines += [ "SK_SUPPORT_GPU=1" ]
 158   } else {
 159     defines += [ "SK_SUPPORT_GPU=0" ]
 160   }
 161
 162   if (is_android) {
 163     defines += [
 164       "SK_BUILD_FOR_ANDROID",
 165       "USE_CHROMIUM_SKIA",
 166     ]
 167   }
 168
 169   if (is_mac) {
 170     defines += [ "SK_BUILD_FOR_MAC" ]
 171   }
 172 }
 173
 174 # Internal-facing config for Skia library code.
 175 config("skia_library_config") {
 176   # These include directories are only included for Skia code and are not
 177   # exported to dependents. It's not clear if this is on purpose, but this
 178   # matches the GYP build.
 179   include_dirs = [
 180     "//third_party/skia/src/core",
 181     "//third_party/skia/src/image",
 182     "//third_party/skia/src/opts",
 183     "//third_party/skia/src/pdf",
 184     "//third_party/skia/src/ports",
 185     "//third_party/skia/src/sfnt",
 186     "//third_party/skia/src/utils",
 187     "//third_party/skia/src/lazy",
 188   ]
 189   if (is_mac || is_ios) {
 190     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 191   }
 192   if (is_mac) {
 193     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 194   }
 195
 196   defines = []
 197
 198   if (component_mode == "shared_library") {
 199     defines += [ "SKIA_IMPLEMENTATION=1" ]
 200   }
 201
 202   if (current_cpu == "arm") {
 203     if (arm_use_neon) {
 204       defines += [ "SK_ARM_HAS_NEON" ]
 205     } else if (arm_optionally_use_neon) {
 206       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 207     }
 208   }
 209
 210   # Settings for text blitting, chosen to approximate the system browser.
 211   if (is_linux) {
 212     defines += [
 213       "SK_GAMMA_EXPONENT=1.2",
 214       "SK_GAMMA_CONTRAST=0.2",
 215       "SK_HIGH_QUALITY_IS_LANCZOS",
 216     ]
 217   } else if (is_android) {
 218     defines += [
 219       "SK_GAMMA_APPLY_TO_A8",
 220       "SK_GAMMA_EXPONENT=1.4",
 221       "SK_GAMMA_CONTRAST=0.0",
 222     ]
 223   } else if (is_win) {
 224     defines += [
 225       "SK_GAMMA_SRGB",
 226       "SK_GAMMA_CONTRAST=0.5",
 227       "SK_HIGH_QUALITY_IS_LANCZOS",
 228     ]
 229   } else if (is_mac) {
 230     defines += [
 231       "SK_GAMMA_SRGB",
 232       "SK_GAMMA_CONTRAST=0.0",
 233       "SK_HIGH_QUALITY_IS_LANCZOS",
 234     ]
 235   }
 236
 237   if (is_android) {
 238     defines += [
 239       # Android devices are typically more memory constrained, so default to a
 240       # smaller glyph cache (it may be overriden at runtime when the renderer
 241       # starts up, depending on the actual device memory).
 242       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 243     ]
 244   } else {
 245     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 246   }
 247
 248   if (is_win) {
 249     include_dirs += [
 250       "//third_party/skia/include/utils/win",
 251       "//third_party/skia/src/utils/win",
 252     ]
 253
 254     defines += [
 255       # On windows, GDI handles are a scarse system-wide resource so we have to
 256       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 257       # fairly small size. http://crbug.com/314387
 258       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 259     ]
 260
 261     cflags = [
 262       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 263       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 264       "/wd4341",  # signed value is out of range for enum constant.
 265       "/wd4345",  # Object is default-initialized if initialization is omitted.
 266       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 267       "/wd4554",  # 'operator' : check operator precedence for possible error
 268       "/wd4748",  # compiler will disable optimizations if a function has inline
 269                   # assembly code contains flow control(jmp or jcc) statements.
 270
 271       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 272     ]
 273   }
 274 }
 275
 276 component("skia") {
 277   sources = [
 278     # Chrome sources.
 279     "config/SkUserConfig.h",
 280     "ext/SkDiscardableMemory_chrome.cc",
 281     "ext/SkDiscardableMemory_chrome.h",
 282     "ext/SkMemory_new_handler.cpp",
 283     "ext/analysis_canvas.cc",
 284     "ext/analysis_canvas.h",
 285     "ext/benchmarking_canvas.cc",
 286     "ext/benchmarking_canvas.h",
 287     "ext/bitmap_platform_device.h",
 288     "ext/convolver.cc",
 289     "ext/convolver.h",
 290     "ext/event_tracer_impl.cc",
 291     "ext/event_tracer_impl.h",
 292     "ext/fontmgr_default_win.cc",
 293     "ext/fontmgr_default_win.h",
 294     "ext/google_logging.cc",
 295     "ext/image_operations.cc",
 296     "ext/image_operations.h",
 297     "ext/opacity_draw_filter.cc",
 298     "ext/opacity_draw_filter.h",
 299     "ext/pixel_ref_utils.cc",
 300     "ext/pixel_ref_utils.h",
 301     "ext/platform_canvas.cc",
 302     "ext/platform_canvas.h",
 303     "ext/platform_device.cc",
 304     "ext/platform_device.h",
 305     "ext/platform_device_linux.cc",
 306     "ext/platform_device_mac.cc",
 307     "ext/platform_device_win.cc",
 308     "ext/recursive_gaussian_convolution.cc",
 309     "ext/recursive_gaussian_convolution.h",
 310     "ext/refptr.h",
 311     "ext/skia_utils_base.cc",
 312     "ext/skia_utils_base.h",
 313     "ext/skia_utils_ios.h",
 314     "ext/skia_utils_ios.mm",
 315     "ext/skia_utils_mac.h",
 316     "ext/skia_utils_mac.mm",
 317     "ext/skia_utils_win.cc",
 318     "ext/skia_utils_win.h",
 319   ]
 320
 321   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 322   sources += gypi_skia_core.sources
 323   sources += gypi_skia_effects.sources
 324   sources += gypi_skia_utils.sources
 325   sources += gypi_values.skia_library_sources
 326
 327   # This and skia_opts are really the same conceptual target so share headers.
 328   allow_circular_includes_from = [ ":skia_opts" ]
 329
 330   if (current_cpu == "arm") {
 331     sources += [
 332       "//third_party/skia/src/core/SkUtilsArm.cpp",
 333       "//third_party/skia/src/core/SkUtilsArm.h",
 334     ]
 335   }
 336
 337   # GPU
 338   if (skia_support_gpu) {
 339     sources += gypi_skia_gpu.skgpu_sources
 340     sources += gypi_skia_gpu.skgpu_null_gl_sources
 341   }
 342
 343   # Remove unused util files include in utils.gypi
 344   sources -= [
 345     "//third_party/skia/include/utils/SkBoundaryPatch.h",
 346     "//third_party/skia/include/utils/SkCamera.h",
 347     "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 348     "//third_party/skia/include/utils/SkCubicInterval.h",
 349     "//third_party/skia/include/utils/SkCullPoints.h",
 350     "//third_party/skia/include/utils/SkDebugUtils.h",
 351     "//third_party/skia/include/utils/SkDumpCanvas.h",
 352     "//third_party/skia/include/utils/SkEventTracer.h",
 353     "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 354     "//third_party/skia/include/utils/SkInterpolator.h",
 355     "//third_party/skia/include/utils/SkLayer.h",
 356     "//third_party/skia/include/utils/SkMeshUtils.h",
 357     "//third_party/skia/include/utils/SkNinePatch.h",
 358     "//third_party/skia/include/utils/SkParsePaint.h",
 359     "//third_party/skia/include/utils/SkParsePath.h",
 360     "//third_party/skia/include/utils/SkRandom.h",
 361     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 362     "//third_party/skia/src/utils/SkBitmapHasher.h",
 363     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 364     "//third_party/skia/src/utils/SkCamera.cpp",
 365     "//third_party/skia/src/utils/SkCanvasStack.h",
 366     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 367     "//third_party/skia/src/utils/SkCullPoints.cpp",
 368     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 369     "//third_party/skia/src/utils/SkFloatUtils.h",
 370     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 371     "//third_party/skia/src/utils/SkInterpolator.cpp",
 372     "//third_party/skia/src/utils/SkLayer.cpp",
 373     "//third_party/skia/src/utils/SkMD5.cpp",
 374     "//third_party/skia/src/utils/SkMD5.h",
 375     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 376     "//third_party/skia/src/utils/SkNinePatch.cpp",
 377     "//third_party/skia/src/utils/SkOSFile.cpp",
 378     "//third_party/skia/src/utils/SkParsePath.cpp",
 379     "//third_party/skia/src/utils/SkSHA1.cpp",
 380     "//third_party/skia/src/utils/SkSHA1.h",
 381     "//third_party/skia/src/utils/SkTFitsIn.h",
 382     "//third_party/skia/src/utils/SkTLogic.h",
 383
 384     # We don't currently need to change thread affinity, so leave out this complexity for now.
 385     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 386     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 387
 388     #testing
 389     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 390     "//third_party/skia/src/fonts/SkGScalerContext.h",
 391   ]
 392
 393   if (is_win) {
 394     sources -= [
 395       # Keeping _win.cpp
 396       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 397       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 398     ]
 399   } else {
 400     sources -= [
 401       # Keeping _pthread.cpp and _pthread_other.cpp.
 402       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 403     ]
 404   }
 405
 406   # need separate win section to handle chromes auto gn filter
 407   # (build/config/BUILDCONFIG.gn)
 408   if (is_win) {
 409     sources -= [
 410       #windows
 411       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 412       "//third_party/skia/include/utils/win/SkHRESULT.h",
 413       "//third_party/skia/include/utils/win/SkIStream.h",
 414       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 415       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 416       "//third_party/skia/src/utils/win/SkIStream.cpp",
 417       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 418     ]
 419   }
 420
 421   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 422     sources -= [ "ext/skia_utils_base.cc" ]
 423   }
 424
 425   # Fixup skia library sources.
 426   if (is_win) {
 427     sources -= [
 428       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 429       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 430       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 431     ]
 432   } else {
 433     sources -= [
 434       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 435       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 436       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 437       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 438       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 439       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 440       "//third_party/skia/src/ports/SkTLS_win.cpp",
 441       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 442       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 443     ]
 444   }
 445   if (!is_android) {
 446     sources -= [
 447       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 448       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 449     ]
 450   }
 451   if (!is_mac) {
 452     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 453   }
 454
 455   if (!is_linux) {
 456     sources -= [
 457       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 458       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 459       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 460     ]
 461   }
 462
 463   if (!is_linux && !is_android) {
 464     sources -= [
 465       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 466       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 467     ]
 468   }
 469
 470   # Select the right BitmapPlatformDevice.
 471   if (is_win) {
 472     sources += [
 473       "ext/bitmap_platform_device_win.cc",
 474       "ext/bitmap_platform_device_win.h",
 475     ]
 476   } else if (is_mac) {
 477     sources += [
 478       "ext/bitmap_platform_device_mac.cc",
 479       "ext/bitmap_platform_device_mac.h",
 480     ]
 481   } else if (use_cairo) {
 482     sources += [
 483       "ext/bitmap_platform_device_cairo.cc",
 484       "ext/bitmap_platform_device_cairo.h",
 485     ]
 486   } else {
 487     sources += [
 488       "ext/bitmap_platform_device_skia.cc",
 489       "ext/bitmap_platform_device_skia.h",
 490     ]
 491   }
 492
 493   if (is_clang) {
 494     # Skia won't compile with some of the more strict clang warnings.
 495     # e.g. it does:
 496     #  SkASSERT(!"sk_out_of_memory");
 497     configs -= [ "//build/config/clang:extra_warnings" ]
 498   }
 499
 500   configs -= [ "//build/config/compiler:chromium_code" ]
 501   configs += [
 502     ":skia_library_config",
 503     "//build/config/compiler:no_chromium_code",
 504   ]
 505   public_configs = [ ":skia_config" ]
 506
 507   deps = [
 508     ":skia_opts",
 509     "//base",
 510     "//base/third_party/dynamic_annotations",
 511     "//third_party/zlib",
 512   ]
 513
 514   if (is_linux) {
 515     configs += [
 516       "//build/config/linux:fontconfig",
 517       "//build/config/linux:freetype2",
 518     ]
 519     if (use_pango) {
 520       configs += [ "//build/config/linux:pangocairo" ]
 521     }
 522     deps += [ "//third_party/icu:icuuc" ]
 523   }
 524
 525   if (is_android) {
 526     set_sources_assignment_filter([])
 527     sources += [ "ext/platform_device_linux.cc" ]
 528     set_sources_assignment_filter(sources_assignment_filter)
 529     deps += [
 530       "//third_party/expat",
 531       "//third_party/freetype-android:freetype",
 532       "//third_party/android_tools:cpu_features",
 533     ]
 534   }
 535
 536   if (skia_support_pdf) {
 537     deps += [ "//third_party/sfntly" ]
 538     sources += gypi_skia_pdf.sources
 539   }
 540
 541   if (is_android && !is_debug) {
 542     configs -= [ "//build/config/compiler:optimize" ]
 543     configs += [ "//build/config/compiler:optimize_max" ]
 544   }
 545 }
 546
 547 # Separated out so it can be compiled with different flags for SSE.
 548 source_set("skia_opts") {
 549   cflags = []
 550   defines = []
 551
 552   if (current_cpu == "x86" || current_cpu == "x64") {
 553     sources = gypi_skia_opts.sse2_sources + gypi_skia_opts.ssse3_sources +
 554               gypi_skia_opts.sse41_sources +
 555               [
 556                 # Chrome-specific.
 557                 "ext/convolver_SSE2.cc",
 558                 "ext/convolver_SSE2.h",
 559               ]
 560
 561     if (is_linux || is_mac) {
 562       cflags += [ "-msse4.1" ]
 563     } else if (is_win) {
 564       defines += [ "SK_CPU_SSE_LEVEL=41" ]
 565     }
 566   } else if (current_cpu == "arm") {
 567     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 568     # ARM), the compiler doesn't like that.
 569     cflags += [ "-fomit-frame-pointer" ]
 570
 571     if (arm_version >= 7) {
 572       sources = gypi_skia_opts.armv7_sources
 573       if (arm_use_neon || arm_optionally_use_neon) {
 574         sources += gypi_skia_opts.neon_sources
 575
 576         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 577         # when running this.
 578         if (!arm_use_neon) {
 579           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 580           cflags += [ "-mfpu=neon" ]
 581         }
 582       }
 583     } else {
 584       sources = gypi_skia_opts.none_sourcees
 585     }
 586   } else if (current_cpu == "mipsel") {
 587     cflags += [ "-fomit-frame-pointer" ]
 588
 589     if (mips_dsp_rev >= 1) {
 590       sources = gypi_skia_opts.mips_dsp_sources
 591       if (mips_dsp_rev >= 2) {
 592         sources += [
 593           # Chrome-specific.
 594           "ext/convolver_mips_dspr2.cc",
 595           "ext/convolver_mips_dspr2.h",
 596         ]
 597       }
 598     } else {
 599       sources = gypi_skia_opts.none_sources
 600     }
 601   } else {
 602     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 603   }
 604
 605   if (is_android && !is_debug) {
 606     configs -= [ "//build/config/compiler:optimize" ]
 607     configs += [ "//build/config/compiler:optimize_max" ]
 608   }
 609
 610   configs -= [ "//build/config/compiler:chromium_code" ]
 611   configs += [
 612     ":skia_config",
 613     ":skia_library_config",
 614     "//build/config/compiler:no_chromium_code",
 615   ]
 616
 617   deps = [
 618     "//base",
 619   ]
 620
 621   visibility = [ ":skia" ]
 622 }
 623
 624 test("skia_unittests") {
 625   sources = [
 626     "ext/analysis_canvas_unittest.cc",
 627     "ext/bitmap_platform_device_mac_unittest.cc",
 628     "ext/convolver_unittest.cc",
 629     "ext/image_operations_unittest.cc",
 630     "ext/pixel_ref_utils_unittest.cc",
 631     "ext/platform_canvas_unittest.cc",
 632     "ext/recursive_gaussian_convolution_unittest.cc",
 633     "ext/refptr_unittest.cc",
 634     "ext/skia_utils_ios_unittest.mm",
 635     "ext/skia_utils_mac_unittest.mm",
 636   ]
 637
 638   if (!is_win && !is_mac) {
 639     sources -= [ "ext/platform_canvas_unittest.cc" ]
 640   }
 641
 642   deps = [
 643     ":skia",
 644     "//base",
 645     "//base/test:run_all_unittests",
 646     "//cc:test_support",  # TODO: Fix this test to not depend on cc.
 647     "//testing/gtest",
 648     "//ui/gfx",
 649     "//ui/gfx/geometry",
 650   ]
 651 }
 652
 653 if (is_linux && !is_chromeos) {
 654   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 655   executable("image_operations_bench") {
 656     sources = [
 657       "ext/image_operations_bench.cc",
 658     ]
 659
 660     deps = [
 661       ":skia",
 662       "//base",
 663     ]
 664   }
 665
 666   executable("filter_fuzz_stub") {
 667     testonly = true
 668     sources = [
 669       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 670     ]
 671
 672     deps = [
 673       ":skia",
 674       "//base",
 675       "//base/test:test_support",
 676     ]
 677   }
 678 }