build/config/BUILDCONFIG.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # =============================================================================
   6 # PLATFORM SELECTION
   7 # =============================================================================
   8 #
   9 # There are two main things to set: "os" and "cpu". The "toolchain" is the name
  10 # of the GN thing that encodes combinations of these things.
  11 #
  12 # Users typically only set the variables "target_os" and "target_cpu" in "gn
  13 # args", the rest are set up by our build and internal to GN.
  14 #
  15 # There are three different types of each of these things: The "host"
  16 # represents the computer doing the compile and never changes. The "target"
  17 # represents the main thing we're trying to build. The "current" represents
  18 # which configuration is currently being defined, which can be either the
  19 # host, the target, or something completely different (like nacl). GN will
  20 # run the same build file multiple times for the different required
  21 # configuration in the same build.
  22 #
  23 # This gives the following variables:
  24 #  - host_os, host_cpu, host_toolchain
  25 #  - target_os, target_cpu, default_toolchain
  26 #  - current_os, current_cpu, current_toolchain.
  27 #
  28 # Note the default_toolchain isn't symmetrical (you would expect
  29 # target_toolchain). This is because the "default" toolchain is a GN built-in
  30 # concept, and "target" is something our build sets up that's symmetrical with
  31 # its GYP counterpart. Potentially the built-in default_toolchain variable
  32 # could be renamed in the future.
  33 #
  34 # When writing build files, to do something only for the host:
  35 #   if (current_toolchain == host_toolchain) { ...
  36
  37 if (target_os == "") {
  38   target_os = host_os
  39 }
  40
  41 if (target_cpu == "") {
  42   if (target_os == "android") {
  43     # If we're building for Android, we should assume that we want to
  44     # build for ARM by default, not the host_cpu (which is likely x64).
  45     # This allows us to not have to specify both target_os and target_cpu
  46     # on the command line.
  47     target_cpu = "arm"
  48   } else {
  49     target_cpu = host_cpu
  50   }
  51 }
  52
  53 if (current_cpu == "") {
  54   current_cpu = target_cpu
  55 }
  56 if (current_os == "") {
  57   current_os = target_os
  58 }
  59
  60 # =============================================================================
  61 # BUILD FLAGS
  62 # =============================================================================
  63 #
  64 # This block lists input arguments to the build, along with their default
  65 # values.
  66 #
  67 # If a value is specified on the command line, it will overwrite the defaults
  68 # given in a declare_args block, otherwise the default will be used.
  69 #
  70 # YOU SHOULD ALMOST NEVER NEED TO ADD FLAGS TO THIS FILE. GN allows any file in
  71 # the build to declare build flags. If you need a flag for a single component,
  72 # you can just declare it in the corresponding BUILD.gn file. If you need a
  73 # flag in multiple components, there are a few options:
  74 #
  75 # - If your feature is a single target, say //components/foo, and the targets
  76 #   depending on foo need to have some define set if foo is enabled: (1) Write
  77 #   a declare_args block in foo's BUILD.gn file listing your enable_foo build
  78 #   flag. (2) Write a config in that file listing the define, and list that
  79 #   config in foo's public_configs. This will propagate that define to all the
  80 #   targets depending on foo. (3) When foo is not enabled, just make it expand
  81 #   to an empty group (or whatever's appropriate for the "off" state of your
  82 #   feature.
  83 #
  84 # - If a semi-random set of targets need to know about a define: (1) In the
  85 #   lowest level of the build that knows about this feature, add a declare_args
  86 #   block in the build file for your enable flag. (2) Write a config that adds
  87 #   a define conditionally based on that build flags. (3) Manually add that
  88 #   config to the "configs" applying to the targets that need the define.
  89 #
  90 # - If a semi-random set of targets need to know about the build flag (to do
  91 #   file inclusion or exclusion, more than just defines): (1) Write a .gni file
  92 #   in the lowest-level directory that knows about the feature. (2) Put the
  93 #   declare_args block with your build flag in that .gni file. (3) Import that
  94 #   .gni file from the BUILD.gn files that need the flag.
  95 #
  96 # Other advice:
  97 #
  98 # - Use boolean values when possible. If you need a default value that expands
  99 #   to some complex thing in the default case (like the location of the
 100 #   compiler which would be computed by a script), use a default value of -1 or
 101 #   the empty string. Outside of the declare_args block, conditionally expand
 102 #   the default value as necessary.
 103 #
 104 # - Use a name like "use_foo" or "is_foo" (whatever is more appropriate for
 105 #   your feature) rather than just "foo".
 106 #
 107 # - Write good comments directly above the declaration with no blank line.
 108 #   These comments will appear as documentation in "gn args --list".
 109 #
 110 # - Don't call exec_script inside declare_args. This will execute the script
 111 #   even if the value is overridden, which is wasteful. See first bullet.
 112
 113 declare_args() {
 114   # Component build.
 115   is_component_build = false
 116
 117   # Debug build.
 118   is_debug = true
 119
 120   # Whether we're a traditional desktop unix.
 121   is_desktop_linux = current_os == "linux" && current_os != "chromeos"
 122
 123   # Set to true when compiling with the Clang compiler. Typically this is used
 124   # to configure warnings.
 125   is_clang = current_os == "mac" || current_os == "ios" ||
 126              current_os == "linux" || current_os == "chromeos"
 127
 128   if (current_os == "chromeos") {
 129     # Allows the target toolchain to be injected as arguments. This is needed
 130     # to support the CrOS build system which supports per-build-configuration
 131     # toolchains.
 132     cros_use_custom_toolchain = false
 133   }
 134
 135   # DON'T ADD MORE FLAGS HERE. Read the comment above.
 136 }
 137
 138 # =============================================================================
 139 # OS DEFINITIONS
 140 # =============================================================================
 141 #
 142 # We set these various is_FOO booleans for convenience in writing OS-based
 143 # conditions.
 144 #
 145 # - is_android, is_chromeos, is_ios, and is_win should be obvious.
 146 # - is_mac is set only for desktop Mac. It is not set on iOS.
 147 # - is_posix is true for mac and any Unix-like system (basically everything
 148 #   except Windows).
 149 # - is_linux is true for desktop Linux and ChromeOS, but not Android (which is
 150 #   generally too different despite being based on the Linux kernel).
 151 #
 152 # Do not add more is_* variants here for random lesser-used Unix systems like
 153 # aix or one of the BSDs. If you need to check these, just check the
 154 # current_os value directly.
 155
 156 if (current_os == "win" || current_os == "winrt_81" ||
 157     current_os == "winrt_81_phone" || current_os == "winrt_10") {
 158   is_android = false
 159   is_chromeos = false
 160   is_ios = false
 161   is_linux = false
 162   is_mac = false
 163   is_nacl = false
 164   is_posix = false
 165   is_win = true
 166 } else if (current_os == "mac") {
 167   is_android = false
 168   is_chromeos = false
 169   is_ios = false
 170   is_linux = false
 171   is_mac = true
 172   is_nacl = false
 173   is_posix = true
 174   is_win = false
 175 } else if (current_os == "android") {
 176   is_android = true
 177   is_chromeos = false
 178   is_ios = false
 179   is_linux = false
 180   is_mac = false
 181   is_nacl = false
 182   is_posix = true
 183   is_win = false
 184 } else if (current_os == "chromeos") {
 185   is_android = false
 186   is_chromeos = true
 187   is_ios = false
 188   is_linux = true
 189   is_mac = false
 190   is_nacl = false
 191   is_posix = true
 192   is_win = false
 193 } else if (current_os == "nacl") {
 194   # current_os == "nacl" will be passed by the nacl toolchain definition.
 195   # It is not set by default or on the command line. We treat is as a
 196   # Posix variant.
 197   is_android = false
 198   is_chromeos = false
 199   is_ios = false
 200   is_linux = false
 201   is_mac = false
 202   is_nacl = true
 203   is_posix = true
 204   is_win = false
 205 } else if (current_os == "ios") {
 206   is_android = false
 207   is_chromeos = false
 208   is_ios = true
 209   is_linux = false
 210   is_mac = false
 211   is_nacl = false
 212   is_posix = true
 213   is_win = false
 214 } else if (current_os == "linux") {
 215   is_android = false
 216   is_chromeos = false
 217   is_ios = false
 218   is_linux = true
 219   is_mac = false
 220   is_nacl = false
 221   is_posix = true
 222   is_win = false
 223 }
 224
 225 # =============================================================================
 226 # SOURCES FILTERS
 227 # =============================================================================
 228 #
 229 # These patterns filter out platform-specific files when assigning to the
 230 # sources variable. The magic variable |sources_assignment_filter| is applied
 231 # to each assignment or appending to the sources variable and matches are
 232 # automatcally removed.
 233 #
 234 # Note that the patterns are NOT regular expressions. Only "*" and "\b" (path
 235 # boundary = end of string or slash) are supported, and the entire string
 236 # muct match the pattern (so you need "*.cc" to match all .cc files, for
 237 # example).
 238
 239 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 240 # below.
 241 sources_assignment_filter = []
 242 if (!is_posix) {
 243   sources_assignment_filter += [
 244     "*_posix.h",
 245     "*_posix.cc",
 246     "*_posix_unittest.h",
 247     "*_posix_unittest.cc",
 248     "*\bposix/*",
 249   ]
 250 }
 251 if (!is_win) {
 252   sources_assignment_filter += [
 253     "*_win.cc",
 254     "*_win.h",
 255     "*_win_unittest.cc",
 256     "*\bwin/*",
 257     "*.def",
 258     "*.rc",
 259   ]
 260 }
 261 if (!is_mac) {
 262   sources_assignment_filter += [
 263     "*_mac.h",
 264     "*_mac.cc",
 265     "*_mac.mm",
 266     "*_mac_unittest.h",
 267     "*_mac_unittest.cc",
 268     "*_mac_unittest.mm",
 269     "*\bmac/*",
 270     "*_cocoa.h",
 271     "*_cocoa.cc",
 272     "*_cocoa.mm",
 273     "*_cocoa_unittest.h",
 274     "*_cocoa_unittest.cc",
 275     "*_cocoa_unittest.mm",
 276     "*\bcocoa/*",
 277   ]
 278 }
 279 if (!is_ios) {
 280   sources_assignment_filter += [
 281     "*_ios.h",
 282     "*_ios.cc",
 283     "*_ios.mm",
 284     "*_ios_unittest.h",
 285     "*_ios_unittest.cc",
 286     "*_ios_unittest.mm",
 287     "*\bios/*",
 288   ]
 289 }
 290 if (!is_mac && !is_ios) {
 291   sources_assignment_filter += [ "*.mm" ]
 292 }
 293 if (!is_linux) {
 294   sources_assignment_filter += [
 295     "*_linux.h",
 296     "*_linux.cc",
 297     "*_linux_unittest.h",
 298     "*_linux_unittest.cc",
 299     "*\blinux/*",
 300   ]
 301 }
 302 if (!is_android) {
 303   sources_assignment_filter += [
 304     "*_android.h",
 305     "*_android.cc",
 306     "*_android_unittest.h",
 307     "*_android_unittest.cc",
 308     "*\bandroid/*",
 309   ]
 310 }
 311 if (!is_chromeos) {
 312   sources_assignment_filter += [
 313     "*_chromeos.h",
 314     "*_chromeos.cc",
 315     "*_chromeos_unittest.h",
 316     "*_chromeos_unittest.cc",
 317     "*\bchromeos/*",
 318   ]
 319 }
 320
 321 # DO NOT ADD MORE PATTERNS TO THIS LIST, see set_sources_assignment_filter call
 322 # below.
 323
 324 # Actually save this list.
 325 #
 326 # These patterns are executed for every file in the source tree of every run.
 327 # Therefore, adding more patterns slows down the build for everybody. We should
 328 # only add automatic patterns for configurations affecting hundreds of files
 329 # across many projects in the tree.
 330 #
 331 # Therefore, we only add rules to this list corresponding to platforms on the
 332 # Chromium waterfall.  This is not for non-officially-supported platforms
 333 # (FreeBSD, etc.) toolkits, (X11, GTK, etc.), or features. For these cases,
 334 # write a conditional in the target to remove the file(s) from the list when
 335 # your platform/toolkit/feature doesn't apply.
 336 set_sources_assignment_filter(sources_assignment_filter)
 337
 338 # =============================================================================
 339 # TARGET DEFAULTS
 340 # =============================================================================
 341 #
 342 # Set up the default configuration for every build target of the given type.
 343 # The values configured here will be automatically set on the scope of the
 344 # corresponding target. Target definitions can add or remove to the settings
 345 # here as needed.
 346
 347 # Holds all configs used for making native executables and libraries, to avoid
 348 # duplication in each target below.
 349 _native_compiler_configs = [
 350   "//build/config:feature_flags",
 351   "//build/config/compiler:compiler",
 352   "//build/config/compiler:compiler_arm_fpu",
 353   "//build/config/compiler:chromium_code",
 354   "//build/config/compiler:default_include_dirs",
 355   "//build/config/compiler:default_optimization",
 356   "//build/config/compiler:default_symbols",
 357   "//build/config/compiler:no_rtti",
 358   "//build/config/compiler:runtime_library",
 359 ]
 360 if (is_win) {
 361   _native_compiler_configs += [
 362     "//build/config/win:lean_and_mean",
 363     "//build/config/win:nominmax",
 364     "//build/config/win:sdk",
 365     "//build/config/win:unicode",
 366     "//build/config/win:winver",
 367   ]
 368 }
 369 if (current_os == "winrt_81" || current_os == "winrt_81_phone" ||
 370     current_os == "winrt_10") {
 371   _native_compiler_configs += [ "//build/config/win:target_winrt" ]
 372 }
 373 if (is_posix) {
 374   _native_compiler_configs += [
 375     "//build/config/gcc:no_exceptions",
 376     "//build/config/gcc:symbol_visibility_hidden",
 377   ]
 378 }
 379
 380 if (is_linux) {
 381   _native_compiler_configs += [ "//build/config/linux:sdk" ]
 382 } else if (is_mac) {
 383   _native_compiler_configs += [ "//build/config/mac:sdk" ]
 384 } else if (is_ios) {
 385   _native_compiler_configs += [ "//build/config/ios:sdk" ]
 386 } else if (is_android) {
 387   _native_compiler_configs += [ "//build/config/android:sdk" ]
 388 }
 389
 390 if (is_clang && !is_nacl) {
 391   _native_compiler_configs += [
 392     "//build/config/clang:find_bad_constructs",
 393     "//build/config/clang:extra_warnings",
 394   ]
 395 }
 396
 397 # Debug/release-related defines.
 398 if (is_debug) {
 399   _native_compiler_configs += [ "//build/config:debug" ]
 400 } else {
 401   _native_compiler_configs += [ "//build/config:release" ]
 402 }
 403
 404 # Windows linker setup for EXEs and DLLs.
 405 if (is_win) {
 406   _windows_linker_configs = [
 407     "//build/config/win:default_incremental_linking",
 408     "//build/config/win:sdk_link",
 409     "//build/config/win:common_linker_setup",
 410
 411     # Default to console-mode apps. Most of our targets are tests and such
 412     # that shouldn't use the windows subsystem.
 413     "//build/config/win:console",
 414   ]
 415 }
 416
 417 # Executable defaults.
 418 _executable_configs =
 419     _native_compiler_configs + [ "//build/config:default_libs" ]
 420 if (is_win) {
 421   _executable_configs += _windows_linker_configs
 422 } else if (is_mac) {
 423   _executable_configs += [
 424     "//build/config/mac:mac_dynamic_flags",
 425     "//build/config/mac:mac_executable_flags",
 426   ]
 427 } else if (is_linux || is_android) {
 428   _executable_configs += [ "//build/config/gcc:executable_ldconfig" ]
 429   if (is_android) {
 430     _executable_configs += [ "//build/config/android:executable_config" ]
 431   }
 432 }
 433 set_defaults("executable") {
 434   configs = _executable_configs
 435 }
 436
 437 # Static library defaults.
 438 set_defaults("static_library") {
 439   configs = _native_compiler_configs
 440 }
 441
 442 # Shared library defaults (also for components in component mode).
 443 _shared_library_configs =
 444     _native_compiler_configs + [ "//build/config:default_libs" ]
 445 if (is_win) {
 446   _shared_library_configs += _windows_linker_configs
 447 } else if (is_mac) {
 448   _shared_library_configs += [ "//build/config/mac:mac_dynamic_flags" ]
 449 } else if (is_android) {
 450   # Strip native JNI exports from shared libraries by default. Binaries that
 451   # want this can remove this config.
 452   _shared_library_configs +=
 453       [ "//build/config/android:hide_native_jni_exports" ]
 454 }
 455 set_defaults("shared_library") {
 456   configs = _shared_library_configs
 457 }
 458 if (is_component_build) {
 459   set_defaults("component") {
 460     configs = _shared_library_configs
 461   }
 462 }
 463
 464 # Source set defaults (also for components in non-component mode).
 465 set_defaults("source_set") {
 466   configs = _native_compiler_configs
 467 }
 468 if (!is_component_build) {
 469   set_defaults("component") {
 470     configs = _native_compiler_configs
 471   }
 472 }
 473
 474 # Test defaults.
 475 set_defaults("test") {
 476   if (is_android) {
 477     configs = _shared_library_configs
 478   } else {
 479     configs = _executable_configs
 480   }
 481 }
 482
 483 # ==============================================================================
 484 # TOOLCHAIN SETUP
 485 # ==============================================================================
 486 #
 487 # Here we set the default toolchain, as well as the variable host_toolchain
 488 # which will identify the toolchain corresponding to the local system when
 489 # doing cross-compiles. When not cross-compiling, this will be the same as the
 490 # default toolchain.
 491
 492 if (is_win) {
 493   # On windows we use the same toolchain for host and target by default.
 494   if (is_clang) {
 495     host_toolchain = "//build/toolchain/win:clang_$current_cpu"
 496   } else {
 497     host_toolchain = "//build/toolchain/win:$current_cpu"
 498   }
 499
 500   if (current_os == "win") {
 501     set_default_toolchain("$host_toolchain")
 502   } else if (current_cpu == "x64") {  # WinRT x64
 503     set_default_toolchain("//build/toolchain/win:winrt_x64")
 504   } else if (current_cpu == "x86") {  # WinRT x86
 505     set_default_toolchain("//build/toolchain/win:winrt_x86")
 506   }
 507 } else if (is_android) {
 508   if (host_os == "linux") {
 509     # Use clang for the x86/64 Linux host builds.
 510     if (host_cpu == "x86" || host_cpu == "x64") {
 511       host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 512     } else {
 513       host_toolchain = "//build/toolchain/linux:$host_cpu"
 514     }
 515   } else if (host_os == "mac") {
 516     host_toolchain = "//build/toolchain/mac:clang_$host_cpu"
 517   } else {
 518     assert(false, "Unknown host for android cross compile")
 519   }
 520   if (is_clang) {
 521     set_default_toolchain("//build/toolchain/android:clang_$current_cpu")
 522   } else {
 523     set_default_toolchain("//build/toolchain/android:$current_cpu")
 524   }
 525 } else if (is_linux) {
 526   if (is_clang) {
 527     host_toolchain = "//build/toolchain/linux:clang_$host_cpu"
 528     set_default_toolchain("//build/toolchain/linux:clang_$current_cpu")
 529   } else {
 530     host_toolchain = "//build/toolchain/linux:$host_cpu"
 531     set_default_toolchain("//build/toolchain/linux:$current_cpu")
 532   }
 533   if (is_chromeos && cros_use_custom_toolchain) {
 534     set_default_toolchain("//build/toolchain/cros:target")
 535   }
 536 } else if (is_mac) {
 537   host_toolchain = "//build/toolchain/mac:clang_x64"
 538   set_default_toolchain(host_toolchain)
 539 } else if (is_ios) {
 540   host_toolchain = "//build/toolchain/mac:clang_x64"
 541   set_default_toolchain("//build/toolchain/mac:ios_clang_arm")
 542 } else if (is_nacl) {
 543   # TODO(GYP): This will need to change when we get NaCl working
 544   # on multiple platforms, but this whole block of code (how we define
 545   # host_toolchain) needs to be reworked regardless to key off of host_os
 546   # and host_cpu rather than the is_* variables.
 547   host_toolchain = "//build/toolchain/linux:clang_x64"
 548 }
 549
 550 # ==============================================================================
 551 # COMPONENT SETUP
 552 # ==============================================================================
 553
 554 if (is_component_build) {
 555   _component_mode = "shared_library"
 556 } else {
 557   _component_mode = "source_set"
 558 }
 559 template("component") {
 560   target(_component_mode, target_name) {
 561     forward_variables_from(invoker, "*")
 562
 563     # All shared libraries must have the sanitizer deps to properly link in
 564     # asan mode (this target will be empty in other cases).
 565     if (!defined(deps)) {
 566       deps = []
 567     }
 568     deps += [ "//build/config/sanitizers:deps" ]
 569   }
 570 }