sandbox/mac/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/mac/mac_sdk.gni")
   6
   7 component("sandbox") {
   8   sources = [
   9     "bootstrap_sandbox.cc",
  10     "bootstrap_sandbox.h",
  11     "dispatch_source_mach.cc",
  12     "dispatch_source_mach.h",
  13     "launchd_interception_server.cc",
  14     "launchd_interception_server.h",
  15     "mach_message_server.cc",
  16     "mach_message_server.h",
  17     "message_server.h",
  18     "os_compatibility.cc",
  19     "os_compatibility.h",
  20     "policy.cc",
  21     "policy.h",
  22     "xpc.cc",
  23     "xpc.h",
  24     "xpc_message_server.cc",
  25     "xpc_message_server.h",
  26   ]
  27
  28   defines = [ "SANDBOX_IMPLEMENTATION" ]
  29   libs = [ "bsm" ]
  30
  31   deps = [
  32     "//base",
  33   ]
  34
  35   # When the build SDK is 10.6, generate a dynamic stub loader. When the
  36   # SDK is higher, then libxpc.dylib will be loaded automatically as part
  37   # of libSystem, and only forward declarations of private symbols are
  38   # necessary.
  39   if (mac_sdk_version == "10.6") {
  40     deps += [ ":generate_stubs" ]
  41   }
  42 }
  43
  44 generate_stubs_script = "//tools/generate_stubs/generate_stubs.py"
  45 generate_stubs_header = "xpc_stubs_header.fragment"
  46 generate_stubs_sig_public = "xpc_stubs.sig"
  47 generate_stubs_sig_private = "xpc_private_stubs.sig"
  48 generate_stubs_project = "sandbox/mac"
  49 generate_stubs_output_stem = "xpc_stubs"
  50
  51 action("generate_stubs") {
  52   script = generate_stubs_script
  53   sources = [
  54     generate_stubs_sig_public,
  55     generate_stubs_sig_private,
  56   ]
  57   inputs = [
  58     generate_stubs_header,
  59   ]
  60   outputs = [
  61     "$target_gen_dir/$generate_stubs_output_stem.cc",
  62     "$target_gen_dir/$generate_stubs_output_stem.h",
  63   ]
  64   args = [
  65     "-i",
  66     rebase_path(target_gen_dir, root_build_dir),
  67     "-o",
  68     rebase_path(target_gen_dir, root_build_dir),
  69     "-t",
  70     "posix_stubs",
  71     "-e",
  72     rebase_path(generate_stubs_header, root_build_dir),
  73     "-s",
  74     generate_stubs_output_stem,
  75     "-p",
  76     generate_stubs_project,
  77     "-x",
  78     "SANDBOX_EXPORT",
  79   ]
  80   args += rebase_path(sources, root_build_dir)
  81 }
  82
  83 test("sandbox_mac_unittests") {
  84   sources = [
  85     "bootstrap_sandbox_unittest.mm",
  86     "dispatch_source_mach_unittest.cc",
  87     "policy_unittest.cc",
  88     "xpc_message_server_unittest.cc",
  89   ]
  90
  91   libs = [
  92     "CoreFoundation.framework",
  93     "Foundation.framework",
  94   ]
  95
  96   deps = [
  97     ":sandbox",
  98     "//base",
  99     "//base/test:run_all_unittests",
 100     "//testing/gtest",
 101   ]
 102 }