ui/events/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 static_library("dom_keycode_converter") {
   9   sources = [
  10     "keycodes/dom/dom_code.h",
  11     "keycodes/dom/dom_key.h",
  12     "keycodes/dom/dom_key_data.inc",
  13     "keycodes/dom/keycode_converter.cc",
  14     "keycodes/dom/keycode_converter.h",
  15     "keycodes/dom/keycode_converter_data.inc",
  16   ]
  17
  18   deps = [
  19     "//base",
  20   ]
  21 }
  22
  23 component("events_base") {
  24   sources = [
  25     "android/scroller.cc",
  26     "android/scroller.h",
  27     "base_event_utils.cc",
  28     "base_event_utils.h",
  29     "event_constants.h",
  30     "event_switches.cc",
  31     "event_switches.h",
  32     "events_base_export.h",
  33     "gesture_curve.h",
  34     "gesture_event_details.cc",
  35     "gesture_event_details.h",
  36     "gestures/fling_curve.cc",
  37     "gestures/fling_curve.h",
  38     "keycodes/dom_us_layout_data.h",
  39     "keycodes/keyboard_code_conversion.cc",
  40     "keycodes/keyboard_code_conversion.h",
  41     "keycodes/keyboard_code_conversion_android.cc",
  42     "keycodes/keyboard_code_conversion_android.h",
  43     "keycodes/keyboard_code_conversion_mac.h",
  44     "keycodes/keyboard_code_conversion_mac.mm",
  45     "keycodes/keyboard_code_conversion_win.cc",
  46     "keycodes/keyboard_code_conversion_win.h",
  47     "keycodes/keyboard_codes.h",
  48     "latency_info.cc",
  49     "latency_info.h",
  50   ]
  51
  52   defines = [ "EVENTS_BASE_IMPLEMENTATION" ]
  53
  54   deps = [
  55     ":dom_keycode_converter",
  56     "//base/third_party/dynamic_annotations",
  57     "//skia",
  58   ]
  59
  60   public_deps = [
  61     "//base",
  62     "//ui/events/platform",
  63     "//ui/gfx",
  64     "//ui/gfx/geometry",
  65   ]
  66
  67   if (use_x11) {
  68     configs += [ "//build/config/linux:x11" ]
  69
  70     sources += [
  71       "keycodes/keyboard_code_conversion_x.cc",
  72       "keycodes/keyboard_code_conversion_x.h",
  73       "x/keysym_to_unicode.cc",
  74       "x/keysym_to_unicode.h",
  75     ]
  76
  77     deps += [ "//ui/gfx/x" ]
  78   }
  79
  80   if (use_x11 || use_ozone) {
  81     sources += [
  82       "keycodes/keyboard_code_conversion_xkb.cc",
  83       "keycodes/keyboard_code_conversion_xkb.h",
  84       "keycodes/xkb_keysym.h",
  85     ]
  86   }
  87 }
  88
  89 component("events") {
  90   sources = [
  91     "cocoa/cocoa_event_utils.h",
  92     "cocoa/cocoa_event_utils.mm",
  93     "cocoa/events_mac.mm",
  94     "event.cc",
  95     "event.h",
  96     "event_dispatcher.cc",
  97     "event_dispatcher.h",
  98     "event_handler.cc",
  99     "event_handler.h",
 100     "event_processor.cc",
 101     "event_processor.h",
 102     "event_rewriter.h",
 103     "event_source.cc",
 104     "event_source.h",
 105     "event_target.cc",
 106     "event_target.h",
 107     "event_target_iterator.h",
 108     "event_targeter.h",
 109     "event_utils.cc",
 110     "event_utils.h",
 111     "events_export.h",
 112     "events_stub.cc",
 113     "gestures/gesture_recognizer_impl_mac.cc",
 114     "gestures/gesture_types.h",
 115     "null_event_targeter.cc",
 116     "null_event_targeter.h",
 117     "win/events_win.cc",
 118   ]
 119
 120   defines = [ "EVENTS_IMPLEMENTATION" ]
 121
 122   public_deps = [
 123     ":events_base",
 124   ]
 125   deps = [
 126     ":dom_keycode_converter",
 127     ":gesture_detection",
 128     "//base/third_party/dynamic_annotations",
 129     "//skia",
 130     "//ui/gfx",
 131     "//ui/gfx/geometry",
 132   ]
 133
 134   if (use_x11) {
 135     sources += [ "x/events_x.cc" ]
 136     configs += [
 137       "//build/config/linux:glib",
 138       "//build/config/linux:x11",
 139     ]
 140     deps += [
 141       "//ui/events/devices",
 142       "//ui/gfx/x",
 143     ]
 144   }
 145
 146   if (!is_chromeos && is_linux) {
 147     sources += [
 148       "linux/text_edit_command_auralinux.cc",
 149       "linux/text_edit_command_auralinux.h",
 150       "linux/text_edit_key_bindings_delegate_auralinux.cc",
 151       "linux/text_edit_key_bindings_delegate_auralinux.h",
 152     ]
 153   }
 154
 155   if (use_ozone) {
 156     sources += [ "ozone/events_ozone.cc" ]
 157     deps += [ "//ui/events/ozone:events_ozone_layout" ]
 158   }
 159
 160   if (use_aura) {
 161     sources += [
 162       "gestures/gesture_provider_aura.cc",
 163       "gestures/gesture_provider_aura.h",
 164       "gestures/gesture_recognizer.h",
 165       "gestures/gesture_recognizer_impl.cc",
 166       "gestures/gesture_recognizer_impl.h",
 167       "gestures/motion_event_aura.cc",
 168       "gestures/motion_event_aura.h",
 169     ]
 170   }
 171
 172   if (is_win || is_mac || use_x11 || use_ozone) {
 173     sources -= [ "events_stub.cc" ]
 174   }
 175 }
 176
 177 component("gesture_detection") {
 178   sources = [
 179     "gesture_detection/bitset_32.h",
 180     "gesture_detection/filtered_gesture_provider.cc",
 181     "gesture_detection/filtered_gesture_provider.h",
 182     "gesture_detection/gesture_configuration.cc",
 183     "gesture_detection/gesture_configuration.h",
 184     "gesture_detection/gesture_detection_export.h",
 185     "gesture_detection/gesture_detector.cc",
 186     "gesture_detection/gesture_detector.h",
 187     "gesture_detection/gesture_event_data.cc",
 188     "gesture_detection/gesture_event_data.h",
 189     "gesture_detection/gesture_event_data_packet.cc",
 190     "gesture_detection/gesture_event_data_packet.h",
 191     "gesture_detection/gesture_listeners.cc",
 192     "gesture_detection/gesture_listeners.h",
 193     "gesture_detection/gesture_provider.cc",
 194     "gesture_detection/gesture_provider.h",
 195     "gesture_detection/gesture_provider_config_helper.cc",
 196     "gesture_detection/gesture_provider_config_helper.h",
 197     "gesture_detection/gesture_touch_uma_histogram.cc",
 198     "gesture_detection/gesture_touch_uma_histogram.h",
 199     "gesture_detection/motion_event.cc",
 200     "gesture_detection/motion_event.h",
 201     "gesture_detection/motion_event_buffer.cc",
 202     "gesture_detection/motion_event_buffer.h",
 203     "gesture_detection/motion_event_generic.cc",
 204     "gesture_detection/motion_event_generic.h",
 205     "gesture_detection/scale_gesture_detector.cc",
 206     "gesture_detection/scale_gesture_detector.h",
 207     "gesture_detection/scale_gesture_listeners.cc",
 208     "gesture_detection/scale_gesture_listeners.h",
 209     "gesture_detection/snap_scroll_controller.cc",
 210     "gesture_detection/snap_scroll_controller.h",
 211     "gesture_detection/touch_disposition_gesture_filter.cc",
 212     "gesture_detection/touch_disposition_gesture_filter.h",
 213     "gesture_detection/velocity_tracker.cc",
 214     "gesture_detection/velocity_tracker.h",
 215     "gesture_detection/velocity_tracker_state.cc",
 216     "gesture_detection/velocity_tracker_state.h",
 217   ]
 218
 219   deps = [
 220     ":events_base",
 221     "//base",
 222     "//base/third_party/dynamic_annotations",
 223     "//ui/gfx",
 224     "//ui/gfx/geometry",
 225   ]
 226
 227   defines = [ "GESTURE_DETECTION_IMPLEMENTATION" ]
 228
 229   if (is_android) {
 230     sources += [ "gesture_detection/gesture_configuration_android.cc" ]
 231   } else if (use_aura) {
 232     sources += [ "gesture_detection/gesture_configuration_aura.cc" ]
 233   } else {
 234     sources += [ "gesture_detection/gesture_configuration_default.cc" ]
 235   }
 236 }
 237
 238 source_set("test_support") {
 239   sources = [
 240     "test/cocoa_test_event_utils.h",
 241     "test/cocoa_test_event_utils.mm",
 242     "test/device_data_manager_test_api.h",
 243     "test/event_generator.cc",
 244     "test/event_generator.h",
 245     "test/events_test_utils.cc",
 246     "test/events_test_utils.h",
 247     "test/motion_event_test_utils.cc",
 248     "test/motion_event_test_utils.h",
 249     "test/platform_event_waiter.cc",
 250     "test/platform_event_waiter.h",
 251     "test/test_event_handler.cc",
 252     "test/test_event_handler.h",
 253     "test/test_event_processor.cc",
 254     "test/test_event_processor.h",
 255     "test/test_event_target.cc",
 256     "test/test_event_target.h",
 257     "test/test_event_targeter.cc",
 258     "test/test_event_targeter.h",
 259   ]
 260
 261   public_deps = [
 262     ":events",
 263     ":events_base",
 264     ":gesture_detection",
 265   ]
 266   deps = [
 267     "//base",
 268     "//skia",
 269     "//ui/events/platform",
 270     "//ui/gfx/geometry",
 271   ]
 272
 273   if (is_ios) {
 274     sources -= [
 275       "test/cocoa_test_event_utils.h",
 276       "test/cocoa_test_event_utils.mm",
 277     ]
 278   }
 279
 280   if (use_x11) {
 281     sources += [
 282       "test/events_test_utils_x11.cc",
 283       "test/events_test_utils_x11.h",
 284     ]
 285     deps += [
 286       "//ui/events/devices",
 287       "//ui/gfx/x",
 288     ]
 289   }
 290
 291   if (use_x11 || use_ozone) {
 292     sources += [ "test/device_data_manager_test_api_impl.cc" ]
 293     deps += [ "//ui/events/devices" ]
 294   } else {
 295     sources += [ "test/device_data_manager_test_api_stub.cc" ]
 296   }
 297 }
 298
 299 test("events_unittests") {
 300   sources = [
 301     "android/scroller_unittest.cc",
 302     "cocoa/events_mac_unittest.mm",
 303     "event_dispatcher_unittest.cc",
 304     "event_processor_unittest.cc",
 305     "event_rewriter_unittest.cc",
 306     "event_unittest.cc",
 307     "gesture_detection/bitset_32_unittest.cc",
 308     "gesture_detection/filtered_gesture_provider_unittest.cc",
 309     "gesture_detection/gesture_event_data_packet_unittest.cc",
 310     "gesture_detection/gesture_provider_unittest.cc",
 311     "gesture_detection/motion_event_buffer_unittest.cc",
 312     "gesture_detection/motion_event_generic_unittest.cc",
 313     "gesture_detection/snap_scroll_controller_unittest.cc",
 314     "gesture_detection/touch_disposition_gesture_filter_unittest.cc",
 315     "gesture_detection/velocity_tracker_unittest.cc",
 316     "gestures/fling_curve_unittest.cc",
 317     "keycodes/dom/keycode_converter_unittest.cc",
 318     "keycodes/keyboard_code_conversion_unittest.cc",
 319     "latency_info_unittest.cc",
 320     "platform/platform_event_source_unittest.cc",
 321   ]
 322
 323   deps = [
 324     ":dom_keycode_converter",
 325     ":events",
 326     ":events_base",
 327     ":gesture_detection",
 328     ":test_support",
 329     "//base",
 330     "//base/test:run_all_unittests",
 331     "//skia",
 332     "//testing/gtest",
 333     "//ui/events/devices",
 334     "//ui/events/platform",
 335     "//ui/gfx:test_support",
 336   ]
 337
 338   if (!is_ios) {
 339     sources += [ "gestures/blink/web_gesture_curve_impl_unittest.cc" ]
 340     deps += [
 341       "//third_party/WebKit/public:blink_headers",
 342       "//ui/events/gestures/blink",
 343     ]
 344   }
 345
 346   include_dirs = [ "//testing/gmock/include" ]
 347
 348   if (use_x11) {
 349     sources += [
 350       "devices/x11/device_data_manager_x11_unittest.cc",
 351       "x/events_x_unittest.cc",
 352     ]
 353     configs += [ "//build/config/linux:x11" ]
 354     deps += [ "//ui/gfx/x" ]
 355   }
 356
 357   if (use_ozone) {
 358     sources += [
 359       "ozone/chromeos/cursor_controller_unittest.cc",
 360       "ozone/evdev/event_converter_evdev_impl_unittest.cc",
 361       "ozone/evdev/event_converter_test_util.cc",
 362       "ozone/evdev/event_device_info_unittest.cc",
 363       "ozone/evdev/event_device_test_util.cc",
 364       "ozone/evdev/input_injector_evdev_unittest.cc",
 365       "ozone/evdev/tablet_event_converter_evdev_unittest.cc",
 366       "ozone/evdev/touch_event_converter_evdev_unittest.cc",
 367       "ozone/evdev/touch_noise/touch_noise_finder_unittest.cc",
 368       "ozone/layout/xkb/xkb_keyboard_layout_engine_unittest.cc",
 369     ]
 370     deps += [
 371       "//ui/events/ozone:events_ozone",
 372       "//ui/events/ozone:events_ozone_evdev",
 373       "//ui/events/ozone:events_ozone_layout",
 374     ]
 375   }
 376
 377   if (use_aura) {
 378     sources += [ "gestures/gesture_provider_aura_unittest.cc" ]
 379   }
 380 }
 381
 382 if (is_nacl) {
 383   source_set("latency_info") {
 384     sources = [
 385       "ipc/latency_info_param_traits.cc",
 386       "ipc/latency_info_param_traits.h",
 387       "latency_info.cc",
 388       "latency_info.h",
 389     ]
 390   }
 391 }