third_party/harfbuzz-ng/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6 import("//build/config/linux/pkg_config.gni")
   7
   8 # The GYP build supports system harfbuzz for non-official builds when using
   9 # pangoft2 1.31.0 or greater (which pulls it in).
  10 # TODO(brettw) we can consider doing this as well, although the benefit is
  11 # unclear and requires shelling out to a script to check the version.
  12 #
  13 # ChromeOS uses an up-to-date system one that we have control over, so we
  14 # don't want to bloat the binary more by including another copy.
  15
  16 declare_args() {
  17   # Since version 1.31.0, pangoft2 which we depend on pulls in harfbuzz
  18   # anyways. However, we want to have control of the version of harfbuzz
  19   # we use, so don't use system harfbuzz for official builds, unless we
  20   # are building for chrome os, where we have the system harfbuzz under
  21   # control as well. We also do not want to use the system harfbuzz
  22   # when cross-compiling for ARM.
  23   use_system_harfbuzz = is_linux && (is_chromeos || (!is_official_build &&
  24                                                      current_cpu != "arm")) &&
  25                         exec_script(pkg_config_script,
  26                                     pkg_config_args + [
  27                                           "--atleast-version=1.31.0",
  28                                           "pangoft2",
  29                                         ],
  30                                     "value")
  31 }
  32
  33 if (use_system_harfbuzz) {
  34   import("//build/config/linux/pkg_config.gni")
  35   pkg_config("harfbuzz_pkgconfig") {
  36     packages = [ "harfbuzz" ]
  37   }
  38   group("harfbuzz-ng") {
  39     public_configs = [ ":harfbuzz_pkgconfig" ]
  40   }
  41 } else {
  42   config("harfbuzz-ng_config") {
  43     include_dirs = [ "src" ]
  44   }
  45
  46   static_library("harfbuzz-ng") {
  47     sources = [
  48       "src/hb-atomic-private.hh",
  49       "src/hb-blob.cc",
  50       "src/hb-blob.h",
  51       "src/hb-buffer-deserialize-json.hh",
  52       "src/hb-buffer-deserialize-text.hh",
  53       "src/hb-buffer-private.hh",
  54       "src/hb-buffer-serialize.cc",
  55       "src/hb-buffer.cc",
  56       "src/hb-buffer.h",
  57       "src/hb-cache-private.hh",
  58       "src/hb-common.cc",
  59       "src/hb-common.h",
  60       "src/hb-deprecated.h",
  61       "src/hb-face-private.hh",
  62       "src/hb-face.cc",
  63       "src/hb-face.h",
  64       "src/hb-fallback-shape.cc",
  65       "src/hb-font-private.hh",
  66       "src/hb-font.cc",
  67       "src/hb-font.h",
  68       "src/hb-icu.cc",
  69       "src/hb-icu.h",
  70       "src/hb-mutex-private.hh",
  71       "src/hb-object-private.hh",
  72       "src/hb-open-file-private.hh",
  73       "src/hb-open-type-private.hh",
  74       "src/hb-ot-head-table.hh",
  75       "src/hb-ot-hhea-table.hh",
  76       "src/hb-ot-hmtx-table.hh",
  77       "src/hb-ot-layout-common-private.hh",
  78       "src/hb-ot-layout-gdef-table.hh",
  79       "src/hb-ot-layout-gpos-table.hh",
  80       "src/hb-ot-layout-gsub-table.hh",
  81       "src/hb-ot-layout-gsubgpos-private.hh",
  82       "src/hb-ot-layout-private.hh",
  83       "src/hb-ot-layout.cc",
  84       "src/hb-ot-layout.h",
  85       "src/hb-ot-map-private.hh",
  86       "src/hb-ot-map.cc",
  87       "src/hb-ot-maxp-table.hh",
  88       "src/hb-ot-name-table.hh",
  89       "src/hb-ot-shape-complex-arabic-fallback.hh",
  90       "src/hb-ot-shape-complex-arabic-table.hh",
  91       "src/hb-ot-shape-complex-arabic.cc",
  92       "src/hb-ot-shape-complex-default.cc",
  93       "src/hb-ot-shape-complex-hangul.cc",
  94       "src/hb-ot-shape-complex-hebrew.cc",
  95       "src/hb-ot-shape-complex-indic-machine.hh",
  96       "src/hb-ot-shape-complex-indic-private.hh",
  97       "src/hb-ot-shape-complex-indic-table.cc",
  98       "src/hb-ot-shape-complex-indic.cc",
  99       "src/hb-ot-shape-complex-myanmar-machine.hh",
 100       "src/hb-ot-shape-complex-myanmar.cc",
 101       "src/hb-ot-shape-complex-private.hh",
 102       "src/hb-ot-shape-complex-sea-machine.hh",
 103       "src/hb-ot-shape-complex-sea.cc",
 104       "src/hb-ot-shape-complex-thai.cc",
 105       "src/hb-ot-shape-complex-tibetan.cc",
 106       "src/hb-ot-shape-fallback-private.hh",
 107       "src/hb-ot-shape-fallback.cc",
 108       "src/hb-ot-shape-normalize-private.hh",
 109       "src/hb-ot-shape-normalize.cc",
 110       "src/hb-ot-shape-private.hh",
 111       "src/hb-ot-shape.cc",
 112       "src/hb-ot-shape.h",
 113       "src/hb-ot-tag.cc",
 114       "src/hb-ot-tag.h",
 115       "src/hb-ot.h",
 116       "src/hb-private.hh",
 117       "src/hb-set-private.hh",
 118       "src/hb-set.cc",
 119       "src/hb-set.h",
 120       "src/hb-shape-plan-private.hh",
 121       "src/hb-shape-plan.cc",
 122       "src/hb-shape-plan.h",
 123       "src/hb-shape.cc",
 124       "src/hb-shape.h",
 125       "src/hb-shaper-impl-private.hh",
 126       "src/hb-shaper-list.hh",
 127       "src/hb-shaper-private.hh",
 128       "src/hb-shaper.cc",
 129       "src/hb-unicode-private.hh",
 130       "src/hb-unicode.cc",
 131       "src/hb-unicode.h",
 132       "src/hb-utf-private.hh",
 133       "src/hb-version.h",
 134       "src/hb-warning.cc",
 135       "src/hb.h",
 136     ]
 137
 138     defines = [
 139       "HAVE_OT",
 140       "HAVE_ICU",
 141       "HAVE_ICU_BUILTIN",
 142       "HB_NO_MT",
 143     ]
 144
 145     configs -= [ "//build/config/compiler:chromium_code" ]
 146     configs += [ "//build/config/compiler:no_chromium_code" ]
 147     public_configs = [ ":harfbuzz-ng_config" ]
 148
 149     deps = [
 150       "//third_party/icu:icuuc",
 151     ]
 152
 153     cflags = []
 154     if (is_clang) {
 155       cflags += [ "-Wno-unused-value" ]
 156     }
 157     if (is_win) {
 158       cflags += [ "/wd4334" ]  # Result of 32-bit shift implicitly converted to 64 bits.
 159     }
 160     if (is_mac) {
 161       sources += [
 162         "src/hb-coretext.cc",
 163         "src/hb-coretext.h",
 164       ]
 165       defines += [ "HAVE_CORETEXT" ]
 166     }
 167   }
 168 }