build/toolchain/mac/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # TODO(brettw) Use "gcc_toolchain.gni" like the Linux toolchains. This requires
   6 # some enhancements since the commands on Mac are slightly different than on
   7 # Linux.
   8
   9 import("../goma.gni")
  10 import("//build/config/ios/ios_sdk.gni")
  11
  12 assert(host_os == "mac")
  13
  14 import("//build/toolchain/clang.gni")
  15 import("//build/toolchain/goma.gni")
  16
  17 if (use_goma) {
  18   goma_prefix = "$goma_dir/gomacc "
  19 } else {
  20   goma_prefix = ""
  21 }
  22
  23 # This will copy the gyp-mac-tool to the build directory. We pass in the source
  24 # file of the win tool.
  25 gyp_mac_tool_source =
  26     rebase_path("//tools/gyp/pylib/gyp/mac_tool.py", root_build_dir)
  27 exec_script("setup_toolchain.py", [ gyp_mac_tool_source ])
  28
  29 # Shared toolchain definition. Invocations should set toolchain_os to set the
  30 # build args in this definition.
  31 template("mac_toolchain") {
  32   toolchain(target_name) {
  33     assert(defined(invoker.cc), "mac_toolchain() must specify a \"cc\" value")
  34     assert(defined(invoker.cxx), "mac_toolchain() must specify a \"cxx\" value")
  35     assert(defined(invoker.ld), "mac_toolchain() must specify a \"ld\" value")
  36     assert(defined(invoker.toolchain_cpu),
  37            "mac_toolchain() must specify a \"toolchain_cpu\"")
  38     assert(defined(invoker.toolchain_os),
  39            "mac_toolchain() must specify a \"toolchain_os\"")
  40
  41     # We can't do string interpolation ($ in strings) on things with dots in
  42     # them. To allow us to use $cc below, for example, we create copies of
  43     # these values in our scope.
  44     cc = invoker.cc
  45     cxx = invoker.cxx
  46     ld = invoker.ld
  47
  48     # Make these apply to all tools below.
  49     lib_switch = "-l"
  50     lib_dir_switch = "-L"
  51
  52     tool("cc") {
  53       depfile = "{{output}}.d"
  54       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
  55       depsformat = "gcc"
  56       description = "CC {{output}}"
  57       outputs = [
  58         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
  59       ]
  60     }
  61
  62     tool("cxx") {
  63       depfile = "{{output}}.d"
  64       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} -c {{source}} -o {{output}}"
  65       depsformat = "gcc"
  66       description = "CXX {{output}}"
  67       outputs = [
  68         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
  69       ]
  70     }
  71
  72     tool("asm") {
  73       # For GCC we can just use the C compiler to compile assembly.
  74       depfile = "{{output}}.d"
  75       command = "$cc -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} -c {{source}} -o {{output}}"
  76       depsformat = "gcc"
  77       description = "ASM {{output}}"
  78       outputs = [
  79         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
  80       ]
  81     }
  82
  83     tool("objc") {
  84       depfile = "{{output}}.d"
  85       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_c}} {{cflags_objc}} -c {{source}} -o {{output}}"
  86       depsformat = "gcc"
  87       description = "OBJC {{output}}"
  88       outputs = [
  89         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
  90       ]
  91     }
  92
  93     tool("objcxx") {
  94       depfile = "{{output}}.d"
  95       command = "$cxx -MMD -MF $depfile {{defines}} {{include_dirs}} {{cflags}} {{cflags_cc}} {{cflags_objcc}} -c {{source}} -o {{output}}"
  96       depsformat = "gcc"
  97       description = "OBJCXX {{output}}"
  98       outputs = [
  99         "{{target_out_dir}}/{{target_output_name}}/{{source_name_part}}.o",
 100       ]
 101     }
 102
 103     tool("alink") {
 104       command = "rm -f {{output}} && ./gyp-mac-tool filter-libtool libtool -static -o {{output}} {{inputs}}"
 105       description = "LIBTOOL-STATIC {{output}}"
 106       outputs = [
 107         "{{target_out_dir}}/{{target_output_name}}{{output_extension}}",
 108       ]
 109       default_output_extension = ".a"
 110       output_prefix = "lib"
 111     }
 112
 113     tool("solink") {
 114       dylib = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"  # eg "./libfoo.dylib"
 115       rspfile = dylib + ".rsp"
 116
 117       # These variables are not built into GN but are helpers that implement
 118       # (1) linking to produce a .so, (2) extracting the symbols from that file
 119       # to a temporary file, (3) if the temporary file has differences from the
 120       # existing .TOC file, overwrite it, otherwise, don't change it.
 121       #
 122       # As a special case, if the library reexports symbols from other dynamic
 123       # libraries, we always update the .TOC and skip the temporary file and
 124       # diffing steps, since that library always needs to be re-linked.
 125       tocname = dylib + ".TOC"
 126       temporary_tocname = dylib + ".tmp"
 127
 128       does_reexport_command = "[ ! -e $dylib -o ! -e $tocname ] || otool -l $dylib | grep -q LC_REEXPORT_DYLIB"
 129
 130       link_command = "$ld -shared {{ldflags}} -o $dylib -Wl,-filelist,$rspfile"
 131       if (is_component_build) {
 132         link_command += " -Wl,-install_name,@rpath/{{target_output_name}}{{output_extension}}"
 133       }
 134       link_command += " {{solibs}} {{libs}}"
 135
 136       replace_command = "if ! cmp -s $temporary_tocname $tocname; then mv $temporary_tocname $tocname"
 137       extract_toc_command = "{ otool -l $dylib | grep LC_ID_DYLIB -A 5; nm -gP $dylib | cut -f1-2 -d' ' | grep -v U\$\$; true; }"
 138
 139       command = "if $does_reexport_command ; then $link_command && $extract_toc_command > $tocname; else $link_command && $extract_toc_command > $temporary_tocname && $replace_command ; fi; fi"
 140
 141       rspfile_content = "{{inputs_newline}}"
 142
 143       description = "SOLINK {{output}}"
 144
 145       # Use this for {{output_extension}} expansions unless a target manually
 146       # overrides it (in which case {{output_extension}} will be what the target
 147       # specifies).
 148       default_output_extension = ".dylib"
 149
 150       output_prefix = "lib"
 151
 152       # Since the above commands only updates the .TOC file when it changes, ask
 153       # Ninja to check if the timestamp actually changed to know if downstream
 154       # dependencies should be recompiled.
 155       restat = true
 156
 157       # Tell GN about the output files. It will link to the dylib but use the
 158       # tocname for dependency management.
 159       outputs = [
 160         dylib,
 161         tocname,
 162       ]
 163       link_output = dylib
 164       depend_output = tocname
 165     }
 166
 167     tool("link") {
 168       outfile = "{{root_out_dir}}/{{target_output_name}}{{output_extension}}"
 169       rspfile = "$outfile.rsp"
 170       command = "$ld {{ldflags}} -o $outfile -Wl,-filelist,$rspfile {{solibs}} {{libs}}"
 171       description = "LINK $outfile"
 172       rspfile_content = "{{inputs_newline}}"
 173       outputs = [
 174         outfile,
 175       ]
 176     }
 177
 178     tool("stamp") {
 179       command = "touch {{output}}"
 180       description = "STAMP {{output}}"
 181     }
 182
 183     tool("copy") {
 184       command = "ln -f {{source}} {{output}} 2>/dev/null || (rm -rf {{output}} && cp -af {{source}} {{output}})"
 185       description = "COPY {{source}} {{output}}"
 186     }
 187
 188     toolchain_args() {
 189       current_cpu = invoker.toolchain_cpu
 190       current_os = invoker.toolchain_os
 191
 192       # These values need to be passed through unchanged.
 193       target_os = target_os
 194       target_cpu = target_cpu
 195
 196       if (defined(invoker.is_clang)) {
 197         is_clang = invoker.is_clang
 198       }
 199     }
 200   }
 201 }
 202
 203 mac_toolchain("clang_arm") {
 204   toolchain_cpu = "arm"
 205   toolchain_os = "mac"
 206   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
 207                        root_build_dir)
 208   cc = "${goma_prefix}$prefix/clang"
 209   cxx = "${goma_prefix}$prefix/clang++"
 210   ld = cxx
 211   is_clang = true
 212 }
 213
 214 mac_toolchain("ios_clang_arm") {
 215   # TODO(GYP): Do we need ios_clang_armv7 and ios_clang_arm64 ?
 216   toolchain_cpu = "arm"
 217   toolchain_os = "mac"
 218
 219   # TODO(GYP): We need to support being able to use the version of clang
 220   # shipped w/ XCode instead of the one pulled from upstream.
 221   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
 222                        root_build_dir)
 223   cc = "${goma_prefix}$prefix/clang"
 224   cxx = "${goma_prefix}$prefix/clang++"
 225   ld = cxx
 226   is_clang = true
 227 }
 228
 229 mac_toolchain("arm") {
 230   toolchain_cpu = "arm"
 231   toolchain_os = "mac"
 232   cc = "${goma_prefix}/gcc"
 233   cxx = "${goma_prefix}/g++"
 234   ld = cxx
 235   is_clang = false
 236 }
 237
 238 mac_toolchain("clang_x64") {
 239   toolchain_cpu = "x64"
 240   toolchain_os = "mac"
 241   prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
 242                        root_build_dir)
 243   cc = "${goma_prefix}$prefix/clang"
 244   cxx = "${goma_prefix}$prefix/clang++"
 245   ld = cxx
 246   is_clang = true
 247 }
 248
 249 mac_toolchain("x64") {
 250   toolchain_cpu = "x64"
 251   toolchain_os = "mac"
 252   cc = "${goma_prefix}/gcc"
 253   cxx = "${goma_prefix}/g++"
 254   ld = cxx
 255   is_clang = false
 256 }