extensions/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//extensions/extensions.gni")
   6 import("//testing/test.gni")
   7 import("//tools/grit/grit_rule.gni")
   8 import("//tools/grit/repack.gni")
   9
  10 assert(enable_extensions)
  11
  12 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  13 group("extensions_resources") {
  14   deps = [
  15     ":extensions_browser_resources",
  16     ":extensions_renderer_resources",
  17     ":extensions_resources_grd",
  18   ]
  19 }
  20
  21 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  22 #              (extensions_resources action)
  23 grit("extensions_resources_grd") {
  24   source = "extensions_resources.grd"
  25   outputs = [
  26     "grit/extensions_resources.h",
  27     "extensions_resources.pak",
  28   ]
  29 }
  30
  31 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  32 #              (extensions_browser_resources action)
  33 grit("extensions_browser_resources") {
  34   source = "browser/resources/extensions_browser_resources.grd"
  35   outputs = [
  36     "grit/extensions_browser_resources.h",
  37     "grit/extensions_browser_resources_map.cc",
  38     "grit/extensions_browser_resources_map.h",
  39     "extensions_browser_resources_100_percent.pak",
  40     "extensions_browser_resources_200_percent.pak",
  41   ]
  42   grit_flags = [
  43     "-E",
  44     "mojom_root=" + rebase_path(root_gen_dir),
  45   ]
  46 }
  47
  48 # GYP version: extensions/extensions_resources.gyp:extensions_resources
  49 #              (extensions_renderer_resources action)
  50 grit("extensions_renderer_resources") {
  51   source = "renderer/resources/extensions_renderer_resources.grd"
  52   outputs = [
  53     "grit/extensions_renderer_resources.h",
  54     "extensions_renderer_resources.pak",
  55   ]
  56   grit_flags = [
  57     "-E",
  58     "mojom_root=" + rebase_path(root_gen_dir),
  59   ]
  60
  61   deps = [
  62     "//device/serial:serial_mojo",
  63     "//extensions/common:mojo",
  64     "//extensions/common/api:mojom",
  65   ]
  66 }
  67
  68 source_set("test_support") {
  69   testonly = true
  70   sources = rebase_path(extensions_gypi_values.extensions_test_support_sources,
  71                         ".",
  72                         "//extensions")
  73
  74   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  75   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
  76
  77   deps = [
  78     ":extensions_resources",
  79     "//base",
  80     "//base:prefs_test_support",
  81     "//components/guest_view:test_support",
  82     "//content/public/common",
  83     "//content/test:test_support",
  84     "//extensions/browser",
  85     "//extensions/common",
  86     "//extensions/common/api",
  87     "//extensions/common/api:api_registration",
  88     "//net:test_support",
  89     "//testing/gmock",
  90     "//testing/gtest",
  91   ]
  92
  93   public_deps = [
  94     "//content/public/browser",
  95     "//extensions/common/api/cast_channel:cast_channel_proto",
  96   ]
  97 }
  98
  99 # GYP version: //extensions/extensions.gyp:extensions_shell_and_test_pak
 100 repack("shell_and_test_pak") {
 101   sources = [
 102     "$root_gen_dir/blink/devtools_resources.pak",
 103     "$root_gen_dir/blink/public/resources/blink_image_resources_100_percent.pak",
 104     "$root_gen_dir/blink/public/resources/blink_resources.pak",
 105     "$root_gen_dir/content/app/strings/content_strings_en-US.pak",
 106     "$root_gen_dir/content/content_resources.pak",
 107     "$root_gen_dir/content/shell/shell_resources.pak",
 108     "$root_gen_dir/extensions/extensions_browser_resources_100_percent.pak",
 109     "$root_gen_dir/extensions/extensions_renderer_resources.pak",
 110     "$root_gen_dir/extensions/extensions_resources.pak",
 111     "$root_gen_dir/extensions/shell/app_shell_resources.pak",
 112     "$root_gen_dir/extensions/strings/extensions_strings_en-US.pak",
 113     "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
 114     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
 115     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
 116   ]
 117
 118   output = "$root_out_dir/extensions_shell_and_test.pak"
 119
 120   deps = [
 121     ":extensions_resources",
 122     "//content:resources",
 123     "//content/browser/devtools:devtools_resources",
 124     "//content/shell:resources",
 125     "//extensions/shell:resources",
 126     "//extensions/strings",
 127     "//third_party/WebKit/public:image_resources",
 128     "//third_party/WebKit/public:resources",
 129     "//ui/resources",
 130     "//ui/strings",
 131   ]
 132 }
 133
 134 test("extensions_unittests") {
 135   sources =
 136       rebase_path(extensions_tests_gypi_values.extensions_unittests_sources,
 137                   ".",
 138                   "//extensions")
 139
 140   sources += [
 141     # TODO(rockot): DisplayInfoProvider::Create() is only implemented in Chrome
 142     # and app_shell. This is wrong.
 143     "shell/browser/shell_display_info_provider.cc",
 144   ]
 145
 146   deps = [
 147     ":extensions_resources",
 148     ":shell_and_test_pak",
 149     ":test_support",
 150     "//base",
 151     "//base:prefs_test_support",
 152     "//base/test:test_support",
 153     "//components/keyed_service/content",
 154     "//components/user_prefs",
 155     "//content/test:test_support",
 156     "//device/bluetooth:mocks",
 157     "//device/serial",
 158     "//device/serial:test_support",
 159     "//extensions/common",
 160     "//extensions/common/api/cast_channel:cast_channel_proto",
 161     "//extensions/renderer",
 162     "//extensions/strings",
 163     "//extensions/utility",
 164     "//mojo/environment:chromium",
 165     "//testing/gmock",
 166     "//testing/gtest",
 167     "//third_party/leveldatabase",
 168     "//third_party/mojo/src/mojo/edk/js",
 169     "//third_party/mojo/src/mojo/edk/system",
 170     "//third_party/mojo/src/mojo/public/cpp/bindings",
 171     "//third_party/mojo/src/mojo/public/interfaces/application",
 172   ]
 173
 174   if (is_win) {
 175     deps += [ "//base/allocator" ]
 176   }
 177
 178   if (is_chromeos) {
 179     sources += [
 180       # TODO(rockot): There are two implementations of VpnServiceFactory, a
 181       # stub in app_shell and a real one in Chrome. This is wrong.
 182       "shell/browser/api/vpn_provider/vpn_service_factory.cc",
 183     ]
 184
 185     deps += [ "//chromeos:test_support" ]
 186   }
 187 }
 188
 189 test("extensions_browsertests") {
 190   sources =
 191       rebase_path(extensions_tests_gypi_values.extensions_browsertests_sources,
 192                   ".",
 193                   "//extensions")
 194
 195   defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
 196
 197   deps = [
 198     ":test_support",
 199     "shell:app_shell_lib",
 200
 201     # TODO(yoz): find the right deps
 202     "//base",
 203     "//base:prefs_test_support",
 204     "//base/test:test_support",
 205     "//components/storage_monitor:test_support",
 206     "//content/test:test_support",
 207     "//device/bluetooth:mocks",
 208     "//mojo/environment:chromium",
 209     "//testing/gmock",
 210     "//testing/gtest",
 211     "//third_party/mojo/src/mojo/edk/js",
 212     "//third_party/mojo/src/mojo/edk/system",
 213     "//third_party/mojo/src/mojo/public/cpp/bindings",
 214   ]
 215
 216   if (is_win) {
 217     deps += [ "//base/allocator" ]
 218   }
 219
 220   if (is_mac) {
 221     deps += [ "shell:app_shell" ]  # Needed for App Shell.app's Helper.
 222   }
 223 }