gpu/config/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6
   7 declare_args() {
   8   # Use the PCI lib to collect GPU information on Linux.
   9   use_libpci = true
  10 }
  11
  12 group("config") {
  13   if (is_component_build) {
  14     public_deps = [
  15       "//gpu",
  16     ]
  17   } else {
  18     public_deps = [
  19       ":config_sources",
  20     ]
  21   }
  22 }
  23
  24 source_set("config_sources") {
  25   visibility = [ "//gpu/*" ]
  26
  27   sources = [
  28     "dx_diag_node.cc",
  29     "dx_diag_node.h",
  30     "gpu_blacklist.cc",
  31     "gpu_blacklist.h",
  32     "gpu_control_list.cc",
  33     "gpu_control_list.h",
  34     "gpu_control_list_jsons.h",
  35     "gpu_driver_bug_list.cc",
  36     "gpu_driver_bug_list.h",
  37     "gpu_driver_bug_list_json.cc",
  38     "gpu_driver_bug_workaround_type.h",
  39     "gpu_dx_diagnostics_win.cc",
  40     "gpu_feature_type.h",
  41     "gpu_info.cc",
  42     "gpu_info.h",
  43     "gpu_info_collector.cc",
  44     "gpu_info_collector.h",
  45     "gpu_info_collector_android.cc",
  46     "gpu_info_collector_linux.cc",
  47     "gpu_info_collector_linux.h",
  48     "gpu_info_collector_mac.mm",
  49     "gpu_info_collector_ozone.cc",
  50     "gpu_info_collector_win.cc",
  51     "gpu_info_collector_x11.cc",
  52     "gpu_test_config.cc",
  53     "gpu_test_config.h",
  54     "gpu_test_expectations_parser.cc",
  55     "gpu_test_expectations_parser.h",
  56     "gpu_util.cc",
  57     "gpu_util.h",
  58     "software_rendering_list_json.cc",
  59   ]
  60
  61   configs += [
  62     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  63     "//build/config/compiler:no_size_t_to_int_warning",
  64     "//gpu:gpu_implementation",
  65   ]
  66
  67   deps = [
  68     "//base",
  69     "//gpu/command_buffer/service:service_sources",
  70     "//third_party/re2",
  71     "//ui/gl",
  72   ]
  73
  74   # Prefer mesa GL headers to system headers, which cause problems on Win.
  75   include_dirs = [ "//third_party/mesa/src/include" ]
  76
  77   if (is_win) {
  78     deps += [ "//third_party/libxml" ]
  79     libs = [
  80       "dxguid.lib",
  81       "setupapi.lib",
  82     ]
  83
  84     if (is_chrome_branded && is_official_build) {
  85       sources += [
  86         "//third_party/amd/AmdCfxPxExt.h",
  87         "//third_party/amd/amd_videocard_info_win.cc",
  88       ]
  89     }
  90   }
  91   if (use_libpci) {
  92     defines = [ "USE_LIBPCI=1" ]
  93   }
  94   if (is_linux && use_libpci && (use_x11 || use_ozone)) {
  95     deps += [ "//build/config/linux:libpci" ]
  96   }
  97   if (is_linux && use_x11) {
  98     configs += [
  99       "//build/config/linux:x11",
 100       "//build/config/linux:xext",
 101     ]
 102     deps += [
 103       "//third_party/libXNVCtrl",
 104       "//ui/gfx/x",
 105     ]
 106   } else {
 107     sources -= [ "gpu_info_collector_x11.cc" ]
 108   }
 109   if (!use_ozone) {
 110     sources -= [ "gpu_info_collector_ozone.cc" ]
 111   }
 112 }