chrome/browser/devtools/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 if (!is_android) {
   6   import("//tools/grit/grit_rule.gni")
   7 }
   8
   9 action("devtools_protocol_constants") {
  10   script = "devtools_protocol_constants_generator.py"
  11
  12   blink_protocol = "//third_party/WebKit/Source/devtools/protocol.json"
  13   browser_protocol = "//content/browser/devtools/browser_protocol.json"
  14   inputs = [
  15     blink_protocol,
  16     browser_protocol,
  17   ]
  18   outputs = [
  19     "$target_gen_dir/devtools_protocol_constants.cc",
  20     "$target_gen_dir/devtools_protocol_constants.h",
  21   ]
  22
  23   args = [ "chrome" ]
  24   args += rebase_path(outputs, root_build_dir)
  25   args += [ rebase_path(blink_protocol, root_build_dir) ]
  26   args += [ rebase_path(browser_protocol, root_build_dir) ]
  27 }
  28
  29 # GYP version: chrome/chrome_debugger.gypi:debugger
  30 static_library("devtools") {
  31   # Note: new sources and deps should be generally added in (!is_android) below.
  32   sources = [
  33     "chrome_devtools_manager_delegate.cc",
  34     "chrome_devtools_manager_delegate.h",
  35     "devtools_network_conditions.cc",
  36     "devtools_network_conditions.h",
  37     "devtools_network_controller.cc",
  38     "devtools_network_controller.h",
  39     "devtools_network_controller_handle.cc",
  40     "devtools_network_controller_handle.h",
  41     "devtools_network_interceptor.cc",
  42     "devtools_network_interceptor.h",
  43     "devtools_network_protocol_handler.cc",
  44     "devtools_network_protocol_handler.h",
  45     "devtools_network_transaction.cc",
  46     "devtools_network_transaction.h",
  47     "devtools_network_transaction_factory.cc",
  48     "devtools_network_transaction_factory.h",
  49     "devtools_protocol.cc",
  50     "devtools_protocol.h",
  51   ]
  52   sources += get_target_outputs(":devtools_protocol_constants")
  53
  54   configs += [
  55     "//build/config/compiler:no_size_t_to_int_warning",
  56     "//build/config/compiler:wexit_time_destructors",
  57     "//build/config:precompiled_headers",
  58     "//third_party/WebKit/public:debug_devtools",
  59   ]
  60
  61   deps = [
  62     ":devtools_protocol_constants",
  63     "//base",
  64     "//content/public/browser",
  65     "//net",
  66   ]
  67
  68   if (!is_android) {
  69     deps += [
  70       "//chrome/app/theme:theme_resources",
  71       "//chrome/common/extensions/api",
  72       "//chrome:extra_resources",
  73       "//chrome:resources",
  74       "//chrome:strings",
  75       "//components/devtools_http_handler",
  76       "//net:http_server",
  77       "//skia",
  78       "//third_party/icu",
  79       "//third_party/leveldatabase",
  80       "//third_party/libusb",
  81       ":webrtc_device_provider_resources",
  82     ]
  83     sources += [
  84       "chrome_devtools_discovery_provider.cc",
  85       "chrome_devtools_discovery_provider.h",
  86       "device/adb/adb_client_socket.cc",
  87       "device/adb/adb_client_socket.h",
  88       "device/adb/adb_device_provider.cc",
  89       "device/adb/adb_device_provider.h",
  90       "device/android_device_info_query.cc",
  91       "device/android_device_manager.cc",
  92       "device/android_device_manager.h",
  93       "device/android_web_socket.cc",
  94       "device/devtools_android_bridge.cc",
  95       "device/devtools_android_bridge.h",
  96       "device/port_forwarding_controller.cc",
  97       "device/port_forwarding_controller.h",
  98       "device/tcp_device_provider.cc",
  99       "device/tcp_device_provider.h",
 100       "device/usb/android_rsa.cc",
 101       "device/usb/android_rsa.h",
 102       "device/usb/android_usb_device.cc",
 103       "device/usb/android_usb_device.h",
 104       "device/usb/android_usb_socket.cc",
 105       "device/usb/android_usb_socket.h",
 106       "device/usb/usb_device_provider.cc",
 107       "device/usb/usb_device_provider.h",
 108       "device/webrtc/devtools_bridge_client.cc",
 109       "device/webrtc/devtools_bridge_client.h",
 110       "device/webrtc/devtools_bridge_instances_request.cc",
 111       "device/webrtc/devtools_bridge_instances_request.h",
 112       "device/webrtc/send_command_request.cc",
 113       "device/webrtc/send_command_request.h",
 114       "device/webrtc/webrtc_device_provider.cc",
 115       "device/webrtc/webrtc_device_provider.h",
 116       "devtools_contents_resizing_strategy.cc",
 117       "devtools_contents_resizing_strategy.h",
 118       "devtools_embedder_message_dispatcher.cc",
 119       "devtools_embedder_message_dispatcher.h",
 120       "devtools_file_helper.cc",
 121       "devtools_file_helper.h",
 122       "devtools_file_system_indexer.cc",
 123       "devtools_file_system_indexer.h",
 124       "devtools_target_impl.cc",
 125       "devtools_target_impl.h",
 126       "devtools_targets_ui.cc",
 127       "devtools_targets_ui.h",
 128       "devtools_toggle_action.cc",
 129       "devtools_toggle_action.h",
 130       "devtools_ui_bindings.cc",
 131       "devtools_ui_bindings.h",
 132       "devtools_window.cc",
 133       "devtools_window.h",
 134       "remote_debugging_server.cc",
 135       "remote_debugging_server.h",
 136     ]
 137   }
 138 }
 139
 140 if (!is_android) {
 141   # GYP version: chrome/browser/devtools/webrtc_device_provider_resources.gyp:webrtc_device_provider_resources
 142   grit("webrtc_device_provider_resources") {
 143     source = "device/webrtc/resources.grd"
 144     output_dir = "$root_gen_dir/chrome"
 145     outputs = [
 146       "grit/webrtc_device_provider_resources.h",
 147       "grit/webrtc_device_provider_resources_map.cc",
 148       "grit/webrtc_device_provider_resources_map.h",
 149       "webrtc_device_provider_resources.pak",
 150     ]
 151   }
 152 }