tools/clang/blink_gc_plugin/CMakeLists.txt

   1 set(LIBRARYNAME BlinkGCPlugin)
   2
   3 set(plugin_sources
   4   BlinkGCPlugin.cpp
   5   Edge.cpp
   6   RecordInfo.cpp)
   7
   8 if(WIN32)
   9   # Clang doesn't support loadable modules on Windows. Unfortunately, building
  10   # the plugin as a static library and linking clang against it doesn't work.
  11   # Since clang doesn't reference any symbols in our static library, the linker
  12   # strips it out completely.
  13   # Instead, we rely on the fact that the SOURCES property of a target is no
  14   # read-only after CMake 3.1 and use it to compile the plugin directly into
  15   # clang...
  16   cmake_minimum_required(VERSION 3.1)
  17   # Paths must be absolute, since we're modifying a target in another directory.
  18   set(absolute_sources "")
  19   foreach(source ${plugin_sources})
  20     list(APPEND absolute_sources ${CMAKE_CURRENT_SOURCE_DIR}/${source})
  21   endforeach()
  22   set_property(TARGET clang APPEND PROPERTY SOURCES ${absolute_sources})
  23
  24   cr_add_test(blink_gc_plugin_test
  25     python
  26     ${CMAKE_CURRENT_SOURCE_DIR}/tests/test.py
  27     ${CMAKE_BINARY_DIR}/bin/clang
  28     )
  29 else()
  30   add_llvm_loadable_module("lib${LIBRARYNAME}" ${plugin_sources})
  31   add_dependencies("lib${LIBRARYNAME}" clang)
  32
  33   cr_install(TARGETS "lib${LIBRARYNAME}" LIBRARY DESTINATION lib)
  34
  35   cr_add_test(blink_gc_plugin_test
  36     python
  37     ${CMAKE_CURRENT_SOURCE_DIR}/tests/test.py
  38     ${CMAKE_BINARY_DIR}/bin/clang
  39     $<TARGET_FILE:lib${LIBRARYNAME}>
  40     )
  41 endif()