remoting/webapp/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # Keep in sync with targets in remoting/remoting_client.gypi.
   6
   7 import("//build/config/features.gni")
   8 import("//remoting/webapp/build_template.gni")
   9 import("//remoting/webapp/files.gni")
  10
  11 # GYP version: remoting/remoting_client:remoting_credits
  12 action("credits") {
  13   about_credits_file = "$target_gen_dir/credits.html"
  14   script = "//tools/licenses.py"
  15
  16   inputs = [
  17     "base/html/credits.tmpl",
  18     "base/html/credits_entry.tmpl",
  19   ]
  20
  21   outputs = [
  22     about_credits_file,
  23   ]
  24
  25   args = [
  26     "credits",
  27     rebase_path(about_credits_file, root_build_dir),
  28     "--file-template",
  29     rebase_path("base/html/credits.tmpl", root_build_dir),
  30     "--entry-template",
  31     rebase_path("base/html/credits_entry.tmpl", root_build_dir),
  32   ]
  33 }
  34
  35 desktop_remoting_webapp("webapp") {
  36   webapp_type = "desktop"
  37   output_dir = "$root_build_dir/remoting/remoting-webapp.v2"
  38   zip_path = "$root_build_dir/remoting/remoting-webapp.v2.zip"
  39   extra_files = [
  40     "crd/remoting_client_pnacl.nmf.jinja2",
  41     # TODO(garykac): Get correct path to this.
  42     #"<(PRODUCT_DIR)/remoting_client_plugin_newlib.pexe",
  43   ]
  44 }
  45
  46 app_remoting_webapp("ar_sample_app") {
  47   app_key = "Sample_App"
  48   app_id = "ljacajndfccfgnfohlgkdphmbnpkjflk"
  49   app_client_id = "sample_client_id"
  50   app_vendor = ""
  51   app_name = "sample_app"
  52   app_fullname = "App Remoting Client"
  53   app_description = "App Remoting client"
  54   app_capabilities = [ "GOOGLE_DRIVE" ]
  55   manifest_key = "remotingdevbuild"
  56 }
  57
  58 app_remoting_shared_module("ar_shared_module") {
  59   #app_client_id = "sample_client_id"
  60   app_name = "shared_module"
  61 }
  62
  63 # GYP version: remoting/remoting_tests.gypi:remoting_browser_test_resources
  64 copy("browser_test_resources") {
  65   sources = remoting_webapp_browsertest_main_html_extra_files
  66   outputs = [
  67     "$root_out_dir/remoting/browser_test_resources/{{source_file_part}}",
  68   ]
  69 }
  70
  71 remoting_unit_test_out_dir = "$root_out_dir/remoting/unittests"
  72
  73 group("unit_tests") {
  74   data_deps = [
  75     ":blanketjs",
  76     ":build_unittest",
  77     ":js_files",
  78     ":qunit",
  79     ":sinonjs",
  80   ]
  81 }
  82
  83 copy("js_files") {
  84   # This list corresponds to webapp_js_files in remoting_webapp_unittests
  85   # target in GYP.
  86   sources = webapp_js_files + remoting_webapp_unittests_all_files
  87   outputs = [
  88     "$remoting_unit_test_out_dir/{{source_file_part}}",
  89   ]
  90 }
  91
  92 copy("blanketjs") {
  93   sources = [
  94     "//third_party/blanketjs/src/blanket.js",
  95     "//third_party/blanketjs/src/qunit_adapter.js",
  96   ]
  97   outputs = [
  98     "$remoting_unit_test_out_dir/blanketjs/{{source_file_part}}",
  99   ]
 100 }
 101
 102 copy("sinonjs") {
 103   sources = [
 104     "//third_party/sinonjs/src/sinon-qunit.js",
 105     "//third_party/sinonjs/src/sinon.js",
 106   ]
 107   outputs = [
 108     "$remoting_unit_test_out_dir/sinonjs/{{source_file_part}}",
 109   ]
 110 }
 111
 112 copy("qunit") {
 113   sources = [
 114     "//third_party/qunit/src/browser_test_harness.js",
 115     "//third_party/qunit/src/qunit.css",
 116     "//third_party/qunit/src/qunit.js",
 117   ]
 118   outputs = [
 119     "$remoting_unit_test_out_dir/qunit/{{source_file_part}}",
 120   ]
 121 }
 122
 123 action("build_unittest") {
 124   script = "build-html.py"
 125   outputs = [
 126     "$remoting_unit_test_out_dir/unittests.html",
 127   ]
 128
 129   # Create a file that contains a list of all the JavaScript files needed
 130   # to build the unit test page. This is needed to avoid problems on platforms
 131   # that limit the size of a command line.
 132   file_list = "$target_gen_dir/remoting_webapp_unittest_files.txt"
 133   files = rebase_path(remoting_webapp_unittests_all_js_files, root_build_dir)
 134   write_file(file_list, files)
 135
 136   args =
 137       rebase_path(outputs, root_build_dir) + [
 138         rebase_path(remoting_webapp_unittests_template_main, root_build_dir),
 139         "--exclude-js",
 140       ] +
 141       rebase_path(remoting_webapp_unittests_exclude_js_files, root_build_dir) +
 142       [
 143         "--js-list-file",
 144         rebase_path(file_list, root_build_dir),
 145       ] + [ "--instrument-js" ] + rebase_path(webapp_js_files, root_build_dir)
 146 }