content/test/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/crypto.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/ui.gni")
   9 import("//build/module_args/v8.gni")
  10 import("//testing/test.gni")
  11 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
  12
  13 content_tests_gypi_values =
  14     exec_script("//build/gypi_to_gn.py",
  15                 [
  16                   rebase_path("../content_tests.gypi"),
  17                   "--replace=<(SHARED_INTERMEDIATE_DIR)=$root_gen_dir",
  18                 ],
  19                 "scope",
  20                 [ "../content_tests.gypi" ])
  21
  22 # GYP version //content/content_tests.gypi:test_support_content
  23 source_set("test_support") {
  24   testonly = true
  25   configs += [ "//build/config:precompiled_headers" ]
  26   public_deps = [
  27     "//content/public/app:both",
  28     "//content/public/browser",
  29     "//content/public/common",
  30   ]
  31   deps = [
  32     "//cc/blink",
  33     "//net:test_support",
  34     "//skia",
  35     "//storage/common",
  36     "//testing/gmock",
  37     "//testing/gtest",
  38     "//ui/accessibility:ax_gen",
  39     "//ui/base",
  40     "//ui/base/ime",
  41     "//ui/base:test_support",
  42     "//ui/events:dom_keycode_converter",
  43     "//ui/events:events_base",
  44     "//ui/events:test_support",
  45     "//ui/events:gesture_detection",
  46     "//ui/gfx:test_support",
  47     "//ui/gl",
  48     "//ui/gl:test_support",
  49     "//ui/resources",
  50     "//url",
  51   ]
  52
  53   if (!is_ios) {
  54     sources =
  55         rebase_path(content_tests_gypi_values.test_support_content_sources,
  56                     ".",
  57                     "//content")
  58
  59     public_deps += [ "//third_party/WebKit/public:blink" ]
  60     deps += [
  61       ":content_test_mojo_bindings",
  62       "//components/scheduler:scheduler",
  63       "//components/scheduler:test_support",
  64       "//content/browser/speech/proto",
  65       "//content/public/child",
  66       "//content/gpu",
  67       "//content/public/plugin",
  68       "//content/public/renderer",
  69       "//content/public/utility",
  70       "//content/shell:pak",
  71       "//cc",
  72       "//cc:test_support",
  73       "//ipc/mojo",
  74       "//media",
  75       "//mojo/application/public/cpp:cpp_for_chromium",
  76       "//mojo/environment:chromium",
  77       "//ppapi/host",
  78       "//ppapi/proxy",
  79       "//ppapi/proxy:test_support",
  80       "//ppapi/shared_impl",
  81       "//ppapi/shared_impl:test_support",
  82       "//storage/browser",
  83       "//storage/common",
  84       "//ui/surface",
  85       "//v8",
  86     ]
  87
  88     if (enable_plugins) {
  89       deps += [ "//content/ppapi_plugin" ]
  90     }
  91
  92     if (enable_webrtc) {
  93       sources += [
  94         "../renderer/media/mock_data_channel_impl.cc",
  95         "../renderer/media/mock_data_channel_impl.h",
  96         "../renderer/media/mock_media_stream_dispatcher.cc",
  97         "../renderer/media/mock_media_stream_dispatcher.h",
  98         "../renderer/media/mock_peer_connection_impl.cc",
  99         "../renderer/media/mock_peer_connection_impl.h",
 100         "../renderer/media/mock_web_rtc_peer_connection_handler_client.cc",
 101         "../renderer/media/mock_web_rtc_peer_connection_handler_client.h",
 102         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.cc",
 103         "../renderer/media/webrtc/mock_peer_connection_dependency_factory.h",
 104       ]
 105
 106       deps += [
 107         "//third_party/libjingle:libjingle_webrtc",
 108         "//third_party/libjingle:libpeerconnection",
 109         "//third_party/webrtc/modules/video_capture",
 110       ]
 111     }
 112     if (!enable_plugins) {
 113       sources -= [ "ppapi_unittest.cc" ]
 114     }
 115
 116     if (use_glib) {
 117       configs += [ "//build/config/linux:glib" ]
 118     }
 119
 120     if (use_aura) {
 121       deps += [
 122         "//ui/aura:test_support",
 123         "//ui/resources:ui_test_pak",
 124         "//ui/wm",
 125       ]
 126     }
 127
 128     if (use_aura || is_mac) {
 129       deps += [ "//ui/compositor" ]
 130     }
 131
 132     if (use_ozone) {
 133       deps += [ "//ui/ozone" ]
 134     }
 135
 136     if (is_win) {
 137       deps += [
 138         "//content:startup_helper_win",
 139         "//third_party/iaccessible2",
 140       ]
 141     }
 142
 143     if (!is_android && !is_ios) {
 144       sources += [
 145         "../browser/compositor/test/no_transport_image_transport_factory.cc",
 146         "../browser/compositor/test/no_transport_image_transport_factory.h",
 147       ]
 148       deps += [
 149         "//ui/compositor",
 150         "//third_party/libvpx",
 151       ]
 152     }
 153
 154     if (is_android) {
 155       deps += [
 156         "//content/shell/android:copy_content_shell_assets",
 157         "//ui/android",
 158         "//ui/shell_dialogs",
 159       ]
 160     }
 161
 162     if (is_win) {
 163       deps += [ "//sandbox" ]
 164     }
 165   } else {  # is_ios
 166     sources = [
 167       "public/test/content_test_suite_base.cc",
 168       "public/test/mock_notification_observer.cc",
 169       "public/test/mock_resource_context.cc",
 170       "public/test/test_browser_thread.cc",
 171       "public/test/test_content_client_initializer.cc",
 172       "public/test/test_notification_tracker.cc",
 173       "public/test/test_utils.cc",
 174       "public/test/unittest_test_suite.cc",
 175       "test/content_test_suite.cc",
 176       "test/test_content_browser_client.cc",
 177       "test/test_content_client.cc",
 178     ]
 179   }
 180   if (v8_use_external_startup_data) {
 181     deps += [ "//gin:gin" ]
 182   }
 183 }
 184
 185 source_set("browsertest_support") {
 186   testonly = true
 187
 188   sources = [
 189     "../public/test/content_browser_test.cc",
 190     "../public/test/content_browser_test.h",
 191     "../public/test/content_browser_test_utils.cc",
 192     "../public/test/content_browser_test_utils.h",
 193     "../public/test/content_browser_test_utils_mac.mm",
 194     "content_browser_test_utils_internal.cc",
 195     "content_browser_test_utils_internal.h",
 196     "content_test_launcher.cc",
 197   ]
 198
 199   deps = [
 200     "//content/shell:content_shell_lib",
 201     "//skia",
 202     "//testing/gtest",
 203     "//ui/accessibility:ax_gen",
 204   ]
 205
 206   if (is_android) {
 207     deps += [ "//content/public/app:both" ]
 208   } else {
 209     deps += [ "//content/public/browser" ]
 210   }
 211 }
 212
 213 mojom("content_test_mojo_bindings") {
 214   sources = [
 215     "../public/test/test_mojo_service.mojom",
 216   ]
 217 }
 218
 219 mojom("web_ui_test_mojo_bindings") {
 220   sources = [
 221     "data/web_ui_test_mojo_bindings.mojom",
 222   ]
 223 }
 224
 225 if (!is_ios) {
 226   # GYP version //content/content_tests.gypi:layouttest_support_content
 227   static_library("layouttest_support") {
 228     testonly = true
 229     sources = rebase_path(
 230             content_tests_gypi_values.layouttest_support_content_sources,
 231             ".",
 232             "//content")
 233
 234     deps = [
 235       ":test_support",
 236       "//cc",
 237       "//cc/blink",
 238       "//components/test_runner:test_runner",
 239       "//content/public/common",
 240       "//skia",
 241       "//v8",
 242       "//ui/accessibility:ax_gen",
 243     ]
 244
 245     if (is_android) {
 246       deps += [ ":jni" ]
 247     }
 248   }
 249
 250   if (is_android) {
 251     import("//build/config/android/rules.gni")
 252
 253     generate_jni("jni") {
 254       sources = [
 255         "../public/test/android/javatests/src/org/chromium/content/browser/test/NestedSystemMessageHandler.java",
 256       ]
 257       jni_package = "content/public/test"
 258     }
 259   }
 260 }  # !is_ios
 261
 262 # TODO(GYP) enable content_browsertests on Mac when it links.
 263 if (!is_mac) {
 264   # TODO(GYP): Delete this after we've converted everything to GN.
 265   # The _run targets exist only for compatibility w/ GYP.
 266   group("content_browsertests_run") {
 267     testonly = true
 268     deps = [
 269       ":content_browsertests",
 270     ]
 271   }
 272
 273   test("content_browsertests") {
 274     sources =
 275         rebase_path(content_tests_gypi_values.content_browsertests_sources,
 276                     ".",
 277                     "//content")
 278
 279     if (is_android || is_linux || is_mac || is_win) {
 280       data = [
 281         "data/",
 282         "//net/data/",
 283         "//media/test/data/",
 284       ]
 285
 286       if (is_android) {
 287         data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 288       } else {
 289         data += [
 290           "$root_out_dir/content_shell.pak",
 291           "//net/tools/testserver/",
 292           "//ppapi/tests/test_case.html",
 293           "//ppapi/tests/test_page.css",
 294           "//third_party/pyftpdlib/",
 295           "//third_party/pywebsocket/",
 296           "//third_party/tlslite/",
 297         ]
 298
 299         if (is_mac) {
 300           data += [
 301             "$root_out_dir/Content Shell.app/",
 302             "$root_out_dir/plugins/test_netscape_plugin.plugin/",
 303           ]
 304         }
 305         if (is_win) {
 306           data += [ "$root_out_dir/plugins/np_test_netscape_plugin.dll" ]
 307         }
 308       }
 309     }
 310
 311     defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 312
 313     configs += [
 314       "//build/config:precompiled_headers",
 315       "//build/config/compiler:no_size_t_to_int_warning",
 316     ]
 317
 318     deps = [
 319       ":browsertest_support",
 320       ":web_ui_test_mojo_bindings",
 321       "//base/allocator",
 322       "//base/test:test_support",
 323       "//content/browser/background_sync:background_sync_proto",
 324       "//content/common:mojo_bindings",
 325       "//content/gpu",
 326       "//content/public/common",
 327       "//content/public/plugin",
 328       "//content/public/renderer",
 329       "//content:resources",
 330       "//content/shell:content_shell_lib",
 331       "//content/shell:pak",
 332       "//content/test:test_support",
 333       "//device/battery",
 334       "//device/battery:mojo_bindings",
 335       "//gin",
 336       "//gpu",
 337       "//ipc:test_support",
 338       "//media:test_support",
 339       "//media/audio:test_support",
 340       "//media/base:test_support",
 341       "//media:shared_memory_support",
 342       "//mojo/application/public/cpp:cpp_for_chromium",
 343       "//mojo/environment:chromium",
 344       "//mojo/test:test_support",
 345       "//net:test_support",
 346       "//ppapi/host",
 347       "//ppapi/proxy",
 348       "//ppapi/proxy:ipc",
 349       "//ppapi/shared_impl",
 350       "//third_party/mojo/src/mojo/edk/system",
 351       "//third_party/mojo/src/mojo/edk/test:test_support",
 352       "//third_party/mojo/src/mojo/public/cpp/bindings",
 353       "//third_party/mojo/src/mojo/public/js",
 354       "//testing/gmock",
 355       "//testing/gtest",
 356       "//third_party/WebKit/public:blink",
 357       "//third_party/leveldatabase",
 358       "//third_party/mesa:osmesa",
 359       "//third_party/zlib",
 360       "//ui/accessibility",
 361       "//ui/accessibility:ax_gen",
 362       "//ui/base",
 363       "//ui/base/ime",
 364       "//ui/gfx",
 365       "//ui/gfx/geometry",
 366       "//ui/gl",
 367       "//ui/gl:test_support",
 368       "//ui/resources",
 369       "//ui/shell_dialogs",
 370       "//ui/snapshot",
 371     ]
 372
 373     data_deps = [
 374       "//ppapi:ppapi_tests",
 375       "//third_party/mesa:osmesa",
 376     ]
 377
 378     if (is_win) {
 379       sources += rebase_path(
 380               content_tests_gypi_values.content_browsertests_win_sources,
 381               ".",
 382               "//content")
 383
 384       deps += [
 385         "//content/app/strings",
 386         "//net:net_resources",
 387         "//third_party/WebKit/public:resources",
 388         "//third_party/iaccessible2",
 389         "//third_party/isimpledom",
 390       ]
 391
 392       libs = [ "oleacc.lib" ]
 393     }
 394
 395     if (is_linux) {
 396       sources -=
 397           [ "../browser/accessibility/dump_accessibility_tree_browsertest.cc" ]
 398     }
 399
 400     if (is_android) {
 401       sources += rebase_path(
 402               content_tests_gypi_values.content_browsertests_android_sources,
 403               ".",
 404               "//content")
 405       sources -=
 406           [ "../browser/battery_status/battery_monitor_impl_browsertest.cc" ]
 407       deps += [
 408         "//content/shell/android:content_shell_jni_headers",
 409         "//content/shell:content_shell_lib",
 410         "//testing/android/native_test:native_test_support",
 411       ]
 412
 413       use_launcher = false
 414     }
 415
 416     if (is_mac) {
 417       sources += [ "../renderer/external_popup_menu_browsertest.cc" ]
 418       deps += [
 419         # Needed for Content Shell.app's Helper.
 420         #"//content/shell:content_shell",  #TODO(GYP) enable for mac
 421       ]
 422     }
 423
 424     if (use_aura && !is_win) {
 425       deps += [ "//ui/events:test_support" ]
 426     }
 427
 428     if (!use_aura && !is_mac) {
 429       sources -=
 430           [ "../browser/compositor/image_transport_factory_browsertest.cc" ]
 431     }
 432
 433     if (enable_webrtc) {
 434       sources += rebase_path(
 435               content_tests_gypi_values.content_browsertests_webrtc_sources,
 436               ".",
 437               "//content")
 438       deps += [ "//testing/perf" ]
 439     }
 440
 441     if (enable_plugins) {
 442       sources += rebase_path(
 443               content_tests_gypi_values.content_browsertests_plugins_sources,
 444               ".",
 445               "//content")
 446       data_deps += [ "//ppapi:ppapi_tests" ]
 447     }
 448
 449     if (enable_web_speech) {
 450       sources += rebase_path(
 451               content_tests_gypi_values.content_browsertests_speech_sources,
 452               ".",
 453               "//content")
 454     }
 455
 456     if (!is_chrome_branded) {
 457       sources += rebase_path(
 458               content_tests_gypi_values.content_browsertests_unofficial_build_sources,
 459               ".",
 460               "//content")
 461     }
 462
 463     if (use_aura) {
 464       deps += [
 465         "//ui/touch_selection:test_support",
 466         "//ui/touch_selection:touch_selection",
 467       ]
 468     } else {
 469       sources -= [
 470         "../browser/renderer_host/input/touch_selection_controller_client_aura_browsertest.cc",
 471         "../browser/web_contents/web_contents_view_aura_browsertest.cc",
 472       ]
 473     }
 474   }
 475 }
 476
 477 # TODO(GYP): Delete this after we've converted everything to GN.
 478 # The _run targets exist only for compatibility w/ GYP.
 479 group("content_unittests_run") {
 480   testonly = true
 481   deps = [
 482     ":content_unittests",
 483   ]
 484 }
 485
 486 test("content_unittests") {
 487   sources = rebase_path(content_tests_gypi_values.content_unittests_sources,
 488                         ".",
 489                         "//content")
 490
 491   if (is_android || is_linux || is_mac || is_win) {
 492     data = [
 493       "data/",
 494       "//net/data/ssl/certificates/",
 495       "//media/test/data/",
 496     ]
 497
 498     if (is_android) {
 499       data += [ "$root_out_dir/content_shell_assets/content_shell.pak" ]
 500     } else {
 501       data += [ "$root_out_dir/content_shell.pak" ]
 502     }
 503   }
 504
 505   configs += [ "//build/config:precompiled_headers" ]
 506
 507   deps = [
 508     ":test_support",
 509     "//base/allocator",
 510     "//base/test:test_support",
 511     "//content/browser/background_sync:background_sync_proto",
 512     "//content/browser/notifications:notification_proto",
 513     "//content/browser/service_worker:service_worker_proto",
 514     "//content/browser/speech/proto",
 515     "//content/common:mojo_bindings",
 516     "//content/public/browser",
 517     "//content/public/common",
 518     "//content/public/common:mojo_bindings",
 519     "//crypto",
 520     "//device/battery",
 521     "//device/battery:mojo_bindings",
 522     "//mojo/environment:chromium",
 523     "//net:extras",
 524     "//net:test_support",
 525     "//skia",
 526     "//sql",
 527     "//sql:test_support",
 528     "//testing/gmock",
 529     "//testing/gtest",
 530     "//third_party/mojo/src/mojo/edk/test:test_support",
 531     "//third_party/mojo/src/mojo/public/cpp/bindings",
 532     "//third_party/re2",
 533     "//ui/accessibility",
 534     "//ui/base",
 535     "//ui/events/blink",
 536     "//ui/gfx",
 537     "//ui/gfx/geometry",
 538     "//ui/gfx/ipc",
 539   ]
 540
 541   if (!is_ios) {
 542     deps += [
 543       "//base/third_party/dynamic_annotations",
 544       "//cc",
 545       "//cc:test_support",
 546       "//cc/surfaces",
 547       "//content:resources",
 548       "//content/gpu",
 549       "//content/public/browser",
 550       "//content/public/child",
 551       "//content/public/plugin",
 552       "//content/public/renderer",
 553       "//gin",
 554       "//gpu",
 555       "//gpu:test_support",
 556       "//ipc:test_support",
 557       "//media:test_support",
 558       "//media:shared_memory_support",
 559       "//media/audio:test_support",
 560       "//media/base:test_support",
 561       "//media/midi:midi",
 562       "//storage/browser",
 563       "//storage/common",
 564       "//third_party/WebKit/public:blink",
 565       "//third_party/icu",
 566       "//third_party/leveldatabase",
 567       "//third_party/libjingle",
 568       "//ui/compositor:test_support",
 569       "//ui/gl",
 570       "//ui/gl:test_support",
 571     ]
 572   }
 573
 574   data_deps = [ "//third_party/mesa:osmesa" ]
 575
 576   if (!is_win) {
 577     sources += [ "../browser/file_descriptor_info_impl_unittest.cc" ]
 578   }
 579
 580   if (enable_plugins) {
 581     sources +=
 582         rebase_path(content_tests_gypi_values.content_unittests_plugins_sources,
 583                     ".",
 584                     "//content")
 585   }
 586
 587   if (enable_webrtc) {
 588     sources +=
 589         rebase_path(content_tests_gypi_values.content_unittests_webrtc_sources,
 590                     ".",
 591                     "//content")
 592     deps += [
 593       "//third_party/libjingle:libjingle_webrtc",
 594       "//third_party/libjingle:libpeerconnection",
 595       "//third_party/webrtc/modules/video_capture",
 596     ]
 597
 598     if (is_linux || is_mac || is_win) {
 599       sources +=
 600           [ "../browser/media/capture/desktop_capture_device_unittest.cc" ]
 601       deps += [ "//third_party/webrtc/modules/desktop_capture" ]
 602     }
 603
 604     if (is_chromeos) {
 605       sources +=
 606           [ "../browser/media/capture/desktop_capture_device_aura_unittest.cc" ]
 607     }
 608   } else {
 609     if (enable_plugins) {
 610       # This file is added only when plugins are enabled, but we don't want it
 611       # unless webrtc is also enabled.
 612       sources -=
 613           [ "../renderer/media/webrtc/video_destination_handler_unittest.cc" ]
 614     }
 615   }
 616
 617   if (enable_web_speech) {
 618     sources +=
 619         rebase_path(content_tests_gypi_values.content_unittests_speech_sources,
 620                     ".",
 621                     "//content")
 622   }
 623
 624   if (is_linux) {
 625     if (use_dbus) {
 626       deps += [ "//dbus:test_support" ]
 627     } else {
 628       sources -=
 629           [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 630     }
 631   }
 632   if (is_win) {
 633     deps += [ "//third_party/iaccessible2" ]
 634   }
 635   if (is_mac) {
 636     # These flags are needed to run the test on Mac.
 637     # Search for comments about "xcode_settings" in chrome_tests.gypi.
 638     ldflags = [ "-Wl,-ObjC" ]
 639
 640     deps += [ "//third_party/ocmock" ]
 641   }
 642   if (is_chromeos) {
 643     sources -= [ "../browser/geolocation/wifi_data_provider_linux_unittest.cc" ]
 644     deps += [ "//chromeos" ]
 645   }
 646   if (is_android) {
 647     sources +=
 648         rebase_path(content_tests_gypi_values.content_unittests_android_sources,
 649                     ".",
 650                     "//content")
 651     sources -= [
 652       "../browser/geolocation/network_location_provider_unittest.cc",
 653       "../browser/geolocation/wifi_data_provider_common_unittest.cc",
 654       "../browser/renderer_host/begin_frame_observer_proxy_unittest.cc",
 655       "../browser/webui/url_data_manager_backend_unittest.cc",
 656     ]
 657     deps += [ "//testing/android/native_test:native_test_native_code" ]
 658   }
 659   if (!is_android && !is_ios) {
 660     deps += [ "//third_party/libvpx" ]
 661   }
 662
 663   if (use_aura) {
 664     deps += [
 665       "//ui/aura",
 666       "//ui/aura_extra",
 667       "//ui/wm",
 668     ]
 669   } else {
 670     sources -= [
 671       "../browser/renderer_host/render_widget_host_view_aura_unittest.cc",
 672       "../browser/renderer_host/web_input_event_aura_unittest.cc",
 673       "../browser/web_contents/aura/overscroll_navigation_overlay_unittest.cc",
 674       "../browser/web_contents/aura/overscroll_window_animation_unittest.cc",
 675       "../browser/web_contents/aura/overscroll_window_delegate_unittest.cc",
 676       "../browser/web_contents/web_contents_view_aura_unittest.cc",
 677     ]
 678   }
 679   if (use_aura || toolkit_views) {
 680     deps += [ "//ui/events:test_support" ]
 681   }
 682   if (!use_aura && !is_mac) {
 683     sources -= [
 684       "../browser/compositor/buffer_queue_unittest.cc",
 685       "../browser/compositor/reflector_impl_unittest.cc",
 686       "../browser/compositor/software_browser_compositor_output_surface_unittest.cc",
 687     ]
 688   }
 689
 690   if (!is_win && !is_mac) {
 691     sources -= [ "../common/plugin_list_unittest.cc" ]
 692   }
 693
 694   if (use_ozone) {
 695     deps += [
 696       "//ui/ozone",
 697       "//ui/ozone:ozone_base",
 698     ]
 699   } else {
 700     sources -=
 701         [ "../browser/compositor/software_output_device_ozone_unittest.cc" ]
 702   }
 703
 704   if (is_mac && use_openssl) {
 705     deps += [ "//third_party/boringssl" ]
 706   }
 707 }
 708
 709 if (!is_mac) {  # TODO(GYP) enable on Mac once it links.
 710   test("content_perftests") {
 711     sources = [
 712       "../browser/renderer_host/input/input_router_impl_perftest.cc",
 713       "../common/cc_messages_perftest.cc",
 714       "../test/run_all_perftests.cc",
 715     ]
 716     deps = [
 717       "//base/allocator",
 718       "//base/test:test_support",
 719       "//content/public/browser",
 720       "//content/public/common",
 721       "//content/test:test_support",
 722       "//cc",
 723       "//skia",
 724       "//testing/gtest",
 725       "//testing/perf",
 726       "//ui/gfx",
 727       "//ui/gfx/geometry",
 728     ]
 729
 730     if (is_android) {
 731       deps += [ "//testing/android/native_test:native_test_native_code" ]
 732     }
 733   }
 734
 735   # TODO(GYP): Delete this after we've converted everything to GN.
 736   # The _run targets exist only for compatibility w/ GYP.
 737   group("content_gl_tests_run") {
 738     testonly = true
 739     deps = [
 740       ":content_gl_tests",
 741     ]
 742   }
 743
 744   test("content_gl_tests") {
 745     sources = [
 746       "../common/gpu/client/gl_helper_unittest.cc",
 747       "../common/gpu/client/gpu_in_process_context_tests.cc",
 748     ]
 749
 750     deps = [
 751       ":test_support",
 752       "//base/allocator",
 753       "//base/test:test_support",
 754       "//content/public/common",
 755       "//gpu/blink",
 756       "//gpu/command_buffer/common",
 757       "//testing/gtest",
 758       "//third_party/WebKit/public:blink",
 759       "//ui/base",
 760       "//ui/gfx",
 761       "//ui/gfx:test_support",
 762       "//ui/gfx/geometry",
 763       "//ui/gl",
 764       "//ui/gl:test_support",
 765       "//v8",
 766     ]
 767
 768     if (is_android) {
 769       deps += [ "//testing/android/native_test:native_test_native_code" ]
 770     } else {
 771       data_deps = [
 772         "//third_party/ffmpeg",
 773         "//third_party/mesa:osmesa",
 774       ]
 775     }
 776   }
 777
 778   test("content_gl_benchmark") {
 779     sources = [
 780       "../common/gpu/client/gl_helper_benchmark.cc",
 781     ]
 782
 783     deps = [
 784       ":test_support",
 785       "//base/allocator",
 786       "//base/test:test_support",
 787       "//content/public/common",
 788       "//gpu/blink",
 789       "//testing/gtest",
 790       "//third_party/WebKit/public:blink",
 791       "//ui/base",
 792       "//ui/gfx",
 793       "//ui/gfx/geometry",
 794       "//ui/gl",
 795       "//ui/gl:test_support",
 796     ]
 797   }
 798 }