ppapi/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 copy("copy_test_files") {
   6   visibility = [ ":*" ]
   7   sources = [
   8     # Keep "test_case.html.mock-http-headers" with "test_case.html".
   9     "tests/ppapi_nacl_tests_newlib.nmf",
  10     "tests/test_case.html",
  11     "tests/test_case.html.mock-http-headers",
  12     "tests/test_page.css",
  13     "tests/test_page.css.mock-http-headers",
  14   ]
  15   outputs = [
  16     "$root_out_dir/{{source_file_part}}",
  17   ]
  18 }
  19
  20 copy("copy_test_files2") {
  21   visibility = [ ":*" ]
  22   sources = [
  23     "tests/test_url_loader_data/hello.txt",
  24   ]
  25   outputs = [
  26     "$root_out_dir/test_url_loader_data/{{source_file_part}}",
  27   ]
  28 }
  29
  30 import("//ppapi/ppapi_sources.gni")
  31 import("//testing/test.gni")
  32
  33 shared_library("ppapi_tests") {
  34   sources = ppapi_sources.test_common_source_files +
  35             ppapi_sources.test_trusted_source_files
  36
  37   configs += [ "//build/config:precompiled_headers" ]
  38   defines = [ "GL_GLEXT_PROTOTYPES" ]
  39   include_dirs = [ "lib/gl/include" ]
  40
  41   deps = [
  42     "//ppapi/cpp",
  43     "//ppapi/shared_impl",
  44     ":copy_test_files",
  45     ":copy_test_files2",
  46   ]
  47 }
  48
  49 shared_library("power_saver_test_plugin") {
  50   sources = [
  51     "tests/power_saver_test_plugin.cc",
  52     "tests/test_utils.cc",
  53   ]
  54
  55   deps = [
  56     "//ppapi/cpp",
  57     "//ppapi/shared_impl",
  58   ]
  59 }
  60
  61 test("ppapi_unittests") {
  62   sources = [
  63     "host/resource_message_filter_unittest.cc",
  64     "proxy/device_enumeration_resource_helper_unittest.cc",
  65     "proxy/file_chooser_resource_unittest.cc",
  66     "proxy/file_system_resource_unittest.cc",
  67     "proxy/flash_resource_unittest.cc",
  68     "proxy/interface_list_unittest.cc",
  69     "proxy/mock_resource.cc",
  70     "proxy/mock_resource.h",
  71     "proxy/nacl_message_scanner_unittest.cc",
  72     "proxy/pdf_resource_unittest.cc",
  73     "proxy/plugin_dispatcher_unittest.cc",
  74     "proxy/plugin_resource_tracker_unittest.cc",
  75     "proxy/plugin_var_tracker_unittest.cc",
  76     "proxy/ppb_var_unittest.cc",
  77     "proxy/ppp_instance_private_proxy_unittest.cc",
  78     "proxy/ppp_instance_proxy_unittest.cc",
  79     "proxy/ppp_messaging_proxy_unittest.cc",
  80     "proxy/printing_resource_unittest.cc",
  81     "proxy/raw_var_data_unittest.cc",
  82     "proxy/serialized_var_unittest.cc",
  83     "proxy/tracked_callback_unittest.cc",
  84     "proxy/video_decoder_resource_unittest.cc",
  85     "proxy/video_encoder_resource_unittest.cc",
  86     "proxy/websocket_resource_unittest.cc",
  87     "shared_impl/media_stream_audio_track_shared_unittest.cc",
  88     "shared_impl/media_stream_buffer_manager_unittest.cc",
  89     "shared_impl/media_stream_video_track_shared_unittest.cc",
  90     "shared_impl/proxy_lock_unittest.cc",
  91     "shared_impl/resource_tracker_unittest.cc",
  92     "shared_impl/thread_aware_callback_unittest.cc",
  93     "shared_impl/time_conversion_unittest.cc",
  94     "shared_impl/var_tracker_unittest.cc",
  95   ]
  96
  97   deps = [
  98     "//base/allocator",
  99     "//base/test:run_all_unittests",
 100     "//base/test:test_support",
 101     "//gpu/ipc",
 102     "//ipc",
 103     "//ipc:test_support",
 104     "//media:shared_memory_support",
 105     "//ppapi/host",
 106     "//ppapi/proxy",
 107     "//ppapi/proxy:test_support",
 108     "//ppapi/shared_impl",
 109     "//ppapi/shared_impl:test_support",
 110     "//testing/gmock",
 111     "//testing/gtest",
 112     "//ui/surface",
 113   ]
 114 }
 115
 116 test("ppapi_perftests") {
 117   sources = [
 118     "proxy/ppapi_perftests.cc",
 119     "proxy/ppp_messaging_proxy_perftest.cc",
 120   ]
 121
 122   deps = [
 123     "//base/allocator",
 124     "//base/test:test_support",
 125     "//ppapi/proxy",
 126     "//ppapi/proxy:test_support",
 127     "//ppapi/shared_impl",
 128     "//ppapi/shared_impl:test_support",
 129     "//testing/gtest",
 130   ]
 131 }
 132
 133 executable("pepper_hash_for_uma") {
 134   sources = [
 135     "tools/pepper_hash_for_uma.cc",
 136   ]
 137
 138   deps = [
 139     "//base",
 140   ]
 141 }
 142
 143 source_set("ppapi_cpp_lib") {
 144   sources = ppapi_sources.cpp_source_files
 145   sources += [
 146     "cpp/module_embedder.h",
 147     "cpp/ppp_entrypoints.cc",
 148   ]
 149 }
 150
 151 source_set("ppapi_gles2_lib") {
 152   include_dirs = [ "lib/gl/include" ]
 153   sources = [
 154     "lib/gl/gles2/gl2ext_ppapi.c",
 155     "lib/gl/gles2/gl2ext_ppapi.h",
 156     "lib/gl/gles2/gles2.c",
 157   ]
 158   deps = [
 159     "//ppapi/cpp",
 160   ]
 161 }
 162
 163 if (is_nacl) {
 164   executable("ppapi_nacl_tests_newlib") {
 165     include_dirs = [
 166       "lib/gl/include",
 167       "..",
 168     ]
 169
 170     sources = ppapi_sources.test_common_source_files +
 171               ppapi_sources.test_nacl_source_files
 172
 173     defines = [ "GL_GLEXT_PROTOTYPES" ]
 174
 175     deps = [
 176       ":ppapi_cpp_lib",
 177       "//ppapi/native_client:ppapi_lib",
 178     ]
 179   }
 180
 181   copy("nacl_tests_copy") {
 182     sources = [
 183       "${root_out_dir}/ppapi_nacl_tests_newlib.nexe",
 184     ]
 185     outputs = [
 186       "${root_build_dir}/{{source_name_part}}_${target_cpu}.nexe",
 187     ]
 188     deps = [
 189       ":ppapi_nacl_tests_newlib",
 190     ]
 191   }
 192 }
 193
 194 group("ppapi_nacl_tests") {
 195   deps = []
 196   if (target_cpu == "x86" || target_cpu == "x64") {
 197     deps += [ ":nacl_tests_copy(//native_client/build/toolchain/nacl:clang_newlib_${target_cpu})" ]
 198   }
 199 }