mandoline/services/core_services/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4 #
   5 # core_services should be thought of as a bundle of many of the services which
   6 # we ship with.
   7
   8 import("//build/config/ui.gni")
   9 import("//mojo/public/mojo_application.gni")
  10
  11 if (is_android) {
  12   import("//build/config/android/rules.gni")
  13
  14   java_library_path = "$target_out_dir/java_library.dex.jar"
  15
  16   mojo_android_application("core_services") {
  17     input_so = "$root_out_dir/lib.stripped/libcore_services.so"
  18     input_dex_jar = java_library_path
  19     deps = [
  20       ":java_library",
  21       ":native_library",
  22     ]
  23   }
  24
  25   shared_library("native_library") {
  26     output_name = "core_services"
  27
  28     sources = [
  29       "android_hooks.cc",
  30     ]
  31
  32     deps = [
  33       ":sources",
  34       "//base",
  35       "//components/resource_provider:jni_headers",
  36       "//net",
  37       "//third_party/mojo/src/mojo/public/c/system:for_shared_library",
  38     ]
  39   }
  40
  41   android_standalone_library("java_library") {
  42     dex_path = java_library_path
  43
  44     deps = [
  45       "//components/resource_provider:java_library",
  46       "//net/android:net_java",
  47     ]
  48   }
  49 } else {
  50   mojo_native_application("core_services") {
  51     deps = [
  52       ":sources",
  53     ]
  54   }
  55 }
  56
  57 source_set("sources") {
  58   sources = [
  59     "core_services_application_delegate.cc",
  60     "main.cc",
  61   ]
  62
  63   deps = [
  64     "//base",
  65     "//components/clipboard:lib",
  66     "//components/filesystem:lib",
  67     "//components/resource_provider:lib",
  68     "//components/view_manager:lib",
  69     "//components/view_manager/surfaces:lib",
  70     "//mandoline/ui/browser:lib",
  71     "//mojo/application/public/cpp",
  72     "//mojo/common:tracing_impl",
  73     "//mojo/services/network:lib",
  74     "//mojo/services/tracing:lib",
  75   ]
  76
  77   if (use_aura) {
  78     deps += [
  79       "//components/view_manager/public/cpp",
  80       "//mandoline/ui/omnibox:lib",
  81     ]
  82   }
  83 }