chrome/renderer/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//tools/grit/grit_rule.gni")
   7
   8 gypi_values = exec_script("//build/gypi_to_gn.py",
   9                           [ rebase_path("../chrome_renderer.gypi") ],
  10                           "scope",
  11                           [ "../chrome_renderer.gypi" ])
  12
  13 # GYP version: chrome/chrome_resources.gyp:chrome_resources
  14 # (generate_renderer_resources action)
  15 grit("resources") {
  16   source = "resources/renderer_resources.grd"
  17   output_dir = "$root_gen_dir/chrome"
  18   output_name = "renderer_resources"
  19   outputs = [
  20     "grit/renderer_resources.h",
  21     "renderer_resources_100_percent.pak",
  22     "renderer_resources_200_percent.pak",
  23     "renderer_resources_300_percent.pak",
  24   ]
  25 }
  26
  27 static_library("renderer") {
  28   sources = rebase_path(gypi_values.chrome_renderer_sources, ".", "..")
  29
  30   defines = []
  31
  32   deps = [
  33     "//base/allocator",
  34     "//chrome/common",
  35     "//chrome/common/net",
  36     "//chrome:resources",
  37     "//chrome:strings",
  38     "//components/autofill/content/renderer",
  39     "//components/cdm/renderer",
  40     "//components/data_reduction_proxy/content/common",
  41     "//components/network_hints/renderer",
  42     "//components/error_page/renderer",
  43     "//components/password_manager/content/renderer",
  44     "//components/plugins/renderer",
  45     "//components/printing/renderer:printing_renderer",
  46     "//components/startup_metric_utils",
  47     "//components/translate/content/renderer",
  48     "//components/translate/core/common",
  49     "//components/translate/core/language_detection",
  50     "//components/visitedlink/renderer",
  51     "//components/web_cache/renderer",
  52     "//content/app/resources",
  53     "//content/app/strings",
  54     "//content/public/renderer",
  55     "//net",
  56     "//skia",
  57     "//storage/common",
  58     "//third_party/WebKit/public:blink",
  59     "//third_party/WebKit/public:resources",
  60     "//third_party/icu",
  61     "//third_party/npapi",
  62     "//third_party/re2",
  63     "//third_party/widevine/cdm:version_h",
  64     "//ui/surface",
  65     "//v8:v8",
  66   ]
  67
  68   if (enable_nacl) {
  69     deps += [
  70       "//components/nacl",
  71       "//components/nacl:nacl_renderer",
  72     ]
  73   }
  74
  75   if (enable_plugins) {
  76     sources +=
  77         rebase_path(gypi_values.chrome_renderer_plugin_sources, ".", "..")
  78     deps += [
  79       "//components/pdf/renderer",
  80       "//ppapi/host",
  81       "//ppapi/proxy",
  82       "//ppapi/proxy:ipc",
  83       "//ppapi/shared_impl",
  84     ]
  85   }
  86
  87   if (safe_browsing_mode == 1) {
  88     sources += rebase_path(gypi_values.chrome_renderer_safe_browsing_sources,
  89                            ".",
  90                            "..")
  91     sources +=
  92         rebase_path(gypi_values.chrome_renderer_basic_safe_browsing_sources,
  93                     ".",
  94                     "..")
  95     defines += [ "FULL_SAFE_BROWSING" ]
  96     deps += [
  97       "//chrome/common/safe_browsing:proto",
  98       "//third_party/smhasher:murmurhash3",
  99     ]
 100   }
 101   if (safe_browsing_mode == 2) {
 102     sources +=
 103         rebase_path(gypi_values.chrome_renderer_basic_safe_browsing_sources,
 104                     ".",
 105                     "..")
 106     defines += [ "MOBILE_SAFE_BROWSING" ]
 107   }
 108
 109   if (enable_extensions) {
 110     sources +=
 111         rebase_path(gypi_values.chrome_renderer_extensions_sources, ".", "..")
 112     deps += [
 113       # TODO(hclam): See crbug.com/298380 for details.
 114       # We should isolate the APIs needed by the renderer.
 115       "//chrome/common/extensions/api",
 116       "//extensions:extensions_resources",
 117       "//extensions/renderer",
 118       "//media/cast:net",
 119       "//media/cast:receiver",
 120       "//media/cast:sender",
 121       "//media/cast/logging/proto",
 122     ]
 123     if (!enable_webrtc) {
 124       sources -= [
 125         "media/cast_receiver_session.cc",
 126         "media/cast_receiver_session.h",
 127         "media/cast_rtp_stream.cc",
 128         "media/cast_rtp_stream.h",
 129       ]
 130     }
 131   }
 132   if (enable_webrtc) {
 133     sources +=
 134         rebase_path(gypi_values.chrome_renderer_webrtc_sources, ".", "..")
 135   }
 136   if (enable_extensions && enable_webrtc) {
 137     sources +=
 138         rebase_path(gypi_values.chrome_renderer_webrtc_extensions_sources,
 139                     ".",
 140                     "..")
 141   }
 142   if (enable_spellcheck) {
 143     sources +=
 144         rebase_path(gypi_values.chrome_renderer_spellchecker_sources, ".", "..")
 145     deps += [ "//third_party/hunspell" ]
 146   }
 147
 148   if (enable_basic_printing || enable_print_preview) {
 149     deps += [ "//printing" ]
 150     sources +=
 151         rebase_path(gypi_values.chrome_renderer_printing_sources, ".", "..")
 152     if (enable_print_preview) {
 153       sources += rebase_path(gypi_values.chrome_renderer_full_printing_sources,
 154                              ".",
 155                              "..")
 156     }
 157   }
 158
 159   if (is_mac) {
 160     deps += [ "//third_party/mach_override" ]
 161   }
 162   if (is_win) {
 163     deps += [
 164       "//chrome_elf",
 165       "//third_party/wtl",
 166     ]
 167   }
 168   if (!is_android) {
 169     sources +=
 170         rebase_path(gypi_values.chrome_renderer_non_android_sources, ".", "..")
 171   }
 172 }
 173
 174 # In GYP this is part of test_support_common.
 175 source_set("test_support") {
 176   testonly = true
 177   visibility = [ "//chrome/test:test_support" ]
 178
 179   sources = [
 180     "chrome_mock_render_thread.cc",
 181     "chrome_mock_render_thread.h",
 182     "safe_browsing/mock_feature_extractor_clock.cc",
 183     "safe_browsing/mock_feature_extractor_clock.h",
 184     "safe_browsing/test_utils.cc",
 185     "safe_browsing/test_utils.h",
 186   ]
 187
 188   deps = [
 189     ":renderer",
 190     "//content/test:test_support",
 191     "//testing/gmock",
 192     "//testing/gtest",
 193   ]
 194
 195   if (enable_print_preview) {
 196     deps += [ "//chrome/service" ]
 197   }
 198
 199   if (enable_webrtc) {
 200     sources += [
 201       "media/mock_webrtc_logging_message_filter.cc",
 202       "media/mock_webrtc_logging_message_filter.h",
 203     ]
 204   }
 205 }