third_party/libxslt/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 config("libxslt_config") {
   6   defines = [ "LIBXSLT_STATIC" ]
   7   include_dirs = [ "." ]
   8 }
   9
  10 static_library("libxslt") {
  11   sources = [
  12     "libxslt/attributes.c",
  13     "libxslt/attributes.h",
  14     "libxslt/attrvt.c",
  15     "libxslt/documents.c",
  16     "libxslt/documents.h",
  17     "libxslt/extensions.c",
  18     "libxslt/extensions.h",
  19     "libxslt/extra.c",
  20     "libxslt/extra.h",
  21     "libxslt/functions.c",
  22     "libxslt/functions.h",
  23     "libxslt/imports.c",
  24     "libxslt/imports.h",
  25     "libxslt/keys.c",
  26     "libxslt/keys.h",
  27     "libxslt/libxslt.h",
  28     "libxslt/namespaces.c",
  29     "libxslt/namespaces.h",
  30     "libxslt/numbers.c",
  31     "libxslt/numbersInternals.h",
  32     "libxslt/pattern.c",
  33     "libxslt/pattern.h",
  34     "libxslt/preproc.c",
  35     "libxslt/preproc.h",
  36     "libxslt/security.c",
  37     "libxslt/security.h",
  38     "libxslt/templates.c",
  39     "libxslt/templates.h",
  40     "libxslt/transform.c",
  41     "libxslt/transform.h",
  42     "libxslt/trio.h",
  43     "libxslt/triodef.h",
  44     "libxslt/variables.c",
  45     "libxslt/variables.h",
  46     "libxslt/win32config.h",
  47     "libxslt/xslt.c",
  48     "libxslt/xslt.h",
  49     "libxslt/xsltInternals.h",
  50     "libxslt/xsltconfig.h",
  51     "libxslt/xsltexports.h",
  52     "libxslt/xsltlocale.c",
  53     "libxslt/xsltlocale.h",
  54     "libxslt/xsltutils.c",
  55     "libxslt/xsltutils.h",
  56     "libxslt/xsltwin32config.h",
  57     "linux/config.h",
  58     "mac/config.h",
  59     "win32/config.h",
  60   ]
  61
  62   config("libxslt_warnings") {
  63     if (is_clang) {
  64       cflags = [
  65         # libxslt stores a char[3] in a `const unsigned char*`.
  66         "-Wno-pointer-sign",
  67
  68         # xsltDefaultRegion and xsltCalibrateTimestamps are only
  69         # used with certain preprocessor defines set.
  70         "-Wno-unused-function",
  71       ]
  72     }
  73   }
  74   configs -= [ "//build/config/compiler:chromium_code" ]
  75   configs += [ "//build/config/compiler:no_chromium_code" ]
  76   configs += [ ":libxslt_warnings" ]
  77   public_configs = [ ":libxslt_config" ]
  78
  79   cflags = []
  80   if (is_linux || is_android) {
  81     include_dirs = [ "linux" ]
  82   } else if (is_win) {
  83     include_dirs = [ "win32" ]
  84     cflags += [ "/wd4267" ]  # size_t to int.
  85   } else if (is_mac) {
  86     include_dirs = [ "mac" ]
  87   }
  88
  89   deps = [
  90     "//third_party/libxml",
  91   ]
  92 }