build/toolchain/android/BUILD.gn

   1 # Copyright 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/sysroot.gni")  # Imports android/config.gni.
   6 import("//build/toolchain/ccache.gni")
   7 import("//build/toolchain/clang.gni")
   8 import("//build/toolchain/goma.gni")
   9 import("//build/toolchain/gcc_toolchain.gni")
  10
  11 # The Android GCC toolchains share most of the same parameters, so we have this
  12 # wrapper around gcc_toolchain to avoid duplication of logic.
  13 #
  14 # Parameters:
  15 #  - android_ndk_sysroot
  16 #      Sysroot for this architecture.
  17 #  - android_ndk_lib_dir
  18 #      Subdirectory inside of android_ndk_sysroot where libs go.
  19 #  - tool_prefix
  20 #      Prefix to be added to the tool names.
  21 #  - toolchain_cpu
  22 #      Same as gcc_toolchain
  23 template("android_gcc_toolchain") {
  24   gcc_toolchain(target_name) {
  25     # Make our manually injected libs relative to the build dir.
  26     android_ndk_lib = rebase_path(
  27             invoker.android_ndk_sysroot + "/" + invoker.android_ndk_lib_dir,
  28             root_build_dir)
  29
  30     libs_section_prefix = "$android_ndk_lib/crtbegin_dynamic.o"
  31     libs_section_postfix = "$android_ndk_lib/crtend_android.o"
  32
  33     solink_libs_section_prefix = "$android_ndk_lib/crtbegin_so.o"
  34     solink_libs_section_postfix = "$android_ndk_lib/crtend_so.o"
  35
  36     # The tools should be run relative to the build dir.
  37     tool_prefix = rebase_path(invoker.tool_prefix, root_build_dir)
  38
  39     if (use_goma) {
  40       assert(!use_ccache, "Goma and ccache can't be used together.")
  41       compiler_prefix = "$goma_dir/gomacc "
  42     } else if (use_ccache) {
  43       compiler_prefix = "ccache "
  44     } else {
  45       compiler_prefix = ""
  46     }
  47
  48     is_clang = invoker.is_clang
  49     if (is_clang) {
  50       if (use_clang_type_profiler) {
  51         prefix = rebase_path("//third_party/llvm-allocated-type/Linux_x64/bin",
  52                              root_build_dir)
  53       } else {
  54         prefix = rebase_path("//third_party/llvm-build/Release+Asserts/bin",
  55                              root_build_dir)
  56       }
  57       cc = "${compiler_prefix}$prefix/clang"
  58       cxx = "${compiler_prefix}$prefix/clang++"
  59     } else {
  60       cc = "${compiler_prefix}${tool_prefix}gcc"
  61       cxx = "${compiler_prefix}${tool_prefix}g++"
  62     }
  63     ar = tool_prefix + "ar"
  64     ld = cxx
  65     readelf = compiler_prefix + tool_prefix + "readelf"
  66     nm = compiler_prefix + tool_prefix + "nm"
  67     strip = "${tool_prefix}strip"
  68
  69     toolchain_os = "android"
  70     toolchain_cpu = invoker.toolchain_cpu
  71   }
  72 }
  73
  74 template("android_gcc_toolchains_helper") {
  75   android_gcc_toolchain(target_name) {
  76     android_ndk_sysroot = invoker.android_ndk_sysroot
  77     android_ndk_lib_dir = invoker.android_ndk_lib_dir
  78     tool_prefix = invoker.tool_prefix
  79     toolchain_cpu = invoker.toolchain_cpu
  80   }
  81
  82   android_gcc_toolchain("clang_$target_name") {
  83     android_ndk_sysroot = invoker.android_ndk_sysroot
  84     android_ndk_lib_dir = invoker.android_ndk_lib_dir
  85     tool_prefix = invoker.tool_prefix
  86     toolchain_cpu = invoker.toolchain_cpu
  87     is_clang = true
  88   }
  89 }
  90
  91 android_gcc_toolchains_helper("x86") {
  92   android_ndk_sysroot = "$android_ndk_root/$x86_android_sysroot_subdir"
  93   android_ndk_lib_dir = "usr/lib"
  94
  95   tool_prefix = "$x86_android_toolchain_root/bin/i686-linux-android-"
  96   toolchain_cpu = "x86"
  97 }
  98
  99 android_gcc_toolchains_helper("arm") {
 100   android_ndk_sysroot = "$android_ndk_root/$arm_android_sysroot_subdir"
 101   android_ndk_lib_dir = "usr/lib"
 102
 103   tool_prefix = "$arm_android_toolchain_root/bin/arm-linux-androideabi-"
 104   toolchain_cpu = "arm"
 105 }
 106
 107 android_gcc_toolchains_helper("mipsel") {
 108   android_ndk_sysroot = "$android_ndk_root/$mips_android_sysroot_subdir"
 109   android_ndk_lib_dir = "usr/lib"
 110
 111   tool_prefix = "$mips_android_toolchain_root/bin/mipsel-linux-android-"
 112   toolchain_cpu = "mipsel"
 113 }
 114
 115 android_gcc_toolchains_helper("x64") {
 116   android_ndk_sysroot = "$android_ndk_root/$x86_64_android_sysroot_subdir"
 117   android_ndk_lib_dir = "usr/lib64"
 118
 119   tool_prefix = "$x86_64_android_toolchain_root/bin/x86_64-linux-android-"
 120   toolchain_cpu = "x86_64"
 121 }
 122
 123 android_gcc_toolchains_helper("arm64") {
 124   android_ndk_sysroot = "$android_ndk_root/$arm64_android_sysroot_subdir"
 125   android_ndk_lib_dir = "usr/lib"
 126
 127   tool_prefix = "$arm64_android_toolchain_root/bin/arm-linux-androideabi-"
 128   toolchain_cpu = "aarch64"
 129 }
 130
 131 android_gcc_toolchains_helper("mips64el") {
 132   android_ndk_sysroot = "$android_ndk_root/$mips64_android_sysroot_subdir"
 133   android_ndk_lib_dir = "usr/lib64"
 134
 135   tool_prefix = "$mips64_android_toolchain_root/bin/mipsel-linux-android-"
 136   toolchain_cpu = "mipsel64el"
 137 }