content/shell/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//tools/grit/repack.gni")
   8 import("//tools/grit/grit_rule.gni")
   9 if (is_android) {
  10   import("//build/config/android/config.gni")
  11 }
  12
  13 declare_args() {
  14   content_shell_product_name = "Content Shell"
  15
  16   # The "19" is so that sites that sniff for version think that this is
  17   # something reasonably current; the "77.34.5" is a hint that this isn't a
  18   # standard Chrome.
  19   content_shell_version = "19.77.34.5"
  20 }
  21
  22 static_library("content_shell_lib") {
  23   testonly = true
  24   sources = [
  25     "android/shell_jni_registrar.cc",
  26     "android/shell_jni_registrar.h",
  27     "android/shell_manager.cc",
  28     "android/shell_manager.h",
  29     "app/blink_test_platform_support.h",
  30     "app/blink_test_platform_support_android.cc",
  31     "app/blink_test_platform_support_linux.cc",
  32     "app/blink_test_platform_support_mac.mm",
  33     "app/blink_test_platform_support_win.cc",
  34     "app/paths_mac.h",
  35     "app/paths_mac.mm",
  36     "app/shell_crash_reporter_client.cc",
  37     "app/shell_crash_reporter_client.h",
  38     "app/shell_main_delegate.cc",
  39     "app/shell_main_delegate.h",
  40     "app/shell_main_delegate_mac.h",
  41     "app/shell_main_delegate_mac.mm",
  42     "browser/blink_test_controller.cc",
  43     "browser/blink_test_controller.h",
  44     "browser/ipc_echo_message_filter.cc",
  45     "browser/ipc_echo_message_filter.h",
  46     "browser/layout_test/layout_test_android.cc",
  47     "browser/layout_test/layout_test_android.h",
  48     "browser/layout_test/layout_test_bluetooth_adapter_provider.cc",
  49     "browser/layout_test/layout_test_bluetooth_adapter_provider.h",
  50     "browser/layout_test/layout_test_browser_context.cc",
  51     "browser/layout_test/layout_test_browser_context.h",
  52     "browser/layout_test/layout_test_browser_main.cc",
  53     "browser/layout_test/layout_test_browser_main.h",
  54     "browser/layout_test/layout_test_browser_main_parts.cc",
  55     "browser/layout_test/layout_test_browser_main_parts.h",
  56     "browser/layout_test/layout_test_content_browser_client.cc",
  57     "browser/layout_test/layout_test_content_browser_client.h",
  58     "browser/layout_test/layout_test_devtools_frontend.cc",
  59     "browser/layout_test/layout_test_devtools_frontend.h",
  60     "browser/layout_test/layout_test_download_manager_delegate.cc",
  61     "browser/layout_test/layout_test_download_manager_delegate.h",
  62     "browser/layout_test/layout_test_javascript_dialog_manager.cc",
  63     "browser/layout_test/layout_test_javascript_dialog_manager.h",
  64     "browser/layout_test/layout_test_message_filter.cc",
  65     "browser/layout_test/layout_test_message_filter.h",
  66     "browser/layout_test/layout_test_navigator_connect_service_factory.cc",
  67     "browser/layout_test/layout_test_navigator_connect_service_factory.h",
  68     "browser/layout_test/layout_test_notification_manager.cc",
  69     "browser/layout_test/layout_test_notification_manager.h",
  70     "browser/layout_test/layout_test_permission_manager.cc",
  71     "browser/layout_test/layout_test_permission_manager.h",
  72     "browser/layout_test/layout_test_push_messaging_service.cc",
  73     "browser/layout_test/layout_test_push_messaging_service.h",
  74     "browser/layout_test/layout_test_resource_dispatcher_host_delegate.cc",
  75     "browser/layout_test/layout_test_resource_dispatcher_host_delegate.h",
  76     "browser/layout_test/layout_test_url_request_context_getter.cc",
  77     "browser/layout_test/layout_test_url_request_context_getter.h",
  78     "browser/notify_done_forwarder.cc",
  79     "browser/notify_done_forwarder.h",
  80     "browser/shell.cc",
  81     "browser/shell.h",
  82     "browser/shell_access_token_store.cc",
  83     "browser/shell_access_token_store.h",
  84     "browser/shell_android.cc",
  85     "browser/shell_application_mac.h",
  86     "browser/shell_application_mac.mm",
  87     "browser/shell_browser_context.cc",
  88     "browser/shell_browser_context.h",
  89     "browser/shell_browser_main.cc",
  90     "browser/shell_browser_main.h",
  91     "browser/shell_browser_main_parts.cc",
  92     "browser/shell_browser_main_parts.h",
  93     "browser/shell_browser_main_parts_mac.mm",
  94     "browser/shell_content_browser_client.cc",
  95     "browser/shell_content_browser_client.h",
  96     "browser/shell_devtools_frontend.cc",
  97     "browser/shell_devtools_frontend.h",
  98     "browser/shell_devtools_manager_delegate.cc",
  99     "browser/shell_devtools_manager_delegate.h",
 100     "browser/shell_download_manager_delegate.cc",
 101     "browser/shell_download_manager_delegate.h",
 102     "browser/shell_javascript_dialog.h",
 103     "browser/shell_javascript_dialog_mac.mm",
 104     "browser/shell_javascript_dialog_manager.cc",
 105     "browser/shell_javascript_dialog_manager.h",
 106     "browser/shell_javascript_dialog_win.cc",
 107     "browser/shell_login_dialog.cc",
 108     "browser/shell_login_dialog.h",
 109     "browser/shell_login_dialog_mac.mm",
 110     "browser/shell_mac.mm",
 111     "browser/shell_mojo_test_utils_android.cc",
 112     "browser/shell_mojo_test_utils_android.h",
 113     "browser/shell_net_log.cc",
 114     "browser/shell_net_log.h",
 115     "browser/shell_network_delegate.cc",
 116     "browser/shell_network_delegate.h",
 117     "browser/shell_permission_manager.cc",
 118     "browser/shell_permission_manager.h",
 119     "browser/shell_platform_data_aura.cc",
 120     "browser/shell_platform_data_aura.h",
 121     "browser/shell_plugin_service_filter.cc",
 122     "browser/shell_plugin_service_filter.h",
 123     "browser/shell_quota_permission_context.cc",
 124     "browser/shell_quota_permission_context.h",
 125     "browser/shell_resource_dispatcher_host_delegate.cc",
 126     "browser/shell_resource_dispatcher_host_delegate.h",
 127     "browser/shell_speech_recognition_manager_delegate.cc",
 128     "browser/shell_speech_recognition_manager_delegate.h",
 129     "browser/shell_url_request_context_getter.cc",
 130     "browser/shell_url_request_context_getter.h",
 131     "browser/shell_web_contents_view_delegate.h",
 132     "browser/shell_web_contents_view_delegate_android.cc",
 133     "browser/shell_web_contents_view_delegate_creator.h",
 134     "browser/shell_web_contents_view_delegate_mac.mm",
 135     "browser/shell_web_contents_view_delegate_win.cc",
 136     "common/layout_test/layout_test_messages.cc",
 137     "common/layout_test/layout_test_messages.h",
 138     "common/leak_detection_result.h",
 139     "common/shell_content_client.cc",
 140     "common/shell_content_client.h",
 141     "common/shell_messages.cc",
 142     "common/shell_messages.h",
 143     "common/shell_switches.cc",
 144     "common/shell_switches.h",
 145     "common/shell_test_configuration.cc",
 146     "common/shell_test_configuration.h",
 147     "common/test_runner/test_preferences.cc",
 148     "common/test_runner/test_preferences.h",
 149     "renderer/ipc_echo.cc",
 150     "renderer/ipc_echo.h",
 151     "renderer/layout_test/blink_test_helpers.cc",
 152     "renderer/layout_test/blink_test_helpers.h",
 153     "renderer/layout_test/blink_test_runner.cc",
 154     "renderer/layout_test/blink_test_runner.h",
 155     "renderer/layout_test/gc_controller.cc",
 156     "renderer/layout_test/gc_controller.h",
 157     "renderer/layout_test/layout_test_content_renderer_client.cc",
 158     "renderer/layout_test/layout_test_content_renderer_client.h",
 159     "renderer/layout_test/layout_test_render_frame_observer.cc",
 160     "renderer/layout_test/layout_test_render_frame_observer.h",
 161     "renderer/layout_test/layout_test_render_process_observer.cc",
 162     "renderer/layout_test/layout_test_render_process_observer.h",
 163     "renderer/layout_test/leak_detector.cc",
 164     "renderer/layout_test/leak_detector.h",
 165     "renderer/shell_content_renderer_client.cc",
 166     "renderer/shell_content_renderer_client.h",
 167     "renderer/shell_render_view_observer.cc",
 168     "renderer/shell_render_view_observer.h",
 169     "renderer/test_runner/accessibility_controller.cc",
 170     "renderer/test_runner/accessibility_controller.h",
 171     "renderer/test_runner/app_banner_client.cc",
 172     "renderer/test_runner/app_banner_client.h",
 173     "renderer/test_runner/event_sender.cc",
 174     "renderer/test_runner/event_sender.h",
 175     "renderer/test_runner/gamepad_controller.cc",
 176     "renderer/test_runner/gamepad_controller.h",
 177     "renderer/test_runner/mock_color_chooser.cc",
 178     "renderer/test_runner/mock_color_chooser.h",
 179     "renderer/test_runner/mock_constraints.cc",
 180     "renderer/test_runner/mock_constraints.h",
 181     "renderer/test_runner/mock_credential_manager_client.cc",
 182     "renderer/test_runner/mock_credential_manager_client.h",
 183     "renderer/test_runner/mock_grammar_check.cc",
 184     "renderer/test_runner/mock_grammar_check.h",
 185     "renderer/test_runner/mock_screen_orientation_client.cc",
 186     "renderer/test_runner/mock_screen_orientation_client.h",
 187     "renderer/test_runner/mock_spell_check.cc",
 188     "renderer/test_runner/mock_spell_check.h",
 189     "renderer/test_runner/mock_web_audio_device.cc",
 190     "renderer/test_runner/mock_web_audio_device.h",
 191     "renderer/test_runner/mock_web_media_stream_center.cc",
 192     "renderer/test_runner/mock_web_media_stream_center.h",
 193     "renderer/test_runner/mock_web_midi_accessor.cc",
 194     "renderer/test_runner/mock_web_midi_accessor.h",
 195     "renderer/test_runner/mock_web_speech_recognizer.cc",
 196     "renderer/test_runner/mock_web_speech_recognizer.h",
 197     "renderer/test_runner/mock_web_theme_engine.cc",
 198     "renderer/test_runner/mock_web_theme_engine.h",
 199     "renderer/test_runner/mock_web_user_media_client.cc",
 200     "renderer/test_runner/mock_web_user_media_client.h",
 201     "renderer/test_runner/mock_webrtc_data_channel_handler.cc",
 202     "renderer/test_runner/mock_webrtc_data_channel_handler.h",
 203     "renderer/test_runner/mock_webrtc_dtmf_sender_handler.cc",
 204     "renderer/test_runner/mock_webrtc_dtmf_sender_handler.h",
 205     "renderer/test_runner/mock_webrtc_peer_connection_handler.cc",
 206     "renderer/test_runner/mock_webrtc_peer_connection_handler.h",
 207     "renderer/test_runner/spell_check_client.cc",
 208     "renderer/test_runner/spell_check_client.h",
 209     "renderer/test_runner/test_common.cc",
 210     "renderer/test_runner/test_common.h",
 211     "renderer/test_runner/test_interfaces.cc",
 212     "renderer/test_runner/test_interfaces.h",
 213     "renderer/test_runner/test_plugin.cc",
 214     "renderer/test_runner/test_plugin.h",
 215     "renderer/test_runner/test_runner.cc",
 216     "renderer/test_runner/test_runner.h",
 217     "renderer/test_runner/text_input_controller.cc",
 218     "renderer/test_runner/text_input_controller.h",
 219     "renderer/test_runner/web_ax_object_proxy.cc",
 220     "renderer/test_runner/web_ax_object_proxy.h",
 221     "renderer/test_runner/web_content_settings.cc",
 222     "renderer/test_runner/web_content_settings.h",
 223     "renderer/test_runner/web_frame_test_proxy.h",
 224     "renderer/test_runner/web_task.cc",
 225     "renderer/test_runner/web_task.h",
 226     "renderer/test_runner/web_test_delegate.h",
 227     "renderer/test_runner/web_test_interfaces.cc",
 228     "renderer/test_runner/web_test_interfaces.h",
 229     "renderer/test_runner/web_test_proxy.cc",
 230     "renderer/test_runner/web_test_proxy.h",
 231     "renderer/test_runner/web_test_runner.h",
 232   ]
 233
 234   # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 235   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 236
 237   defines = [ "CONTENT_SHELL_VERSION=\"$content_shell_version\"" ]
 238
 239   public_deps = [
 240     # This exposes all public content APIs.
 241     "//content/public/app:both",
 242     "//content/public/browser",
 243     "//content/public/common",
 244     "//content/public/plugin",
 245     "//content/public/renderer",
 246     "//content/public/utility",
 247   ]
 248   deps = [
 249     ":resources",
 250     "//base",
 251     "//base:base_static",
 252     "//base/allocator",
 253     "//base/third_party/dynamic_annotations",
 254     "//cc",
 255     "//components/crash/app",
 256     "//components/devtools_discovery",
 257     "//components/devtools_http_handler",
 258     "//components/web_cache/renderer",
 259     "//content:resources",
 260     "//content/app/resources",
 261     "//content/app/strings",
 262     "//content/gpu",
 263     "//content/test:layouttest_support",
 264     "//device/bluetooth",
 265     "//device/bluetooth:mocks",
 266     "//gin",
 267     "//gpu",
 268     "//ipc",
 269     "//media",
 270     "//net",
 271     "//net:net_resources",
 272     "//skia",
 273     "//storage/browser",
 274     "//testing/gmock",
 275     "//testing/gtest",
 276     "//third_party/WebKit/public:blink",
 277     "//third_party/WebKit/public:image_resources",
 278     "//third_party/WebKit/public:resources",
 279     "//third_party/WebKit/public:test_support",
 280     "//third_party/icu",
 281     "//ui/base",
 282     "//ui/base/ime",
 283     "//ui/events:events_base",
 284     "//ui/gfx",
 285     "//ui/gfx/geometry",
 286     "//ui/gfx/ipc",
 287     "//ui/gl",
 288     "//url",
 289     "//v8",
 290
 291     #'copy_test_netscape_plugin',  TODO(GYP)
 292   ]
 293   if (enable_plugins) {
 294     deps += [ "//content/ppapi_plugin" ]
 295   }
 296
 297   if (is_win) {
 298     #'LinkIncremental': '<(msvs_large_module_debug_link_mode)',  TODO(GYP)
 299     sources += [
 300       "common/v8_breakpad_support_win.cc",
 301       "common/v8_breakpad_support_win.h",
 302     ]
 303   }
 304
 305   if (is_linux) {
 306     configs += [ "//build/config/linux:fontconfig" ]
 307   }
 308
 309   if (use_x11) {
 310     # Some tests rely on this tool at runtime. Note: it might be better if
 311     # the tests that needed it had this as a dep instead of adding it here.
 312     datadeps = [
 313       "//tools/xdisplaycheck",
 314     ]
 315
 316     deps += [ "//ui/events/devices" ]
 317   }
 318
 319   if (is_android) {
 320     deps += [ "//content/shell/android:content_shell_jni_headers" ]
 321     #deps -= [ "copy_test_netscape_plugin" ]  TODO(GYP)
 322   }
 323
 324   if (is_posix && !is_mac) {
 325     deps += [ "//components/crash/browser" ]
 326   }
 327
 328   if (use_aura) {
 329     deps += [
 330       "//ui/aura",
 331       "//ui/aura:test_support",
 332       "//ui/events",
 333       "//ui/strings",
 334       "//ui/wm",
 335     ]
 336
 337     if (toolkit_views) {
 338       sources += [ "browser/shell_views.cc" ]
 339       deps += [
 340         "//ui/resources",
 341         "//ui/views/controls/webview",
 342         "//ui/views",
 343         "//ui/views:test_support",
 344       ]
 345     } else {
 346       sources += [ "browser/shell_aura.cc" ]
 347     }
 348   } else {
 349     sources -= [
 350       "browser/shell_platform_data_aura.cc",
 351       "browser/shell_platform_data_aura.h",
 352     ]
 353   }
 354
 355   # The test plugin relies on X11.
 356   if (is_linux && !use_x11) {
 357     #deps -= [ 'copy_test_netscape_plugin' ]  TODO(GYP)
 358   }
 359
 360   if (is_chromeos) {
 361     deps += [
 362       "//chromeos",
 363       "//ui/wm:test_support",
 364     ]
 365   }
 366
 367   if (is_linux) {
 368     deps += [ "//third_party/freetype2" ]
 369   }
 370
 371   if (!enable_plugins) {
 372     sources -= [
 373       "browser/shell_plugin_service_filter.cc",
 374       "browser/shell_plugin_service_filter.h",
 375     ]
 376   }
 377 }
 378
 379 grit("content_shell_resources_grit") {
 380   visibility = [ ":*" ]
 381   source = "shell_resources.grd"
 382   outputs = [
 383     "grit/shell_resources.h",
 384     "shell_resources.pak",
 385     "shell_resources.rc",
 386   ]
 387 }
 388
 389 copy("copy_shell_resources") {
 390   sources = [
 391     "$target_gen_dir/shell_resources.pak",
 392   ]
 393   outputs = [
 394     "$root_out_dir/shell_resources.pak",
 395   ]
 396
 397   public_deps = [
 398     ":content_shell_resources_grit",
 399   ]
 400 }
 401
 402 # Font copies.
 403 if (!is_mac) {
 404   copy("copy_ahem") {
 405     visibility = [ ":*" ]
 406     sources = [
 407       "renderer/test_runner/resources/fonts/AHEM____.TTF",
 408     ]
 409     outputs = [
 410       "$root_out_dir/AHEM____.TTF",
 411     ]
 412   }
 413 }
 414 if (use_x11) {
 415   copy("copy_x11_fonts") {
 416     visibility = [ ":*" ]
 417     sources = [
 418       "//third_party/gardiner_mod/GardinerModBug.ttf",
 419       "//third_party/gardiner_mod/GardinerModCat.ttf",
 420       "renderer/test_runner/resources/fonts/fonts.conf",
 421     ]
 422     outputs = [
 423       "$root_out_dir/{{source_file_part}}",
 424     ]
 425   }
 426 }
 427 if (is_android) {
 428   copy("copy_android_fonts") {
 429     visibility = [ ":*" ]
 430     sources = [
 431       "renderer/test_runner/resources/fonts/android_fallback_fonts.xml",
 432       "renderer/test_runner/resources/fonts/android_main_fonts.xml",
 433     ]
 434     outputs = [
 435       "$root_out_dir/{{source_file_part}}",
 436     ]
 437   }
 438 }
 439
 440 group("resources") {
 441   public_deps = [
 442     ":copy_shell_resources",
 443   ]
 444   deps = []
 445
 446   if (is_mac) {
 447     # TODO(GYP) Mac bundle resources.
 448     #'all_dependent_settings': {
 449     #  'mac_bundle_resources': [
 450     #    'shell/renderer/test_runner/resources/fonts/AHEM____.TTF',
 451     #    'shell/renderer/test_runner/resources/fonts/ChromiumAATTest.ttf',
 452     #    '<(SHARED_INTERMEDIATE_DIR)/webkit/missingImage.png',
 453     #    '<(SHARED_INTERMEDIATE_DIR)/webkit/textAreaResizeCorner.png',
 454     #  ],
 455     #},
 456   } else {
 457     deps += [ ":copy_ahem" ]
 458   }
 459
 460   if (use_x11) {
 461     deps += [ ":copy_x11_fonts" ]
 462   }
 463   if (is_android) {
 464     deps += [ ":copy_android_fonts" ]
 465   }
 466 }
 467
 468 repack("pak") {
 469   sources = [
 470     "$root_gen_dir/blink/public/resources/blink_image_resources_100_percent.pak",
 471     "$root_gen_dir/blink/public/resources/blink_resources.pak",
 472     "$root_gen_dir/content/app/resources/content_resources_100_percent.pak",
 473     "$root_gen_dir/content/app/strings/content_strings_en-US.pak",
 474     "$root_gen_dir/content/browser/tracing/tracing_resources.pak",
 475     "$root_gen_dir/content/content_resources.pak",
 476     "$root_gen_dir/content/shell/shell_resources.pak",
 477     "$root_gen_dir/net/net_resources.pak",
 478     "$root_gen_dir/ui/resources/ui_resources_100_percent.pak",
 479     "$root_gen_dir/ui/resources/webui_resources.pak",
 480     "$root_gen_dir/ui/strings/app_locale_settings_en-US.pak",
 481     "$root_gen_dir/ui/strings/ui_strings_en-US.pak",
 482   ]
 483
 484   deps = [
 485     ":resources",
 486     "//content:resources",
 487     "//content/app/resources",
 488     "//content/app/strings",
 489     "//content/browser/tracing:resources",
 490     "//net:net_resources",
 491     "//third_party/WebKit/public:image_resources",
 492     "//third_party/WebKit/public:resources",
 493     "//ui/resources",
 494     "//ui/strings",
 495   ]
 496
 497   sources += [ "$root_gen_dir/blink/devtools_resources.pak" ]
 498   deps += [ "//content/browser/devtools:resources" ]
 499   output = "$root_out_dir/content_shell.pak"
 500 }
 501
 502 # TODO(GYP): Figure out what this should be on android
 503 # and make linking this work on the Mac.
 504 if (!is_android && !is_mac) {
 505   executable("content_shell") {
 506     testonly = true
 507
 508     # TODO(GYP) mac resource bundle stuff for this target.
 509     # TODO(GYP) Windows content shell settings:
 510     #  - Manifest.
 511     #  - RC file.
 512     #  - 'LinkIncremental': '<(msvs_large_module_debug_link_mode)',
 513     sources = [
 514       "app/shell_main.cc",
 515     ]
 516
 517     deps = [
 518       ":content_shell_lib",
 519       ":pak",
 520       "//base/allocator",
 521     ]
 522
 523     if (is_win) {
 524       deps += [ "//sandbox" ]
 525       if (!is_asan) {
 526         configs -= [ "//build/config/win:console" ]
 527         configs += [ "//build/config/win:windowed" ]
 528       }
 529     }
 530
 531     if (is_mac) {
 532       # TODO(GYP) lots of stuff from GYP file here.
 533     }
 534
 535     if (is_android) {
 536       # Some tests rely on this tool. It might be nicer if these tests relied on
 537       # image diff rather than having content shell depend on it.
 538       datadeps = [
 539         "//tools/imagediff($host_toolchain)",
 540       ]
 541     }
 542   }
 543 } else {
 544   group("content_shell") {
 545     testonly = true
 546     deps = [
 547       ":content_shell_lib",
 548     ]
 549   }
 550 }
 551
 552 if (is_mac || is_win) {
 553   # GYP version: content/content_shell_and_tests.gyp:layout_test_helper
 554   executable("layout_test_helper") {
 555     sources = [
 556       "renderer/test_runner/helper/layout_test_helper_mac.mm",
 557       "renderer/test_runner/helper/layout_test_helper_win.cc",
 558     ]
 559
 560     if (is_mac) {
 561       libs = [ "AppKit.framework" ]
 562     }
 563   }
 564 }
 565
 566 if (is_win) {
 567   # GYP version: content/content_shell_and_tests.gyp:content_shell_crash_service
 568   executable("crash_service") {
 569     sources = [
 570       "tools/content_shell_crash_service.cc",
 571     ]
 572
 573     deps = [
 574       "//base",
 575       "//components/crash/tools:crash_service",
 576     ]
 577
 578     configs -= [ "//build/config/win:console" ]
 579     configs += [ "//build/config/win:windowed" ]
 580   }
 581 }