components/invalidation/impl/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4 if (is_android) {
   5   import("//build/config/android/rules.gni")
   6 }
   7
   8 source_set("impl") {
   9   sources = [
  10     "invalidation_logger.cc",
  11     "invalidation_logger.h",
  12     "invalidation_logger_observer.h",
  13     "invalidation_prefs.cc",
  14     "invalidation_prefs.h",
  15     "invalidation_service_util.cc",
  16     "invalidation_service_util.h",
  17     "invalidation_state_tracker.cc",
  18     "invalidation_state_tracker.h",
  19     "invalidation_switches.cc",
  20     "invalidation_switches.h",
  21     "invalidator.cc",
  22     "invalidator.h",
  23     "invalidator_registrar.cc",
  24     "invalidator_registrar.h",
  25     "invalidator_storage.cc",
  26     "invalidator_storage.h",
  27     "mock_ack_handler.cc",
  28     "mock_ack_handler.h",
  29     "profile_invalidation_provider.cc",
  30     "profile_invalidation_provider.h",
  31     "unacked_invalidation_set.cc",
  32     "unacked_invalidation_set.h",
  33   ]
  34   if (!is_android) {
  35     sources += [
  36       "gcm_invalidation_bridge.cc",
  37       "gcm_invalidation_bridge.h",
  38       "gcm_network_channel.cc",
  39       "gcm_network_channel.h",
  40       "gcm_network_channel_delegate.h",
  41       "invalidation_notifier.cc",
  42       "invalidation_notifier.h",
  43       "non_blocking_invalidator.cc",
  44       "non_blocking_invalidator.h",
  45       "notifier_reason_util.cc",
  46       "notifier_reason_util.h",
  47       "p2p_invalidator.cc",
  48       "p2p_invalidator.h",
  49       "push_client_channel.cc",
  50       "push_client_channel.h",
  51       "registration_manager.cc",
  52       "registration_manager.h",
  53       "state_writer.h",
  54       "sync_invalidation_listener.cc",
  55       "sync_invalidation_listener.h",
  56       "sync_system_resources.cc",
  57       "sync_system_resources.h",
  58       "ticl_invalidation_service.cc",
  59       "ticl_invalidation_service.h",
  60       "ticl_settings_provider.cc",
  61       "ticl_settings_provider.h",
  62     ]
  63   }
  64   public_deps = [
  65     "//components/invalidation/public",
  66   ]
  67   deps = [
  68     "//base",
  69     "//base:i18n",
  70     "//base:prefs",
  71     "//components/gcm_driver",
  72     "//components/keyed_service/core",
  73     "//components/pref_registry",
  74     "//components/signin/core/browser",
  75     "//google_apis",
  76     "//jingle:notifier",
  77     "//net:net",
  78
  79     # TODO(sync): Remove this (http://crbug.com/133352);
  80     "//third_party/protobuf:protobuf_lite",
  81   ]
  82
  83   if (is_android) {
  84     sources += [
  85       "android/component_jni_registrar.cc",
  86       "android/component_jni_registrar.h",
  87       "invalidation_service_android.cc",
  88       "invalidation_service_android.h",
  89     ]
  90     deps += [ ":jni_headers" ]
  91   }
  92 }
  93
  94 source_set("unit_tests") {
  95   testonly = true
  96   sources = [
  97     "invalidation_logger_unittest.cc",
  98   ]
  99   deps = [
 100     ":impl",
 101     ":test_support",
 102     "//testing/gmock",
 103     "//testing/gtest",
 104   ]
 105
 106   if (is_android) {
 107     sources += [ "invalidation_service_android_unittest.cc" ]
 108     deps += [ ":jni_headers" ]
 109   } else {
 110     # Non-Android tests.
 111     sources += [
 112       "fake_invalidator_unittest.cc",
 113       "gcm_network_channel_unittest.cc",
 114       "invalidation_notifier_unittest.cc",
 115       "invalidator_registrar_unittest.cc",
 116       "non_blocking_invalidator_unittest.cc",
 117       "object_id_invalidation_map_unittest.cc",
 118       "p2p_invalidator_unittest.cc",
 119       "push_client_channel_unittest.cc",
 120       "registration_manager_unittest.cc",
 121       "single_object_invalidation_set_unittest.cc",
 122       "sync_invalidation_listener_unittest.cc",
 123       "sync_system_resources_unittest.cc",
 124       "ticl_invalidation_service_unittest.cc",
 125       "unacked_invalidation_set_unittest.cc",
 126     ]
 127   }
 128 }
 129
 130 static_library("test_support") {
 131   testonly = true
 132   sources = [
 133     "fake_invalidation_handler.cc",
 134     "fake_invalidation_handler.h",
 135     "fake_invalidation_state_tracker.cc",
 136     "fake_invalidation_state_tracker.h",
 137     "fake_invalidator.cc",
 138     "fake_invalidator.h",
 139     "invalidation_service_test_template.cc",
 140     "invalidation_service_test_template.h",
 141     "invalidation_test_util.cc",
 142     "invalidation_test_util.h",
 143     "invalidator_test_template.cc",
 144     "invalidator_test_template.h",
 145     "object_id_invalidation_map_test_util.cc",
 146     "object_id_invalidation_map_test_util.h",
 147     "unacked_invalidation_set_test_util.cc",
 148     "unacked_invalidation_set_test_util.h",
 149   ]
 150
 151   public_deps = [
 152     ":impl",
 153     "//jingle:notifier_test_util",
 154     "//third_party/cacheinvalidation",
 155   ]
 156   deps = [
 157     "//base",
 158     "//components/gcm_driver:test_support",
 159     "//components/keyed_service/core",
 160     "//google_apis",
 161     "//jingle:notifier",
 162     "//net",
 163     "//testing/gmock",
 164
 165     # TODO(sync): Remove this (http://crbug.com/133352);
 166     "//third_party/protobuf:protobuf_lite",
 167
 168     # "//third_party/cacheinvalidation/src/google/cacheinvalidation:cacheinvalidation_proto_cpp",
 169   ]
 170
 171   if (is_android) {
 172     deps += [ ":jni_headers" ]
 173   } else {
 174     sources += [
 175       "p2p_invalidation_service.cc",
 176       "p2p_invalidation_service.h",
 177     ]
 178   }
 179 }
 180
 181 if (is_android) {
 182   android_library("java") {
 183     deps = [
 184       ":proto_java",
 185       "//base:base_java",
 186       "//sync/android:sync_java",
 187       "//third_party/android_protobuf:protobuf_nano_javalib",
 188       "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 189       "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 190       "//third_party/jsr-305:jsr_305_javalib",
 191     ]
 192     DEPRECATED_java_in_dir = "android/java/src"
 193   }
 194   proto_java_library("proto_java") {
 195     proto_path = "android/proto"
 196     sources = [
 197       "$proto_path/serialized_invalidation.proto",
 198     ]
 199   }
 200   android_library("javatests") {
 201     deps = [
 202       ":java",
 203       "//base:base_java",
 204       "//base:base_java_test_support",
 205       "//sync/android:sync_java",
 206       "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 207       "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 208     ]
 209     DEPRECATED_java_in_dir = "android/javatests/src"
 210   }
 211   junit_binary("junit_tests") {
 212     java_files = [ "android/junit/src/org/chromium/components/invalidation/PendingInvalidationTest.java" ]
 213     deps = [
 214       ":java",
 215       "//base:base_java",
 216       "//base:base_java_test_support",
 217     ]
 218   }
 219   generate_jni("jni_headers") {
 220     sources = [
 221       "android/java/src/org/chromium/components/invalidation/InvalidationService.java",
 222     ]
 223     jni_package = "components/invalidation"
 224   }
 225 }