media/midi/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//media/media_options.gni")
   9 import("//testing/test.gni")
  10
  11 if (is_android) {
  12   # For generate_jni().
  13   import("//build/config/android/rules.gni")
  14 }
  15
  16 # Common configuration for targets in the media/midi directory.
  17 config("midi_config") {
  18   if (use_alsa && use_udev) {
  19     defines = [
  20       "USE_ALSA",
  21       "USE_UDEV",
  22     ]
  23   }
  24
  25   visibility = [ ":*" ]
  26 }
  27
  28 # USB MIDI specific source files that are used in Android port, and unit tests.
  29 # These can't easily be a source set because "midi" is a component and the
  30 # component export flags must always be the same.
  31 usb_midi_sources = [
  32   "midi_manager_usb.cc",
  33   "midi_manager_usb.h",
  34   "usb_midi_descriptor_parser.cc",
  35   "usb_midi_descriptor_parser.h",
  36   "usb_midi_device.h",
  37   "usb_midi_export.h",
  38   "usb_midi_input_stream.cc",
  39   "usb_midi_input_stream.h",
  40   "usb_midi_jack.h",
  41   "usb_midi_output_stream.cc",
  42   "usb_midi_output_stream.h",
  43 ]
  44
  45 # Android specific Java source files that are used to generate jni header files.
  46 if (is_android) {
  47   android_library("midi_java") {
  48     deps = [
  49       "//base:base_java",
  50     ]
  51
  52     DEPRECATED_java_in_dir = "java/src"
  53   }
  54
  55   generate_jni("midi_jni_headers") {
  56     sources = [
  57       "java/src/org/chromium/media/midi/MidiDeviceAndroid.java",
  58       "java/src/org/chromium/media/midi/MidiInputPortAndroid.java",
  59       "java/src/org/chromium/media/midi/MidiManagerAndroid.java",
  60       "java/src/org/chromium/media/midi/MidiOutputPortAndroid.java",
  61       "java/src/org/chromium/media/midi/UsbMidiDeviceAndroid.java",
  62       "java/src/org/chromium/media/midi/UsbMidiDeviceFactoryAndroid.java",
  63     ]
  64     jni_package = "media/midi"
  65   }
  66 }
  67
  68 component("midi") {
  69   sources = [
  70     "midi_export.h",
  71     "midi_manager.cc",
  72     "midi_manager.h",
  73     "midi_manager_mac.cc",
  74     "midi_manager_mac.h",
  75     "midi_manager_win.cc",
  76     "midi_manager_win.h",
  77     "midi_message_queue.cc",
  78     "midi_message_queue.h",
  79     "midi_message_util.cc",
  80     "midi_message_util.h",
  81     "midi_port_info.cc",
  82     "midi_port_info.h",
  83     "midi_scheduler.cc",
  84     "midi_scheduler.h",
  85     "midi_switches.cc",
  86     "midi_switches.h",
  87   ]
  88
  89   configs += [ ":midi_config" ]
  90
  91   defines = [ "MIDI_IMPLEMENTATION" ]
  92   deps = [
  93     "//base",
  94   ]
  95   libs = []
  96
  97   if (is_android) {
  98     # TODO(yhirano): Consider having "android" subdirectory.
  99     sources += [
 100                  "midi_device_android.cc",
 101                  "midi_device_android.h",
 102                  "midi_jni_registrar.cc",
 103                  "midi_jni_registrar.h",
 104                  "midi_input_port_android.cc",
 105                  "midi_input_port_android.h",
 106                  "midi_manager_android.cc",
 107                  "midi_manager_android.h",
 108                  "midi_output_port_android.cc",
 109                  "midi_output_port_android.h",
 110                  "usb_midi_device_android.cc",
 111                  "usb_midi_device_android.h",
 112                  "usb_midi_device_factory_android.cc",
 113                  "usb_midi_device_factory_android.h",
 114                ] + usb_midi_sources
 115
 116     # Since the USB sources are part of the component.
 117     defines += [ "EXPORT_USB_MIDI" ]
 118
 119     deps += [
 120       "//base:i18n",
 121       ":midi_jni_headers",
 122     ]
 123   }
 124
 125   if (is_mac) {
 126     libs += [
 127       "CoreAudio.framework",
 128       "CoreMIDI.framework",
 129     ]
 130   }
 131
 132   if (is_win) {
 133     deps += [ "//device/usb" ]
 134   }
 135
 136   if (use_alsa && use_udev) {
 137     deps += [
 138       "//crypto",
 139       "//crypto:platform",
 140     ]
 141     libs += [ "asound" ]
 142     sources += [
 143       "midi_manager_alsa.cc",
 144       "midi_manager_alsa.h",
 145     ]
 146   }
 147
 148   if (use_udev) {
 149     deps += [ "//device/udev_linux" ]
 150   }
 151 }
 152
 153 # TODO(GYP): Delete this after we've converted everything to GN.
 154 # The _run targets exist only for compatibility w/ GYP.
 155 group("midi_unittests_run") {
 156   testonly = true
 157   deps = [
 158     ":midi_unittests",
 159   ]
 160 }
 161
 162 test("midi_unittests") {
 163   sources = [
 164     "midi_manager_unittest.cc",
 165     "midi_manager_usb_unittest.cc",
 166     "midi_message_queue_unittest.cc",
 167     "midi_message_util_unittest.cc",
 168     "usb_midi_descriptor_parser_unittest.cc",
 169     "usb_midi_input_stream_unittest.cc",
 170     "usb_midi_output_stream_unittest.cc",
 171   ]
 172
 173   configs += [ ":midi_config" ]
 174   deps = [
 175     ":midi",
 176     "//base/test/:run_all_unittests",
 177     "//base/test/:test_support",
 178     "//testing/gtest",
 179   ]
 180
 181   if (is_android) {
 182     isolate_file = "midi_unittests.isolate"
 183   }
 184
 185   if (!is_android) {
 186     sources += usb_midi_sources
 187   }
 188
 189   if (is_mac) {
 190     sources += [ "midi_manager_mac_unittest.cc" ]
 191   }
 192
 193   if (use_alsa && use_udev) {
 194     sources += [ "midi_manager_alsa_unittest.cc" ]
 195   }
 196
 197   if (use_x11) {
 198     deps += [ "//tools/xdisplaycheck" ]
 199   }
 200 }