chrome/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/crypto.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/ui.gni")
   9 import("//third_party/protobuf/proto_library.gni")
  10
  11 # //build/config/android/rules.gni imports //tools/grit/grit_rule.gni, which
  12 # produces a conflict for the "grit" template so we have to only include one.
  13 if (is_android) {
  14   import("//build/config/android/rules.gni")
  15 } else {
  16   import("//tools/grit/grit_rule.gni")
  17 }
  18 if (is_desktop_linux) {
  19   import("//build/config/linux/pkg_config.gni")
  20 }
  21
  22 declare_args() {
  23   # 'Ok Google' hotwording is disabled by default. Set to true to enable. (This
  24   # will download a closed-source NaCl module at startup.) Chrome-branded
  25   # ChromeOS builds have this enabled by default.
  26   enable_hotwording = is_chrome_branded && is_chromeos
  27 }
  28
  29 about_credits_file = "$target_gen_dir/about_credits.html"
  30 additional_modules_list_file =
  31     "$root_gen_dir/chrome/browser/internal/additional_modules_list.txt"
  32
  33 gypi_values = exec_script("//build/gypi_to_gn.py",
  34                           [ rebase_path("../chrome_browser.gypi") ],
  35                           "scope",
  36                           [ "../chrome_browser.gypi" ])
  37
  38 if (is_win) {
  39   # This is in a separate config so the flags can be applied to dependents.
  40   # ldflags in GN aren't automatically inherited.
  41   config("browser_win_linker_flags") {
  42     libs = [
  43       "credui.lib",
  44       "netapi32.lib",
  45       "ndfapi.lib",  # Used by browser/net/net_error_diagnostics_dialog_win.h
  46     ]
  47     ldflags = [ "/DELAYLOAD:ndfapi.dll" ]
  48   }
  49 }
  50
  51 if (is_desktop_linux) {
  52   # Gnome-keyring is normally dynamically loaded. The gnome_keyring config
  53   # will set this up.
  54   pkg_config("gnome_keyring") {
  55     packages = [ "gnome-keyring-1" ]
  56     defines = [
  57       "USE_GNOME_KEYRING",
  58       "DLOPEN_GNOME_KEYRING",
  59     ]
  60     ignore_libs = true
  61   }
  62
  63   # If you want to link gnome-keyring directly (use only for unit tests)
  64   # ADDITIONALLY add this config on top of ":gnome_keyring". pkg-config is a
  65   # bit slow, so prefer not to run it again. In practice, gnome-keyring's libs
  66   # are just itself and common gnome ones we link already, so we can get away
  67   # with additionally just coding the library name here.
  68   config("gnome_keyring_direct") {
  69     libs = [ "gnome-keyring" ]
  70   }
  71 }
  72
  73 source_set("browser") {
  74   configs += [
  75     "//build/config/compiler:wexit_time_destructors",
  76     "//build/config:precompiled_headers",
  77     "//third_party/WebKit/public:debug_devtools",
  78   ]
  79   defines = []
  80   sources = []
  81   libs = []
  82   ldflags = []
  83
  84   # iOS/non-iOS shared deps. New dependencies should generally be added in the
  85   # non-iOS deps below.
  86   public_deps = [
  87     "//components/autofill/core/browser",
  88     "//content/public/browser",
  89     "//sql",
  90     "//sync",
  91   ]
  92   deps = [
  93     "//base/allocator",
  94     "//chrome:extra_resources",
  95     "//chrome:resources",
  96     "//chrome:strings",
  97     "//chrome/app:generated_resources_map",
  98     "//chrome/app/resources:platform_locale_settings",
  99     "//chrome/app/theme:theme_resources",
 100     "//chrome/browser/net:encrypted_cert_logger_proto",
 101     "//chrome/browser/net:probe_message_proto",
 102     "//chrome/browser/ssl:cert_logger_proto",
 103     "//chrome/browser/ui",
 104     "//chrome/common",
 105     "//components/autofill/core/browser",
 106     "//components/bookmarks/browser",
 107     "//components/bookmarks/managed",
 108     "//components/captive_portal",
 109     "//components/cloud_devices/common",
 110     "//components/component_updater",
 111     "//components/compression",
 112     "//components/content_settings/content/common",
 113     "//components/content_settings/core/browser",
 114     "//components/content_settings/core/common",
 115     "//components/crx_file",
 116     "//components/data_reduction_proxy/core/browser",
 117     "//components/device_event_log",
 118     "//components/domain_reliability",
 119     "//components/enhanced_bookmarks",
 120     "//components/favicon/core",
 121     "//components/favicon_base",
 122     "//components/gcm_driver",
 123     "//components/gcm_driver/instance_id",
 124     "//components/google/core/browser",
 125     "//components/guest_view/browser",
 126     "//components/handoff",
 127     "//components/history/core/browser",
 128     "//components/history/core/common",
 129     "//components/infobars/core",
 130     "//components/invalidation/impl",
 131     "//components/metrics:gpu",
 132     "//components/metrics:net",
 133     "//components/metrics:profiler",
 134     "//components/metrics/proto:proto",
 135     "//components/mime_util",
 136     "//components/navigation_metrics",
 137     "//components/network_time",
 138     "//components/offline_pages",
 139     "//components/omnibox/browser",
 140     "//components/os_crypt",
 141     "//components/packed_ct_ev_whitelist",
 142     "//components/password_manager/core/browser",
 143     "//components/password_manager/core/common",
 144     "//components/policy:policy_component",
 145     "//components/proxy_config",
 146     "//components/query_parser",
 147     "//components/rappor",
 148     "//components/renderer_context_menu",
 149     "//components/search",
 150     "//components/search_engines",
 151     "//components/search_provider_logos",
 152     "//components/security_interstitials/core",
 153     "//components/signin/core/browser",
 154     "//components/startup_metric_utils",
 155     "//components/strings",
 156     "//components/suggestions",
 157     "//components/sync_driver",
 158     "//components/tracing:startup_tracing",
 159     "//components/translate/core/browser",
 160     "//components/translate/core/common",
 161     "//components/ui/zoom",
 162     "//components/undo",
 163     "//components/update_client",
 164     "//components/url_formatter",
 165     "//components/user_prefs",
 166     "//components/user_prefs/tracked:user_prefs_tracked",
 167     "//components/variations",
 168     "//components/variations/net",
 169     "//components/variations/service",
 170     "//components/webdata/common",
 171     "//components/webdata_services",
 172     "//components/web_resource",
 173     "//content/public/browser",
 174     "//content/public/common",
 175     "//courgette:courgette_lib",
 176     "//crypto",
 177     "//google_apis",
 178     "//gpu/config",
 179     "//skia",
 180     "//sql",
 181     "//sync",
 182     "//third_party/cacheinvalidation",
 183     "//third_party/icu",
 184     "//third_party/libxml",
 185     "//third_party/libjingle",
 186     "//third_party/widevine/cdm:version_h",
 187     "//third_party/zlib",
 188     "//third_party/zlib:minizip",
 189     "//third_party/zlib:zip",
 190     "//ui/base",
 191     "//ui/events:events_base",
 192     "//ui/gfx",
 193     "//ui/gfx/geometry",
 194     "//ui/message_center",
 195     "//ui/shell_dialogs",
 196     "//ui/strings",
 197     "//ui/resources",
 198   ]
 199
 200   sources +=
 201       rebase_path(gypi_values.chrome_browser_undo_sources, ".", "//chrome")
 202
 203   if (!is_ios) {
 204     sources +=
 205         rebase_path(gypi_values.chrome_browser_non_ios_sources, ".", "//chrome")
 206     sources += rebase_path(gypi_values.chrome_browser_autocomplete_sources,
 207                            ".",
 208                            "//chrome")
 209     sources += rebase_path(gypi_values.chrome_browser_bookmark_sources,
 210                            ".",
 211                            "//chrome")
 212     sources += rebase_path(gypi_values.chrome_browser_browser_process_sources,
 213                            ".",
 214                            "//chrome")
 215     sources += rebase_path(gypi_values.chrome_browser_content_settings_sources,
 216                            ".",
 217                            "//chrome")
 218     sources += rebase_path(gypi_values.chrome_browser_engagement_sources,
 219                            ".",
 220                            "//chrome")
 221     sources +=
 222         rebase_path(gypi_values.chrome_browser_favicon_sources, ".", "//chrome")
 223     sources +=
 224         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 225     sources +=
 226         rebase_path(gypi_values.chrome_browser_history_sources, ".", "//chrome")
 227     sources +=
 228         rebase_path(gypi_values.chrome_browser_metrics_sources, ".", "//chrome")
 229     sources +=
 230         rebase_path(gypi_values.chrome_browser_net_sources, ".", "//chrome")
 231     sources += rebase_path(gypi_values.chrome_browser_password_manager_sources,
 232                            ".",
 233                            "//chrome")
 234     sources += rebase_path(gypi_values.chrome_browser_permissions_sources,
 235                            ".",
 236                            "//chrome")
 237     sources += rebase_path(gypi_values.chrome_browser_predictor_sources,
 238                            ".",
 239                            "//chrome")
 240     sources +=
 241         rebase_path(gypi_values.chrome_browser_pref_sources, ".", "//chrome")
 242     sources += rebase_path(gypi_values.chrome_browser_profiles_sources,
 243                            ".",
 244                            "//chrome")
 245     sources += rebase_path(gypi_values.chrome_browser_search_engines_sources,
 246                            ".",
 247                            "//chrome")
 248     sources += rebase_path(gypi_values.chrome_browser_services_sources,
 249                            ".",
 250                            "//chrome")
 251     sources +=
 252         rebase_path(gypi_values.chrome_browser_session_sources, ".", "//chrome")
 253     sources +=
 254         rebase_path(gypi_values.chrome_browser_signin_sources, ".", "//chrome")
 255     sources +=
 256         rebase_path(gypi_values.chrome_browser_ssl_sources, ".", "//chrome")
 257     sources +=
 258         rebase_path(gypi_values.chrome_browser_sync_sources, ".", "//chrome")
 259     sources += rebase_path(gypi_values.chrome_browser_web_resource_sources,
 260                            ".",
 261                            "//chrome")
 262
 263     deps += [
 264       "//apps",
 265       "//cc",
 266       "//chrome/app:generated_resources_map",
 267       "//chrome/app/theme:theme_resources",
 268       "//chrome/browser/devtools",
 269       "//chrome/browser/resources:component_extension_resources",
 270       "//chrome/common/net",
 271       "//chrome/installer/util",
 272       "//components/about_handler",
 273       "//components/app_modal",
 274       "//components/autofill/content/browser",
 275       "//components/browsing_data",
 276       "//components/data_reduction_proxy/content/browser",
 277       "//components/devtools_discovery",
 278       "//components/devtools_http_handler",
 279       "//components/dom_distiller/content:content_browser",
 280       "//components/favicon/content",
 281       "//components/history/content/browser",
 282       "//components/keyed_service/content",
 283       "//components/navigation_interception",
 284       "//components/password_manager/content/browser",
 285       "//components/password_manager/sync/browser",
 286       "//components/plugins/common",
 287       "//components/proxy_config",
 288       "//components/safe_json",
 289       "//components/sessions",
 290       "//components/storage_monitor",
 291       "//components/translate/content/browser",
 292       "//components/upload_list",
 293       "//components/url_matcher",
 294       "//components/visitedlink/browser",
 295       "//components/visitedlink/common",
 296       "//components/web_cache/browser",
 297       "//components/web_modal",
 298       "//content/app/resources",
 299       "//media",
 300       "//mojo/application/public/cpp",
 301       "//mojo/common",
 302       "//mojo/environment:chromium",
 303       "//net:extras",
 304       "//net:net_with_v8",
 305       "//storage/browser",
 306       "//storage/common",
 307       "//third_party/WebKit/public:image_resources",
 308       "//third_party/WebKit/public:resources",
 309       "//third_party/leveldatabase",
 310       "//third_party/libaddressinput",
 311       "//third_party/libyuv",
 312       "//third_party/mojo/src/mojo/edk/system",
 313       "//third_party/mojo/src/mojo/public/cpp/bindings",
 314       "//third_party/mojo/src/mojo/public/js",
 315       "//third_party/re2",
 316       "//third_party/smhasher:cityhash",
 317       "//third_party/webrtc/modules/desktop_capture",
 318       "//ui/base/ime",
 319       "//ui/gl",
 320       "//ui/resources",
 321       "//ui/surface",
 322       "//ui/web_dialogs",
 323       "//v8",
 324     ]
 325
 326     if (toolkit_views) {
 327       deps += [ "//ui/views" ]
 328     }
 329   } else {  # iOS
 330     sources +=
 331         rebase_path(gypi_values.chrome_browser_ios_sources, ".", "//chrome")
 332     sources +=
 333         rebase_path(gypi_values.chrome_browser_google_sources, ".", "//chrome")
 334     deps += [ "//net" ]
 335     libs += [
 336       "CoreTelephony.framework",
 337       "CoreText.framework",
 338       "MobileCoreServices.framework",
 339       "QuartzCore.framework",
 340     ]
 341     ldflags += [
 342       "-weak_framework",
 343       "CoreImage",
 344     ]
 345   }
 346
 347   if (is_win || is_mac) {
 348     sources +=
 349         rebase_path(gypi_values.chrome_browser_win_mac_sources, ".", "//chrome")
 350   }
 351   if (!is_win && !is_mac && !is_ios) {
 352     sources += [ "net/net_error_diagnostics_dialog_generic.cc" ]
 353   }
 354   if (!is_android && !is_ios && !is_chromeos && enable_configuration_policy) {
 355     sources += [
 356       "net/disk_cache_dir_policy_handler.cc",
 357       "net/disk_cache_dir_policy_handler.h",
 358     ]
 359   }
 360   if (!is_android && !is_ios && enable_configuration_policy) {
 361     sources += [
 362       "download/download_dir_policy_handler.cc",
 363       "download/download_dir_policy_handler.h",
 364     ]
 365   }
 366   if (is_mac) {
 367     sources +=
 368         rebase_path(gypi_values.chrome_browser_mac_sources, ".", "//chrome")
 369     deps += [
 370       #"app_shim"  TODO(GYP) bug 512600
 371       #"browser_app_shim"  TODO(GYP) bug 512600
 372     ]
 373   }
 374   if (enable_extensions) {
 375     public_deps += [ "//chrome/browser/extensions" ]
 376     deps += [
 377       "//chrome/browser/sync_file_system/drive_backend:sync_file_system_drive_proto",
 378       "//chrome/common/extensions/api",
 379       "//chrome/common/extensions/api:api_registration",
 380       "//components/drive:drive",
 381       "//components/proximity_auth/ble",
 382       "//components/proximity_auth/cryptauth",
 383       "//extensions/components/javascript_dialog_extensions_client",
 384       "//media/cast:net",
 385     ]
 386     sources += rebase_path(gypi_values.chrome_browser_extensions_sources,
 387                            ".",
 388                            "//chrome")
 389   }
 390   if (enable_background) {
 391     sources += rebase_path(gypi_values.chrome_browser_background_sources,
 392                            ".",
 393                            "//chrome")
 394     if (!use_aura || is_win || is_chromeos) {
 395       sources -= [ "background/background_mode_manager_aura.cc" ]
 396     }
 397   }
 398   if (enable_task_manager) {
 399     sources += rebase_path(gypi_values.chrome_browser_task_manager_sources,
 400                            ".",
 401                            "//chrome")
 402   }
 403   if (enable_spellcheck) {
 404     sources += rebase_path(gypi_values.chrome_browser_spellchecker_sources,
 405                            ".",
 406                            "//chrome")
 407     if (!is_android) {
 408       deps += [ "//third_party/hunspell" ]
 409     }
 410   }
 411   if (enable_nacl) {
 412     sources +=
 413         rebase_path(gypi_values.chrome_browser_nacl_sources, ".", "//chrome")
 414     deps += [ "//components/nacl:nacl_browser" ]
 415   }
 416
 417   if (enable_configuration_policy) {
 418     sources +=
 419         rebase_path(gypi_values.chrome_browser_policy_shared_with_ios_sources,
 420                     ".",
 421                     "//chrome")
 422     deps += [
 423       "//components/policy",
 424       "//components/policy/proto",
 425     ]
 426     if (!is_ios) {
 427       sources += rebase_path(gypi_values.chrome_browser_policy_non_ios_sources,
 428                              ".",
 429                              "//chrome")
 430     }
 431     if (!is_chromeos) {
 432       sources += rebase_path(
 433               gypi_values.chrome_browser_policy_shared_with_ios_not_chromeos_sources,
 434               ".",
 435               "//chrome")
 436     }
 437     if (is_win || is_mac || is_desktop_linux) {
 438       sources += rebase_path(gypi_values.chrome_browser_policy_desktop_sources,
 439                              ".",
 440                              "//chrome")
 441     }
 442     if (is_android || is_ios) {
 443       sources += rebase_path(gypi_values.chrome_browser_policy_mobile_sources,
 444                              ".",
 445                              "//chrome")
 446     } else {
 447       deps += [
 448         "//chrome/browser/policy:path_parser",
 449         "//net:net_browser_services",
 450       ]
 451     }
 452   } else {
 453     # Configuration policy disabled.
 454     sources += rebase_path(gypi_values.chrome_browser_policy_disabled_sources,
 455                            ".",
 456                            "//chrome")
 457   }
 458
 459   if (enable_plugins) {
 460     sources +=
 461         rebase_path(gypi_values.chrome_browser_plugins_sources, ".", "//chrome")
 462     deps += [
 463       "//components/pdf/browser",
 464       "//ppapi/proxy:ipc",
 465       "//third_party/adobe/flash:flapper_version_h",
 466     ]
 467   }
 468   if (safe_browsing_mode != 0) {
 469     sources +=
 470         rebase_path(gypi_values.chrome_browser_safe_browsing_basic_sources,
 471                     ".",
 472                     "//chrome")
 473     deps += [
 474       "//chrome/browser/safe_browsing:chunk_proto",
 475       "//chrome/browser/safe_browsing:metadata_proto",
 476       "//chrome/browser/safe_browsing:report_proto",
 477     ]
 478     if (safe_browsing_mode == 1) {
 479       sources +=
 480           rebase_path(gypi_values.chrome_browser_safe_browsing_full_sources,
 481                       ".",
 482                       "//chrome")
 483       deps += [ "//chrome/common/safe_browsing:proto" ]
 484     } else if (safe_browsing_mode == 3) {
 485       sources += rebase_path(
 486               gypi_values.chrome_browser_safe_browsing_mobile_extended_sources,
 487               ".",
 488               "//chrome")
 489     }
 490   }
 491
 492   if (enable_hotwording) {
 493     defines += [ "ENABLE_HOTWORDING" ]
 494   }
 495
 496   if (is_linux) {
 497     deps += [ "//device/media_transfer_protocol" ]
 498   }
 499
 500   if (use_udev) {
 501     deps += [ "//device/udev_linux" ]
 502   }
 503
 504   if (is_linux && !is_chromeos) {
 505     deps += [ "//third_party/speech-dispatcher" ]
 506   }
 507
 508   if (is_chromeos) {
 509     sources += rebase_path(gypi_values.chrome_browser_chromeos_sources,
 510                            ".",
 511                            "//chrome")
 512     deps += [ "//chrome/browser/chromeos" ]
 513   } else {
 514     # Non-ChromeOS.
 515     sources += rebase_path(gypi_values.chrome_browser_non_chromeos_sources,
 516                            ".",
 517                            "//chrome")
 518   }
 519
 520   if (is_ios) {
 521     sources -= [
 522       "metrics/signin_status_metrics_provider_base.cc",
 523       "metrics/signin_status_metrics_provider_base.h",
 524     ]
 525   }
 526
 527   if (is_chromeos || is_ios) {
 528     sources -= [
 529       "metrics/signin_status_metrics_provider.cc",
 530       "metrics/signin_status_metrics_provider.h",
 531     ]
 532   }
 533
 534   if (use_cups) {
 535     configs += [ "//printing:cups" ]
 536   }
 537   if (is_desktop_linux) {
 538     sources += rebase_path(gypi_values.chrome_browser_gnome_keyring_sources,
 539                            ".",
 540                            "//chrome")
 541     configs += [ ":gnome_keyring" ]
 542   }
 543   if (is_desktop_linux) {
 544     sources += rebase_path(gypi_values.chrome_browser_libsecret_sources,
 545                            ".",
 546                            "//chrome")
 547     defines += [ "USE_LIBSECRET" ]
 548   }
 549   if (use_aura) {
 550     sources +=
 551         rebase_path(gypi_values.chrome_browser_aura_sources, ".", "//chrome")
 552     deps += [
 553       "//ui/aura",
 554       "//ui/compositor",
 555       "//ui/keyboard",
 556     ]
 557   }
 558   if (ui_compositor_image_transport) {
 559     deps += [ "//ui/gl" ]
 560   }
 561
 562   if (use_ash) {
 563     sources +=
 564         rebase_path(gypi_values.chrome_browser_ash_sources, ".", "//chrome")
 565   }
 566
 567   if (use_x11) {
 568     sources +=
 569         rebase_path(gypi_values.chrome_browser_x11_sources, ".", "//chrome")
 570   } else {
 571     sources -= [ "password_manager/password_store_x.cc" ]
 572   }
 573   if (is_posix && !is_mac && !is_ios) {
 574     sources += [
 575       "//chrome/app/chrome_crash_reporter_client.cc",
 576       "//chrome/app/chrome_crash_reporter_client.h",
 577     ]
 578     deps += [
 579       "//components/crash/app",
 580       "//components/crash/browser",
 581     ]
 582   }
 583   if (use_nss_certs) {
 584     sources +=
 585         rebase_path(gypi_values.chrome_browser_nss_sources, ".", "//chrome")
 586     if (is_chromeos) {
 587       sources -= [ "net/nss_context_linux.cc" ]
 588     }
 589   }
 590   if (enable_notifications) {
 591     sources += rebase_path(gypi_values.chrome_browser_notifications_sources,
 592                            ".",
 593                            "//chrome")
 594     if (!is_android) {
 595       sources += rebase_path(
 596               gypi_values.chrome_browser_notifications_non_android_sources,
 597               ".",
 598               "//chrome")
 599     }
 600   }
 601   if (enable_themes) {
 602     sources +=
 603         rebase_path(gypi_values.chrome_browser_themes_sources, ".", "//chrome")
 604   }
 605
 606   if (enable_basic_printing || enable_print_preview) {
 607     # Some form of printing support.
 608     sources += rebase_path(gypi_values.chrome_browser_printing_basic_sources,
 609                            ".",
 610                            "//chrome")
 611     deps += [
 612       "//printing",
 613       "//components/printing/browser",
 614     ]
 615
 616     if (is_win) {
 617       sources += rebase_path(gypi_values.chrome_browser_printing_emf_sources,
 618                              ".",
 619                              "//chrome")
 620     }
 621     if (enable_print_preview) {
 622       # Full printing on top of the above.
 623       sources += rebase_path(gypi_values.chrome_browser_printing_full_sources,
 624                              ".",
 625                              "//chrome")
 626     } else {
 627       # Partial-only printing support.
 628       sources +=
 629           rebase_path(gypi_values.chrome_browser_printing_basic_only_sources,
 630                       ".",
 631                       "//chrome")
 632     }
 633   }
 634   if (enable_captive_portal_detection) {
 635     sources += rebase_path(gypi_values.chrome_browser_captive_portal_sources,
 636                            ".",
 637                            "//chrome")
 638   }
 639   if (enable_session_service) {
 640     sources += rebase_path(gypi_values.chrome_browser_session_service_sources,
 641                            ".",
 642                            "//chrome")
 643   }
 644
 645   if (!is_android && !is_ios && !is_chromeos) {
 646     sources +=
 647         rebase_path(gypi_values.chrome_browser_desktop_sources, ".", "//chrome")
 648   }
 649
 650   if (is_android || is_ios) {
 651     # Mobile.
 652     sources +=
 653         rebase_path(gypi_values.chrome_browser_mobile_sources, ".", "//chrome")
 654   } else {
 655     # Non-mobile.
 656     sources += rebase_path(gypi_values.chrome_browser_non_mobile_sources,
 657                            ".",
 658                            "//chrome")
 659     deps += [
 660       "//components/feedback",
 661       "//device/core",
 662       "//device/devices_app/public/cpp",
 663       "//device/devices_app/public/cpp:factory",
 664       "//device/usb",
 665     ]
 666   }
 667
 668   if (!is_official_build) {
 669     sources += [
 670       "search/local_files_ntp_source.cc",
 671       "search/local_files_ntp_source.h",
 672     ]
 673   }
 674
 675   if (is_android) {
 676     sources +=
 677         rebase_path(gypi_values.chrome_browser_android_sources, ".", "//chrome")
 678     sources += rebase_path(gypi_values.chrome_browser_bookmark_android_sources,
 679                            ".",
 680                            "//chrome")
 681     deps += [
 682       ":client_discourse_context_proto",
 683       ":delta_file_proto",
 684       ":jni_headers",
 685       "//components/cdm/browser",
 686       "//components/enhanced_bookmarks",
 687       "//components/precache/content",
 688       "//components/precache/core",
 689       "//components/resources:components_resources",
 690       "//components/service_tab_launcher",
 691       "//components/toolbar",
 692       "//components/web_contents_delegate_android",
 693       "//third_party/android_opengl/etc1",
 694       "//third_party/android_tools:cpu_features",
 695       "//third_party/libaddressinput:util",
 696     ]
 697     deps -= [
 698       "//third_party/libaddressinput",
 699       "//components/storage_monitor",
 700       "//components/web_modal",
 701     ]
 702     defines += [ "ENABLE_DATA_REDUCTION_PROXY_DEBUGGING" ]
 703
 704     if (use_seccomp_bpf) {
 705       defines += [ "USE_SECCOMP_BPF" ]
 706       deps += [ "//sandbox/linux:seccomp_bpf" ]
 707     }
 708   }
 709
 710   if (is_mac) {
 711     deps += [
 712       "//third_party/google_toolbox_for_mac",
 713       "//third_party/mozilla",
 714     ]
 715     libs += [
 716       "Accelerate.framework",
 717       "AddressBook.framework",
 718       "AudioUnit.framework",
 719       "DiskArbitration.framework",
 720       "IOKit.framework",
 721       "ImageCaptureCore.framework",
 722       "OpenGL.framework",
 723       "QuartzCore.framework",
 724       "SecurityInterface.framework",
 725     ]
 726   }
 727
 728   if (enable_rlz) {
 729     deps += [ ":rlz" ]
 730   }
 731
 732   # TODO(GYP)
 733   # Temporary fix to break the browser target into smaller chunks so it
 734   # will link with goma builds.
 735   #["OS=="win" and chromium_win_pch==0", {
 736   #  "msvs_shard": 4,
 737   #}],
 738
 739   if (is_win) {
 740     sources +=
 741         rebase_path(gypi_values.chrome_browser_win_sources, ".", "//chrome")
 742     public_deps += [
 743       "//ui/views",
 744       "//ui/views/controls/webview",
 745     ]
 746     deps += [
 747       ":chrome_process_finder",
 748       "//chrome:version_header",
 749       "//chrome/installer/util:strings",
 750       "//chrome_elf",
 751       "//chrome_elf:constants",
 752       "//chrome_elf:dll_hash",
 753       "//components/browser_watcher",
 754       "//components/browser_watcher:browser_watcher_client",
 755       "//google_update",
 756       "//third_party/iaccessible2",
 757       "//third_party/isimpledom",
 758       "//third_party/wtl",
 759       "//ui/metro_viewer",
 760       "//win8:metro_viewer",
 761     ]
 762
 763     all_dependent_configs = [ ":browser_win_linker_flags" ]
 764
 765     if (!is_chrome_branded) {
 766       deps -= [ "//google_update" ]
 767       sources -= [
 768         "google/did_run_updater_win.cc",
 769         "google/did_run_updater_win.h",
 770         "google/google_update_win.cc",
 771         "google/google_update_win.h",
 772       ]
 773     }
 774   } else {
 775     # Non-Windows.
 776     sources +=
 777         rebase_path(gypi_values.chrome_browser_non_win_sources, ".", "//chrome")
 778     if (toolkit_views) {
 779       deps += [
 780         "//ui/views",
 781         "//ui/views/controls/webview",
 782       ]
 783     }
 784   }
 785
 786   if (is_linux) {
 787     sources +=
 788         rebase_path(gypi_values.chrome_browser_linux_sources, ".", "//chrome")
 789     if (use_aura) {
 790       configs += [
 791         "//build/config/linux:dbus",
 792         "//build/config/linux:fontconfig",
 793       ]
 794       deps += [ "//dbus" ]
 795     }
 796     if (use_x11) {
 797       configs += [ "//build/config/linux:x11" ]
 798       deps += [ "//ui/gfx/x" ]
 799     }
 800   }
 801
 802   if (is_desktop_linux) {
 803     sources += rebase_path(gypi_values.chrome_browser_linux_desktop_sources,
 804                            ".",
 805                            "//chrome")
 806   }
 807   if (enable_plugin_installation) {
 808     sources +=
 809         rebase_path(gypi_values.chrome_browser_plugin_installation_sources,
 810                     ".",
 811                     "//chrome")
 812   }
 813   if (enable_app_list) {
 814     deps += [ "//ui/app_list" ]
 815   }
 816   if (enable_supervised_users) {
 817     sources += rebase_path(gypi_values.chrome_browser_supervised_user_sources,
 818                            ".",
 819                            "//chrome")
 820   }
 821   if (enable_supervised_users && !is_android && !is_ios) {
 822     sources +=
 823         rebase_path(gypi_values.chrome_browser_supervised_user_legacy_sources,
 824                     ".",
 825                     "//chrome")
 826   }
 827   if (enable_supervised_users && enable_themes) {
 828     sources += rebase_path(
 829             gypi_values.chrome_browser_supervised_user_and_themes_sources,
 830             ".",
 831             "//chrome")
 832   }
 833   if (enable_webrtc) {
 834     sources +=
 835         rebase_path(gypi_values.chrome_browser_webrtc_sources, ".", "//chrome")
 836   }
 837   if (enable_service_discovery) {
 838     sources += rebase_path(gypi_values.chrome_browser_service_discovery_sources,
 839                            ".",
 840                            "//chrome")
 841   }
 842   if (enable_mdns) {
 843     sources +=
 844         rebase_path(gypi_values.chrome_browser_mdns_sources, ".", "//chrome")
 845   }
 846   if (!enable_autofill_dialog || is_android || is_ios) {
 847     sources -= [
 848       "autofill/validation_rules_storage_factory.cc",
 849       "autofill/validation_rules_storage_factory.h",
 850     ]
 851   }
 852   if (enable_wifi_bootstrapping) {
 853     sources +=
 854         rebase_path(gypi_values.chrome_browser_wifi_bootstrapping_sources,
 855                     ".",
 856                     "//chrome")
 857     if (is_win || is_mac) {
 858       # TODO(brettw) as of this writing wifi bootstrapping is set on Windows
 859       # and Mac, so this test is meaningless. Can we merge these lists?
 860       sources += rebase_path(
 861               gypi_values.chrome_browser_wifi_bootstrapping_win_mac_sources,
 862               ".",
 863               "//chrome")
 864     }
 865   }
 866   if (enable_media_router) {
 867     deps += [ "//chrome/browser/media/router" ]
 868   }
 869 }
 870
 871 if (is_android) {
 872   # GYP version: chrome/chrome_browser.gypi:chrome_browser_jni_headers
 873   generate_jni("jni_headers") {
 874     sources =
 875         rebase_path(gypi_values.chrome_browser_jni_sources, ".", "//chrome")
 876     jni_package = "chrome"
 877   }
 878
 879   #GYP: '//chrome/chrome_browser.gypi:client_discourse_context_proto'
 880   proto_library("client_discourse_context_proto") {
 881     sources = [
 882       "android/proto/client_discourse_context.proto",
 883     ]
 884   }
 885
 886   #GYP: '//chrome/chrome_browser.gypi:delta_file_proto'
 887   proto_library("delta_file_proto") {
 888     sources = [
 889       "android/proto/delta_file.proto",
 890     ]
 891   }
 892 }
 893
 894 if (is_win) {
 895   source_set("chrome_process_finder") {
 896     sources = [
 897       "chrome_process_finder_win.cc",
 898       "chrome_process_finder_win.h",
 899     ]
 900     deps = [
 901       "//base",
 902       "//chrome/browser/metro_utils",
 903       "//chrome/common:constants",
 904     ]
 905     if (enable_configuration_policy) {
 906       deps += [ "//chrome/browser/policy:path_parser" ]
 907     }
 908   }
 909 }
 910
 911 # GYP version: chrome/chrome_resources.gyp:chrome_resources
 912 # (generate_browser_resources action)
 913 grit("resources") {
 914   source = "browser_resources.grd"
 915   output_dir = "$root_gen_dir/chrome"
 916   outputs = [
 917     "grit/browser_resources.h",
 918     "browser_resources.pak",
 919   ]
 920
 921   omnibox_mojom_file =
 922       "$root_gen_dir/chrome/browser/ui/webui/omnibox/omnibox.mojom.js"
 923
 924   grit_flags = [
 925     "-E",
 926     "about_credits_file=" + rebase_path(about_credits_file, root_build_dir),
 927     "-E",
 928     "additional_modules_list_file=" +
 929         rebase_path(additional_modules_list_file, root_build_dir),
 930     "-E",
 931     "omnibox_mojom_file=" + rebase_path(omnibox_mojom_file, root_build_dir),
 932   ]
 933
 934   deps = [
 935     ":about_credits",
 936     ":chrome_internal_resources_gen",
 937
 938     # Depend only on the generated mojo bindings since we read the .mojom.js
 939     # file, rather than the whole mojo target which will link the C++ bindings.
 940     "//chrome/browser/ui/webui/omnibox:mojo_bindings__generator",
 941   ]
 942   inputs = [
 943     omnibox_mojom_file,
 944   ]
 945 }
 946
 947 # GYP version: chrome/chrome_resource.gyp:about_credits
 948 action("about_credits") {
 949   script = "//tools/licenses.py"
 950
 951   inputs = [
 952     # This is not a complete list. TODO(phajdan.jr, dbeam): licenses.py needs to
 953     # generate a .d file with all the licenses/credits that about:credits uses.
 954     # Then about:credits will automatically rebuild when one of them changes.
 955     # See: depfile in gn's documentation (gn help depfile).
 956     "resources/about_credits.tmpl",
 957     "resources/about_credits_entry.tmpl",
 958   ]
 959
 960   outputs = [
 961     about_credits_file,
 962   ]
 963
 964   args = [
 965     "credits",
 966     rebase_path(about_credits_file, root_build_dir),
 967   ]
 968 }
 969
 970 # GYP version: chrome/chrome_resource.gyp:chrome_internal_resources_gen
 971 if (is_chrome_branded) {
 972   action("chrome_internal_resources_gen") {
 973     script = "internal/transform_additional_modules_list.py"
 974     sources = [
 975       "internal/resources/additional_modules_list.input",
 976     ]
 977     outputs = [
 978       additional_modules_list_file,
 979     ]
 980     args = rebase_path(sources, root_build_dir) +
 981            rebase_path(outputs, root_build_dir)
 982   }
 983 } else {
 984   group("chrome_internal_resources_gen") {
 985     # Empty placeholder.
 986   }
 987 }
 988
 989 # In GYP this is part of test_support_common.
 990 source_set("test_support") {
 991   testonly = true
 992
 993   # Always include this via the main test support target.
 994   visibility = [ "//chrome/test:test_support" ]
 995
 996   sources = [
 997     "browsing_data/mock_browsing_data_appcache_helper.cc",
 998     "browsing_data/mock_browsing_data_appcache_helper.h",
 999     "browsing_data/mock_browsing_data_cache_storage_helper.cc",
1000     "browsing_data/mock_browsing_data_cache_storage_helper.h",
1001     "browsing_data/mock_browsing_data_channel_id_helper.cc",
1002     "browsing_data/mock_browsing_data_channel_id_helper.h",
1003     "browsing_data/mock_browsing_data_cookie_helper.cc",
1004     "browsing_data/mock_browsing_data_cookie_helper.h",
1005     "browsing_data/mock_browsing_data_database_helper.cc",
1006     "browsing_data/mock_browsing_data_database_helper.h",
1007     "browsing_data/mock_browsing_data_file_system_helper.cc",
1008     "browsing_data/mock_browsing_data_file_system_helper.h",
1009     "browsing_data/mock_browsing_data_flash_lso_helper.cc",
1010     "browsing_data/mock_browsing_data_flash_lso_helper.h",
1011     "browsing_data/mock_browsing_data_indexed_db_helper.cc",
1012     "browsing_data/mock_browsing_data_indexed_db_helper.h",
1013     "browsing_data/mock_browsing_data_local_storage_helper.cc",
1014     "browsing_data/mock_browsing_data_local_storage_helper.h",
1015     "browsing_data/mock_browsing_data_quota_helper.cc",
1016     "browsing_data/mock_browsing_data_quota_helper.h",
1017     "browsing_data/mock_browsing_data_service_worker_helper.cc",
1018     "browsing_data/mock_browsing_data_service_worker_helper.h",
1019     "download/download_test_file_activity_observer.cc",
1020     "download/download_test_file_activity_observer.h",
1021     "download/test_download_shelf.cc",
1022     "download/test_download_shelf.h",
1023     "invalidation/fake_invalidation_service.cc",
1024     "invalidation/fake_invalidation_service.h",
1025     "media/fake_desktop_media_list.cc",
1026     "media/fake_desktop_media_list.h",
1027     "net/dns_probe_test_util.cc",
1028     "net/dns_probe_test_util.h",
1029     "net/url_request_mock_util.cc",
1030     "net/url_request_mock_util.h",
1031     "notifications/notification_test_util.cc",
1032     "notifications/notification_test_util.h",
1033     "password_manager/mock_password_store_service.cc",
1034     "password_manager/mock_password_store_service.h",
1035     "password_manager/null_password_store_service.cc",
1036     "password_manager/null_password_store_service.h",
1037     "password_manager/password_manager_test_base.cc",
1038     "password_manager/password_manager_test_base.h",
1039     "password_manager/test_password_store_service.cc",
1040     "password_manager/test_password_store_service.h",
1041     "prefs/pref_service_mock_factory.cc",
1042     "prefs/pref_service_mock_factory.h",
1043     "profile_resetter/profile_resetter_test_base.cc",
1044     "profile_resetter/profile_resetter_test_base.h",
1045     "search_engines/template_url_service_factory_test_util.cc",
1046     "search_engines/template_url_service_factory_test_util.h",
1047     "search_engines/template_url_service_test_util.cc",
1048     "search_engines/template_url_service_test_util.h",
1049     "sessions/session_restore_test_helper.cc",
1050     "sessions/session_restore_test_helper.h",
1051     "sessions/session_service_test_helper.cc",
1052     "sessions/session_service_test_helper.h",
1053     "signin/fake_account_fetcher_service_builder.cc",
1054     "signin/fake_account_fetcher_service_builder.h",
1055     "signin/fake_gaia_cookie_manager_service.cc",
1056     "signin/fake_gaia_cookie_manager_service.h",
1057     "signin/fake_profile_oauth2_token_service_builder.cc",
1058     "signin/fake_profile_oauth2_token_service_builder.h",
1059     "signin/fake_signin_manager_builder.cc",
1060     "signin/fake_signin_manager_builder.h",
1061     "ssl/ssl_client_auth_requestor_mock.cc",
1062     "ssl/ssl_client_auth_requestor_mock.h",
1063     "sync/profile_sync_components_factory_mock.cc",
1064     "sync/profile_sync_components_factory_mock.h",
1065     "sync/profile_sync_service_mock.cc",
1066     "sync/profile_sync_service_mock.h",
1067     "ui/webui/signin/login_ui_test_utils.cc",
1068     "ui/webui/signin/login_ui_test_utils.h",
1069   ]
1070
1071   configs += [ "//build/config:precompiled_headers" ]
1072
1073   public_deps = [
1074     ":browser",
1075     "//chrome/browser/ui:test_support",
1076   ]
1077   deps = [
1078     "//base:prefs_test_support",
1079     "//chrome/browser",
1080     "//chrome/common",
1081     "//chrome/common/safe_browsing:proto",
1082     "//components/invalidation/impl",
1083     "//components/invalidation/impl:test_support",
1084     "//components/password_manager/core/browser:test_support",
1085     "//components/search_engines:test_support",
1086     "//components/user_prefs/tracked:user_prefs_tracked_test_support",
1087     "//content/test:test_support",
1088     "//chrome/app/theme:theme_resources",
1089     "//net:test_support",
1090     "//skia",
1091     "//testing/gmock",
1092     "//testing/gtest",
1093     "//ui/gfx",
1094   ]
1095
1096   if (!is_ios) {
1097     deps += [
1098       "//components/sessions:test_support",
1099       "//google_apis:test_support",
1100     ]
1101   }
1102
1103   if (enable_extensions) {
1104     sources += [
1105       "extensions/extension_action_test_util.cc",
1106       "extensions/extension_action_test_util.h",
1107     ]
1108     deps += [ "//extensions:test_support" ]
1109   }
1110
1111   if (is_chromeos) {
1112     sources += [
1113       "chromeos/app_mode/fake_cws.cc",
1114       "chromeos/app_mode/fake_cws.h",
1115       "chromeos/file_manager/fake_disk_mount_manager.cc",
1116       "chromeos/file_manager/fake_disk_mount_manager.h",
1117       "chromeos/input_method/mock_candidate_window_controller.cc",
1118       "chromeos/input_method/mock_candidate_window_controller.h",
1119       "chromeos/input_method/mock_input_method_engine.cc",
1120       "chromeos/input_method/mock_input_method_engine.h",
1121       "chromeos/input_method/mock_input_method_manager.cc",
1122       "chromeos/input_method/mock_input_method_manager.h",
1123       "chromeos/login/screens/mock_device_disabled_screen_actor.cc",
1124       "chromeos/login/screens/mock_device_disabled_screen_actor.h",
1125       "chromeos/login/session/user_session_manager_test_api.cc",
1126       "chromeos/login/session/user_session_manager_test_api.h",
1127       "chromeos/login/test/js_checker.cc",
1128       "chromeos/login/test/js_checker.h",
1129       "chromeos/login/test/oobe_screen_waiter.cc",
1130       "chromeos/login/test/oobe_screen_waiter.h",
1131       "chromeos/login/ui/mock_login_display.cc",
1132       "chromeos/login/ui/mock_login_display.h",
1133       "chromeos/login/ui/mock_login_display_host.cc",
1134       "chromeos/login/ui/mock_login_display_host.h",
1135       "chromeos/login/users/avatar/mock_user_image_manager.cc",
1136       "chromeos/login/users/avatar/mock_user_image_manager.h",
1137       "chromeos/login/users/fake_chrome_user_manager.cc",
1138       "chromeos/login/users/fake_chrome_user_manager.h",
1139       "chromeos/login/users/fake_supervised_user_manager.cc",
1140       "chromeos/login/users/fake_supervised_user_manager.h",
1141       "chromeos/login/users/mock_user_manager.cc",
1142       "chromeos/login/users/mock_user_manager.h",
1143       "chromeos/net/network_portal_detector_test_utils.cc",
1144       "chromeos/net/network_portal_detector_test_utils.h",
1145       "chromeos/policy/cloud_external_data_manager_base_test_util.cc",
1146       "chromeos/policy/cloud_external_data_manager_base_test_util.h",
1147       "chromeos/policy/device_policy_builder.cc",
1148       "chromeos/policy/device_policy_builder.h",
1149       "chromeos/policy/fake_consumer_management_service.cc",
1150       "chromeos/policy/fake_consumer_management_service.h",
1151       "chromeos/policy/fake_device_cloud_policy_initializer.cc",
1152       "chromeos/policy/fake_device_cloud_policy_initializer.h",
1153       "chromeos/policy/fake_device_cloud_policy_manager.cc",
1154       "chromeos/policy/fake_device_cloud_policy_manager.h",
1155       "chromeos/policy/stub_enterprise_install_attributes.cc",
1156       "chromeos/policy/stub_enterprise_install_attributes.h",
1157       "chromeos/settings/device_settings_test_helper.cc",
1158       "chromeos/settings/device_settings_test_helper.h",
1159       "chromeos/system/fake_input_device_settings.cc",
1160       "chromeos/system/fake_input_device_settings.h",
1161     ]
1162     configs += [ "//build/config/linux:dbus" ]
1163     deps += [ "//chromeos:test_support" ]
1164   }
1165
1166   if (enable_configuration_policy) {
1167     sources += [
1168       "policy/test/local_policy_test_server.cc",
1169       "policy/test/local_policy_test_server.h",
1170     ]
1171     public_deps += [
1172       "//components/policy:policy_component_test_support",
1173       "//components/policy:test_support",
1174     ]
1175   }
1176
1177   if (safe_browsing_mode == 1) {
1178     sources += [
1179       "extensions/fake_safe_browsing_database_manager.cc",
1180       "extensions/fake_safe_browsing_database_manager.h",
1181     ]
1182   }
1183
1184   if (enable_extensions) {
1185     sources += [
1186       "extensions/api/messaging/native_messaging_test_util.cc",
1187       "extensions/api/messaging/native_messaging_test_util.h",
1188       "extensions/extension_notification_observer.cc",
1189       "extensions/extension_notification_observer.h",
1190       "extensions/mock_extension_special_storage_policy.cc",
1191       "extensions/mock_extension_special_storage_policy.h",
1192       "extensions/test_blacklist.cc",
1193       "extensions/test_blacklist.h",
1194       "extensions/test_blacklist_state_fetcher.cc",
1195       "extensions/test_blacklist_state_fetcher.h",
1196       "extensions/test_extension_dir.cc",
1197       "extensions/test_extension_dir.h",
1198       "extensions/test_extension_environment.cc",
1199       "extensions/test_extension_environment.h",
1200       "extensions/test_extension_prefs.cc",
1201       "extensions/test_extension_prefs.h",
1202       "extensions/test_extension_service.cc",
1203       "extensions/test_extension_service.h",
1204       "extensions/test_extension_system.cc",
1205       "extensions/test_extension_system.h",
1206       "media_galleries/media_galleries_test_util.cc",
1207       "media_galleries/media_galleries_test_util.h",
1208     ]
1209     deps += [
1210       "//components/drive:test_support",
1211       "//components/storage_monitor:test_support",
1212     ]
1213   }
1214
1215   if (enable_mdns) {
1216     sources += [
1217       "local_discovery/test_service_discovery_client.cc",
1218       "local_discovery/test_service_discovery_client.h",
1219     ]
1220   }
1221
1222   if (enable_app_list) {
1223     sources += [
1224       "ui/app_list/test/chrome_app_list_test_support.cc",
1225       "ui/app_list/test/chrome_app_list_test_support.h",
1226       "ui/app_list/test/test_app_list_controller_delegate.cc",
1227       "ui/app_list/test/test_app_list_controller_delegate.h",
1228     ]
1229   }
1230
1231   if (enable_wifi_bootstrapping) {
1232     sources += [
1233       "local_discovery/wifi/mock_wifi_manager.cc",
1234       "local_discovery/wifi/mock_wifi_manager.h",
1235     ]
1236   }
1237 }
1238
1239 if (enable_rlz_support) {
1240   source_set("rlz") {
1241     sources =
1242         rebase_path(gypi_values.chrome_browser_rlz_sources, ".", "//chrome")
1243     deps = [
1244       "//components/google/core/browser",
1245       "//components/omnibox/browser",
1246       "//components/rlz",
1247       "//components/search_engines",
1248       "//rlz:rlz_lib",
1249     ]
1250   }
1251 }